Prototipazione rapida con Gemini

L'API Generative Language di Google consente di creare prototipi senza problemi utilizzando i modelli Gemini. Ti consente di testare ed esplorare le funzionalità dei modelli Gemini senza dover configurare un'infrastruttura complessa o gestire il deployment dei modelli. Lo strumento di prototipazione basato su browser di Google Google AI Studio utilizza l'API Generative Language per abilitare la prototipazione basata su browser con modelli generativi.

Con l'SDK Vertex AI per ABAP, puoi utilizzare l'API di linguaggio generativo (API Gemini) per iniziare il tuo percorso di prototipazione direttamente dall'ambiente ABAP. Per accedere ai modelli Gemini, hai bisogno di una chiave API generata da Google AI Studio. Devi generare questa chiave API una sola volta.

Genera una chiave API

La chiave API generata da Google AI Studio offre un modo pratico per eseguire l'autenticazione nell'API Gemini.

Per generare una chiave API, svolgi i seguenti passaggi:

  1. In Google AI Studio, apri la pagina Chiavi API.

    Ottieni una chiave API

  2. Fai clic su Crea chiave API.

  3. Se sono stati compilati, leggi e accetta l'avviso legale, poi fai clic su Continua.

  4. Se compilato, leggi e conferma il promemoria relativo all'impostazione di sicurezza.

  5. Nella finestra di dialogo Crea chiave API, seleziona una delle seguenti opzioni, come appropriato:

    • Crea chiave API nel nuovo progetto
    • Creare una chiave API in un progetto esistente

  6. Copia la stringa della chiave e tienila al sicuro. Questa chiave API è necessaria per configurare l'autenticazione all'API Gemini.

  7. Copia il numero del progetto Google Cloud in cui viene generata la chiave API. Servirà in un secondo momento.

Configura l'autenticazione

Per eseguire l'autenticazione nell'API Gemini utilizzando una chiave API, utilizza uno dei seguenti metodi:

Esegui l'autenticazione utilizzando una chiave API archiviata in SAP SSF

Per proteggere la chiave API, puoi archiviarla in SAP SSF e configurare una chiave client con la classe di autenticazione SSF. Puoi utilizzare questa chiave client per accedere all'API Gemini. Per ulteriori informazioni, vedi:

Esegui l'autenticazione utilizzando una chiave API tramite una classe di autenticazione personalizzata

In alternativa, puoi creare una classe di autenticazione personalizzata per conservare la chiave API e configurare una chiave client con la classe di autenticazione personalizzata.

Versione on-premise o qualsiasi versione cloud

  1. Nel sistema SAP, crea una classe Z implementando l'interfaccia /GOOG/IF_AUTH fornita con l'SDK ABAP per Google Cloud:

    1. In SAP GUI, esegui il codice transazione SE24.
    2. Nel campo Tipo di oggetto, digita un nome, ad esempio Z_TEST_GEMINI_API, quindi fai clic su Crea.
    3. Assicurati che Tipo di oggetto sia Classe e poi fai clic su OK.
    4. Nel campo Descrizione, fornisci una descrizione della classe, ad esempio Class for authentication to Google AI Studio, quindi salvala come Oggetto locale o in una Richiesta di trasporto.
    5. Apri la scheda Interfacce, aggiungi l'interfaccia /GOOG/IF_AUTH e premi Invio.
    6. Apri la scheda Metodi. I metodi dell'interfaccia /GOOG/IF_AUTH vengono implementati automaticamente nella classe Z.
    7. Fai doppio clic sul metodo /GOOG/IF_AUTH~GET_ACCESS_TOKEN.

    8. Nel metodo /GOOG/IF_AUTH~GET_ACCESS_TOKEN, aggiungi il seguente codice:

      ev_auth_type = /goog/if_auth=>c_auth_type_apik_ssf.
cv_token = 'API_KEY'.
GET TIME STAMP FIELD ev_logtime.

      Sostituisci API_KEY con la chiave API generata in Google AI Studio.

    9. Attiva il tuo corso Z.

  2. Nel sistema SAP, crea una configurazione della chiave client:

    1. In SAP GUI, esegui il codice transazione /GOOG/SDK_IMG.

      In alternativa, esegui il codice transazione SPRO e poi fai clic su Immagine di riferimento SAP.

    2. Fai clic su ABAP SDK for Google Cloud > Impostazioni di base > Configura chiave client.

    3. Fai clic su Nuove voci.

    4. Inserisci i valori per i seguenti campi:

    Campo Descrizione
    Nome della chiave Google Cloud Specifica un nome per la configurazione della chiave client, ad esempio TEST_GEMINI_API.
    Nome dell'account di servizio Google Cloud Lascia vuoto questo campo.
    Ambito Google Cloud Lascia vuoto questo campo.
    Identificatore progetto Google Cloud Specifica il numero del progetto Google Cloud in cui è archiviata la chiave API.
    Nome comando Lascia vuoto questo campo.
    Classe di autorizzazione Specifica la classe Z che hai creato nel passaggio precedente, ad esempio Z_TEST_GEMINI_API.
    Memorizzazione nella cache dei token

    Lascia vuoto questo campo.
    Secondi di aggiornamento token Lascia vuoto questo campo.
    Parametro di autorizzazione 1 Lascia vuoto questo campo.
    Parametro di autorizzazione 2 Lascia vuoto questo campo.
    1. Salva la nuova voce.

  3. Prendi nota della chiave client. Utilizza questa chiave client per l'autenticazione.

Versione SAP BTP

  1. Nell'ambiente ABAP di SAP BTP, crea una nuova classe ereditando la classe /GOOG/CL_AUTH_BASE fornita con l'SDK ABAP per Google Cloud:

    1. Nella piattaforma Eclipse, fai clic con il tasto destro del mouse sul pacchetto in cui vuoi creare una classe, quindi fai clic su Nuovo > Classe ABAP.
    2. Nel campo Nome, inserisci ZCL_TEST_GEMINI_API.
    3. Nel campo Descrizione, inserisci Authentication Class for testing Gemini API.
    4. Nel campo Superclass (Superclasse), inserisci /GOOG/CL_AUTH_BASE.
    5. Fai clic su Avanti.
    6. Seleziona una Richiesta di trasporto o creane una nuova.
    7. Fai clic su Fine.

    8. Nell'editor, sostituisci il codice esistente con il seguente:

      CLASS zcl_test_gemini_api DEFINITION
  PUBLIC
  INHERITING FROM /goog/cl_auth_base FINAL
  CREATE PUBLIC.
  PUBLIC SECTION.
    CONSTANTS: BEGIN OF c_com_scn_sdk,
                 wif     TYPE /goog/comm_scenario VALUE '/GOOG/COM_SDK_WIF',
                 apik_sm TYPE /goog/comm_scenario VALUE '/GOOG/COM_SDK_APIKSM',
                 END OF c_com_scn_sdk.
    METHODS get_access_token REDEFINITION.
 PROTECTED SECTION.
 PRIVATE SECTION.
ENDCLASS.
CLASS zcl_test_gemini_api IMPLEMENTATION.
  METHOD get_access_token.
    ev_auth_type = CONV #( apikey_sm ).
    ev_token = API_KEY.
  ENDMETHOD.
ENDCLASS.

      Sostituisci API_KEY con la chiave API che hai generato in Google AI Studio.

    9. Attiva il tuo corso Z.

    10. Vai alle proprietà di questa classe, vai alla scheda Stato API e poi rilascia l'API con lo stato del contratto C1.

      Per ulteriori informazioni sullo stato dell'API, consulta Releasing Development Objects.

  2. Accedi al launchpad SAP Fiori del sistema ABAP BTP in cui è installato l'SDK ABAP per Google Cloud.

  3. Accedi all'app Google SDK: Main Configuration (SDK Google: configurazione principale) ed esegui i seguenti passaggi:

    1. Fai clic su Crea.

    2. Nella finestra di dialogo Crea nuova voce, inserisci i valori per i seguenti campi:

      Campo Descrizione
      Nome della chiave Google Cloud Specifica un nome per la configurazione della chiave client, ad esempio GEMINI_QUICK_TEST.
      Nome dell'account di servizio Google Cloud Lascia vuoto questo campo.
      Ambito Google Cloud Lascia vuoto questo campo.
      Identificatore progetto Google Cloud Specifica l'ID progetto del progetto Google Cloud in cui hai creato la chiave API.
      Numero del progetto Google Cloud Specifica il numero del progetto Google Cloud in cui hai creato la chiave API.
      Tipo di autenticazione Seleziona Z.
      Authentication Class Seleziona il corso ZCL_TEST_GEMINI_API che hai creato in un passaggio precedente.

    3. Salva la nuova voce.

  4. Prendi nota della chiave client. Utilizza questa chiave client per l'autenticazione.

Esegui il codice campione

Versione on-premise o qualsiasi versione cloud

Puoi esplorare le funzionalità dell'API Gemini utilizzando la demo di AI Studio fornita con l'SDK Vertex AI per ABAP.

Per eseguire la demo di AI Studio, segui questi passaggi:

  1. In SAP GUI, esegui il codice transazione /GOOG/SDK_IMG.

    In alternativa, esegui il codice transazione SPRO e poi fai clic su Immagine di riferimento SAP.

  2. Vai ad ABAP SDK for Google Cloud > Demo.

  3. Apri SDK Vertex AI: demo: prototipazione con l'API di linguaggio generativo.

  4. Nel campo Chiave client, inserisci la chiave client che hai creato nella sezione Configurare l'autenticazione.

  5. Nel campo Model ID, inserisci l'ID del modello LLM che vuoi utilizzare, ad esempio gemini-1.5-flash. Per informazioni sui modelli disponibili, consulta Varianti del modello.

  6. Se vuoi, specifica i seguenti parametri di generazione, a seconda dei casi:

    • Numero massimo di token di output
    • Tipo MIME di risposta
    • Temperatura
    • TopK
    • TopP

    Per informazioni su questi parametri di generazione del modello, consulta Eseguire esperimenti con i valori dei parametri.

  7. Nel campo Inserisci istruzioni di sistema, fornisci un'istruzione di sistema.

  8. Nel campo Inserisci prompt, fornisci il prompt di input.

  9. Esegui il programma. L'area Risposta dall'LLM mostra l'output generato.

Versione SAP BTP

Puoi esplorare le funzionalità dell'API Gemini eseguendo il seguente codice campione:

  1. Nella piattaforma Eclipse, fai clic con il tasto destro del mouse sul pacchetto in cui vuoi creare una classe, quindi fai clic su Nuovo > Classe ABAP.

  2. Nel campo Nome, inserisci ZCL_INVOKE_LLM.

  3. Nel campo Descrizione, inserisci Sample class for testing Gemini API.

  4. Fai clic su Avanti.

  5. Seleziona una richiesta di trasporto o creane una nuova.

  6. Fai clic su Fine.

  7. Nell'editor, sostituisci il codice esistente con il seguente:

    CLASS zcl_invoke_llm DEFINITION
 PUBLIC FINAL
 CREATE PUBLIC.
 PUBLIC SECTION.
   INTERFACES if_oo_adt_classrun.
ENDCLASS.
CLASS zcl_invoke_llm IMPLEMENTATION.
 METHOD if_oo_adt_classrun~main.
   DATA lv_sys_instruction TYPE string.
   DATA lv_client_key      TYPE /goog/keyname.
   DATA lv_model_id        TYPE string.
   DATA lv_max_tokens      TYPE int4.
   DATA lv_resp_mime_type  TYPE string.
   DATA lv_prompt          TYPE string.
   DATA lv_temperature     TYPE /goog/num_float.
   DATA lv_top_k           TYPE int4.
   DATA lv_top_p           TYPE /goog/num_float.
   DATA ls_input           TYPE /goog/cl_generativelang_v1beta=>ty_045.
   DATA ls_output          TYPE /goog/cl_generativelang_v1beta=>ty_046.
   DATA ls_part            TYPE /goog/cl_generativelang_v1beta=>ty_068.
   DATA lt_parts           TYPE /goog/cl_generativelang_v1beta=>ty_t_068.
   DATA ls_content         TYPE /goog/cl_generativelang_v1beta=>ty_018.
   DATA lv_msg             TYPE string.
   DATA ls_raw             TYPE string.
   DATA lv_err_msg         TYPE string.
   DATA lo_cx_sdk          TYPE REF TO /goog/cx_sdk.

   " TODO Developer: Set values for Mandatory Fields
   lv_model_id = 'gemini-1.5-flash'.  " You can also change the Model ID of your choosing
   lv_client_key = 'GEMINI_QUICK_TEST'.    " Client key configured

   " TODO Developer: Set values for Optional Fields, if required
   " lv_temperature =
   " lv_top_k =
   " lv_top_p =
   " lv_max_tokens =

   " TODO Developer: (Optional) Set the System Instruction
    lv_sys_instruction  = 'You are an Italian Chef in a 5 Star Restaurant'.

   " TODO Developer: (Mandatory) Set the Prompt
    lv_prompt = 'Give me a recipe to make Margarita Pizza'.
   IF lv_temperature IS NOT INITIAL.
     ls_input-generation_config-temperature = lv_temperature.
   ENDIF.
   IF lv_top_k IS NOT INITIAL.
     ls_input-generation_config-top_k = lv_top_k.
   ENDIF.
   IF lv_top_p IS NOT INITIAL.
     ls_input-generation_config-top_p = lv_top_p.
   ENDIF.
   IF lv_max_tokens IS NOT INITIAL.
     ls_input-generation_config-max_output_tokens = lv_max_tokens.
   ENDIF.
   IF lv_sys_instruction IS NOT INITIAL.
     ls_input-system_instruction-role = 'system'.
     ls_part-text = lv_sys_instruction.
     APPEND ls_part TO ls_input-system_instruction-parts.
     CLEAR ls_part.
   ENDIF.
   ls_content-role = 'user'.
   IF lv_prompt IS NOT INITIAL.
     ls_part-text = lv_prompt.
     APPEND ls_part TO ls_content-parts.
     CLEAR ls_part.
   ENDIF.
   APPEND ls_content TO ls_input-contents.
   CLEAR ls_content.
   TRY.
       DATA(lo_llm_invoker) = NEW /goog/cl_generativelang_v1beta( iv_key_name = lv_client_key ).
     CATCH /goog/cx_sdk INTO lo_cx_sdk.
       lv_err_msg = lo_cx_sdk->get_text( ).
out->write( |Exception occurred, reason: { lv_err_msg }| ).
   ENDTRY.
   TRY.
       lo_llm_invoker->generate_content_models( EXPORTING iv_p_models_id = lv_model_id
                                                          is_input       = ls_input
                                                IMPORTING es_raw         = ls_raw
                                                          es_output      = ls_output
                                                          ev_ret_code    = DATA(lv_ret_code)
                                                          ev_err_text    = DATA(lv_err_text)
                                                          es_err_resp    = DATA(ls_err_resp) ).
     CATCH /goog/cx_sdk INTO lo_cx_sdk.
       lv_err_msg = lo_cx_sdk->get_text( ).
       out->write( |Exception occurred, reason: { lv_err_msg }| ).
       RETURN.
   ENDTRY.
   IF lo_llm_invoker->is_success( lv_ret_code ) = abap_true.
     ASSIGN ls_output-candidates[ 1 ] TO FIELD-SYMBOL(<ls_candidate>).
     IF sy-subrc = 0.
       lt_parts = <ls_candidate>-content-parts.
       ASSIGN lt_parts[ 1 ] TO FIELD-SYMBOL(<ls_part>).
       IF sy-subrc = 0.
         DATA(lv_response) = <ls_part>-text.
         out->write( lv_response ).
       ELSE.
         out->write( |Model stopped generating response due to finish reason: { <ls_candidate>-finish_reason }| ).
         out->write( |Read more about finish reason in the below link:| ).
         out->write( |https://cloud.google.com/vertex-ai/docs/reference/rest/v1/GenerateContentResponse#FinishReason| ).
       ENDIF.
     ENDIF.
   ELSE.
     out->write( |Error occurred, reason: { lv_ret_code }:{ lv_err_text }| ).
   ENDIF.
 ENDMETHOD.
ENDCLASS.

  8. Attiva il corso.

  9. Esegui il codice ABAP.

Creare prototipi di casi d'uso dell'IA utilizzando ABAP

Puoi creare prototipi di applicazioni SAP utilizzando le classi /GOOG/CL_GENERATIVELANGUAGE_V1 e /GOOG/CL_GENERATIVELANG_V1BETA fornite con l'SDK. Puoi richiamare queste classi dal tuo ambiente ABAP utilizzando la chiave client che hai creato nella sezione Configurare l'autenticazione.

Passaggi successivi