Retrieve metadata of a file

This code sample can be used to retrieve the metadata of an object from a Cloud Storage bucket.

For a comprehensive collection of code samples for the SAP BTP edition of ABAP SDK for Google Cloud, see the code sample repository on GitHub.

For a comprehensive collection of code samples for the on-premises or any cloud edition of ABAP SDK for Google Cloud, see the code samples repository on GitHub.

Code sample

SAP BTP edition

" --------------------------------------------------------------------
"  Copyright 2024 Google LLC                                         -
"                                                                    -
"  Licensed under the Apache License, Version 2.0 (the "License");   -
"  you may not use this file except in compliance with the License.  -
"  You may obtain a copy of the License at                           -
"      https://www.apache.org/licenses/LICENSE-2.0                   -
"  Unless required by applicable law or agreed to in writing,        -
"  software distributed under the License is distributed on an       -
"  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND,      -
"  either express or implied.                                        -
"  See the License for the specific language governing permissions   -
"  and limitations under the License.                                -
" --------------------------------------------------------------------
CLASS zcl_cs_retrieve_file_metadata DEFINITION
  PUBLIC FINAL
  CREATE PUBLIC.

  PUBLIC SECTION.
    INTERFACES if_oo_adt_classrun.
ENDCLASS.


CLASS zcl_cs_retrieve_file_metadata IMPLEMENTATION.
  METHOD if_oo_adt_classrun~main.
    " Data Declarations
    DATA lv_p_bucket TYPE string.
    DATA lv_p_object TYPE string.

    TRY.
        " Open HTTP Connection
        " Pass the configured client key
        DATA(lo_client) = NEW /goog/cl_storage_v1( iv_key_name = 'CLIENT_KEY' ).

        " Populate the data that needs to be passed to the api
        " Name of the bucket
        lv_p_bucket = 'sample-bucket'.
        " Name of the object
        lv_p_object = 'sample-object'.

        " Call API method
        lo_client->get_objects( EXPORTING iv_p_bucket = lv_p_bucket
                                          iv_p_object = lv_p_object
                                IMPORTING es_output   = DATA(ls_output)
                                          ev_ret_code = DATA(lv_ret_code)
                                          ev_err_text = DATA(lv_err_text) ).

        IF lo_client->is_success( lv_ret_code ).
          out->write( 'Object metadata retrieved successfully!' ).
          out->write( |Bucket Name: { ls_output-bucket }| ).
          out->write( |Object Name: { ls_output-name }| ).
          out->write( |Content Type: { ls_output-content_type }| ).
        ELSE.
          out->write( | Error occurred: { lv_err_text }| ).
        ENDIF.

        " Close HTTP connection
        lo_client->close( ).

      CATCH /goog/cx_sdk INTO DATA(lo_sdk_excp).
        lv_err_text = lo_sdk_excp->get_text( ).
        out->write( |Exception occurred: { lv_err_text } | ).
    ENDTRY.
  ENDMETHOD.
ENDCLASS.

On-premises or any cloud edition

**********************************************************************
*  Copyright 2023 Google LLC                                         *
*                                                                    *
*  Licensed under the Apache License, Version 2.0 (the "License");   *
*  you may not use this file except in compliance with the License.  *
*  You may obtain a copy of the License at                           *
*      https://www.apache.org/licenses/LICENSE-2.0                   *
*  Unless required by applicable law or agreed to in writing,        *
*  software distributed under the License is distributed on an       *
*  "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND,      *
*  either express or implied.                                        *
*  See the License for the specific language governing permissions   *
*  and limitations under the License.                                *
**********************************************************************

REPORT zr_retrieve_file_metadata.

* Data Declarations
DATA:
  lv_p_bucket TYPE string,
  lv_p_object TYPE string.

TRY.
*  Open HTTP Connection
    DATA(lo_client) = NEW /goog/cl_storage_v1( iv_key_name = 'CLIENT_KEY' ).

*  Populate the data that needs to be passed to the api
    "Name of the bucket
    lv_p_bucket       = 'sample-bucket'.
    "Name of the object
    lv_p_object        = 'sample-object'.

*     Call API method
    CALL METHOD lo_client->get_objects
      EXPORTING
        iv_p_bucket = lv_p_bucket
        iv_p_object = lv_p_object
      IMPORTING
        es_output   = DATA(ls_output)
        ev_ret_code = DATA(lv_ret_code)
        ev_err_text = DATA(lv_err_text).

    IF lo_client->is_success( lv_ret_code ).
      MESSAGE 'Object metadata retrieved successfully!' TYPE 'S'.
      WRITE: 'Bucket Name:', ls_output-bucket.
      WRITE:/ 'Object Name:', ls_output-name.
      WRITE:/ 'Content Type:', ls_output-content_type.
    ELSE.
      MESSAGE lv_err_text TYPE 'E'.
    ENDIF.
*   Close HTTP connection
    lo_client->close( ).

  CATCH /goog/cx_sdk INTO DATA(lo_exception).
    MESSAGE lo_exception->get_text( ) TYPE 'E'.
ENDTRY.