Dokumen ini menjelaskan arsitektur referensi untuk melindungi data perusahaan sensitif di SAP menggunakan Cloud Data Loss Prevention (DLP) API dengan edisi SAP BTP ABAP SDK untuk Google Cloud.
Sangat penting untuk melindungi data perusahaan yang sensitif seperti informasi identitas pribadi (PII) yang Anda simpan di SAP. Membagikan data perusahaan sensitif dari SAP kepada orang atau sistem yang salah dapat merusak reputasi perusahaan Anda dan menyebabkan kerugian finansial. DLP API memberikan cara yang andal dan fleksibel untuk menambahkan lapisan perlindungan untuk data sensitif. API ini dapat menemukan, mengklasifikasikan, dan menghapus identitas informasi sensitif sebelum disimpan di atau dikirim dari SAP. Fitur ini membantu Anda mengidentifikasi dan mengamankan informasi rahasia secara proaktif, mengurangi risiko pelanggaran data, dan memastikan kepatuhan terhadap peraturan privasi.
Audiens yang dituju untuk dokumen ini mencakup developer ABAP, arsitek solusi SAP, dan arsitek cloud yang tanggung jawabnya mencakup keamanan data, pemrosesan data, atau analisis data. Dokumen ini mengasumsikan bahwa Anda sudah memahami pemrosesan data dan privasi data, Perlindungan Data Sensitif, dan konsep terkait, seperti InfoTypes dan detektor infoType.
Arsitektur
Diagram berikut menunjukkan arsitektur referensi untuk solusi DLP, yang mencakup komponen dari lingkungan SAP BTP ABAP dan Google Cloud.
Arsitektur solusi DLP ini mencakup komponen berikut:
| Komponen | Subsistem | Detail |
|---|---|---|
| 1 | Sumber input | Berfungsi sebagai titik entri untuk data. |
| 2 | Layanan klien | Class ABAP yang berinteraksi dengan semua komponen lainnya. Aplikasi ini menerima data sumber, mengirim data ke DLP API melalui ABAP SDK untuk Google Cloud guna diproses, dan menyimpan data yang diproses di datastore SAP. |
| 3 | ABAP SDK untuk Google Cloud | ABAP SDK untuk Google Cloud edisi SAP BTP untuk mengakses DLP API. |
| 4 | DLP API | DLP API menyediakan berbagai metode transformasi untuk de-identifikasi PII. |
| 5 | Datastore target | Sistem SAP ERP, yang berjalan di cloud atau di lokal, tempat data disimpan setelah PII diproses dan dideidentifikasi. |
Produk yang digunakan
Arsitektur referensi ini menggunakan produk Google Cloud berikut:
Kasus penggunaan
Bagian ini memberikan contoh kasus penggunaan yang dapat Anda gunakan untuk DLP API guna melindungi data perusahaan sensitif di SAP.
Mematuhi peraturan privasi data
Organisasi sering kali diwajibkan untuk mende-identifikasi data sensitif. Ada banyak kebijakan pemerintah seperti GDPR dan DPDP, yang mewajibkan PII tidak disimpan dalam kondisi tertentu.
Biaya
Untuk mengetahui perkiraan biaya resource Google Cloud yang digunakan oleh DLP API, lihat perkiraan yang telah dihitung sebelumnya di Kalkulator Harga Google Cloud.
Alternatif desain
Meskipun dokumen ini berfokus pada ABAP SDK untuk Google Cloud edisi SAP BTP, Anda dapat memperoleh hasil yang serupa dengan menggunakan ABAP SDK untuk Google Cloud edisi cloud atau lokal. Dalam penyiapan ini, Anda dapat menyimpan data sensitif (PII) yang diproses dan dide-identifikasi dalam sistem SAP lokal.
Deployment
Bagian ini menunjukkan cara men-deploy solusi yang melindungi data sensitif selama pembuatan partner bisnis (orang) di sistem SAP Anda. Berdasarkan konfigurasi yang ditetapkan oleh organisasi Anda, solusi ini dapat menyamarkan, menghapus identifikasi, atau menganonimkan data.
Sebelum memulai
Sebelum menerapkan solusi berdasarkan arsitektur referensi ini, pastikan Anda telah menyelesaikan prasyarat berikut:
Anda memiliki akun dan project Google Cloud.
Penagihan diaktifkan untuk project Anda. Untuk informasi tentang cara mengonfirmasi bahwa penagihan diaktifkan untuk project Anda, lihat Memverifikasi status penagihan project.
ABAP SDK untuk Google Cloud edisi SAP BTP telah diinstal dan dikonfigurasi.
Autentikasi untuk mengakses Google Cloud API sudah disiapkan. Untuk informasi tentang cara menyiapkan autentikasi, lihat Menyiapkan autentikasi untuk ABAP SDK edisi SAP BTP untuk Google Cloud.
DLP API diaktifkan di project Google Cloud Anda.
Mengimplementasikan layanan klien untuk de-identifikasi PII
Input dari sumber data diproses di layanan klien yang Anda terapkan dalam Lingkungan ABAP SAP BTP. Layanan klien ini dapat terdiri dari subkomponen berikut:
- Konfigurasi aturan: Menyimpan aturan bisnis yang perlu diterapkan untuk berbagai jenis kolom yang relevan dengan PII.
- Modul Proxy DLP: Memanggil DLP API melalui ABAP SDK edisi SAP BTP untuk Google Cloud.
Konfigurasi aturan
Di lingkungan SAP BTP ABAP, Anda membuat tabel konfigurasi untuk mempertahankan aturan transformasi yang perlu diterapkan untuk berbagai jenis kolom yang relevan dengan PII. Di lingkungan produksi, Anda dapat menggunakan alat seperti SAP Fiori untuk mengelola data dalam tabel ini.
Anda dapat menerapkan contoh aturan berikut:
- Setiap kolom dengan alamat email harus diganti dengan nilai dummy.
- Setiap kolom yang berisi nomor telepon harus disamarkan.
- Kolom apa pun yang berisi komentar, catatan, atau komentar tidak boleh berisi informasi apa pun yang terkait dengan alamat email.
- Setiap kolom dengan detail rekening bank harus ditokenisasi menggunakan metode de-identifikasi berbasis kripto.
Berikut adalah definisi contoh tabel konfigurasi:
define table zgoog_dlp_config {
key client : abap.clnt not null;
key keyword : abap.char(60) not null;
key infotype : abap.char(60) not null;
surrogate_infotype : abap.char(60);
common_alphabhet : abap.char(20);
masking_char : abap.char(1);
number_to_mask : int4;
}
Contoh berikut menunjukkan contoh aturan transformasi:
lt_dlp_config = VALUE #(
( client = sy-mandt keyword = 'EMAIL' infotype = 'EMAIL_ADDRESS' )
( client = sy-mandt keyword = 'PHONE NUMBER' infotype = 'PHONE_NUMBER' number_to_mask = 5 masking_char = '*' )
( client = sy-mandt keyword = 'REMARKS' infotype = 'EMAIL_ADDRESS' )
( client = sy-mandt keyword = 'REMARKS' infotype = 'PHONE_NUMBER' )
( client = sy-mandt keyword = 'BANK ACCOUNT' infotype = 'FINANCIAL_ACCOUNT_NUMBER' surrogate_infotype = 'ACCOUNT' common_alphabhet = 'ALPHA_NUMERIC' )
).
Modul proxy DLP
Anda dapat membuat subkomponen khusus yang diberi nama modul proxy DLP. Modul ini dapat berupa class ABAP atau layanan REST. Fungsi utamanya adalah untuk menghapus identifikasi PII menggunakan aturan transformasi yang Anda tentukan sebelumnya.
Modul proxy DLP menggunakan metode DEIDENTIFY_CONTENT dari class /GOOG/CL_DLP_V2 dalam edisi SAP BTP ABAP SDK untuk Google Cloud.
Bagian berikut menunjukkan contoh implementasi cara menggunakan modul proxy DLP untuk penghapusan identifikasi PII dalam berbagai skenario.
Penggantian: Mengganti nilai sensitif yang terdeteksi dengan nilai pengganti yang ditentukan
Untuk mengganti ID email yang terdeteksi dengan nilai generik, lakukan langkah-langkah berikut:
Buat objek klien untuk class
/GOOG/CL_DLP_V2.Gunakan tabel konfigurasi untuk menentukan jenis transformasi yang akan diterapkan.
Untuk menyamarkan ID email, ganti dengan nilai pengganti seperti
EMAIL_ID@EXAMPLE.COM.Panggil DLP API.
Gunakan metode
DEIDENTIFY_CONTENTdengan semua parameter yang relevan, termasuk nilai penggantian, dan tampilkan output ke layanan klien.
Contoh kode berikut menggambarkan langkah-langkah sebelumnya:
DATA: ls_input TYPE /goog/cl_dlp_v2=>ty_055,
ls_transformations TYPE /goog/cl_dlp_v2=>ty_100.
TRY.
DATA(lo_client) = NEW /goog/cl_dlp_v2( iv_key_name = 'CLIENT_KEY' ).
DATA(lv_p_projects_id) = CONV string( lo_client->gv_project_id ).
"As a developer, you need to read the configuration into mt_dlp_config
TRY.
"As a developer, you need to read the configuration
DATA(ls_dlp_config) = mt_dlp_config[ keyword = iv_input_type ].
"Populate the input parameters to DLP API for replacement
INSERT VALUE #( name = ls_dlp_config-infotype ) INTO TABLE ls_input-inspect_config-info_types.ls_transformations-primitive_transformation-replace_config-new_value-string_value = 'REPLACEMENT_VALUE'.
INSERT ls_transformations INTO TABLE ls_input-deidentify_config-info_type_transformations-transformations.
ls_input-item-value = iv_input_value.
"Call DLP API client stub
TRY.
lo_client->deidentify_content(
EXPORTING
iv_p_projects_id = lv_p_projects_id
is_input = ls_input
IMPORTING
es_output = DATA(ls_output)
ev_ret_code = DATA(lv_ret_code)
ev_err_text = DATA(lv_err_text)
).
CATCH /goog/cx_sdk INTO DATA(lx_sdk_exception).
ev_message = lx_sdk_exception->get_text( ).
ENDTRY.
IF lo_client->is_success( lv_ret_code ).
ev_message = lv_err_text.
ELSE.
ev_output_value = ls_output-item-value.
ENDIF.
CATCH cx_sy_itab_line_not_found INTO DATA(lx_not_found).
ev_output_value = iv_input_value.
ENDTRY.
"Close the http client
lo_client->close_http_client( ).
CATCH /goog/cx_sdk INTO DATA(lx_sdk).
ev_message = lx_sdk->get_text( ).
ENDTRY.
Ganti kode berikut:
CLIENT_KEY: Kunci klien yang dikonfigurasi untuk autentikasi.REPLACEMENT_VALUE: Nilai pengganti, sepertiEMAIL_ID@EXAMPLE.COM.
Penyamaran: Menghapus semua atau sebagian nilai sensitif yang terdeteksi
Untuk menghapus semua atau sebagian nilai sensitif yang terdeteksi, lakukan langkah-langkah berikut:
Buat objek klien untuk class
/GOOG/CL_DLP_V2.Gunakan tabel konfigurasi untuk menentukan jenis transformasi yang akan diterapkan.
Tentukan untuk menghapus semua atau sebagian nilai sensitif yang terdeteksi.
Panggil DLP API.
Gunakan metode
DEIDENTIFY_CONTENTdengan semua parameter yang relevan dan tampilkan output ke layanan klien.
DATA: ls_input TYPE /goog/cl_dlp_v2=>ty_055,
ls_transformations TYPE /goog/cl_dlp_v2=>ty_100,
lo_redact TYPE REF TO data.
DATA(lo_client) = NEW /goog/cl_dlp_v2( iv_key_name = 'CLIENT_KEY' ).
DATA(lv_p_projects_id) = CONV string( lo_client->gv_project_id ).
"As a developer, you need to read the configuration into mt_dlp_config
TRY.
"Read the configuration
DATA(ls_dlp_config) = mt_dlp_config[ keyword = iv_input_type ].
"Populate the input parameters to DLP API for redaction
CREATE DATA lo_redact TYPE REF TO string.
INSERT VALUE #( name = ls_dlp_config-infotype ) INTO TABLE ls_input-inspect_config-info_types.
INSERT VALUE #( name = ls_dlp_config-infotype ) INTO TABLE ls_transformations-info_types.
ls_transformations-primitive_transformation-redact_config = lo_redact.
INSERT ls_transformations INTO TABLE ls_input-deidentify_config-info_type_transformations-transformations.
ls_input-item-value = iv_input_value.
"Call DLP API client stub
TRY.
lo_client->deidentify_content(
EXPORTING
iv_p_projects_id = lv_p_projects_id
is_input = ls_input
IMPORTING
es_output = DATA(ls_output)
ev_ret_code = DATA(lv_ret_code)
ev_err_text = DATA(lv_err_text)
).
CATCH /goog/cx_sdk INTO lx_sdk_exception.
ev_message = lx_sdk_exception->get_text( ).
ENDTRY.
IF lo_client->is_success( lv_ret_code ).
ev_message = lv_err_text.
ELSE.
ev_output_value = ls_output-item-value.
ENDIF.
CATCH cx_sy_itab_line_not_found INTO lx_not_found.
ev_output_value = iv_input_value.
ENDTRY.
"Close the http client
lo_client->close_http_client( ).
CATCH /goog/cx_sdk INTO DATA(lx_sdk).
ev_message = lx_sdk->get_text( ).
ENDTRY.
Ganti CLIENT_KEY dengan kunci klien yang dikonfigurasi untuk autentikasi.
Penyamaran: Mengganti sejumlah karakter nilai sensitif dengan karakter yang ditentukan, seperti hash (#) atau tanda bintang (*)
Untuk mengganti nilai dengan karakter yang ditentukan, lakukan langkah-langkah berikut:
Buat objek klien untuk class
/GOOG/CL_DLP_V2.Gunakan tabel konfigurasi untuk menentukan jenis transformasi yang akan diterapkan.
Tetapkan karakter masking dan jumlah karakter yang akan di-masking sesuai dengan tabel konfigurasi.
Panggil DLP API.
Gunakan metode
DEIDENTIFY_CONTENTdengan semua parameter yang relevan, termasuk nilai penggantian, dan tampilkan output ke layanan klien.
DATA: ls_input TYPE /goog/cl_dlp_v2=>ty_055,
ls_transformations TYPE /goog/cl_dlp_v2=>ty_100.
TRY.
DATA(lo_client) = NEW /goog/cl_dlp_v2( iv_key_name = 'CLIENT_KEY' ).
DATA(lv_p_projects_id) = CONV string( lo_client->gv_project_id ).
"As a developer, you need to read the configuration into mt_dlp_config
TRY.
"Read the configuration
DATA(ls_dlp_config) = mt_dlp_config[ keyword = iv_input_type ].
"Populate the input parameters to DLP API for masking
INSERT VALUE #( name = ls_dlp_config-infotype ) INTO TABLE ls_input-inspect_config-info_types.
ls_transformations-primitive_transformation-character_mask_config-number_to_mask = ls_dlp_config-number_to_mask.
ls_transformations-primitive_transformation-character_mask_config-masking_character = ls_dlp_config-masking_char.
INSERT ls_transformations INTO TABLE ls_input-deidentify_config-info_type_transformations-transformations.
ls_input-item-value = iv_input_value.
"Call DLP API client stub
TRY.
lo_client->deidentify_content(
EXPORTING
iv_p_projects_id = lv_p_projects_id
is_input = ls_input
IMPORTING
es_output = DATA(ls_output)
ev_ret_code = DATA(lv_ret_code)
ev_err_text = DATA(lv_err_text)
).
CATCH /goog/cx_sdk INTO lx_sdk_exception.
ev_message = lx_sdk_exception->get_text( ).
ENDTRY.
IF lo_client->is_success( lv_ret_code ).
ev_message = lv_err_text.
ELSE.
ev_output_value = ls_output-item-value.
ENDIF.
CATCH cx_sy_itab_line_not_found INTO lx_not_found.
ev_output_value = iv_input_value.
ENDTRY.
"Close the http client
lo_client->close_http_client( ).
CATCH /goog/cx_sdk INTO DATA(lx_sdk).
ev_message = lx_sdk->get_text( ).
ENDTRY.
Ganti CLIENT_KEY dengan kunci klien yang dikonfigurasi untuk autentikasi.
Tokenisasi berbasis kripto: Mengenkripsi nilai data sensitif asli menggunakan kunci kriptografis
Untuk tokenisasi berbasis kripto, Anda perlu membuat kunci kripto dan kunci gabungan. Panduan ini menggunakan enkripsi yang mempertahankan format. Metode ini membuat token yang memiliki panjang dan karakter yang sama dengan nilai input asli.
Untuk menghapus identitas nilai data sensitif menggunakan pemetaan hash kripto, lakukan langkah-langkah berikut:
Buat objek klien untuk class
/GOOG/CL_DLP_V2.Gunakan tabel konfigurasi untuk menentukan jenis transformasi yang akan diterapkan.
Tetapkan kunci kripto dan kunci gabungan yang dibuat sebelumnya.
Panggil DLP API.
Gunakan metode
DEIDENTIFY_CONTENTdengan semua parameter yang relevan untuk enkripsi kriptografis dan tampilkan output ke layanan klien.
DATA: ls_input TYPE /goog/cl_dlp_v2=>ty_055,
ls_transformations TYPE /goog/cl_dlp_v2=>ty_100,
ls_kms_wrapped_key TYPE /goog/cl_dlp_v2=>ty_123,
ls_crypto_key TYPE /goog/cl_dlp_v2=>ty_040,
ls_crypto_hash_config TYPE /goog/cl_dlp_v2=>ty_039.
TRY.
DATA(lo_client) = NEW /goog/cl_dlp_v2( iv_key_name = 'CLIENT_KEY' ).
DATA(lv_p_projects_id) = CONV string( lo_client->gv_project_id ).
"As a developer, you need to read the configuration into lt_dlp_config
"As a developer, you need to populate the crypto key name and wrapped key
ls_kms_wrapped_key-crypto_key_name = 'CRYPTO_KEY_NAME'. "Crypto_key_name.
ls_kms_wrapped_key-wrapped_key = 'WRAPPED_KEY_NAME'. "Wrapped_key.
ls_crypto_key-kms_wrapped = ls_kms_wrapped_key.
ls_crypto_hash_config-crypto_key = ls_crypto_key.
TRY.
"Read the configuration
DATA(ls_dlp_config) = mt_dlp_config[ keyword = iv_input_type ].
"Populate the input parameters to DLP API for cryptographic encryption
INSERT VALUE #( name = ls_dlp_config-infotype ) INTO TABLE ls_input-inspect_config-info_types.
INSERT VALUE #( name = ls_dlp_config-infotype ) INTO TABLE ls_transformations-info_types. ls_transformations-primitive_transformation-crypto_replace_ffx_fpe_config-crypto_key-kms_wrapped = ls_kms_wrapped_key. ls_transformations-primitive_transformation-crypto_replace_ffx_fpe_config-surrogate_info_type-name = ls_dlp_config-surrogate_infotype. ls_transformations-primitive_transformation-crypto_replace_ffx_fpe_config-common_alphabet = ls_dlp_config-common_alphabhet.
INSERT ls_transformations INTO TABLE ls_input-deidentify_config-info_type_transformations-transformations.
ls_input-item-value = iv_input_value.
"Add the info type identification string to map the subsequent value to relevant infotype
CONCATENATE 'Bank Account' ls_input-item-value INTO ls_input-item-value SEPARATED BY space.
"Call DLP API client stub
TRY.
lo_client->deidentify_content(
EXPORTING
iv_p_projects_id = lv_p_projects_id
is_input = ls_input
IMPORTING
es_output = DATA(ls_output)
ev_ret_code = DATA(lv_ret_code)
ev_err_text = DATA(lv_err_text)
).
CATCH /goog/cx_sdk INTO DATA(lx_sdk_exception).
ev_message = lx_sdk_exception->get_text( ).
ENDTRY.
IF lo_client->is_success( lv_ret_code ).
ev_message = lv_err_text.
ELSE.
"Removing the info type identification string added earlier and keeping only the encrypted value
REPLACE ALL OCCURRENCES OF SUBSTRING 'Bank Account' IN ls_output-item-value WITH ''.
REPLACE ALL OCCURRENCES OF SUBSTRING 'ACCOUNT(10):' IN ls_output-item-value WITH ''.
ev_output_value = ls_output-item-value.
ENDIF.
CATCH cx_sy_itab_line_not_found INTO lx_not_found.
ev_output_value = iv_input_value.
ENDTRY.
"Close the http client
lo_client->close_http_client( ).
CATCH /goog/cx_sdk INTO DATA(lx_sdk).
ev_message = lx_sdk->get_text( ).
ENDTRY.
Ganti kode berikut:
CLIENT_KEY: Kunci klien yang dikonfigurasi untuk autentikasi.CRYPTO_KEY_NAME: Nama kunci kriptografis.WRAPPED_KEY_NAME: Nama kunci yang digabungkan.
Mengirim data input ke layanan klien
Mengirim data dari sistem sumber input ke layanan klien. Anda dapat mengirimkan data menggunakan panggilan API, aplikasi UI frontend, file lokal, aplikasi pihak ketiga, atau sumber lainnya.
Untuk mengetahui informasi tentang cara mem-build Aplikasi SAP Fiori, lihat Mem-build Aplikasi SAP Fiori Menggunakan Model Pemrograman Aplikasi RESTful ABAP.
Memanggil modul proxy DLP
Panggil modul proxy DLP dari layanan klien, yang menerima input sumber.
Contoh kode berikut mengilustrasikan cara memanggil modul proxy DLP dari layanan klien:
DATA : lv_input TYPE string,
lv_output TYPE String.
"As a developer, you need to populate input data into relevant fields
"Redaction: Deletes all or part of a detected sensitive value
" - Remarks
lv_input = lv_email_address.
zgoog_cl_dlp_proxy=>call_dlp( EXPORTING iv_input_value = lv_input iv_input_type = 'EMAIL'
IMPORTING ev_output_value = lv_output ev_message = ev_message ).
ls_bupa_email_address-email_address = lv_output.
"Masking: Replaces a number of characters of a sensitive value with a specified surrogate character, such as a hash (#) or asterisk (*).
" - Phone Number
lv_input = lv_phone_number.
zgoog_cl_dlp_proxy=>call_dlp( EXPORTING iv_input_value = lv_input iv_input_type = 'PHONE NUMBER'
IMPORTING ev_output_value = lv_output ev_message = ev_message ).
ls_bupa_phone_number-phone_number = lv_output.
"Replacement: Replaces a detected sensitive value with a specified surrogate value.
" - Email ID
lv_input = lv_address_comm_remarks.
zgoog_cl_dlp_proxy=>call_dlp( EXPORTING iv_input_value = lv_input iv_input_type = 'REMARKS'
IMPORTING ev_output_value = lv_output ev_message = ev_message ).
ls_bupa_email_address-address_comm_remarks = lv_output.
"Crypto-based tokenization: Encrypts the original sensitive data value by using a cryptographic key. Sensitive Data Protection supports several types of tokenization,
"including transformations that can be reversed, or "re-identified."
" - Bank account number
lv_input = lv_bank_account.
zgoog_cl_dlp_proxy=>call_dlp( EXPORTING iv_input_value = lv_input iv_input_type = 'BANK ACCOUNT'
IMPORTING ev_output_value = lv_output ev_message = ev_message ).
ls_bupa_bank_details-bank_account = lv_output.
Menyimpan data ke dalam sistem SAP ERP
Setelah kolom yang relevan dideidentifikasi, di layanan klien, terapkan logika untuk menyimpan data ke penyimpanan target. Ini dapat berupa layanan Cloud Storage atau sistem SAP lokal Anda.
Langkah selanjutnya
Untuk men-deploy contoh solusi yang dijelaskan dalam panduan ini dengan upaya minimal, gunakan contoh kode yang disediakan di GitHub.
Pelajari berbagai metode transformasi yang tersedia di DLP API untuk menemukan yang paling sesuai dengan kebutuhan bisnis spesifik Anda.
Untuk mempelajari ABAP SDK untuk Google Cloud, lihat Ringkasan ABAP SDK untuk Google Cloud.
Jika Anda memerlukan bantuan untuk menyelesaikan masalah terkait ABAP SDK untuk Google Cloud, lakukan hal berikut:
- Lihat panduan pemecahan masalah ABAP SDK untuk Google Cloud.
- Ajukan pertanyaan dan diskusikan ABAP SDK untuk Google Cloud dengan komunitas di Cloud Forum.
- Kumpulkan semua informasi diagnostik yang tersedia dan hubungi Cloud Customer Care. Untuk mengetahui informasi tentang cara menghubungi Layanan Pelanggan, lihat Mendapatkan dukungan untuk SAP di Google Cloud.
Kontributor
Penulis: Sanchita Mohta | SAP Application Engineer
Kontributor lainnya: Vikash Kumar | Technical Writer