翻译文本

本快速入门介绍如何通过 SAP BTP 版本的 ABAP SDK for Google Cloud，使用 Cloud Translation API v2 创建一个程序，以将文本从英语翻译成德语。

准备工作

在运行本快速入门之前，请确保您或您的管理员已满足以下前提条件：

您拥有一个 Google Cloud 账号和项目。
您的项目已启用结算功能。了解如何确认您的项目是否已启用结算功能。
已安装并配置 SAP BTP 版本的 ABAP SDK for Google Cloud。了解如何安装和配置 ABAP SDK for Google Cloud 的 SAP BTP 版本。
已设置用于访问 Google Cloud APIs 的身份验证。了解如何设置身份验证。
您有权访问 SAP BTP、ABAP 环境。
您已在最新的 Eclipse 平台上下载并安装了最新的 ABAP 开发工具 (ADT)。
您已创建 ABAP Cloud 项目。

确保已在 Google Cloud 项目中启用 Cloud Translation API。

转到 API 库

创建 ABAP 类以翻译文本

创建软件包：

注意：如果您已有软件包，则可以使用现有软件包。跳过步骤 1。
1. 在 ADT 中，转到 Project Explorer。
2. 右键点击软件包 ZLOCAL，然后选择新建 > ABAP 软件包。
3. 为软件包输入以下详细信息：
  - 名称：输入 ZABAPSDK_TEST。
  - 说明：输入 ABAP SDK Test Package。
4. 点击下一步。
5. 在选择传输请求对话框中，选中创建新请求复选框。
6. 输入传输请求的说明。
7. 点击完成。
创建一个 ABAP 类以调用 Cloud Translation API：
1. 右键点击 ABAP 软件包，然后选择新建 > ABAP 类。
2. 为 ABAP 类输入以下详细信息：
  - 名称：输入 ZGOOG_CL_QS_TRANSLATION。
  - 说明：输入 Quick start for Translation API。
3. 点击下一步。
4. 选择传输请求，然后点击完成。

在代码编辑器中，将默认代码替换为以下代码段：

CLASS zcl_qs_translate_test DEFINITION
 PUBLIC FINAL
 CREATE PUBLIC.

 PUBLIC SECTION.
   INTERFACES if_oo_adt_classrun.
ENDCLASS.

CLASS zcl_qs_translate_test IMPLEMENTATION.
 METHOD if_oo_adt_classrun~main.
   DATA ls_input        TYPE /goog/cl_translation_v2=>ty_006.
   DATA lt_translations TYPE /goog/cl_translation_v2=>ty_translations.
   DATA ls_texts        TYPE /goog/cl_translation_v2=>ty_008.
   DATA lo_translate    TYPE REF TO /goog/cl_translation_v2.

   TRY.
       " Instantiate API client stub
       lo_translate = NEW #( iv_key_name = 'DEMO_TRANSLATE' ).

       " Pass the text to be translated to the required parameter
       ls_input = VALUE #( format = 'text'
                           source = 'en'
                           target = 'de'
                           q      = VALUE #( ( |The Earth is the third planet from the Sun| ) ) ).

       " Call the API method to translate text
       lo_translate->translate_translations( EXPORTING is_input    = ls_input
                                             IMPORTING es_output   = DATA(ls_output)
                                                       ev_ret_code = DATA(lv_ret_code)
                                                       ev_err_text = DATA(lv_err_text)
                                                       es_err_resp = DATA(ls_err_resp) ).
       IF lo_translate->is_success( lv_ret_code ) = abap_true.
         lt_translations = ls_output-data.
         TRY.
             ls_texts = lt_translations-translations[ 1 ].
             out->write( |Translation Successful| ).
             out->write( |Translated Text is:  { ls_texts-translated_text }| ).
           CATCH cx_sy_itab_line_not_found.
             out->write( |Translation not fetched| ).
         ENDTRY.
       ENDIF.

       " Close HTTP connection
       lo_translate->close( ).

     CATCH /goog/cx_sdk INTO DATA(lo_exception).
       " Handle exception here
   ENDTRY.
 ENDMETHOD.
ENDCLASS.

将 DEMO_TRANSLATE 替换为客户端密钥名称。

保存并启用更改。
运行您的应用：
1. 选择 ABAP 类 ZGOOG_CL_QS_TRANSLATION。
2. 依次点击运行 > 运行方式 > ABAP 应用（控制台）。或者，按 F9。如果创建成功，将显示以下输出：
```
'Translation Successful'
'Translated Text is: Die Erde ist der dritte Planet von der Sonne'
```

后续步骤

阅读使用 SAP BTP 版本的 ABAP SDK for Google Cloud 进行应用开发指南。
在 Cloud 论坛上提出问题并在社区中探讨 ABAP SDK for Google Cloud。