Interagire con i flussi di lavoro SAP da Google Chat

Questo documento descrive un'architettura di riferimento per la creazione di app di Google Chat interattive per SAP utilizzando l'edizione on-premise o qualsiasi versione cloud di ABAP SDK for Google Cloud. Con le app di chat interattive, oltre a ricevere notifiche, gli utenti possono eseguire azioni sui flussi di lavoro SAP, ad esempio approvare o rifiutare le richieste, direttamente all'interno di Google Workspace.

Il pubblico di destinazione di questo documento include sviluppatori ABAP, architetti di soluzioni SAP e architetti cloud. Questo documento presuppone che tu abbia dimestichezza con le app di chat disponibili in Google Workspace.

Architettura

Il seguente diagramma mostra un'architettura di riferimento per l'implementazione di app di chat interattive per SAP:

App di chat interattive per SAP

Questa architettura di riferimento include i seguenti componenti:

# Componente Dettagli
1 Processi o transazioni SAP Qualsiasi processo o transazione SAP che deve inviare messaggi agli utenti. È il punto di partenza per attivare la comunicazione tramite Google Chat.
2 ABAP SDK for Google Cloud Agisce da ponte tra i sistemi SAP e Google Cloud, consentendo la comunicazione HTTPS sicura con l'API Google Chat.
3 Progetto dell'app Google Chat Il progetto Google Cloud in cui hai attivato l'API Google Chat e configurato l'app Chat.
4 spazio di Chat

Una stanza dedicata all'interno di Google Chat in cui il sistema SAP può comunicare con gli utenti.

Le app di Chat si trovano in questo spazio e forniscono un stream di informazioni in tempo reale dai tuoi sistemi SAP tramite l'API Google Chat.
5 Progetto Apps Script

Il progetto Apps Script in cui implementi la logica dell'app Chat per ricevere ed elaborare i messaggi.
6 Pub/Sub

Il progetto Apps Script pubblica le azioni utente, come approvazioni o rifiuti, come messaggi in un argomento Pub/Sub.

L'SDK ABAP per Google Cloud utilizza una sottoscrizione Pub/Sub per eseguire il pull di questi messaggi dall'argomento. In questo modo, il sistema SAP può elaborare queste azioni e attivare gli aggiornamenti necessari ai processi aziendali.

Prodotti utilizzati

Questa architettura di riferimento utilizza i seguenti prodotti Google:

  • ABAP SDK for Google Cloud: ti aiuta a sviluppare applicazioni ABAP che connettono i tuoi sistemi SAP ai servizi Google Cloud, come Google Chat.

  • Google Chat: ti aiuta a creare app di chat interattive e collaborative, migliorando la comunicazione e la produttività.

  • Apps Script: ti consente di eseguire l'integrazione e l'automazione delle attività nei prodotti Google.

  • Pub/Sub: ti consente di inviare e ricevere messaggi tra applicazioni indipendenti.

Casi d'uso

Le app di chat interattiva ti consentono di eseguire azioni sui flussi di lavoro SAP, ad esempio approvare o rifiutare le richieste. Il seguente diagramma mostra un pattern di chat interattivo per i flussi di lavoro di approvazione degli ordini di acquisto (OA) e di vendita (OV):

Approvazione del flusso di lavoro delle app di chat interattive

Il seguente elenco mostra alcuni casi d'uso di app di chat interattive per SAP:

  • Gestione degli eventi del flusso di lavoro: puoi interagire con un'app Chat per gestire il tuo flusso di lavoro. Ad esempio, se un ordine di acquisto richiede la tua attenzione, puoi eseguire le seguenti operazioni tramite l'app Chat:

    • Approvare l'ordine
    • Rifiutare l'ordine
    • Richiedi ulteriori dettagli

  • Avvisi di sistema: puoi inviare avvisi a uno spazio di Chat pensato per gli amministratori di sistema per informarli del raggiungimento di varie soglie di sistema. Ad esempio, utilizzo dello spazio su disco, operazioni in esecuzione prolungata, bloccati della cache o scadenza della licenza.

  • Aggiornamenti dello stato dei job: puoi inviare aggiornamenti per i job personalizzati di lunga durata a un gruppo di utenti in attesa del completamento di questi job e che eseguono operazioni di post-elaborazione.

Note sul layout

Quando progetti app di chat per i tuoi casi d'uso, esistono diversi fattori che possono influenzare le tue decisioni di progettazione. Questa sezione fornisce indicazioni per aiutarti a utilizzare questa architettura di riferimento per sviluppare architetture che ti consentano di soddisfare i tuoi requisiti specifici per sicurezza, privacy, conformità e costi.

Configurazione dell'app Google Chat

  • Nome dell'app di Chat: fornisci un nome chiaro e significativo per la tua app di Chat. Per un'esperienza utente senza interruzioni, assicurati che il nome dell'app di Chat rifletta con precisione le sue funzionalità o i servizi con cui è integrata.

  • Fusi orari: uno spazio di Chat può essere condiviso da membri appartenenti a vari fusi orari. Pertanto, è essenziale configurare le app Chat per trasmettere i messaggi in un momento opportuno per tutti gli utenti dello spazio. In alternativa, per avvisi o notifiche importanti, puoi designare membri per gli spazi di Chat con un fuso orario condiviso e creare una logica per determinare a quale spazio l'app Chat può inviare messaggi.

Sicurezza, privacy e conformità

Per mantenere la riservatezza, è fondamentale implementare controlli rigorosi sulla condivisione di informazioni sensibili, come i dati di contatto dei clienti, gli IBAN o altri dati che devono essere noti all'interno degli spazi di Chat. Inoltre, quando vengono aggiunti nuovi utenti agli spazi di Chat, dove vengono aggiunte le app di Chat, è essenziale stabilire norme chiare per garantire una gestione appropriata di questa attività.

Puoi anche prendere in considerazione l'utilizzo dell'API Cloud Data Loss Prevention (DLP) per desensibilizzare i contenuti dei messaggi. Per informazioni su come proteggere i dati aziendali sensibili in SAP utilizzando l'API DLP, consulta Protezione dei dati in SAP con l'API DLP.

Per motivi di sicurezza, assicurati che gli amministratori di Google Workspace seguano le best practice consigliate da Google.

Quote e limiti

L'API Google Chat è un servizio condiviso, pertanto sono applicabili quote e limitazioni. Se superi una quota, ricevi una risposta con codice di stato HTTP 429: Too many requests. Per ulteriori informazioni su quote e limiti, consulta Limiti di utilizzo.

L'API Google Chat non prevede costi di utilizzo, ma Google Chat è un prodotto Google Workspace. Google Workspace, una suite di strumenti di produttività in bundle, include Gmail, Documenti, Fogli, Slides, le app Google Chat e altro ancora. La sua struttura di prezzi è olistica, il che significa che non puoi selezionare e acquistare singoli componenti. Per ulteriori informazioni sui prezzi, vedi Prezzi di Google Workspace.

Opzioni di impostazione della connessione

Per gestire le interazioni all'interno di Google Chat, questa architettura di riferimento utilizza Apps Script come backend. Il codice, ospitato in un progetto Apps Script, deve essere scritto in JavaScript.

In alternativa, puoi creare la tua app di chat interattiva utilizzando le funzioni Cloud Run o App Engine con un endpoint HTTP. Per informazioni su come utilizzare le funzioni Cloud Run per Google Chat, consulta Creare un'app Google Chat HTTP. Per creare la logica dell'app di Chat nelle funzioni Cloud Run, puoi utilizzare le librerie Cloud e scegliere tra più linguaggi, ad esempio Node.js, Java o Python. Dopo aver eseguito il deployment della funzione Cloud Run, nella configurazione dell'app Chat, in Impostazioni di connessione, seleziona URL endpoint HTTP e fornisci l'URL per l'attivatore della funzione Cloud Run.

Prima di iniziare

Prima di implementare una soluzione basata su questa architettura di riferimento, assicurati di aver completato i seguenti prerequisiti:

Configurare un progetto Apps Script

Per ricevere ed elaborare i messaggi, implementa la logica dell'app Chat in un progetto Apps Script. Apps Script fornisce la logica e l'automazione di backend. Ti consente di scrivere codice per gestire eventi come l'estrazione dei messaggi degli utenti, l'elaborazione dei clic sui pulsanti e l'attivazione di azioni a valle.

Per configurare un progetto Apps Script, svolgi i seguenti passaggi:

  1. Vai a Apps Script.

  2. Crea uno script per gestire la logica dell'app Chat per la ricezione ed elaborazione dei messaggi. Per informazioni su come creare uno script, consulta la guida rapida di Google Apps Script.

    Ad esempio, devi scrivere codice JavaScript per gestire vari tipi di funzioni. Il seguente codice campione illustra come gestire l'evento OnCardClicked:

    function onCardClick(event) {
console.info(event);
let message = 'Button Clicked';
// Get the function name from parameter
var functionToCall = event.action.parameters[0].value;
// Get the action name from parameter
var actionTaken = event.action.parameters[1].value;
// Call the function dynamically
if (this[functionToCall]) {
  this[functionToCall](actionTaken);
} else {
  // Handle invalid function name
  console.log('Function not found:', functionToCall);
}
return { "text": message };
}

    Questo codice campione esegue le seguenti funzioni:

    • Leggi il clic sul pulsante: determina il pulsante su cui è stato fatto clic e l'azione prevista dall'utente.
    • Trova il codice corretto da eseguire: utilizza le informazioni del clic sul pulsante per trovare un codice corrispondente all'interno dell'app Chat.
    • Esegue il codice: esegue il codice corrispondente per eseguire l'azione richiesta dall'utente.
    • Gestisce gli errori: se non riesce a trovare il codice corrispondente, viene visualizzato un messaggio di errore.

  3. Collega il tuo progetto Google Cloud al progetto Apps Script. Per informazioni su come collegare i progetti, consulta Collegare il progetto Google Cloud.

  4. Crea un deployment per lo script. Per informazioni su come eseguire il deployment dello script, vedi Creare e gestire i deployment.

  5. Prendi nota dell'ID deployment. Per informazioni su come trovare un ID deployment, consulta Trovare un ID deployment.

Per ulteriori informazioni sulla configurazione del progetto Apps Script, consulta la guida rapida all'app di Chat di Google Apps Script.

Configurare l'app Google Chat

Per configurare l'app Google Chat:

  1. Nella console Google Cloud, cerca "API Google Chat", fai clic su API Google Chat e poi su Gestisci.

    Vai all'API Chat

  2. Fai clic su Configurazione e configura l'app Google Chat:

    1. In Nome dell'app, inserisci Quickstart SAP App.
    2. In URL avatar, inserisci https://developers.google.com/chat/images/quickstart-app-avatar.png.
    3. In Descrizione, inserisci Quickstart app for SAP.

  3. In Impostazioni di connessione, seleziona Apps Script.

  4. Inserisci l'ID di deployment dello script che hai creato nella sezione Configurare un progetto Apps Script.

  5. Fai clic su Salva.

Configurare l'autenticazione per le app Google Chat

Puoi autenticarti nelle app Google Chat in due modi: come app stessa o come utente.

Quando la tua app deve eseguire attività automatiche, ad esempio l'invio di notifiche di sistema senza interazione diretta dell'utente, utilizza un account di servizio. Se vuoi che la tua app agisca per conto di un utente, ad esempio inviando un messaggio come quella persona specifica, devi disporre dell'autenticazione utente. Questo approccio di autenticazione doppia offre flessibilità e controllo sul modo in cui la tua app interagisce con Google Chat.

L'SDK ABAP per Google Cloud ti consente di configurare entrambi i tipi di autenticazione. Per informazioni su come configurare l'autenticazione per le app Google Chat, consulta:

Per informazioni sui metodi dell'API Google Chat e sui relativi ambiti di autorizzazione supportati, vedi Autenticare e autorizzare le app di Chat e le richieste API di Google Chat.

L'architettura di riferimento descritta in questo documento utilizza l'autenticazione come app di chat e utilizza i token di accesso per l'autenticazione.

Per configurare l'autenticazione come app di chat, svolgi i seguenti passaggi:

  1. Nella console Google Cloud, configura la schermata per il consenso OAuth e scegli gli ambiti.
  2. Nella console Google Cloud, crea un account di servizio.
  3. (Facoltativo) Assegna i ruoli IAM all'account di servizio per concedere l'accesso alle risorse del progetto Google Cloud. Per ulteriori informazioni, vedi Gestire l'accesso agli account di servizio.

  4. Nel sistema SAP, configura una chiave client con i seguenti dettagli:

    Campo Descrizione
    Nome della chiave Google Cloud Specifica un nome per la configurazione della chiave client. Ad esempio, ABAP_SDK_CHAT.
    Nome dell'account di servizio Google Cloud

    Specifica il nome dell'account di servizio a cui hai concesso le autorizzazioni per accedere all'API Google Chat. Ad esempio, sap-example-svc-acct@example-project-123456.iam.gserviceaccount.com.
    Ambito Google Cloud Specifica l'ambito di accesso API: https://www.googleapis.com/auth/chat.bot.
    Identificatore progetto Google Cloud Specifica l'ID del progetto Google Cloud contenente l'API Google Chat abilitata.
    Nome del comando Lascia vuoto questo campo.
    Classe di autorizzazione

    Specifica la classe di autorizzazione, se opportuno:

    • Per l'autenticazione tramite token di accesso: /GOOG/CL_AUTH_GOOGLE
    • Per l'autenticazione tramite JWT: /GOOG/CL_AUTH_JWT
    Memorizzazione nella cache dei token

    Il flag che determina se i token di accesso recuperati da Google Cloud vengono memorizzati nella cache o meno.

    Ti consigliamo di attivare la memorizzazione nella cache dei token al termine della configurazione e del test della connessione a Google Cloud. Per ulteriori informazioni sulla memorizzazione nella cache dei token, consulta Attivare la memorizzazione nella cache dei token.
    Secondi di aggiornamento token Il periodo di tempo, in secondi, prima che un token di accesso scada e debba essere aggiornato. Il valore predefinito è 3500.
    Parametro di autorizzazione 1 Lascia vuoto questo campo.
    Parametro di autorizzazione 2 Lascia vuoto questo campo.

Per informazioni dettagliate sulla procedura di configurazione dell'autenticazione, consulta Eseguire l'autenticazione utilizzando i token di accesso o Eseguire l'autenticazione utilizzando i token web JSON.

Aggiungere l'app Google Chat agli spazi

  1. Apri le app Google Chat o Gmail.
  2. Aggiungi l'app Chat a uno spazio di Chat. Per informazioni su come aggiungere app a uno spazio di Chat, consulta Aggiungere app a conversazioni o spazi.

Progettare schede interattive per le azioni utente

Le schede offrono un modo visivamente accattivante e interattivo per presentare le informazioni, migliorando l'esperienza utente complessiva. Possono includere elementi come titoli, immagini, pulsanti e altro ancora, consentendo agli utenti di interagire con i contenuti direttamente all'interno dell'interfaccia di Chat. Ad esempio, una scheda del flusso di lavoro dell'ordine di acquisto potrebbe includere le seguenti informazioni:

  • Numero ordine d'acquisto.
  • Data del documento
  • Tipo di documento
  • Fornitore
  • Tipo di spedizione
  • Link per aprire la visualizzazione dell'ordine di acquisto nell'app SAP Fiori e un pulsante per approvarlo

Per progettare schede interattive utilizzando l'SDK ABAP per Google Cloud, utilizza l'interfaccia personalizzata ZGOOG_IF_CHAT_CARDS_V2 dal repository GitHub. Questa interfaccia personalizzata contiene i tipi ABAP necessari per creare schede. Puoi creare schede come la seguente scheda di esempio del flusso di lavoro degli ordini:

Scheda App di chat

Per saperne di più sulla progettazione dei messaggi delle schede, consulta Creare schede per le app Google Chat.

Per inviare messaggi da un sistema SAP a uno spazio di Chat utilizzando l'SDK ABAP per Google Cloud, utilizza il metodo CREATE_MESSAGES della classe /GOOG/CL_CHAT_V1.

Il seguente esempio di codice mostra come inviare un messaggio della scheda da un sistema SAP a uno spazio di Chat:


REPORT zsend_interactive_card.

DATA lv_client_key TYPE /goog/keyname.
DATA ls_input      TYPE /goog/cl_chat_v1=>ty_072.
DATA lv_space_id   TYPE string.
DATA ls_widget     TYPE zgoog_if_chat_cards_v2=>ty_widget.
DATA ls_section    TYPE zgoog_if_chat_cards_v2=>ty_sections.
DATA ls_card_v2    TYPE zgoog_if_chat_cards_v2=>ty_cards_v2.
DATA ls_card       TYPE /goog/cl_chat_v1=>ty_012.
DATA ls_rb         TYPE zgoog_if_chat_cards_v2=>ty_selection_item.
DATA ls_button     TYPE zgoog_if_chat_cards_v2=>ty_button.
DATA ls_param      TYPE zgoog_if_chat_cards_v2=>ty_action_parameters.

lv_client_key = 'CLIENT_KEY'.
lv_space_id   = 'SPACE_ID'.

TRY.

    DATA(lo_chat) = NEW /goog/cl_chat_v1( iv_key_name = lv_client_key ).
  CATCH /goog/cx_sdk INTO DATA(lo_excp).
    " Handle exception here
ENDTRY.

" Building the Cards Structure
ls_card_v2-header = VALUE zgoog_if_chat_cards_v2=>ty_header(
                              title     = 'Purchase Order Workflow - Level 2 Approval Alert!'
                              subtitle  = 'PO Number: 8700000035'
                              image_url = 'https://developers.google.com/chat/images/quickstart-app-avatar.png' ).
ls_section-header = 'Purchase Order Details'.

ls_widget-decorated_text = VALUE zgoog_if_chat_cards_v2=>ty_decorated_text(
                                     icon = VALUE zgoog_if_chat_cards_v2=>ty_icon( known_icon = 'INVITE' )
                                     text = 'Document Date: 2024-10-23' ).
ls_section-widgets = VALUE #( ( ls_widget ) ).
CLEAR ls_widget.

ls_widget-decorated_text = VALUE zgoog_if_chat_cards_v2=>ty_decorated_text(
    icon = VALUE zgoog_if_chat_cards_v2=>ty_icon(
                     material_icon = VALUE zgoog_if_chat_cards_v2=>ty_material_icon( name = 'category' ) )
    text = 'Document Type: Standard PO'  ).

ls_section-widgets = VALUE #( BASE ls_section-widgets
                              ( ls_widget ) ).
CLEAR ls_widget.

ls_widget-decorated_text = VALUE zgoog_if_chat_cards_v2=>ty_decorated_text(
    icon = VALUE zgoog_if_chat_cards_v2=>ty_icon(
                     material_icon = VALUE zgoog_if_chat_cards_v2=>ty_material_icon( name = 'conveyor_belt' ) )
    text = 'Supplier: 5300000061 - Cymbal Industries'  ).

ls_section-widgets = VALUE #( BASE ls_section-widgets
                              ( ls_widget ) ).
CLEAR ls_widget.

ls_widget-decorated_text = VALUE zgoog_if_chat_cards_v2=>ty_decorated_text(
                                     icon = VALUE zgoog_if_chat_cards_v2=>ty_icon( known_icon = 'TRAIN' )
                                     text = 'Shipping Type: RAIL' ).
ls_section-widgets = VALUE #( BASE ls_section-widgets
                              ( ls_widget ) ).
CLEAR ls_widget.

ls_button = VALUE #( text  = 'Display Purchase Order'
                     color = VALUE zgoog_if_chat_cards_v2=>ty_color( alpha = '1'
                                                                     blue  = '1'
                                                                     green = '0'
                                                                     red   = '1' ) ).

" Replace this with URL for Fiori Application
ls_button-on_click-open_link-url = 'https://developers.google.com/workspace/chat'.
ls_widget-button_list-buttons = VALUE #(  BASE ls_widget-button_list-buttons
                                         ( ls_button ) ).
CLEAR ls_button.

ls_button = VALUE #( text                     = 'Approve Purchase Order'
                     on_click-action-function = 'onCardClick'
                     color                    = VALUE zgoog_if_chat_cards_v2=>ty_color( alpha = '1'
                                                                                        blue  = '0.2'
                                                                                        green = '0.4'
                                                                                        red   = '0' ) ).
ls_param-key   = 'functionToCall'.
ls_param-value = 'sendToPubSub'.  " Replace this with function name on AppsScript
ls_button-on_click-action-parameters = VALUE #( BASE ls_button-on_click-action-parameters
                                                ( ls_param ) ).
CLEAR ls_param.

ls_param-key   = 'action'.
ls_param-value = 'approved'.    " Indicate approval action has taken place
ls_button-on_click-action-parameters = VALUE #( BASE ls_button-on_click-action-parameters
                                                ( ls_param ) ).
CLEAR ls_param.

ls_widget-button_list-buttons = VALUE #(  BASE ls_widget-button_list-buttons
                                         ( ls_button ) ).
CLEAR ls_button.

ls_button = VALUE #( text                     = 'Reject Purchase Order'
                     on_click-action-function = 'onCardClick'
                     color                    = VALUE zgoog_if_chat_cards_v2=>ty_color( alpha = '1'
                                                                                        blue  = '0'
                                                                                        green = '0'
                                                                                        red   = '0.7' ) ).

ls_param-key   = 'functionToCall'.
ls_param-value = 'sendToPubSub'.  " Function name on AppsScript
ls_button-on_click-action-parameters = VALUE #( BASE ls_button-on_click-action-parameters
                                                ( ls_param ) ).
CLEAR ls_param.

ls_param-key   = 'action'.
ls_param-value = 'rejected'.    " Indicate reject action has taken place
ls_button-on_click-action-parameters = VALUE #( BASE ls_button-on_click-action-parameters
                                                ( ls_param ) ).
CLEAR ls_param.

ls_widget-button_list-buttons = VALUE #(  BASE ls_widget-button_list-buttons
                                         ( ls_button ) ).
CLEAR ls_button.

ls_section-widgets = VALUE #( BASE ls_section-widgets
                              ( ls_widget ) ).

ls_card_v2-sections = VALUE #( ( ls_section ) ).

ls_card-card = REF #( ls_card_v2 ).
ls_input-cards_v2 = VALUE #( (  ls_card ) ).

TRY.
    lo_chat->create_messages( EXPORTING iv_p_spaces_id = lv_space_id
                                        is_input       = ls_input
                              IMPORTING es_output      = DATA(ls_output)
                                        ev_ret_code    = DATA(lv_ret_code)
                                        ev_err_text    = DATA(lv_err_text)
                                        es_err_resp    = DATA(ls_err_resp) ).
  CATCH /goog/cx_sdk INTO lo_excp.
    " Handle exception here
ENDTRY.

IF lo_chat->is_error( lv_ret_code ).
  " Handle error here
ELSE.
  " Handle success here
ENDIF.

Sostituisci quanto segue:

  • CLIENT_KEY: la chiave client configurata per l'autenticazione.

  • SPACE_ID: l'ID identificatore univoco dello spazio di Chat. Per trovare l'ID dello spazio di Chat, apri lo spazio di Google Chat nel browser web. Puoi trovare l'ID nell'URL, come illustrato nello screenshot seguente:

    ID spazio delle app di chat

Design alternativo

Per il tuo sistema SAP S/4 HANA o ECC ospitato su Google Cloud, puoi prendere in considerazione la seguente architettura di riferimento alternativa per progettare le tue app di chat interattive:

Opzione di design alternativa per le app di chat interattiva per SAP

Questa architettura di riferimento si basa sulle seguenti considerazioni:

  1. Le procedure o le transazioni SAP di origine responsabili dell'invio di messaggi agli utenti.
  2. L'ABAP SDK for Google Cloud invia messaggi chiamando il metodo dell'API Google Chat: spaces.messages.create.
  3. L'API Google Chat invia i messaggi allo spazio di Chat corrispondente.
  4. Gli utenti dello spazio ricevono notifiche e poi rispondono per eseguire un'azione, ad esempio fare clic su un pulsante.
  5. L'azione utente richiama il progetto Apps Script per gestire l'evento corrispondente.
  6. Il progetto Apps Script invoca l'API Pub/Sub per pubblicare i messaggi.
  7. La funzione Cloud Run elabora i messaggi e pubblica gli eventi utilizzando l'attivatore Eventarc.
  8. La funzione Cloud Run chiama il nodo SICF tramite un connettore VPC serverless.
  9. Il sistema SAP elabora l'evento e attiva le azioni a valle in base alla logica di business definita.

Questa architettura di riferimento richiede l'implementazione della logica in tre livelli:

  • Il livello ABAP per la creazione di un messaggio di chat, la gestione dell'evento e i procedimenti aziendali successivi.
  • Il livello di Apps Script per gestire l'evento nello spazio di Chat e pubblicare i messaggi in un argomento Pub/Sub.
  • Le funzioni Cloud Run ricevono messaggi dalla sottoscrizione Pub/Sub. Se vuoi, puoi formattare i messaggi e chiamare il servizio SICF ospitato sul tuo sistema SAP tramite il connettore VPC.

Passaggi successivi

Collaboratori

Autore: Satish Inamdar | Ingegnere delle applicazioni SAP

Altro collaboratore: Vikash Kumar | Technical Writer