Cloud Functions 호출

이 빠른 시작에서는 Cloud Functions API를 사용하여 함수가 수신하는 인수로 구성된 메시지를 게시하는 함수를 호출하는 방법을 보여줍니다.

시작하기 전에

이 빠른 시작을 실행하기 전에 직접 또는 관리자가 다음 기본 요건을 완료했는지 확인합니다.

  • Google Cloud 프로젝트에서 Cloud Functions API가 사용 설정되어 있는지 확인합니다.

    API 라이브러리로 이동

  • SAP 시스템이 호스팅되는 환경에 따라 Cloud Functions 호출 인증을 설정합니다. 자세한 내용은 Cloud Functions 호출을 위한 인증을 참조하세요. 클라이언트 키를 다음과 같이 구성합니다.

    • Cloud 함수 엔드포인트에 액세스하려면 DEMO-CF라는 클라이언트 키를 만듭니다.
    • Cloud 함수를 호출하려면 DEMO-CF-INVOKER라는 클라이언트 키를 만듭니다.

  • Google Cloud 콘솔에서 제공된 인수를 사용하여 메시지를 게시하는 2세대 HTTP 함수 cf-gen2-hello-with-args를 작성합니다.

        exports.helloWorld = (req, res) => {
    let name = req.body.name || req.query.name;
    let full_name = `${req.body.firstname} ${req.body.lastname}`;
    res.status(200).send(`Hello ${name}! Full Name: ${full_name}`);
  };

    HTTP 함수 작성 방법에 대한 자세한 내용은 Cloud Functions 작성을 참조하세요.

Cloud Functions를 호출하는 프로그램 만들기

  1. SAP 시스템에서 SE38 트랜잭션을 사용하여 커스텀 네임스페이스(예: Z 또는 Y)에 실행 가능한 프로그램을 만듭니다.

    1. SAP GUI에서 트랜잭션 코드 SE38을 입력합니다.

    2. 프로그램 필드에 프로그램 이름을 입력합니다(예: ZDEMO_CLOUDFUNC_INVOKER).

    3. 만들기를 클릭합니다.

    4. 프로그램 속성을 지정합니다.

      1. 제목 필드에 프로그램 제목을 입력합니다(예: Invoke Cloud Function using Cloud Function Invoker).

      2. 유형 필드에서 Executable Program을 선택합니다.

      3. 저장을 클릭합니다.

    5. 프로그램을 로컬 객체로 저장합니다.

    6. ABAP 편집기에서 다음 코드를 추가합니다.

      **********************************************************************
*  Copyright 2024 Google LLC                                         *
*                                                                    *
*  Licensed under the Apache License, Version 2.0 (the "License");   *
*  you may not use this file except in compliance with the License.  *
*  You may obtain a copy of the License at                           *
*      https://www.apache.org/licenses/LICENSE-2.0                   *
*  Unless required by applicable law or agreed to in writing,        *
*  software distributed under the License is distributed on an       *
*  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND,      *
*  either express or implied.                                        *
*  See the License for the specific language governing permissions   *
*  and limitations under the License.                                *
**********************************************************************
REPORT zr_qs_cfinvoker.

DATA(lv_cf_name)  = CONV string( 'cf-gen2-hello-with-args' ).
DATA(lv_msg)      = CONV string( '{"firstname": "John", "lastname" : "Doe"}' ).


TRY.
    " Create a Client API stub for Cloud Functions
    DATA(lo_cloudfunc_client) = NEW /goog/cl_cloudfunc_v2( iv_key_name   = 'DEMO_CF' ).
    " Create a Client API stub for Cloud Function Invoker.
    " Internally this uses the Cloud Function instance to fetch the cloud function HTTP endpoint
    DATA(lo_cfinvoker_client) = NEW /goog/cl_cloudfunc_invoker( iv_key_name   = 'DEMO_CF_INVOKER' ).

    " Send additional query parameters as inputs to the cloud function.
    lo_cfinvoker_client->add_common_qparam( iv_name  = 'name'
                                            iv_value = 'Johnny' ).

    lo_cfinvoker_client->invoke(
      EXPORTING
        iv_cf_name      = lv_cf_name            "Cloud Function Name
        iv_cf_location  = 'us-central1'         "Location where the Cloud Function is hosted
        io_cf_instance  = lo_cloudfunc_client   "Instance of cloud Function Client API Stub
        iv_body         = lv_msg                "Input payload to the Cloud Function
        iv_content_type = 'application/json'
        iv_method       = 'POST'
      IMPORTING
        es_output       = DATA(lv_output)
        ev_ret_code     = DATA(lv_ret_code)
        ev_err_text     = DATA(lv_err_text)
        es_err_resp     = DATA(ls_err_resp)
    ).

    IF lo_cfinvoker_client->is_success( iv_code = lv_ret_code ).
      WRITE: / 'HTTP Return Code:', lv_ret_code.
      WRITE: / 'Response:', lv_output. "Output of cloud function
    ELSE.
      WRITE: / 'HTTP Return Code:', lv_ret_code.
      WRITE: / 'Error:', lv_err_text.
    ENDIF.

  CATCH /goog/cx_sdk INTO DATA(lo_exp).
    WRITE: / lo_exp->get_text( ).
ENDTRY.

    다음을 바꿉니다.

    • DEMO_CF: Cloud 함수 엔드포인트에 액세스하는 데 사용되는 클라이언트 키의 이름
    • DEMO_CF_INVOKER: Cloud 함수를 호출하는 데 사용되는 클라이언트 키의 이름

  2. SE38에서 애플리케이션을 실행합니다. 성공하면 다음과 같은 출력이 표시됩니다.

     HTTP Return Code:        200
 Response: Hello Johnny! Full Name: John Doe

다음 단계