Tieni presente che stai visualizzando la documentazione di Looker. Per la documentazione di Looker Studio, visita https://support.google.com/looker-studio.

Crea un'istanza di Looker (Google Cloud core)

Questa pagina illustra come eseguire il provisioning di un'istanza di Looker (Google Cloud core).

Prima di iniziare

Nella pagina del selettore di progetti della console Google Cloud, crea un progetto Google Cloud o passa a un progetto esistente.
Vai al selettore progetti
Abilita l'API Looker per il tuo progetto nella console Google Cloud. Quando abiliti l'API, potresti dover aggiornare la pagina della console per confermare che l'API è stata abilitata.
Abilita l'API
Abilita l'API Service Networking per il tuo progetto nella console Google Cloud. Quando abiliti l'API, potresti dover aggiornare la pagina della console per confermare che l'API è stata abilitata.
Abilita l'API
Configura un client OAuth e crea credenziali di autorizzazione. Il client OAuth consente di eseguire l'autenticazione e di accedere all'istanza. Devi configurare OAuth per creare un'istanza di Looker (Google Cloud core), anche se utilizzi un metodo di autenticazione diverso per autenticare gli utenti nell'istanza.
Se vuoi utilizzare un IP privato, Controlli di servizio VPC o chiavi di crittografia gestite dal cliente (CMEK) con l'istanza di Looker (Google Cloud core) che stai creando, è necessaria una configurazione aggiuntiva prima della creazione dell'istanza. Durante la creazione dell'istanza potrebbe essere necessaria anche una configurazione aggiuntiva della versione e della rete.

Ruoli obbligatori

Per ottenere le autorizzazioni necessarie per creare un'istanza di Looker (Google Cloud core), chiedi all'amministratore di concederti il ruolo IAM Amministratore Looker (roles/looker.admin) per il progetto in cui risiede l'istanza. Per saperne di più sulla concessione dei ruoli, consulta Gestire l'accesso.

Potresti anche essere in grado di ottenere le autorizzazioni richieste tramite i ruoli personalizzati o altri ruoli predefiniti.

Potresti anche aver bisogno di ruoli IAM aggiuntivi per configurare l'IP privato, i Controlli di servizio VPC o le chiavi di crittografia gestite dal cliente (CMEK). Per saperne di più, consulta le pagine della documentazione relative a queste funzionalità.

Crea un'istanza di Looker (Google Cloud core)

Looker (Google Cloud core) richiede circa 60 minuti per generare una nuova istanza.

Per creare la tua istanza di Looker (Google Cloud core), seleziona una delle seguenti opzioni:

console

Vai alla pagina del prodotto Looker (Google Cloud core) dal tuo progetto nella console Google Cloud. Se hai già creato un'istanza di Looker (Google Cloud core) all'interno di questo progetto, si aprirà la pagina Istanze.
Vai a Looker (Google Cloud core)
Fai clic su CREA ISTANZA.
Nella sezione Nome istanza, specifica un nome per l'istanza di Looker (Google Cloud core). Una volta creato, il nome dell'istanza non è associato all'URL dell'istanza di Looker (Google Cloud core). Il nome dell'istanza non può essere modificato dopo la creazione dell'istanza.
Nella sezione Credenziali applicazione OAuth, inserisci l'ID client OAuth e il segreto OAuth che hai creato quando hai configurato il client OAuth.
Nella sezione Regione, seleziona l'opzione appropriata dal menu a discesa. La regione appropriata è quella in cui è ospitata l'istanza di Looker (Google Cloud core). Seleziona la regione che corrisponde a quella nel contratto di abbonamento, dove è allocata la quota per il tuo progetto. Le regioni disponibili sono elencate nella pagina della documentazione delle località di Looker (Google Cloud core).
Nota: non puoi modificare la regione dopo aver creato l'istanza.
Nella sezione Edition, imposta la versione dell'istanza in base alle esigenze della tua organizzazione. Il tipo di edizione influisce su alcune delle funzionalità disponibili per l'istanza. Queste sono le opzioni disponibili:
- Standard: piattaforma Looker per piccole organizzazioni o team con meno di 50 utenti. Può essere acquistato tramite un contratto annuale.
- Enterprise: piattaforma Looker con funzionalità di sicurezza avanzate per gestire un'ampia gamma di casi d'uso interni per BI e analisi. Disponibile con un contratto annuale.
- Incorpora: piattaforma Looker per il deployment e la gestione di applicazioni esterne affidabili di analisi e personalizzate su larga scala. Disponibile con un contratto annuale.
Le versioni non possono essere modificate dopo la creazione dell'istanza. Se vuoi cambiare versione, puoi utilizzare le funzioni di importazione e esportazione per spostare i dati dell'istanza di Looker (Google Cloud core) in una nuova istanza configurata con una versione diversa.
Nella sezione Personalizza la tua istanza, fai clic su MOSTRA OPZIONI DI CONFIGURAZIONE per visualizzare un gruppo di impostazioni aggiuntive che puoi personalizzare per l'istanza.
Nella sezione Connessioni sono visualizzate le opzioni di connessione di rete. Il tipo di connessione di rete selezionato influisce sulle funzionalità di Looker disponibili per l'istanza. Sono disponibili le seguenti opzioni di connessione di rete:
- IP pubblico: assegna un indirizzo IP esterno accessibile da internet.
- IP privato: assegna un indirizzo IP interno ospitato da Google a cui è possibile accedere da un Virtual Private Cloud (VPC). Puoi utilizzare questo indirizzo per connetterti da altre risorse con accesso al VPC. Se selezioni questa opzione, segui le istruzioni nella pagina della documentazione Creare una connessione con IP privato per Looker (Google Cloud core) per completare la configurazione della rete. Solo le versioni Enterprise e Embed supportano l'IP privato.
Nota: l'IP privato deve essere assegnato al momento della creazione dell'istanza. Non è possibile aggiungere o rimuovere l'IP privato da un'istanza dopo la creazione dell'istanza.
- Puoi anche selezionare entrambe le opzioni. Se selezioni entrambe le opzioni, il traffico in entrata verrà instradato tramite IP pubblico e quello in uscita verrà instradato tramite IP privato. L'istanza di Looker (Google Cloud core) non utilizzerà l'IP pubblico per generare il traffico internet in uscita.
Se selezioni solo IP privato oppure sia IP pubblico sia IP privato, segui i passaggi nella pagina della documentazione Utilizzare l'IP privato con Looker (Google Cloud core) per completare la configurazione della rete durante la creazione dell'istanza.
Nella sezione Crittografia, puoi scegliere se utilizzare la crittografia predefinita gestita da Google o una chiave di crittografia gestita dal cliente (CMEK). Consulta la pagina della documentazione Utilizzo delle chiavi di crittografia gestite dal cliente con Looker (Google Cloud core) per saperne di più su CMEK e su come configurarla durante la creazione dell'istanza. Il tipo di crittografia non può essere modificato dopo la creazione dell'istanza.
Nella sezione Periodo di manutenzione, puoi facoltativamente specificare il giorno della settimana e l'ora in cui Looker (Google Cloud core) pianifica la manutenzione. I periodi di manutenzione durano un'ora. Per impostazione predefinita, l'opzione Periodo preferito nel Periodo di manutenzione è impostata su Qualsiasi periodo.
Nella sezione Periodo in cui evitare la manutenzione, puoi facoltativamente specificare un intervallo di giorni in cui Looker (Google Cloud core) non pianifica la manutenzione. I periodi in cui evitare la manutenzione possono durare fino a 60 giorni. Devi consentire almeno 14 giorni di disponibilità per la manutenzione tra un periodo in cui evitare la manutenzione e l'altro.
Fai clic su Crea.

Durante la creazione dell'istanza, il sistema ti reindirizzerà alla pagina Istanze all'interno della console. Potresti dover aggiornare la pagina per visualizzare lo stato della nuova istanza. Puoi anche vedere l'attività di creazione dell'istanza facendo clic sull'icona delle notifiche nel menu della console Google Cloud. Durante la creazione dell'istanza, l'icona delle notifiche nel menu della console Google Cloud sarà circondata da un'icona di caricamento.

gcloud

Se utilizzi CMEK, quindi crea l'account di servizio Looker e segui prima le istruzioni per configurare CMEK.
Utilizza il comando gcloud looker instances create per creare l'istanza:
```
gcloud looker instances create INSTANCE_NAME \
--project=PROJECT_ID \
--oauth-client-id=OAUTH_CLIENT_ID \
--oauth-client-secret=OAUTH_CLIENT_SECRET \
--region=REGION \
--edition=EDITION \
[--consumer-network=CONSUMER_NETWORK --private-ip-enabled --reserved-range=RESERVED_RANGE]
[--no-public-ip-enabled]
[--public-ip-enabled]
[--async]
```
Sostituisci quanto segue:
- INSTANCE_NAME: un nome per l'istanza di Looker (Google Cloud core); non è associato all'URL dell'istanza.
- PROJECT_ID: il nome del progetto Google Cloud in cui stai creando l'istanza di Looker (Google Cloud core).
- OAUTH_CLIENT_ID e OAUTH_CLIENT_SECRET: l'ID client OAuth e il secret OAuth che hai creato quando hai configurato il client OAuth. Dopo aver creato l'istanza, inserisci l'URL dell'istanza nella sezione URI di reindirizzamento autorizzati del client OAuth.
- REGION: la regione in cui è ospitata l'istanza di Looker (Google Cloud core). Seleziona la regione corrispondente a quella indicata nel contratto di abbonamento. Le regioni disponibili sono elencate nella pagina della documentazione delle località di Looker (Google Cloud core).
- EDITION: la versione dell'istanza. I valori possibili sono core-standard-annual, core-enterprise-annual o core-embed-annual. Le versioni non possono essere modificate dopo la creazione dell'istanza. Se vuoi cambiare versione, puoi utilizzare le funzioni di importazione e esportazione per spostare i dati dell'istanza di Looker (Google Cloud core) in una nuova istanza configurata con una versione diversa.
- CONSUMER_NETWORK: la tua rete VPC o il VPC condiviso. Deve essere impostato se stai creando un'istanza di IP privato.
- RESERVED_RANGE: l'intervallo di indirizzi IP all'interno del VPC in cui Google eseguirà il provisioning di una subnet per la tua istanza Looker (Google Cloud core). Deve essere impostato se stai creando un'istanza di IP privato.
Puoi includere anche questi flag:
- --private-ip-enabled abilita l'IP privato.
- --public-ip-enabled o --no-public-ip-enabled sono utilizzati per abilitare o disabilitare l'IP pubblico.
- --async è l'opzione consigliata per la creazione di un'istanza di Looker (Google Cloud core).
Puoi aggiungere altri parametri per applicare altre impostazioni dell'istanza:
```
[--maintenance-window-day=MAINTENANCE_WINDOW_DAY
      --maintenance-window-time=MAINTENANCE_WINDOW_TIME]
[--deny-maintenance-period-end-date=DENY_MAINTENANCE_PERIOD_END_DATE
      --deny-maintenance-period-start-date=DENY_MAINTENANCE_PERIOD_START_DATE
      --deny-maintenance-period-time=DENY_MAINTENANCE_PERIOD_TIME]
--kms-key=KMS_KEY_ID
```
Sostituisci quanto segue:
- MAINTENANCE_WINDOW_DAY: deve essere uno dei seguenti: friday, monday, saturday, sunday, thursday, tuesday, wednesday. Per saperne di più sulle impostazioni del periodo di manutenzione, consulta la pagina della documentazione Gestire i criteri di manutenzione per Looker (Google Cloud core).
- MAINTENANCE_WINDOW_TIME e DENY_MAINTENANCE_PERIOD_TIME: devono essere espressi nell'ora UTC nel formato 24 ore (ad esempio 13:00, 17:45).
- DENY_MAINTENANCE_PERIOD_START_DATE e DENY_MAINTENANCE_PERIOD_END_DATE: devono essere nel formato YYYY-MM-DD.
- KMS_KEY_ID: deve essere la chiave creata durante la configurazione delle chiavi di crittografia gestite dal cliente (CMEK).

Terraform

Utilizza la seguente risorsa Terraform per eseguire il provisioning di un'istanza Looker standard (Google Cloud core) con funzionalità di base:

# Creates a Standard edition Looker (Google Cloud core) instance with basic functionality enabled.
resource "google_looker_instance" "main" {
  name             = "my-instance"
  platform_edition = "LOOKER_CORE_STANDARD"
  region           = "us-central1"
  oauth_config {
    client_id     = "my-client-id"
    client_secret = "my-client-secret"
  }
}

Utilizza la seguente risorsa Terraform per eseguire il provisioning di un'istanza Looker (Google Cloud core) con impostazioni aggiuntive applicate:

# Creates a Standard edition Looker (Google Cloud core) instance with full functionality enabled.

resource "google_looker_instance" "main" {
  name              = "my-instance"
  platform_edition  = "LOOKER_CORE_STANDARD"
  region            = "us-central1"
  public_ip_enabled = true
  admin_settings {
    allowed_email_domains = ["google.com"]
  }
  // User metadata config is only available when platform edition is LOOKER_CORE_STANDARD.
  user_metadata {
    additional_developer_user_count = 10
    additional_standard_user_count  = 10
    additional_viewer_user_count    = 10
  }
  maintenance_window {
    day_of_week = "THURSDAY"
    start_time {
      hours   = 22
      minutes = 0
      seconds = 0
      nanos   = 0
    }
  }
  deny_maintenance_period {
    start_date {
      year  = 2050
      month = 1
      day   = 1
    }
    end_date {
      year  = 2050
      month = 2
      day   = 1
    }
    time {
      hours   = 10
      minutes = 0
      seconds = 0
      nanos   = 0
    }
  }
  oauth_config {
    client_id     = "my-client-id"
    client_secret = "my-client-secret"
  }
}

Utilizza la seguente risorsa Terraform per eseguire il provisioning di un'istanza Looker (Google Cloud core) Enterprise con una connessione di rete privata:

# Creates an Enterprise edition Looker (Google Cloud core) instance with full, Private IP functionality.
resource "google_looker_instance" "main" {
  name               = "my-instance"
  platform_edition   = "LOOKER_CORE_ENTERPRISE_ANNUAL"
  region             = "us-central1"
  private_ip_enabled = true
  public_ip_enabled  = false
  reserved_range     = google_compute_global_address.main.name
  consumer_network   = data.google_compute_network.main.id
  admin_settings {
    allowed_email_domains = ["google.com"]
  }
  encryption_config {
    kms_key_name = google_kms_crypto_key.main.id
  }
  maintenance_window {
    day_of_week = "THURSDAY"
    start_time {
      hours   = 22
      minutes = 0
      seconds = 0
      nanos   = 0
    }
  }
  deny_maintenance_period {
    start_date {
      year  = 2050
      month = 1
      day   = 1
    }
    end_date {
      year  = 2050
      month = 2
      day   = 1
    }
    time {
      hours   = 10
      minutes = 0
      seconds = 0
      nanos   = 0
    }
  }
  oauth_config {
    client_id     = "my-client-id"
    client_secret = "my-client-secret"
  }
  depends_on = [
    google_service_networking_connection.main,
    google_kms_crypto_key.main
  ]
}

resource "google_kms_key_ring" "main" {
  name     = "keyring-example"
  location = "us-central1"
}

resource "google_kms_crypto_key" "main" {
  name     = "crypto-key-example"
  key_ring = google_kms_key_ring.main.id
}

resource "google_service_networking_connection" "main" {
  network                 = data.google_compute_network.main.id
  service                 = "servicenetworking.googleapis.com"
  reserved_peering_ranges = [google_compute_global_address.main.name]
}

resource "google_compute_global_address" "main" {
  name          = "looker-range"
  purpose       = "VPC_PEERING"
  address_type  = "INTERNAL"
  prefix_length = 20
  network       = data.google_compute_network.main.id
}

data "google_project" "main" {}

data "google_compute_network" "main" {
  name = "default"
}

resource "google_kms_crypto_key_iam_member" "main" {
  crypto_key_id = google_kms_crypto_key.main.id
  role          = "roles/cloudkms.cryptoKeyEncrypterDecrypter"
  member        = "serviceAccount:service-${data.google_project.main.number}@gcp-sa-looker.iam.gserviceaccount.com"
}

Per scoprire come applicare o rimuovere una configurazione Terraform, consulta Comandi Terraform di base.

Una volta avviata, la creazione dell'istanza non può essere messa in pausa o terminata. Una volta eseguito il provisioning della risorsa Terraform, il terminale stamperà il seguente messaggio:

Creation complete after XmXs [id=projects/PROJECT-ID/locations/REGION/instances/my-instance-randomly-generated-name]

Apply complete! Resources: X added, X changed, X destroyed.

Per visualizzare lo stato della nuova istanza, a cui verrà assegnato un nome generato in modo casuale, visita la pagina Istanze all'interno della console.

Il provisioning dell'istanza potrebbe richiedere fino a 60 minuti.

Dopo aver creato l'istanza, inserisci l'URL dell'istanza nella sezione URI di reindirizzamento autorizzati del client OAuth.

Una volta creata l'istanza e completata la configurazione di OAuth, puoi visualizzare l'istanza accedendo all'URL dell'istanza, che sarà mostrato nella pagina Istanze. Quindi puoi selezionare il metodo di autenticazione degli utenti e aggiungere utenti, connetterti al tuo database e continuare la configurazione dell'istanza.

Account di servizio Looker

Looker (Google Cloud core) utilizza un agente di servizio, chiamato account di servizio Looker, per eseguire determinate attività. Un singolo account di servizio Looker funziona per conto di tutte le istanze Looker (Google Cloud core) di un determinato progetto Google Cloud. L'account di servizio Looker viene creato automaticamente la prima volta che viene creata un'istanza di Looker (Google Cloud core) in un progetto.

A volte, ad esempio quando utilizzi le Credenziali predefinite dell'applicazione (ADC) con una connessione a BigQuery in un altro progetto, devi visualizzare le informazioni sull'account di servizio Looker, come il suo indirizzo email.

In alternativa, se prevedi di utilizzare CMEK e intendi utilizzare Google Cloud CLI, Terraform o l'API per configurare CMEK prima di creare l'istanza di Looker (Google Cloud core), devi creare manualmente l'account di servizio Looker prima di creare l'istanza.

Per visualizzare o creare l'account di servizio Looker, seleziona una delle seguenti opzioni:

console

Per visualizzare l'account di servizio Looker:

Nella console Google Cloud, vai alla pagina IAM.
Vai a IAM
Seleziona il progetto in cui si trova l'istanza di Looker (Google Cloud core).
Seleziona la casella di controllo Includi concessioni di ruoli fornite da Google.

gcloud

Per creare o visualizzare l'account di servizio Looker:


gcloud beta services identity create --service=looker.googleapis.com --project=PROJECT_ID

Sostituisci PROJECT_ID con il progetto in cui si trova l'istanza di Looker (Google Cloud core).

Il nome dell'account di servizio sarà Looker Service Account. L'email avrà il formato service-<project number>@gcp-sa-looker.iam.gserviceaccount.com.

Crea un'istanza di Looker (Google Cloud core)

Prima di iniziare

Ruoli obbligatori

Crea un'istanza di Looker (Google Cloud core)

console

gcloud

Terraform

Account di servizio Looker

console

gcloud

Passaggi successivi