Membuat instance Looker (Google Cloud core) IP publik

Halaman ini membahas cara menyediakan instance Looker (Google Cloud core) IP publik.

Sebelum memulai

  1. Di konsol Google Cloud, pada halaman pemilih project, buat project Google Cloud atau buka project yang sudah ada.

    Buka pemilih project

  2. Aktifkan Looker API untuk project Anda di konsol Google Cloud. Saat mengaktifkan API, Anda mungkin perlu memuat ulang halaman konsol untuk mengonfirmasi bahwa API telah diaktifkan.

    Mengaktifkan API

  3. Siapkan klien OAuth dan buat kredensial otorisasi. Klien OAuth memungkinkan Anda mengautentikasi dan mengakses instance. Anda harus menyiapkan OAuth untuk membuat instance Looker (inti Google Cloud), meskipun Anda menggunakan metode autentikasi yang berbeda untuk mengautentikasi pengguna ke instance Anda.
  4. Jika ingin menggunakan Kontrol Layanan VPC, Anda harus membuat instance IP pribadi, bukan instance IP publik.

Peran yang diperlukan

Untuk mendapatkan izin yang diperlukan guna membuat instance Looker (inti Google Cloud), minta administrator untuk memberi Anda peran IAM Looker Admin (roles/looker.admin) di project tempat instance akan berada. Untuk mengetahui informasi selengkapnya tentang cara memberikan peran, lihat Mengelola akses ke project, folder, dan organisasi.

Anda mungkin juga bisa mendapatkan izin yang diperlukan melalui peran khusus atau peran bawaan lainnya.

Anda mungkin juga memerlukan peran IAM tambahan jika ingin menyiapkan kunci enkripsi yang dikelola pelanggan (CMEK). Buka halaman Kontrol akses dengan IAM di dokumentasi Cloud Key Management Service untuk mempelajari lebih lanjut.

Membuat instance Looker (Google Cloud core)

Looker (Google Cloud core) memerlukan waktu sekitar 60 menit untuk membuat instance baru.

Untuk membuat instance Looker (Google Cloud core), pilih salah satu opsi berikut:

console

  1. Buka halaman produk Looker (inti Google Cloud) dari project Anda di konsol Google Cloud. Jika Anda telah membuat instance Looker (Google Cloud core) dalam project ini, tindakan ini akan membuka halaman Instance.

    Buka Looker (Google Cloud core)

  2. Klik CREATE INSTANCE.
  3. Di bagian Instance name, berikan nama untuk instance Looker (Google Cloud core) Anda. Nama instance tidak dikaitkan dengan URL instance Looker (Google Cloud core) setelah dibuat. Nama instance tidak dapat diubah setelah pembuatan instance.
  4. Di bagian Kredensial Aplikasi OAuth, masukkan client ID OAuth dan secret OAuth yang Anda buat saat menyiapkan klien OAuth.
  5. Di bagian Region, pilih opsi yang sesuai dari menu drop-down untuk menghosting instance Looker (inti Google Cloud) Anda. Pilih region yang cocok dengan region dalam kontrak langganan, tempat kuota untuk project Anda dialokasikan. Region yang tersedia tercantum di halaman dokumentasi lokasi Looker (Google Cloud Core).

  6. Di bagian Edisi, tetapkan edisi instance sesuai dengan kebutuhan organisasi Anda. Jenis edisi memengaruhi beberapa fitur yang tersedia untuk instance. Pastikan Anda memilih jenis edisi yang sama seperti yang tercantum dalam kontrak tahunan dan Anda memiliki kuota yang dialokasikan untuk jenis edisi tersebut. Berikut adalah opsi edisi:

    • Standar: Platform Looker (Google Cloud core) untuk organisasi kecil atau tim yang memiliki kurang dari 50 pengguna
    • Enterprise: Platform Looker (Google Cloud core) dengan fitur keamanan yang ditingkatkan untuk menangani berbagai kasus penggunaan BI dan analisis internal
    • Sisipkan: Platform Looker (Google Cloud core) untuk men-deploy dan mengelola analisis eksternal dan aplikasi kustom yang andal dalam skala besar

    Edisi tidak dapat diubah setelah pembuatan instance. Jika ingin mengubah edisi, Anda dapat menggunakan impor dan ekspor untuk memindahkan data instance Looker (inti Google Cloud) ke instance baru yang dikonfigurasi dengan edisi yang berbeda.

  7. Di bagian Sesuaikan instance Anda, klik TAMPILKAN OPSI KONFIGURASI untuk menampilkan grup setelan tambahan yang dapat Anda sesuaikan untuk instance.

  8. Di bagian Koneksi, pilih hanya IP Publik. Setelan koneksi IP publik menetapkan alamat IP eksternal yang dapat diakses internet dan tersedia untuk semua jenis edisi.

    Jika Anda hanya memilih IP Pribadi atau IP Publik dan IP Pribadi, ikuti langkah-langkah di halaman dokumentasi Membuat instance Looker (Google Cloud core) dengan IP pribadi untuk menyelesaikan penyiapan jaringan selama pembuatan instance.

  9. Di bagian Enkripsi, Anda dapat memilih jenis enkripsi yang akan digunakan di instance. Opsi enkripsi berikut tersedia:

  10. Di bagian Maintenance Window, Anda dapat menentukan hari dan jam saat Looker (inti Google Cloud) menjadwalkan pemeliharaan. Masa pemeliharaan berlangsung selama satu jam. Secara default, opsi Periode Pilihan di Periode Pemeliharaan ditetapkan ke Periode apa pun.

  11. Di bagian Tolak Periode Pemeliharaan, Anda dapat menentukan blok hari saat Looker (inti Google Cloud) tidak menjadwalkan pemeliharaan. Periode pemeliharaan penolakan dapat berlangsung hingga 60 hari. Anda harus memberikan waktu minimal 14 hari dari waktu pemeliharaan di antara 2 periode pemeliharaan yang ditolak.

  12. Klik Create.

gcloud

  1. Jika Anda menggunakan CMEK, buat akun layanan Looker dan ikuti petunjuk untuk menyiapkan CMEK terlebih dahulu.

  2. Gunakan perintah gcloud looker instances create untuk membuat instance:

    gcloud looker instances create INSTANCE_NAME \
--project=PROJECT_ID \
--oauth-client-id=OAUTH_CLIENT_ID \
--oauth-client-secret=OAUTH_CLIENT_SECRET \
--region=REGION \
--edition=EDITION \
[--consumer-network=CONSUMER_NETWORK --private-ip-enabled --reserved-range=RESERVED_RANGE]
[--no-public-ip-enabled]
[--public-ip-enabled]
[--async]

    Ganti kode berikut:

    • INSTANCE_NAME: nama untuk instance Looker (Google Cloud core) Anda; nama ini tidak terkait dengan URL instance.
    • PROJECT_ID: nama project Google Cloud tempat Anda membuat instance Looker (Google Cloud core).
    • OAUTH_CLIENT_ID dan OAUTH_CLIENT_SECRET: client ID OAuth dan secret OAuth yang Anda buat saat menyiapkan klien OAuth. Setelah instance dibuat, siapkan URI pengalihan yang diberi otorisasi di klien OAuth yang telah Anda buat sebelumnya.
    • REGION: region tempat instance Looker (Google Cloud core) Anda dihosting. Pilih region yang cocok dengan region dalam kontrak langganan. Region yang tersedia tercantum di halaman dokumentasi lokasi Looker (Google Cloud Core).
    • EDITION: edisi untuk instance. Kemungkinan nilainya adalah core-standard-annual, core-enterprise-annual, atau core-embed-annual. Edisi tidak dapat diubah setelah pembuatan instance. Jika ingin mengubah edisi, Anda dapat menggunakan impor dan ekspor untuk memindahkan data instance Looker (inti Google Cloud) ke instance baru yang dikonfigurasi dengan edisi yang berbeda.
    • CONSUMER_NETWORK: jaringan VPC atau VPC Bersama. Harus ditetapkan jika Anda membuat instance IP pribadi.
    • RESERVED_RANGE: rentang alamat IP dalam VPC tempat Google akan menyediakan subjaringan untuk instance Looker (inti Google Cloud) Anda. Jangan tentukan rentang jika Anda mengaktifkan koneksi jaringan IP pribadi untuk instance.

    Sertakan juga flag berikut:

    • --public-ip-enabled digunakan untuk mengaktifkan IP publik.
    • --async direkomendasikan saat Anda membuat instance Looker (Google Cloud core).

  3. Anda dapat menambahkan parameter lainnya untuk menerapkan setelan instance lainnya: 

    [--maintenance-window-day=MAINTENANCE_WINDOW_DAY
      --maintenance-window-time=MAINTENANCE_WINDOW_TIME]
[--deny-maintenance-period-end-date=DENY_MAINTENANCE_PERIOD_END_DATE
      --deny-maintenance-period-start-date=DENY_MAINTENANCE_PERIOD_START_DATE
      --deny-maintenance-period-time=DENY_MAINTENANCE_PERIOD_TIME]
--kms-key=KMS_KEY_ID
[--fips-enabled]
    Ganti kode berikut:

    • MAINTENANCE_WINDOW_DAY: harus berupa salah satu dari hal berikut: friday, monday, saturday, sunday, thursday, tuesday, wednesday. Lihat halaman dokumentasi Mengelola kebijakan pemeliharaan untuk Looker (inti Google Cloud) untuk mengetahui informasi selengkapnya tentang setelan periode pemeliharaan.
    • MAINTENANCE_WINDOW_TIME dan DENY_MAINTENANCE_PERIOD_TIME: harus dalam waktu UTC dalam format 24 jam (misalnya, 13.00, 17.45).
    • DENY_MAINTENANCE_PERIOD_START_DATE dan DENY_MAINTENANCE_PERIOD_END_DATE: harus dalam format YYYY-MM-DD.
    • KMS_KEY_ID: harus berupa kunci yang dibuat saat menyiapkan kunci enkripsi yang dikelola pelanggan (CMEK).

    Anda dapat menyertakan flag --fips-enabled untuk mengaktifkan kepatuhan FIPS 140-2 level 1.

Terraform

Gunakan resource Terraform berikut untuk menyediakan instance Looker (Google Cloud core) Standard dengan fungsi dasar:

# Creates a Standard edition Looker (Google Cloud core) instance with basic functionality enabled.
resource "google_looker_instance" "main" {
  name             = "my-instance"
  platform_edition = "LOOKER_CORE_STANDARD"
  region           = "us-central1"
  oauth_config {
    client_id     = "my-client-id"
    client_secret = "my-client-secret"
  }
}

Gunakan resource Terraform berikut untuk menyediakan instance Looker (Google Cloud core) Standar dengan setelan tambahan yang diterapkan:

# Creates a Standard edition Looker (Google Cloud core) instance with full functionality enabled.

resource "google_looker_instance" "main" {
  name              = "my-instance"
  platform_edition  = "LOOKER_CORE_STANDARD"
  region            = "us-central1"
  public_ip_enabled = true
  admin_settings {
    allowed_email_domains = ["google.com"]
  }
  // User metadata config is only available when platform edition is LOOKER_CORE_STANDARD.
  user_metadata {
    additional_developer_user_count = 10
    additional_standard_user_count  = 10
    additional_viewer_user_count    = 10
  }
  maintenance_window {
    day_of_week = "THURSDAY"
    start_time {
      hours   = 22
      minutes = 0
      seconds = 0
      nanos   = 0
    }
  }
  deny_maintenance_period {
    start_date {
      year  = 2050
      month = 1
      day   = 1
    }
    end_date {
      year  = 2050
      month = 2
      day   = 1
    }
    time {
      hours   = 10
      minutes = 0
      seconds = 0
      nanos   = 0
    }
  }
  oauth_config {
    client_id     = "my-client-id"
    client_secret = "my-client-secret"
  }
}

Gunakan resource Terraform berikut untuk menyediakan instance Looker (Google Cloud core) Enterprise dengan koneksi jaringan pribadi:

# Creates an Enterprise edition Looker (Google Cloud core) instance with full, Private IP functionality.
resource "google_looker_instance" "main" {
  name               = "my-instance"
  platform_edition   = "LOOKER_CORE_ENTERPRISE_ANNUAL"
  region             = "us-central1"
  private_ip_enabled = true
  public_ip_enabled  = false
  reserved_range     = google_compute_global_address.main.name
  consumer_network   = data.google_compute_network.main.id
  admin_settings {
    allowed_email_domains = ["google.com"]
  }
  encryption_config {
    kms_key_name = google_kms_crypto_key.main.id
  }
  maintenance_window {
    day_of_week = "THURSDAY"
    start_time {
      hours   = 22
      minutes = 0
      seconds = 0
      nanos   = 0
    }
  }
  deny_maintenance_period {
    start_date {
      year  = 2050
      month = 1
      day   = 1
    }
    end_date {
      year  = 2050
      month = 2
      day   = 1
    }
    time {
      hours   = 10
      minutes = 0
      seconds = 0
      nanos   = 0
    }
  }
  oauth_config {
    client_id     = "my-client-id"
    client_secret = "my-client-secret"
  }
  depends_on = [
    google_service_networking_connection.main,
    google_kms_crypto_key.main
  ]
}

resource "google_kms_key_ring" "main" {
  name     = "keyring-example"
  location = "us-central1"
}

resource "google_kms_crypto_key" "main" {
  name     = "crypto-key-example"
  key_ring = google_kms_key_ring.main.id
}

resource "google_service_networking_connection" "main" {
  network                 = data.google_compute_network.main.id
  service                 = "servicenetworking.googleapis.com"
  reserved_peering_ranges = [google_compute_global_address.main.name]
}

resource "google_compute_global_address" "main" {
  name          = "looker-range"
  purpose       = "VPC_PEERING"
  address_type  = "INTERNAL"
  prefix_length = 20
  network       = data.google_compute_network.main.id
}

data "google_project" "main" {}

data "google_compute_network" "main" {
  name = "default"
}

resource "google_kms_crypto_key_iam_member" "main" {
  crypto_key_id = google_kms_crypto_key.main.id
  role          = "roles/cloudkms.cryptoKeyEncrypterDecrypter"
  member        = "serviceAccount:service-${data.google_project.main.number}@gcp-sa-looker.iam.gserviceaccount.com"
}

Untuk mempelajari cara menerapkan atau menghapus konfigurasi Terraform, lihat Perintah dasar Terraform.

Pembuatan instance tidak dapat dijeda atau dihentikan setelah dimulai. Jika resource Terraform berhasil disediakan, terminal akan mencetak pesan berikut:

Creation complete after XmXs [id=projects/PROJECT-ID/locations/REGION/instances/my-instance-randomly-generated-name]


Apply complete! Resources: X added, X changed, X destroyed.

Untuk melihat status instance baru Anda, yang akan diberi nama yang dibuat secara acak, buka halaman Instance di dalam konsol.

Saat instance sedang dibuat, Anda dapat melihat statusnya di halaman Instances dalam konsol. Anda juga dapat melihat aktivitas pembuatan instance dengan mengklik ikon notifikasi di menu konsol Google Cloud.

Setelah instance IP publik dibuat, URL publik instance akan muncul di kolom Instance URL di halaman Instances.

Setelah instance dibuat, siapkan URI pengalihan yang diberi otorisasi di klien OAuth yang telah Anda buat sebelumnya.

Setelah instance dibuat dan Anda telah menyelesaikan penyiapan OAuth, Anda dapat melihat instance dengan membuka URL instance, yang akan ditampilkan di halaman Instances.

Langkah selanjutnya