テキストを翻訳する

このクイックスタートでは、ABAP SDK for Google Cloud の SAP BTP エディションを利用して Cloud Translation API v2 を使用し、英語からドイツ語にテキストを翻訳するプログラムの作成方法について説明します。

始める前に

このクイックスタートを実行する前に、自身または管理者によって次の事前準備が完了していることを確認してください。

テキストを翻訳する ABAP クラスを作成する

  1. パッケージを作成します。

    1. ADT で、Project Explorer に移動します。
    2. パッケージ ZLOCAL を右クリックし、[新規] > [ABAP パッケージ] を選択します。

    3. パッケージの次の詳細情報を入力します。

      • 名前: 「ZABAPSDK_TEST」と入力します。
      • 説明: 「ABAP SDK Test Package」と入力します。

    4. [次へ] をクリックします。

    5. [トランスポート リクエストを選択] ダイアログで、[新しいリクエストを作成] チェックボックスをオンにします。

    6. トランスポート リクエストの説明を入力します。

    7. [完了] をクリックします。

  2. Cloud Translation API を呼び出す ABAP クラスを作成します。

    1. ABAP パッケージを右クリックし、[新規] > [ABAP クラス] を選択します。

    2. ABAP クラスの次の詳細情報を入力します。

      • 名前: 「ZGOOG_CL_QS_TRANSLATION」と入力します。
      • 説明: 「Quick start for Translation API」と入力します。

    3. [次へ] をクリックします。

    4. トランスポート リクエストを選択し、[完了] をクリックします。

  3. コードエディタで、デフォルトのコードを次のコード スニペットに置き換えます。

    " --------------------------------------------------------------------
"  Copyright 2024 Google LLC                                         -
"                                                                    -
"  Licensed under the Apache License, Version 2.0 (the "License");   -
"  you may not use this file except in compliance with the License.  -
"  You may obtain a copy of the License at                           -
"      https://www.apache.org/licenses/LICENSE-2.0                   -
"  Unless required by applicable law or agreed to in writing,        -
"  software distributed under the License is distributed on an       -
"  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND,      -
"  either express or implied.                                        -
"  See the License for the specific language governing permissions   -
"  and limitations under the License.                                -
" --------------------------------------------------------------------
class ZCL_QS_TRANSLATE_TEXT definition
  public
  final
  create public .

public section.

  interfaces IF_OO_ADT_CLASSRUN .
ENDCLASS.



CLASS ZCL_QS_TRANSLATE_TEXT IMPLEMENTATION.


  METHOD IF_OO_ADT_CLASSRUN~MAIN.
    DATA ls_input        TYPE /goog/cl_translation_v2=>ty_006.
    DATA lt_translations TYPE /goog/cl_translation_v2=>ty_translations.
    DATA ls_texts        TYPE /goog/cl_translation_v2=>ty_008.
    DATA lo_translate    TYPE REF TO /goog/cl_translation_v2.

    TRY.
        " Open HTTP Connection
        " The client key DEMO_TRANSLATE is an example, replace this with actual value
        lo_translate = NEW #( iv_key_name = 'DEMO_TRANSLATE' ).

        " Pass the text to be translated to the required parameter
        ls_input = VALUE #( format = 'text'
                            source = 'en'
                            target = 'de'
                            q      = VALUE #( ( |The Earth is the third planet from the Sun| ) ) ).

        " Call the API method to translate text
        lo_translate->translate_translations( EXPORTING is_input    = ls_input
                                              IMPORTING es_output   = DATA(ls_output)
                                                        ev_ret_code = DATA(lv_ret_code)
                                                        ev_err_text = DATA(lv_err_text)
                                                        es_err_resp = DATA(ls_err_resp) ).
        IF lo_translate->is_success( lv_ret_code ) = abap_true.
          lt_translations = ls_output-data.
          TRY.
              ls_texts = lt_translations-translations[ 1 ].
              out->write( |Translation Successful| ).
              out->write( |Translated Text is:  { ls_texts-translated_text }| ).
            CATCH cx_sy_itab_line_not_found.
              out->write( |Translation not fetched| ).
          ENDTRY.
        ENDIF.

        " Close HTTP connection
        lo_translate->close( ).

      CATCH /goog/cx_sdk INTO DATA(lo_exception).
        " Handle exception here
    ENDTRY.
  ENDMETHOD.
ENDCLASS.

    DEMO_TRANSLATE はクライアント キー名に置き換えます。

  4. 変更を保存して有効にします。

  5. アプリケーションを実行します。

    1. ABAP クラス ZGOOG_CL_QS_TRANSLATION を選択します。
    2. [実行] > [実行形式] > [ABAP アプリケーション（コンソール）] をクリックします。または、F9 キーを押します。成功すると、次の出力が表示されます。
      'Translation Successful'
'Translated Text is: Die Erde ist der dritte Planet von der Sonne'

次のステップ