ABAP 환경에서 Vertex AI Agent 호출

이 빠른 시작에서는 ABAP 환경에서 Agent Development Kit (ADK)로 빌드된 Vertex AI 에이전트를 호출하는 방법을 보여줍니다.

이 가이드에서는 ABAP SDK for Google Cloud의 온프레미스 또는 클라우드 버전을 사용하여 AI 에이전트를 호출하는 프로세스를 설명하며 생성 또는 배포 절차는 다루지 않습니다. Google Agentspace 및 Google AI를 통한 고객 참여 도구 모음을 지원하는 동일한 프레임워크를 기반으로 에이전트를 설계하는 오픈소스 프레임워크인 에이전트 개발 키트 (ADK)를 사용하여 AI 에이전트를 만듭니다. 그런 다음 Vertex AI의 완전 관리형 런타임인 Vertex AI Agent Engine에 에이전트를 배포합니다. Vertex AI Agent Engine을 사용하면 빌트인 테스트, 출시, 안정성을 통해 전 세계적으로 안전하게 확장하여 맞춤 에이전트를 프로덕션에 배포할 수 있습니다.

시작하기 전에

이 빠른 시작을 실행하기 전에 직접 또는 관리자가 다음 기본 요건을 완료했는지 확인합니다.

Vertex AI Agent Engine에 에이전트 배포

에이전트를 만들고 테스트한 후 Vertex AI Agent Engine에 배포합니다. 이 빠른 시작에서는 날씨 및 시간 에이전트를 만들고 에이전트를 Vertex AI Agent Engine에 배포합니다.

에이전트를 만들고, 테스트하고, 배포하는 방법에 대한 자세한 내용은 다음을 참고하세요.

상담사가 관리 세션을 사용할 수 있도록 필요한 권한을 부여했는지 확인합니다.

배포 후에는 다음 예와 유사한 리소스 식별자가 제공되며, 이를 통해 ABAP 프로그램 내에서 에이전트 호출을 사용 설정할 수 있습니다.

AgentEngine created. Resource name: projects/project_id/locations/us-central1/reasoningEngines/REASONING_ENGINE_ID

리소스 식별자에서 REASONING_ENGINE_ID를 기록해 둡니다(예: 6384464913570601984). 이 값은 이후 단계에서 필요합니다.

ABAP 환경에서 Vertex AI Agents를 호출하는 프로그램 만들기

  1. SAP 시스템에서 SE38 트랜잭션을 사용하여 커스텀 네임스페이스(예: Z 또는 Y)에 실행 가능한 프로그램을 만듭니다.

    1. SAP GUI에서 트랜잭션 코드 SE38을 입력합니다.

    2. 프로그램 필드에 프로그램 이름을 입력합니다(예: ZDEMO_CALL_AGENT).

    3. 만들기를 클릭합니다.

    4. 프로그램 속성을 지정합니다.

      1. 제목 필드에 프로그램 제목을 입력합니다(예: Call Vertex AI Agent).

      2. 유형 필드에서 Executable Program을 선택합니다.

      3. 저장을 클릭합니다.

    5. 프로그램을 로컬 객체로 저장합니다.

    6. ABAP 편집기에서 다음 코드를 추가합니다.

        REPORT zdemo_call_agent.

  DATA lv_p_projects_id          TYPE string.
  DATA lv_p_locations_id         TYPE string.
  DATA lv_p_reasoning_engines_id TYPE string.
  DATA ls_input                  TYPE /goog/cl_aiplatform_v1=>ty_1072.

  TYPES: BEGIN OF ty_agent_input,
          message    TYPE string,
          session_id TYPE string,
          user_id    TYPE string,
        END OF ty_agent_input.

  DATA ls_agent_input TYPE ty_agent_input.

  TYPES: BEGIN OF ty_response,
          content TYPE /goog/cl_aiplatform_v1=>ty_695,
        END OF ty_response.
  DATA ls_agent_response TYPE ty_response.

  TRY.

      " Open HTTP Connection
      DATA(lo_client) = NEW /goog/cl_aiplatform_v1( iv_key_name = 'DEMO_AIPLATFORM' ).
      DATA lv_agent_response_txt TYPE string.

      " Populate relevant parameters
      lv_p_projects_id = lo_client->gv_project_id.
      lv_p_locations_id = 'LOCATION_ID'.
      lv_p_reasoning_engines_id = 'REASONING_ENGINE_ID'.

      ls_agent_input-message = 'What is the weather in New York'. "Prompt
      ls_agent_input-user_id = 'use-101'.
      ls_input-class_method = 'stream_query'.
      GET REFERENCE OF ls_agent_input INTO ls_input-input.

      lo_client->add_json_name_mapping( iv_abap = 'CLASS_METHOD' iv_json = 'class_method' ).
      lo_client->add_json_name_mapping( iv_abap = 'SESSION_ID'  iv_json = 'session_id' ).
      lo_client->add_json_name_mapping( iv_abap = 'USER_ID' iv_json = 'user_id' ).

      " Call API method: aiplatform.projects.locations.reasoningEngines.streamQuery
      lo_client->stream_query_reasoning_engi( EXPORTING iv_p_projects_id          = lv_p_projects_id
                                                        iv_p_locations_id         = lv_p_locations_id
                                                        iv_p_reasoning_engines_id = lv_p_reasoning_engines_id
                                                        is_input                  = ls_input
                                              IMPORTING es_raw                    = lv_agent_response_txt
                                                        ev_ret_code               = DATA(lv_ret_code)
                                                        ev_err_text               = DATA(lv_err_text)
                                                        es_err_resp               = DATA(ls_err_resp) ).

      " Handle the output
      IF lo_client->is_success( lv_ret_code ).
        SPLIT lv_agent_response_txt AT cl_abap_char_utilities=>newline INTO TABLE DATA(lt_result_event_tab).

        " Deserialize to read the final response event from agent
        /goog/cl_json_util=>deserialize_json( EXPORTING iv_json        = lt_result_event_tab[ 3 ]
                                                        iv_pretty_name = /ui2/cl_json=>pretty_mode-extended
                                              IMPORTING es_data        = ls_agent_response ).

        cl_demo_output=>display( ls_agent_response-content-parts[ 1 ]-text ).

      ELSE.
        MESSAGE lv_err_text TYPE 'E'.
      ENDIF.

      " Close HTTP Connection
      lo_client->close( ).

    CATCH /goog/cx_sdk INTO DATA(lo_exception).
      MESSAGE lo_exception->get_text( ) TYPE 'E'.
  ENDTRY.

      다음을 바꿉니다.

      • DEMO_AIPLATFORM: Google Cloud인증을 위한 클라이언트 키입니다.
      • LOCATION_ID: 에이전트가 배포된 위치입니다. 에이전트를 초기화할 때 위치를 지정합니다. 자세한 내용은 에이전트 초기화를 참고하세요.
      • REASONING_ENGINE_ID: Vertex AI Agent Engine에 에이전트 배포 섹션에 기록한 에이전트의 리소스 식별자입니다.

  2. SE38에서 애플리케이션을 실행합니다.

  3. 결과가 에이전트를 로컬에서 실행할 때 관찰된 결과와 일치하는지 확인합니다.

    Example response: OK. The weather in New York is sunny with a temperature of 25 degrees Celsius (41 degrees Fahrenheit).

다음 단계