Crie análises com base no contexto

As Operações de Segurança do Google permitem que você veja a telemetria, o contexto da entidade, os relacionamentos e as vulnerabilidades como uma única detecção na sua conta das Operações de Segurança do Google. Ele fornece contextualização de entidades para permitir que você entenda os padrões comportamentais na telemetria e o contexto das entidades afetadas desses padrões.

Por exemplo:

  • Exibir as permissões para uma conta em que está sendo feita uma tentativa de login de força bruta.
  • A importância dos dados hospedados por um recurso que também é a origem da atividade de rede de saída.

Os clientes podem usar essa contextualização para filtragem de detecção, priorização heurística de alertas, triagem e investigação.

Os analistas de segurança e os engenheiros de detecção normalmente trabalham para criar uma detecção em um padrão básico de telemetria de eventos (uma conexão de rede de saída), criando inúmeras detecções para os analistas fazerem triagem. Os analistas tentam reunir um entendimento do que aconteceu para acionar o alerta e da importância da ameaça.

A análise baseada em contexto incorpora recursos avançados de enriquecimento anteriormente no fluxo de trabalho de execução e criação de detecção, permitindo que você forneça os seguintes recursos adicionais:

  • Disponibilização do contexto relevante para a pontuação de risco contextual das detecções orientada por heurística no momento da execução da detecção, e não no estágio de triagem humana
  • Reduzir o tempo gasto na triagem e na combinação manual de informações de sistemas de segurança de TI diferentes (consoles EDR, registros de firewall/proxy, contexto do CMDB e do IAM, resultados da verificação de vulnerabilidades)
  • Permitir que analistas e engenheiros de detecção filtrem clusters inteiros de ameaças que podem ser esperados ou representam pouco/nenhum perigo para a empresa (testes de malware em um ambiente de sandbox, vulnerabilidades e atividades anômalas em uma rede de desenvolvimento sem dados ou acesso confidenciais, entre outros)

Como criar regras para análises com base no contexto

Use as regras do mecanismo de detecção para pesquisar dados de contexto de entidades na sua conta das Operações de Segurança do Google.

Para pesquisar dados de contexto de entidade, siga estas etapas:

  1. Especifique uma fonte usando udm ou entidade.

    $eventname.[<source>].field1.field2 Para um contexto de entidade, <target> é "gráfico". Para um evento de UDM, <target> é "udm". Se omitido, o padrão de <source> é udm.

  2. Especifique os dados da entidade:

    $e1.graph.entity.hostname = "my-hostname"

    $e1.graph.entity.relations.relationship = "OWNS"

  3. Especificar dados de eventos de UDM. As instruções a seguir são equivalentes.

    $e1.udm.principal.asset_id = "my_asset_id"

    $e1.principal.asset_id = "my_asset_id"

É possível criar muitos dos mesmos tipos de regras para contextos de entidade que você criaria para eventos de UDM, incluindo o seguinte:

  • Várias regras de evento

  • Como comparar contextos de entidade com outros contextos de entidade

  • Como comparar contextos de entidade com eventos de UDM

  • Campos repetidos em contextos de entidade

  • Janelas deslizantes

  • Como calcular uma pontuação de risco para detecções

Ao contrário de um evento de UDM, o contexto de uma entidade não tem um carimbo de data/hora específico. Cada registro de contexto da entidade tem um intervalo de tempo, "entity.metadata.interval", em que o contexto da entidade é válido. Esse intervalo de tempo pode não ser um limite de dia e pode ter qualquer duração.

Um evento de UDM será correlacionado a um registro de contexto de entidade somente quando o carimbo de data/hora do evento de UDM estiver dentro do intervalo de tempo do registro de contexto da entidade. Se essa condição não for atendida, o UDM e a entidade não serão avaliados para detecções. O mecanismo de detecção aplica isso implicitamente, e você não precisa especificá-lo como uma condição em uma regra.

  • Ao comparar eventos de UDM a um contexto de entidade com o janelamento, um contexto de entidade representa um valor constante em uma janela especificada.
  • Se houver buckets do dia adjacentes em que o contexto da entidade muda seu valor, as Operações de Segurança do Google tentarão corresponder a todos os valores de contexto da entidade e retornar todas as correspondências encontradas.

Exemplo de regras

Como pesquisar entidades com contexto de administrador

A regra a seguir pesquisa entidades que também estão vinculadas a privilégios de administrador. Ela procura as vezes em que alguém com privilégio de administrador tentou fazer login ou sair do sistema.

rule LoginLogout {
  meta:
  events:
    ($log_inout.metadata.event_type = "USER_LOGIN" or  $log_inout.metadata.event_type = "USER_LOGOUT")
    $log_inout.principal.user.user_display_name = $user

    $context.graph.entity.user.user_display_name = $user
    $context.graph.entity.resource.attribute.roles.type = "ADMINISTRATOR"

  match:
    $user over 2m

  condition:
    $log_inout and $context
}

Exemplo de janela deslizante

O exemplo de janela deslizante a seguir é válido.

rule Detection {
  meta:
  events:
    $e1.graph.entity.hostname = $host
    $e2.udm.principal.hostname = $host

  match:
    // Using e2 (a UDM event) as a pivot.
    $host over 3h after $e2

  condition:
    $e1 and $e2
}

Exemplo de janela deslizante inválida

O exemplo de janela deslizante a seguir é inválido. O contexto da entidade não pode ser usado como uma tabela dinâmica para uma janela deslizante.

rule Detection {
  meta:
  events:
    $e1.graph.entity.hostname = $host
    $e2.udm.principal.hostname = $host

  match:
    // Attempting to use $e1 (an entity context) as a pivot. Invalid.
    $host over 3h after $e1

  condition:
    $e1 and $e2
}

Exemplo de login usando a seção de resultado

O exemplo a seguir usa a seção outcome para calcular uma pontuação de risco para a detecção.

rule Detection {
  meta:
  events:
    $auth.metadata.event_type = "USER_LOGIN"
    $auth.metadata.vendor_name = "Acme"
    $auth.metadata.product_name = "Acme SSO"
    $auth.target.user.userid = $user
    $auth.target.user.termination_date.seconds > 0

    $auth.metadata.event_timestamp.seconds >
       $context.graph.entity.user.termination_date.seconds

    $context.graph.metadata.vendor_name = "Microsoft"
    $context.graph.metadata.product_name = "Azure Active Directory"
    $context.graph.metadata.entity_type = "USER"
    $context.graph.entity.user.userid = $user
    $context.graph.entity.user.termination_date.seconds > 0

  match:
    $user over 15m

  outcome:
    $risk_score = max(
        if ( $auth.metadata.event_type = "USER_LOGIN", 50) +
        if (
            $context.graph.entity.user.title = "Remote" nocase or
            $context.graph.entity.user.title = "Temp" nocase or
            $context.graph.entity.user.title = "Vendor" nocase, 40) +
        if ( $context.graph.entity.user.title = "Legal" nocase, 10)
    )

  condition:
    $auth and $context
}

Exemplo de inicialização de processo suspeito

O exemplo a seguir avalia dados do processo do evento de UDM em relação aos dados de contexto de IOC armazenados como um contexto de entidade.

rule ProcessLaunch {
  meta:
  events:
    $ioc.graph.metadata.vendor_name = "ACME"
    $ioc.graph.metadata.product_name = "IOCs"
    $ioc.graph.metadata.entity_type = "FILE"
    $ioc.graph.entity.file.sha256 = $hash

    $process.metadata.event_type = "PROCESS_LAUNCH"
    $process.principal.hostname = $hostname
    (
        not $process.target.process.file.sha256 = "" and
        $process.target.process.file.sha256 = $hash
    )

  match:
    $hash over 15m

  condition:
    $ioc and $process
}

Outros qualificadores para o contexto da entidade

Para criar uma variável de evento que use um contexto de entidade, forneça um <source> após o nome do evento. O <source> precisa ser graph.

O padrão a seguir se refere a um contexto de entidade:

  • $e.graph.entity.hostname

Há dois métodos equivalentes para se referir a um evento de UDM:

  • $u.udm.principal.asset_id
  • $u.principal.asset_id

É possível misturar e combinar todos esses qualificadores no texto da regra. Também é possível usar qualificadores diferentes para o mesmo evento.

Seção de resultados

O mecanismo de detecção é compatível com uma seção outcome que permite derivar mais informações de uma regra. A lógica definida na seção outcome é avaliada em cada detecção. Se uma regra gera N detecções, cada uma das N detecções pode resultar em um conjunto diferente de resultados.

Veja um exemplo de regra que usa a seção outcome aqui.

O uso e a sintaxe detalhados de uma seção outcome podem ser encontrados nesta seção.

Seção de resultados e agrupamento de detecção de duplicação / eliminação

Para regras com uma seção de correspondência, lembre-se de que as detecções são "agrupadas por" as variáveis de correspondência. Isso faz com que a duplicação das detecções seja eliminada, de modo que uma linha seja retornada para cada conjunto exclusivo de variáveis de correspondência e janela de tempo.

As variáveis de resultado são ignoradas ao fazer essa eliminação de duplicação. Assim, se houver duas detecções diferentes com os mesmos valores para as variáveis de correspondência e a janela de tempo, mas com valores diferentes para as variáveis de resultado, a duplicação delas será eliminada, e você verá apenas uma detecção. Isso pode acontecer quando uma detecção foi criada devido à chegada tardia de dados, por exemplo. Aqui está um exemplo que ilustra este caso.

rule ExampleOutcomeRule {
  ...
  match:
    $hostname over <some window>
  outcome:
    $risk_score = <some logic here>
  ...
}

Esta regra resulta nas seguintes correspondências:

Detecção 1: nome do host: test-hostname janela de tempo: [t1, t2] risk_score: 10

Detecção 2: nome do host: test-hostname janela de tempo: [t1, t2] risk_score: 73

Como as variáveis de correspondência e a janela de tempo são as mesmas para a Detecção 1 e a Detecção 2, a duplicação delas será eliminada, e você verá apenas uma detecção, mesmo que a variável de resultado, risk_score, seja diferente.

A seguir

Para informações sobre como as operações de segurança do Google ingere dados contextuais e enriquece entidades, consulte Como as operações de segurança do Google enriquecem dados de eventos e entidades.