Memublikasikan pesan ke Google Cloud Pub/Sub

Panduan memulai ini menunjukkan cara membuat program yang memublikasikan pesan "Hello World!" ke topik Pub/Sub menggunakan Pub/Sub API melalui ABAP SDK edisi SAP BTP untuk Google Cloud.

Sebelum memulai

Sebelum menjalankan panduan memulai ini, pastikan Anda atau administrator Anda telah memenuhi prasyarat berikut:

  • Memberikan peran IAM roles/pubsub.publisher kepada akun layanan.

  • Pastikan Pub/Sub API diaktifkan di project Google Cloud Anda.

    Buka koleksi API

  • Buat topik Pub/Sub SAMPLE_TOPIC_01 dan tambahkan langganan pull SAMPLE_SUB_TOPIC_01 ke topik yang sama. Untuk mengetahui informasi selengkapnya, lihat Membuat topik dan Membuat langganan.

Membuat class ABAP untuk memublikasikan pesan ke topik Pub/Sub

  1. Buat paket:

    1. Di ADT, buka Project Explorer.
    2. Klik kanan paket ZLOCAL, lalu pilih New > ABAP Package.

    3. Masukkan detail berikut untuk paket Anda:

      • Nama: masukkan ZABAPSDK_TEST.
      • Deskripsi: masukkan ABAP SDK Test Package.

    4. Klik Berikutnya.

    5. Pada dialog Select a Transport Request, centang kotak Create a new request.

    6. Masukkan deskripsi untuk permintaan transpor.

    7. Klik Selesai.

  2. Buat class ABAP untuk memanggil Pub/Sub API:

    1. Klik kanan paket ABAP, lalu pilih New > ABAP Class.

    2. Masukkan detail berikut untuk class ABAP Anda:

      • Nama: masukkan ZGOOG_CL_QS_PUBSUB.
      • Deskripsi: masukkan Quick start for Pub/Sub API.

    3. Klik Berikutnya.

    4. Pilih permintaan transpor, lalu klik Selesai.

  3. Di editor kode, ganti kode default dengan cuplikan kode berikut:

    " --------------------------------------------------------------------
"  Copyright 2024 Google LLC                                         -
"                                                                    -
"  Licensed under the Apache License, Version 2.0 (the "License");   -
"  you may not use this file except in compliance with the License.  -
"  You may obtain a copy of the License at                           -
"      https://www.apache.org/licenses/LICENSE-2.0                   -
"  Unless required by applicable law or agreed to in writing,        -
"  software distributed under the License is distributed on an       -
"  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND,      -
"  either express or implied.                                        -
"  See the License for the specific language governing permissions   -
"  and limitations under the License.                                -
" --------------------------------------------------------------------
CLASS zcl_qs_publish_messages DEFINITION
  PUBLIC FINAL
  CREATE PUBLIC.

  PUBLIC SECTION.
    INTERFACES if_oo_adt_classrun.
ENDCLASS.



CLASS ZCL_QS_PUBLISH_MESSAGES IMPLEMENTATION.


  METHOD if_oo_adt_classrun~main.

    DATA ls_input         TYPE /goog/cl_pubsub_v1=>ty_023.
    DATA lo_pubsub        TYPE REF TO /goog/cl_pubsub_v1.
    DATA lv_p_projects_id TYPE string.
    DATA lv_p_topics_id   TYPE string.

    TRY.
        " Open HTTP connection
        " The client key DEMO_PUBSUB is an example, replace this with actual value
        lo_pubsub = NEW /goog/cl_pubsub_v1( iv_key_name = 'DEMO_PUBSUB' ).

        " Pass the relevant input parameters
        " The value shown below is an example. Replace it with actual value
        lv_p_topics_id = 'SAMPLE_TOPIC_01'.

        lv_p_projects_id = lo_pubsub->gv_project_id.
        APPEND VALUE #( data = cl_http_utility=>encode_base64( 'Hello World!' ) )
               TO ls_input-messages.

        " Call the API
        lo_pubsub->publish_topics( EXPORTING iv_p_projects_id = lv_p_projects_id
                                             iv_p_topics_id   = lv_p_topics_id
                                             is_input         = ls_input
                                   IMPORTING
                                             es_output        = DATA(ls_output)
                                             ev_ret_code      = DATA(lv_ret_code)
                                             ev_err_text      = DATA(lv_err_text)
                                             es_err_resp      = DATA(ls_err_resp) ).

        " Handle the output
        IF lo_pubsub->is_success( lv_ret_code ).
          out->write( 'Message was published!' ).
        ELSE.
          out->write( 'Message was not published!' ).
        ENDIF.

        " Close the HTTP Connection
        lo_pubsub->close( ).

      CATCH /goog/cx_sdk INTO DATA(lo_exception).
        " Handle exception here
    ENDTRY.
  ENDMETHOD.
ENDCLASS.

    Ganti DEMO_PUBSUB dengan nama kunci klien.

  4. Simpan dan aktifkan perubahan.

  5. Jalankan aplikasi Anda:

    1. Pilih class ABAP ZGOOG_CL_QS_PUBSUB.
    2. Klik Jalankan > Jalankan Sebagai > Aplikasi ABAP (Konsol). Atau, tekan F9.

  6. Untuk memvalidasi hasilnya, ikuti langkah-langkah berikut:

    1. Di konsol Google Cloud, buka Pub/Sub.

    2. Pilih langganan SAMPLE_SUB_TOPIC_01, lalu buka tab Pesan.

    3. Gunakan fitur PULL untuk memeriksa apakah pesan "Hello World!" telah dipublikasikan ke topik.

Langkah selanjutnya