Esta página foi traduzida pela API Cloud Translation.

Prototipagem rápida com o Gemini

A API Generativa Language do Google permite criar protótipos sem problemas usando os modelos Gemini. Com ela, você testa e explora os recursos dos modelos Gemini sem precisar configurar infraestruturas complexas ou gerenciar a implantação de modelos. O Google AI Studio, ferramenta de prototipagem baseada em navegador do Google, usa a API Generative Language para ativar a prototipagem baseada em navegador com modelos generativos.

Com o SDK da Vertex AI para ABAP, você pode usar a API Generative Language, a API Gemini, para iniciar sua jornada de prototipagem diretamente no seu ambiente ABAP. Você precisa de uma chave de API gerada no Google AI Studio para acessar os modelos do Gemini. Só é necessário gerar essa chave de API uma vez.

Gerar uma chave de API

A chave de API gerada pelo Google AI Studio é uma maneira conveniente de autenticar na API Gemini.

Para gerar uma chave de API, siga estas etapas:

No Google AI Studio, abra a página Chaves de API.

consiga uma chave de API
Clique em Criar chave de API.
Se ele for preenchido, leia e confirme o aviso legal e clique em Continuar.
Se estiver preenchido, leia e confirme o lembrete de configuração de segurança.
Na caixa de diálogo Criar chave de API, selecione uma das seguintes opções, conforme apropriado:
- Criar uma chave de API em um novo projeto
- Criar chave de API em um projeto atual
Copie a string da chave e guarde-a com segurança. Você precisa dessa chave de API para configurar a autenticação da API Gemini.
Copie o número do projeto do Google Cloud em que a chave da API é gerada. Você vai precisar dele em uma etapa posterior.

Configurar a autenticação

Para autenticar na API Gemini usando uma chave de API, use um dos seguintes métodos:

Autenticar usando uma chave de API em uma classe de autenticação personalizada

Você pode criar uma classe de autenticação personalizada para manter a chave de API e configurar uma chave de cliente com a classe de autenticação personalizada.

No ambiente SAP BTP, ABAP, crie uma nova classe herdando a classe /GOOG/CL_AUTH_BASE que acompanha o SDK do ABAP for Google Cloud:
1. Na plataforma Eclipse, clique com o botão direito do mouse no pacote em que você quer criar uma classe e clique em New > ABAP Class.
2. No campo Nome, use ZCL_TEST_GEMINI_API.
3. No campo Descrição, insira Authentication Class for testing Gemini API.
4. No campo Superclass, digite /GOOG/CL_AUTH_BASE.
5. Clique em Próxima.
6. Selecione uma solicitação de transporte ou crie uma.
7. Clique em Concluir.
8. No editor, substitua o código existente pelo seguinte:
```
CLASS zcl_test_gemini_api DEFINITION
    PUBLIC
    INHERITING FROM /goog/cl_auth_base FINAL
    CREATE PUBLIC.
    PUBLIC SECTION.
        CONSTANTS: BEGIN OF c_com_scn_sdk,
                                wif     TYPE /goog/comm_scenario VALUE '/GOOG/COM_SDK_WIF',
                                apik_sm TYPE /goog/comm_scenario VALUE '/GOOG/COM_SDK_APIKSM',
                                END OF c_com_scn_sdk.
        METHODS get_access_token REDEFINITION.
PROTECTED SECTION.
PRIVATE SECTION.
ENDCLASS.
CLASS zcl_test_gemini_api IMPLEMENTATION.
    METHOD get_access_token.
        ev_auth_type = CONV #( apikey_sm ).
        ev_token = API_KEY.
    ENDMETHOD.
ENDCLASS.
```
  Substitua API_KEY pela chave de API gerada no Google AI Studio.
  
  Observação: lembre-se de usar suas chaves de API com segurança. Não compartilhe nem as incorpore em códigos que o público possa ver. Para saber mais sobre as práticas recomendadas de proteção da chave de API, consulte Proteger chave de API.
9. Ative a classe Z.
10. Acesse as propriedades dessa classe, a guia Estado da API e libere a API com o estado do contrato C1.
  
  Para mais informações sobre o estado da API, consulte Como liberar objetos de desenvolvimento.
Acesse a plataforma de lançamento do SAP Fiori do sistema BTP ABAP em que o ABAP SDK for Google Cloud está instalado.

Acesse o app SDK do Google: configuração principal e siga estas etapas:

Clique em Criar.

Na caixa de diálogo Criar nova entrada, insira valores para os seguintes campos:

Campo	Descrição
Nome da chave do Google Cloud	Especifique um nome da configuração da chave do cliente, como `GEMINI_QUICK_TEST`.
Nome da conta de serviço do Google Cloud	Deixe esse campo em branco.
Escopo do Google Cloud	Deixe esse campo em branco.
Identificador de projeto do Google Cloud	Especifique o ID do projeto do Google Cloud em que você criou a chave de API.
Número do projeto do Google Cloud	Especifique o número do projeto do Google Cloud em que você criou a chave de API.
Tipo de autenticação	Selecione `Z`.
Classe de autenticação	Selecione a classe `ZCL_TEST_GEMINI_API` que você criou em uma etapa anterior.

Salve a nova entrada.

Anote a chave de cliente. Você usará essa chave de cliente para autenticação.

Executar o exemplo de código

Para conferir os recursos da API Gemini, execute o seguinte código de exemplo:

Na plataforma Eclipse, clique com o botão direito do mouse no pacote em que você quer criar uma classe e clique em New > ABAP Class.
No campo Nome, use ZCL_INVOKE_LLM.
No campo Descrição, use Sample class for testing Gemini API.
Clique em Próxima.
Selecione ou crie uma solicitação de transporte.
Clique em Concluir.

No editor, substitua o código existente pelo seguinte:

CLASS zcl_invoke_llm DEFINITION
PUBLIC FINAL
CREATE PUBLIC.
PUBLIC SECTION.
    INTERFACES if_oo_adt_classrun.
ENDCLASS.
CLASS zcl_invoke_llm IMPLEMENTATION.
METHOD if_oo_adt_classrun~main.
    DATA lv_sys_instruction TYPE string.
    DATA lv_client_key      TYPE /goog/keyname.
    DATA lv_model_id        TYPE string.
    DATA lv_max_tokens      TYPE int4.
    DATA lv_resp_mime_type  TYPE string.
    DATA lv_prompt          TYPE string.
    DATA lv_temperature     TYPE /goog/num_float.
    DATA lv_top_k           TYPE int4.
    DATA lv_top_p           TYPE /goog/num_float.
    DATA ls_input           TYPE /goog/cl_generativelang_v1beta=>ty_045.
    DATA ls_output          TYPE /goog/cl_generativelang_v1beta=>ty_046.
    DATA ls_part            TYPE /goog/cl_generativelang_v1beta=>ty_068.
    DATA lt_parts           TYPE /goog/cl_generativelang_v1beta=>ty_t_068.
    DATA ls_content         TYPE /goog/cl_generativelang_v1beta=>ty_018.
    DATA lv_msg             TYPE string.
    DATA ls_raw             TYPE string.
    DATA lv_err_msg         TYPE string.
    DATA lo_cx_sdk          TYPE REF TO /goog/cx_sdk.

    " TODO Developer: Set values for Mandatory Fields
    lv_model_id = 'gemini-1.5-flash'.  " You can also change the Model ID of your choosing
    lv_client_key = 'GEMINI_QUICK_TEST'.    " Client key configured

    " TODO Developer: Set values for Optional Fields, if required
    " lv_temperature =
    " lv_top_k =
    " lv_top_p =
    " lv_max_tokens =

    " TODO Developer: (Optional) Set the System Instruction
        lv_sys_instruction  = 'You are an Italian Chef in a 5 Star Restaurant'.

    " TODO Developer: (Mandatory) Set the Prompt
        lv_prompt = 'Give me a recipe to make Margarita Pizza'.
    IF lv_temperature IS NOT INITIAL.
        ls_input-generation_config-temperature = lv_temperature.
    ENDIF.
    IF lv_top_k IS NOT INITIAL.
        ls_input-generation_config-top_k = lv_top_k.
    ENDIF.
    IF lv_top_p IS NOT INITIAL.
        ls_input-generation_config-top_p = lv_top_p.
    ENDIF.
    IF lv_max_tokens IS NOT INITIAL.
        ls_input-generation_config-max_output_tokens = lv_max_tokens.
    ENDIF.
    IF lv_sys_instruction IS NOT INITIAL.
        ls_input-system_instruction-role = 'system'.
        ls_part-text = lv_sys_instruction.
        APPEND ls_part TO ls_input-system_instruction-parts.
        CLEAR ls_part.
    ENDIF.
    ls_content-role = 'user'.
    IF lv_prompt IS NOT INITIAL.
        ls_part-text = lv_prompt.
        APPEND ls_part TO ls_content-parts.
        CLEAR ls_part.
    ENDIF.
    APPEND ls_content TO ls_input-contents.
    CLEAR ls_content.
    TRY.
            DATA(lo_llm_invoker) = NEW /goog/cl_generativelang_v1beta( iv_key_name = lv_client_key ).
        CATCH /goog/cx_sdk INTO lo_cx_sdk.
            lv_err_msg = lo_cx_sdk->get_text( ).
out->write( |Exception occurred, reason: { lv_err_msg }| ).
    ENDTRY.
    TRY.
            lo_llm_invoker->generate_content_models( EXPORTING iv_p_models_id = lv_model_id
                                                                                                                    is_input       = ls_input
                                                                                                IMPORTING es_raw         = ls_raw
                                                                                                                    es_output      = ls_output
                                                                                                                    ev_ret_code    = DATA(lv_ret_code)
                                                                                                                    ev_err_text    = DATA(lv_err_text)
                                                                                                                    es_err_resp    = DATA(ls_err_resp) ).
        CATCH /goog/cx_sdk INTO lo_cx_sdk.
            lv_err_msg = lo_cx_sdk->get_text( ).
            out->write( |Exception occurred, reason: { lv_err_msg }| ).
            RETURN.
    ENDTRY.
    IF lo_llm_invoker->is_success( lv_ret_code ) = abap_true.
        ASSIGN ls_output-candidates[ 1 ] TO FIELD-SYMBOL(<ls_candidate>).
        IF sy-subrc = 0.
            lt_parts = <ls_candidate>-content-parts.
            ASSIGN lt_parts[ 1 ] TO FIELD-SYMBOL(<ls_part>).
            IF sy-subrc = 0.
                DATA(lv_response) = <ls_part>-text.
                out->write( lv_response ).
            ELSE.
                out->write( |Model stopped generating response due to finish reason: { <ls_candidate>-finish_reason }| ).
                out->write( |Read more about finish reason in the below link:| ).
                out->write( |https://cloud.google.com/vertex-ai/docs/reference/rest/v1/GenerateContentResponse#FinishReason| ).
            ENDIF.
        ENDIF.
    ELSE.
        out->write( |Error occurred, reason: { lv_ret_code }:{ lv_err_text }| ).
    ENDIF.
ENDMETHOD.
ENDCLASS.

Ative sua turma.
Execute o código ABAP.

Prototipar casos de uso de IA usando ABAP

É possível criar protótipos de aplicativos SAP usando as classes /GOOG/CL_GENERATIVELANGUAGE_V1 e /GOOG/CL_GENERATIVELANG_V1BETA enviadas com o SDK. É possível invocar essas classes no ambiente ABAP usando a chave de cliente que você criou na seção Configurar autenticação.

A seguir

Saiba como instalar e configurar o SDK da Vertex AI para ABAP.
Saiba mais sobre IA generativa na Vertex AI para SAP.
Faça suas perguntas e converse sobre o SDK da Vertex AI para ABAP com a comunidade em Fóruns do Cloud.