Application Integration でサポートされているコネクタをご覧ください。

認証プロファイルを管理する

Application Integration のタスクでは、外部アプリケーション、サービス、データソースへの接続が必要になる場合があります。認証プロファイルを使用すると、Application Integration で接続の認証情報を構成して保存できます。保存された認証プロファイルを使用するようにタスクを構成できます。認証プロファイルの作成は 1 回限りのアクティビティであり、同じプロファイルを複数の統合で再利用できます。

必要なロール

認証プロファイルの管理に必要な権限を取得するには、統合に関する次の IAM ロールを付与するよう管理者に依頼してください。

Application Integration 管理者（roles/integrations.integrationAdmin）
認証プロファイルを作成する: Application Integration 編集者（roles/integrations.integrationEditor）
認証プロファイルを編集する: Application Integration 編集者（roles/integrations.integrationEditor）
認証プロファイルを削除する: Application Integration 管理者（roles/integrations.integrationAdmin）

ロールの付与については、プロジェクト、フォルダ、組織へのアクセスを管理するをご覧ください。

必要な権限は、カスタムロールや他の事前定義ロールから取得することもできます。

OAuth 2.0 クライアント ID を作成する

クライアント ID は、Google の OAuth サーバーで個々のアプリケーションを識別するために使用します。アプリケーションが複数のプラットフォームで実行されている場合は、それぞれに独自のクライアント ID が必要です。 OAuth 2.0 をアプリケーションで使用するには OAuth 2.0 クライアント ID が必要です。アプリケーションは OAuth 2.0 アクセストークンを要求するときにこの ID を使用します。

OAuth 2.0 クライアント ID を作成するには、次の手順に従います。

Google Cloud コンソールで、[API とサービス] の [認証情報] に移動します。
認証情報に進む
[+ 認証情報の作成] をクリックし、使用可能なオプションのリストから [OAuth クライアント ID] を選択します。
[OAuth クライアント ID の作成] ページが表示されます。
アプリケーションの種類: プルダウンリストから [ウェブアプリケーション] を選択します。
名前: OAuth 2.0 クライアントの名前を入力して、Cloud コンソールでクライアントを識別します。
[承認済みのリダイレクト URI] で、[+ URI を追加] をクリックして次のように入力します。
```
 https://console.cloud.google.com/integrations/callback/locations/AUTH_PROFILE_REGION
```
[作成] をクリックします。
OAuth 2.0 クライアント ID が正常に作成されました。

新しい認証プロファイルの作成

新しい認証プロファイルを作成するには、次のいずれかのオプションを選択します。

Console

Google Cloud コンソールで [Application Integration] ページに移動します。
Application Integration に移動
ナビゲーションメニューで [Auth プロファイル] をクリックします。

[Authentication Profiles] ページが表示されます。

[作成] をクリックして、次の詳細を入力します。
- [プロファイル名] フィールドに、統合エディタに表示する認証プロファイルの名前を入力します。
- [リージョン] リストから、認証プロファイルのリージョンを選択します。
- [説明] フィールドに、認証プロファイルの説明を入力します。
- [続行] をクリックします。
- [認証タイプ] リストから認証タイプを選択し、必要な詳細を入力します。選択した内容に基づいて、認証情報に必要な追加フィールドがダイアログに表示されます。次の認証タイプのいずれかを選択できます。
- 必要に応じて、サーバーがクライアントの ID を検証するために使用する SSL/TLS クライアント証明書を追加できます。次のフィールドに入力できます。
  1. SSL 証明書
  2. 秘密鍵
  3. 秘密鍵のパスフレーズ
[作成] をクリックします。

Terraform

google_integrations_client リソースを使用します。 Terraform を使用して、次の認証プロファイルを作成できます。

認証トークン
SSL/TLS クライアント証明書のみ
JSON Web Token（JWT）
OAuth 2.0 認証コード
OAuth 2.0 クライアント認証情報
OIDC ID トークン
サービスアカウント

認証トークン

次の例では、us-central1 リージョンに認証トークン認証タイプを作成します。

resource "google_integrations_client" "client" {
  location = "us-central1"
}

resource "google_integrations_auth_config" "auth_config_auth_token" {
  location     = "us-central1"
  display_name = "tf-auth-token"
  description  = "Test auth config created via terraform"
  decrypted_credential {
    credential_type = "AUTH_TOKEN"
    auth_token {
      type  = "Basic"
      token = "some-random-token"
    }
  }
  depends_on = [google_integrations_client.client]
}

SSL / TLS クライアント認証

次の例では、us-central1 リージョンに SSL / TLS クライアント証明書認証タイプを作成します。

resource "google_integrations_auth_config" "auth_config_certificate" {
  location     = "us-central1"
  display_name = "tf-certificate"
  description  = "Test auth config created via terraform"
  decrypted_credential {
    credential_type = "CLIENT_CERTIFICATE_ONLY"
  }
  client_certificate {
    ssl_certificate       = <<EOT
-----BEGIN CERTIFICATE-----
MIICTTCCAbagAwIBAgIJAPT0tSKNxan/MA0GCSqGSIb3DQEBCwUAMCoxFzAVBgNV
BAoTDkdvb2dsZSBURVNUSU5HMQ8wDQYDVQQDEwZ0ZXN0Q0EwHhcNMTUwMTAxMDAw
MDAwWhcNMjUwMTAxMDAwMDAwWjAuMRcwFQYDVQQKEw5Hb29nbGUgVEVTVElORzET
MBEGA1UEAwwKam9lQGJhbmFuYTCBnzANBgkqhkiG9w0BAQEFAAOBjQAwgYkCgYEA
vDYFgMgxi5W488d9J7UpCInl0NXmZQpJDEHE4hvkaRlH7pnC71H0DLt0/3zATRP1
JzY2+eqBmbGl4/sgZKYv8UrLnNyQNUTsNx1iZAfPUflf5FwgVsai8BM0pUciq1NB
xD429VFcrGZNucvFLh72RuRFIKH8WUpiK/iZNFkWhZ0CAwEAAaN3MHUwDgYDVR0P
AQH/BAQDAgWgMB0GA1UdJQQWMBQGCCsGAQUFBwMBBggrBgEFBQcDAjAMBgNVHRMB
Af8EAjAAMBkGA1UdDgQSBBCVgnFBCWgL/iwCqnGrhTPQMBsGA1UdIwQUMBKAEKey
Um2o4k2WiEVA0ldQvNYwDQYJKoZIhvcNAQELBQADgYEAYK986R4E3L1v+Q6esBtW
JrUwA9UmJRSQr0N5w3o9XzarU37/bkjOP0Fw0k/A6Vv1n3vlciYfBFaBIam1qRHr
5dMsYf4CZS6w50r7hyzqyrwDoyNxkLnd2PdcHT/sym1QmflsjEs7pejtnohO6N2H
wQW6M0H7Zt8claGRla4fKkg=
-----END CERTIFICATE-----
EOT
    encrypted_private_key = <<EOT
-----BEGIN PRIVATE KEY-----
MIIEvQIBADANBgkqhkiG9w0BAQEFAASCBKcwggSjAgEAAoIBAQCA/Oj2HXqs5fTk
j/8DrlOQtLG3K9RMsYHvnwICLxkGqVcTfut58hDFLbQM8C3C0ENAKitNJplCJmYG
8VpgZzgq8VxaGnlP/sXUFLMGksd5sATn0sY3SkPndTKk/dqqA4MIh/dYfh19ynEN
hB9Ll/h54Yic2je2Qaxe/uMMu8RODTz3oCn7FcoYpPvfygfU0ntn4IcqH/hts5DG
s+3otJk4entRZglQDxR+sWOsbLtJIQZDP8rH3jDVdl5l3wspgtMTY8b5T5+pLm0p
/OzCmxT0dq/O6BhpxI1xf/zcdRZeWk5DTJxTi5AgPquTlAG/B6A3HkqBJ14hT/Rk
iv7Ma3DLAgMBAAECggEABATkf9VfpiAT9zYdouk50bBpckvymQTyQLD8SlBaX+KY
kgv/pHSXK4Pm4iensrQerFLgfqPA3U+FiqjW5Mv7c1VRK6HJbuVkpdzoXLI9IQsL
vsBY7//9Ajk5P7NokjdB6JPdU/2dHROuQVa59cxPtzpHo0htnPlDOKXfFZZuoZ17
Nr8WQHrHy8P8ABM1tLOzvU9Nlh7TcjQvev+HxkLek4qzYyJ/Ac7XOjg/XKUm1tZk
O3BHr8YLabwyjO7l1t+2b14rUTL/8pfUZnAkEi3FAlPxm3ilftmX65zliC9G4ghk
dr5PByT3DqnuIIglua9bISv1H34ogecd+9a6EU7RxQKBgQC2RPKLounXZo8vYiU4
sFTEvjbs+u9Ypk4OrNLnb8KdacLBUaJGnf++xbBoKpwFCBJfy//fvuQfusYF9Gyn
GxL43tw94C/H5upQYnDsmnQak6TbOu3mA24OGK7Rcq6NEHgeCY4HomutnSiPTZJq
8jlpqgqh1itETe5avgkMNq3zBwKBgQC1KlztGzvbB+rUDc6Kfvk5pUbCSFKMMMa2
NWNXeD6i2iA56zEYSbTjKQ3u9pjUV8LNqAdUFxmbdPxZjheNK2dEm68SVRXPKOeB
EmQT+t/EyW9LqBEA2oZt3h2hXtK8ppJjQm4XUCDs1NphP87eNzx5FLzJWjG8VqDq
jOvApNqPHQKBgDQqlZSbgvvwUYjJOUf5R7mri0LWKwyfRHX0xsQQe43cCC6WM7Cs
Zdbu86dMkqzp+4BJfalHFDl0llp782D8Ybiy6CwZbvNyxptNIW7GYfZ9TVCllBMh
5izIqbgub4DWNtq591l+Bf2BnmstU3uiagYw8awSBP4eo9p6y1IgkDafAoGBAJbi
lIiqEP0IqA06/pWc0Qew3rD7OT0ndqjU6Es2i7xovURf3QDkinJThBZNbdYUzdsp
IgloP9yY33/a90SNLLIYlARJtyNVZxK59X4qiOpF9prlfFvgpOumfbkj15JljTB8
aGKkSvfVA5jRYwLysDwMCHwO0bOR1u3itos5AgsFAoGAKEGms1kuQ5/HyFgSmg9G
wBUzu+5Y08/A37rvyXsR6GjmlZJvULEopJNUNCOOpITNQikXK63sIFry7/59eGv5
UwKadZbfwbVF5ipu59UxfVE3lipf/mYePDqMkHVWv/8p+OnnJt9uKnyW8VSOu5uk
82QF30zbIWDTUjrcugVAs+E=
-----END PRIVATE KEY-----
EOT
  }
  depends_on = [google_integrations_client.client]
}

JSON Web Token（JWT）

次の例では、us-central1 リージョンに JSON Web Token（JWT）認証タイプを作成します。

resource "google_integrations_auth_config" "auth_config_jwt" {
  location     = "us-central1"
  display_name = "tf-jwt"
  description  = "Test auth config created via terraform"
  decrypted_credential {
    credential_type = "JWT"
    jwt {
      jwt_header  = "{\"alg\": \"HS256\", \"typ\": \"JWT\"}"
      jwt_payload = "{\"sub\": \"1234567890\", \"name\": \"John Doe\", \"iat\": 1516239022}"
      secret      = "secret"
    }
  }
  depends_on = [google_integrations_client.client]
}

OAuth 2.0 認証コード

次の例では、us-central1 リージョンに SSL / TLS クライアント証明書認証タイプを作成します。

resource "google_integrations_auth_config" "auth_config_oauth2_authorization_code" {
  location     = "us-central1"
  display_name = "tf-oauth2-authorization-code"
  description  = "Test auth config created via terraform"
  decrypted_credential {
    credential_type = "OAUTH2_AUTHORIZATION_CODE"
    oauth2_authorization_code {
      client_id      = "Kf7utRvgr95oGO5YMmhFOLo8"
      client_secret  = "D-XXFDDMLrg2deDgczzHTBwC3p16wRK1rdKuuoFdWqO0wliJ"
      scope          = "photo offline_access"
      auth_endpoint  = "https://authorization-server.com/authorize"
      token_endpoint = "https://authorization-server.com/token"
    }
  }
  depends_on = [google_integrations_client.client]
}

OAuth 2.0 クライアント認証情報

次の例では、us-central1 リージョンに OAuth 2.0 クライアント認証情報認証タイプを作成します。

resource "google_integrations_auth_config" "auth_config_oauth2_client_credentials" {
  location     = "us-central1"
  display_name = "tf-oauth2-client-credentials"
  description  = "Test auth config created via terraform"
  decrypted_credential {
    credential_type = "OAUTH2_CLIENT_CREDENTIALS"
    oauth2_client_credentials {
      client_id      = "demo-backend-client"
      client_secret  = "MJlO3binatD9jk1"
      scope          = "read"
      token_endpoint = "https://login-demo.curity.io/oauth/v2/oauth-token"
      request_type   = "ENCODED_HEADER"
      token_params {
        entries {
          key {
            literal_value {
              string_value = "string-key"
            }
          }
          value {
            literal_value {
              string_value = "string-value"
            }
          }
        }
      }
    }
  }
  depends_on = [google_integrations_client.client]
}

Google OIDC ID トークン

次の例では、us-central1 リージョンに Google OIDC ID トークン認証タイプを作成します。

resource "random_id" "default" {
  byte_length = 8
}

resource "google_service_account" "service_account" {
  account_id   = "sa-${random_id.default.hex}"
  display_name = "Service Account"
}

resource "google_integrations_auth_config" "auth_config_oidc_token" {
  location     = "us-central1"
  display_name = "tf-oidc-token"
  description  = "Test auth config created via terraform"
  decrypted_credential {
    credential_type = "OIDC_TOKEN"
    oidc_token {
      service_account_email = google_service_account.service_account.email
      audience = "https://us-central1-project.cloudfunctions.net/functionA 1234987819200.apps.googleusercontent.com"
    }
  }
depends_on = [google_service_account.service_account, google_integrations_client.client]
}

サービスアカウント

次の例では、us-central1 リージョンにサービスアカウント認証タイプを作成します。

resource "random_id" "default" {
  byte_length = 8
}
  
resource "google_service_account" "service_account" {
  account_id   = "sa-${random_id.default.hex}"
  display_name = "Service Account"
}
resource "google_integrations_auth_config" "auth_config_service_account" {
  location     = "us-central1"
  display_name = "tf-service-account"
  description  = "Test auth config created via terraform"
  decrypted_credential {
    credential_type = "SERVICE_ACCOUNT"
    service_account_credentials {
    service_account = google_service_account.service_account.email
    scope = "https://www.googleapis.com/auth/cloud-platform https://www.googleapis.com/auth/adexchange.buyer https://www.googleapis.com/auth/admob.readonly"
    }
  }
depends_on = [google_service_account.service_account, google_integrations_client.client]
}

保存すると、新しい認証プロファイルは、認証が必要なタスクの [Authorization profile to use] プルダウンのオプションとして使用できるようになります。

（省略可）統合タスクを構成する前に認証プロファイルを作成していない場合は、タスク構成ペインで、[使用する認証プロファイル] プルダウンから [+ 新しい認証プロファイルを追加] を選択して、プロファイル作成ダイアログにアクセスできます。前述の手順で新しい認証プロファイルを作成します。

認証プロファイルを編集する

認証プロファイルを編集するには、次の手順を実行します。

Google Cloud コンソールで [Application Integration] ページに移動します。
Application Integration に移動
ナビゲーションメニューで [Auth プロファイル] をクリックします。

[Authentication Profiles] ページが表示されます。

[Authentication Profiles] ページのプルダウンメニューを使用して、認証プロファイルの [リージョン] を選択します。
（アクションメニュー）をクリックし、[編集] をクリックします。
[認証プロファイル] ダイアログが表示されます。
詳細を編集し、[保存] をクリックします。

認証プロファイルを削除する

認証プロファイルを削除するには、次の手順を実行します。

Google Cloud コンソールで [Application Integration] ページに移動します。
Application Integration に移動
ナビゲーションメニューで [Auth プロファイル] をクリックします。

[Authentication Profiles] ページが表示されます。

[Authentication Profiles] ページのプルダウンメニューを使用して、認証プロファイルの [リージョン] を選択します。
[削除] をクリックします。

認証の種類

統合タスクを完了するために必要な認証タイプは、認可サーバーで構成された認証によって異なります。認可サーバーには、スタンドアロンサーバー、または呼び出し元クライアントに認証情報を発行する API を使用できます。Application Integration では、次の認証タイプがサポートされています。

認証トークン
Google OIDC ID トークン
JSON Web Token（JWT）
OAuth 2.0 認証コード
OAuth 2.0 クライアント認証情報
OAuth 2.0 のリソースオーナーパスワード認証情報
SSL/TLS クライアント証明書のみ
サービスアカウント

以降のセクションでは、認証タイプの構成プロパティについて説明します。

認証トークン

認証トークンでは、トークン（認証情報）が使用されます。認証情報は、Authorization: TYPE CREDENTIALS 形式の HTTP Authorization リクエストヘッダーでサーバーに送信されます。この認証タイプを構成するには、次のプロパティを設定します。

タイプ: 認証タイプ（Basic、Bearer、MAC など）。
トークン: 認証タイプの認証情報。

認証サーバーで SSL/TLS 証明書が必要な場合は、証明書と秘密鍵をアップロードします。