Pubblicare messaggi in Google Cloud Pub/Sub

Questa guida rapida mostra come creare un programma che pubblica un messaggio "Hello World!" in un argomento Pub/Sub utilizzando l'API Pub/Sub.

Prima di iniziare

Prima di eseguire questa guida rapida, assicurati che tu o i tuoi amministratori abbiate completato i seguenti prerequisiti:

  • Concedi all'account di servizio il ruolo IAM roles/pubsub.publisher.

  • Assicurati che l'API Pub/Sub sia abilitata nel tuo progetto Google Cloud.

    Vai alla libreria API

  • Crea un argomento Pub/Sub SAMPLE_TOPIC_01 e aggiungi una sottoscrizione pull SAMPLE_SUB_TOPIC_01 allo stesso. Per maggiori informazioni, vedi Creare un argomento e Creare una sottoscrizione.

Creare un programma per pubblicare messaggi su Google Cloud

  1. Nel sistema SAP, crea un programma eseguibile nel tuo spazio dei nomi personalizzato (ad esempio Z o Y) utilizzando la transazione SE38.

    1. Nella GUI di SAP, inserisci il codice transazione SE38.

    2. Nel campo Programma, inserisci il nome del programma, ad esempio ZDEMO_PUBSUB.

    3. Fai clic su Crea.

    4. Specifica gli attributi del programma:

      1. Nel campo Titolo, inserisci un titolo per il programma, ad esempio Publish messages to a Pub/Sub topic.

      2. Nel campo Tipo, scegli Executable Program.

      3. Fai clic su Salva.

    5. Salva il programma come oggetto locale.

    6. Nell'Editor ABAP, aggiungi il seguente codice:

      **********************************************************************
*  Copyright 2023 Google LLC                                         *
*                                                                    *
*  Licensed under the Apache License, Version 2.0 (the "License");   *
*  you may not use this file except in compliance with the License.  *
*  You may obtain a copy of the License at                           *
*      https://www.apache.org/licenses/LICENSE-2.0                   *
*  Unless required by applicable law or agreed to in writing,        *
*  software distributed under the License is distributed on an       *
*  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND,      *
*  either express or implied.                                        *
*  See the License for the specific language governing permissions   *
*  and limitations under the License.                                *
**********************************************************************

REPORT zr_qs_publish_messages.

* Data Declaration
DATA:
  lv_p_projects_id TYPE string,
  lv_p_topics_id   TYPE string,
  ls_input         TYPE /goog/cl_pubsub_v1=>ty_023.

TRY.
* Instantiate the client stub
    DATA(lo_pubsub) = NEW /goog/cl_pubsub_v1( iv_key_name = 'DEMO_PUBSUB' ).

* Pass the relevant input parameters
    lv_p_topics_id = 'SAMPLE_TOPIC_01'.
    lv_p_projects_id = lo_pubsub->gv_project_id.
    APPEND VALUE #( data = cl_http_utility=>encode_base64( 'Hello World!' ) ) to ls_input-messages.

* Call the API
    CALL METHOD lo_pubsub->publish_topics
      EXPORTING
        iv_p_projects_id = lv_p_projects_id
        iv_p_topics_id   = lv_p_topics_id
        is_input         = ls_input
      IMPORTING
        es_output        = DATA(ls_output)
        ev_ret_code      = DATA(lv_ret_code)
        ev_err_text      = DATA(lv_err_text)
        es_err_resp      = DATA(ls_err_resp).

* Handle the output
    IF lo_pubsub->is_success( lv_ret_code ).
      MESSAGE 'Message was published!' TYPE 'S'.
    ELSE.
      MESSAGE 'Message was not published!' TYPE 'E'.
    ENDIF.

* Close the HTTP Connection
    lo_pubsub->close( ).

  CATCH /goog/cx_sdk INTO DATA(lo_exception).
    MESSAGE lo_exception->get_text( ) TYPE 'E'.
ENDTRY.

      Sostituisci DEMO_PUBSUB con il nome della chiave client.

  2. Esegui l'applicazione in SE38.

  3. Per convalidare i risultati:

    1. Nella console Google Cloud, vai a Pub/Sub.

    2. Seleziona l'abbonamento SAMPLE_SUB_TOPIC_01 e vai alla scheda Messaggi.

    3. Usa la funzionalità PULL per verificare se il messaggio "Hello World!" è stato pubblicato nell'argomento.

Passaggi successivi