Globalen externen HTTP(S)-Load-Balancer (klassisch) mit Cloud Storage-Buckets einrichten

Dieses Dokument beschreibt, wie Sie einen externen HTTP(S)-Load-Balancer erstellen, um Anfragen für statische Inhalte an Cloud Storage-Buckets weiterzuleiten. Nachdem Sie einen Load-Balancer mit den Back-End-Buckets konfiguriert haben, werden mit /love-to-fetch beginnende Anfragen an URL-Pfade an den Cloud us-east1-Cloud-Storage-Bucket gesendet. Alle anderen Anfragen werden an den europe-north1-Cloud Storage-Bucket gesendet, unabhängig von der Region des Nutzers.

Wenn Ihre Back-Ends dynamische Inhalte über HTTP(S) bereitstellen, sollten Sie statt Back-End-Diensten Back-End-Buckets verwenden.

Eine detaillierte Anleitung dazu finden Sie direkt in der Google Cloud Console. Klicken Sie dazu einfach auf Anleitung:

Anleitung

Cloud Storage-Buckets als Back-Ends des Load-Balancers

Ein externer HTTP(S)-Load-Balancer leitet über eine URL-Zuordnung Traffic von angegebenen URL-Pfaden an Ihre Back-Ends weiter.

Im folgenden Diagramm sendet der Load-Balancer Traffic mit dem Pfad /love-to-fetch/ an einen Cloud Storage-Bucket in der Region us-east1. Alle anderen Anfragen werden an einen Cloud Storage-Bucket in der Region europe-north1 gesendet.

Der Load-Balancer sendet Traffic an ein Cloud Storage-Back-End. — Traffic an Cloud Storage verteilen

Cloud Storage verwendet standardmäßig den gleichen Cache wie Cloud CDN. Wenn Sie Cloud CDN für den Back-End-Bucket aktivieren, können Sie Cloud CDN-Steuerelemente für Ihre Inhalte verwenden. Cloud CDN-Steuerelemente umfassen beispielsweise Cache-Modi, signierte URLs und Entwertung. Mit Cloud CDN können Sie auch große Inhalte (> 10 MB) im Cache speichern. Wenn Sie Cloud CDN nicht für Ihren Back-End-Bucket aktivieren, können Sie nur Cache-Control-Ursprungsheader verwenden, um das Caching für kleinere Inhalte zu steuern, wie durch die Cloud Storage-Metadaten festgelegt.

Hinweis

Richten Sie Ihr System so ein, dass die folgenden Voraussetzungen erfüllt sind. Wenn Sie die Dienstprogramme gcloud und gsutil verwenden, können Sie beide entsprechend den Erläuterungen in der Kurzanleitung: gsutil-Tool verwenden installieren.

Standardprojekt festlegen

Console

Melden Sie sich bei Ihrem Google Cloud-Konto an. Wenn Sie mit Google Cloud noch nicht vertraut sind, erstellen Sie ein Konto, um die Leistungsfähigkeit unserer Produkte in der Praxis sehen und bewerten zu können. Neukunden erhalten außerdem ein Guthaben von 300 $, um Arbeitslasten auszuführen, zu testen und bereitzustellen.

Wählen Sie in der Google Cloud Console auf der Seite der Projektauswahl ein Google Cloud-Projekt aus oder erstellen Sie eines.

Zur Projektauswahl

Die Abrechnung für das Cloud-Projekt muss aktiviert sein. So prüfen Sie, ob die Abrechnung für ein Projekt aktiviert ist.

Wählen Sie in der Google Cloud Console auf der Seite der Projektauswahl ein Google Cloud-Projekt aus oder erstellen Sie eines.

Zur Projektauswahl

Die Abrechnung für das Cloud-Projekt muss aktiviert sein. So prüfen Sie, ob die Abrechnung für ein Projekt aktiviert ist.

gcloud/gsutil

gcloud config set project PROJECT_ID

oder

gsutil config set project PROJECT_ID

Ersetzen Sie PROJECT_ID durch das Projekt, das Sie für diesen Leitfaden verwenden.

Terraform

export GOOGLE_CLOUD_PROJECT=PROJECT_ID

Berechtigungen

Um diesem Leitfaden zu folgen, müssen Sie Cloud Storage-Buckets und einen Load-Balancer in einem Projekt erstellen. Sie sollten entweder Inhaber oder Bearbeiter des Projekts sein oder die folgenden IAM-Rollen für Compute Engine haben:

Aufgabe	Erforderliche Rolle
Load-Balancer-Komponenten erstellen	Netzwerkadministrator
Cloud Storage-Buckets erstellen	Storage-Objekt-Administrator

Weitere Informationen finden Sie in folgenden Leitfäden:

SSL-Zertifikatsressource einrichten

Erstellen Sie für einen HTTPS-Load-Balancer eine SSL-Zertifikatsressource, wie in der folgenden Dokumentation beschrieben:

Wir empfehlen die Verwendung eines von Google verwalteten Zertifikats.

In diesem Beispiel wird angenommen, dass Sie bereits eine SSL-Zertifikatsressource mit dem Namen www-ssl-cert haben.

Cloud Storage-Buckets und Inhalte vorbereiten

So bereiten Sie die Cloud Storage-Buckets vor:

Erstellen Sie die Buckets.
Kopieren Sie Inhalte in die Buckets.
Gewähren Sie öffentlichen Zugriff auf die Buckets.

Cloud Storage-Buckets erstellen

In diesem Beispiel erstellen Sie zwei Cloud Storage-Buckets für den Zugriff durch den Load-Balancer. Für Produktionsbereitstellungen empfehlen wir die Auswahl eines multiregionalen Buckets, der Objekte automatisch in mehreren Google Cloud-Regionen repliziert. Dies kann die Verfügbarkeit Ihrer Inhalte verbessern und die Fehlertoleranz in Ihrer gesamten Anwendung verbessern.

Notieren Sie die Namen der von Ihnen erstellten Cloud Storage-Buckets, da sie später verwendet werden. In diesem Leitfaden werden sie als BUCKET_1_NAME und BUCKET_2_NAME bezeichnet.

Console

Wechseln Sie in der Google Cloud Console zur Seite Cloud Storage-Buckets.

Cloud Storage-Bucket aufrufen
Klicken Sie auf Bucket erstellen.
Geben Sie im Feld Bucket benennen einen global eindeutigen Namen ein, der den Benennungsrichtlinien entspricht.
Klicken Sie auf Speicherort für Daten auswählen.
Legen Sie Standorttyp auf Region fest.
Setzen Sie Standort auf europe-north1. Dies ist BUCKET_1_NAME in diesem Leitfaden.
Klicken Sie auf Erstellen.
Klicken Sie auf Buckets, um zur Seite "Cloud Storage-Bucket" zurückzukehren. Folgen Sie dieser Anleitung, um einen zweiten Bucket zu erstellen. Legen Sie dabei den Standort jedoch auf us-east1 fest. Dies ist BUCKET_2_NAME in diesem Leitfaden.

gcloud/gsutil

gsutil mb -p PROJECT_ID -c standard -l europe-north1 -b on gs://BUCKET_1_NAME

gsutil mb -p PROJECT_ID -c standard -l us-east1 -b on gs://BUCKET_2_NAME

Ersetzen Sie BUCKET_1_NAME und BUCKET_2_NAME durch die Namen der Buckets, die Sie erstellen möchten.

Terraform

Verwenden Sie zum Erstellen der Buckets die Ressource google_storage_bucket.

external_http_lb_bucket_backend/main.tf

Auf GitHub ansehen Feedback

# Create Cloud Storage buckets
resource "random_id" "bucket_prefix" {
  byte_length = 8
}

resource "google_storage_bucket" "bucket_1" {
  name                        = "${random_id.bucket_prefix.hex}-bucket-1"
  location                    = "us-east1"
  uniform_bucket_level_access = true
  storage_class               = "STANDARD"
  // delete bucket and contents on destroy.
  force_destroy = true
}

resource "google_storage_bucket" "bucket_2" {
  name                        = "${random_id.bucket_prefix.hex}-bucket-2"
  location                    = "us-east1"
  uniform_bucket_level_access = true
  storage_class               = "STANDARD"
  // delete bucket and contents on destroy.
  force_destroy = true
}

Informationen zum Anwenden oder Entfernen einer Terraform-Konfiguration finden Sie unter Grundlegende Terraform-Befehle.

Inhalte in Cloud Storage-Buckets übertragen

Sie können die Einrichtung später testen, indem Sie die folgenden Images aus einem öffentlichen Cloud Storage-Bucket in Ihre eigenen Cloud Storage-Buckets kopieren.

gcloud/gsutil

Klicken Sie auf Google Cloud Shell aktivieren.
Führen Sie in Cloud Shell die folgenden Befehle aus und ersetzen Sie die Variablen für die Bucket-Namen durch Ihre Cloud Storage-Bucket-Namen:

gsutil cp gs://gcp-external-http-lb-with-bucket/three-cats.jpg gs://BUCKET_1_NAME/never-fetch/

gsutil cp gs://gcp-external-http-lb-with-bucket/two-dogs.jpg gs://BUCKET_2_NAME/love-to-fetch/

Terraform

Zum Kopieren von Elementen in den Bucket können Sie die Ressource google_storage_bucket_object verwenden.

external_http_lb_bucket_backend/main.tf

Auf GitHub ansehen Feedback

resource "google_storage_bucket_object" "cat_image" {
  name         = "never-fetch/three-cats.jpg"
  source       = "images/three-cats.jpg"
  content_type = "image/jpeg"

  bucket = google_storage_bucket.bucket_1.name
}

resource "google_storage_bucket_object" "dog_image" {
  name         = "love-to-fetch/two-dogs.jpg"
  source       = "images/two-dogs.jpg"
  content_type = "image/jpeg"

  bucket = google_storage_bucket.bucket_2.name
}

Alternativ können Sie die null_resource-Ressource verwenden.

resource "null_resource" "upload_cat_image" {
  provisioner "local-exec" {
    command = "gsutil cp -r gs://gcp-external-http-lb-with-bucket/three-cats.jpg gs://${google_storage_bucket.bucket_1.name}/never-fetch/"
  }
}

resource "null_resource" "upload_dog_image" {
  provisioner "local-exec" {
    command = "gsutil cp -r gs://gcp-external-http-lb-with-bucket/two-dogs.jpg gs://${google_storage_bucket.bucket_2.name}/love-to-fetch/"
  }
}

Klicken Sie in der Google Cloud Console auf der Detailseite jedes Buckets auf Aktualisieren, um zu prüfen, ob die Datei erfolgreich kopiert wurde.

Cloud Storage-Buckets öffentlich lesbar machen

Wenn Sie Cloud Storage-Buckets öffentlich lesbar machen, kann jeder im Internet die zugehörigen Objekte auflisten und ansehen sowie die zugehörigen Metadaten (mit Ausnahme von ACLs) aufrufen. Nehmen Sie keine vertraulichen Informationen in Ihre öffentlichen Buckets auf.

Speichern Sie keine öffentlichen Objekte und sensiblen Daten im selben Bucket, um die Wahrscheinlichkeit einer versehentlichen Veröffentlichung vertraulicher Informationen zu verringern. Weitere Informationen finden Sie unter Empfohlene Bucket-Architektur.

Console

Um allen Nutzern Zugriff auf Objekte in Ihren Buckets zu gewähren, wiederholen Sie das folgende Verfahren für jeden Bucket:

Wechseln Sie in der Google Cloud Console zur Seite Cloud Storage-Buckets.

Cloud Storage-Bucket aufrufen
Klicken Sie auf den Bucket-Namen und dann auf den Tab Berechtigungen.
Klicken Sie auf Add.
Geben Sie im Feld Neue Hauptkonten allUsers ein.
Wählen Sie im Feld Rolle auswählen die Option Cloud Storage > Storage-Objekt-Betrachter aus.
Klicken Sie auf Speichern.
Klicken Sie auf Öffentlichen Zugriff erlauben.

gcloud/gsutil

Führen Sie die folgenden Befehle aus, um allen Nutzern Zugriff auf Objekte in Ihren Buckets zu gewähren:

gsutil iam ch allUsers:objectViewer gs://BUCKET_1_NAME

gsutil iam ch allUsers:objectViewer gs://BUCKET_2_NAME

Terraform

Verwenden Sie die Ressource google_storage_bucket_iam_member, um allen Nutzern Zugriff auf Objekte in Ihren Buckets zu gewähren, und geben Sie das Mitglied allUsers an.

external_http_lb_bucket_backend/main.tf

Auf GitHub ansehen Feedback

# Make buckets public
resource "google_storage_bucket_iam_member" "bucket_1" {
  bucket = google_storage_bucket.bucket_1.name
  role   = "roles/storage.objectViewer"
  member = "allUsers"
}

resource "google_storage_bucket_iam_member" "bucket_2" {
  bucket = google_storage_bucket.bucket_2.name
  role   = "roles/storage.objectViewer"
  member = "allUsers"
}

Externe IP-Adresse reservieren

Nachdem Sie Ihre Cloud Storage-Buckets eingerichtet haben, können Sie eine globale statische externe IP-Adresse reservieren, die Ihre Zielgruppe verwendet, um Ihren Load-Balancer zu erreichen.

Dieser Schritt ist optional, wird jedoch empfohlen, da eine statische externe IP-Adresse eine einzelne Adresse bietet, auf die Ihre Domain verweisen soll.

Console

Gehen Sie in der Google Cloud Console auf die Seite Externe IP-Adressen.

Zu externen IP-Adressen
Klicken Sie auf Statische Adresse reservieren.
Geben Sie im Feld Name den Wert example-ip ein.
Setzen Sie die Netzwerkdienststufe auf Premium.
Setzen Sie die IP-Version auf IPv4.
Legen Sie für Typ Global fest.
Klicken Sie auf Reservieren.

gcloud/gsutil

gcloud compute addresses create example-ip \
    --network-tier=PREMIUM \
    --ip-version=IPV4 \
    --global

Notieren Sie sich die reservierte IPv4-Adresse:

gcloud compute addresses describe example-ip \
    --format="get(address)" \
    --global

Terraform

Verwenden Sie zum Reservieren der externen IP-Adresse die Ressource google_compute_global_address.

external_http_lb_bucket_backend/main.tf

Auf GitHub ansehen Feedback

# Reserve IP address
resource "google_compute_global_address" "default" {
  name = "example-ip"
}

Externen HTTP(S)-Load-Balancer mit Back-End-Buckets erstellen

In dieser Anleitung wird beschrieben, wie Sie einen HTTP- oder einen HTTPS-Load-Balancer erstellen. Zum Erstellen eines HTTPS-Load-Balancers müssen Sie dem Front-End des Load-Balancers eine SSL-Zertifikatsressource hinzufügen. Weitere Informationen finden Sie in der Übersicht zu SSL-Zertifikaten.

Console

Konfiguration starten

Öffnen Sie in der Google Cloud Console die Seite "Load-Balancing".

Load-Balancing aufrufen
Klicken Sie auf Load-Balancer erstellen.
Klicken Sie in der Karte HTTP(S)-Load-Balancing auf Konfiguration starten.
Wählen Sie unter Internet oder nur intern die Option Vom Internet zu meinen VMs oder serverlosen Diensten aus.
Wählen Sie unter Global oder regional die Option Globaler HTTP(S)-Load-Balancer (klassisch) aus.
Klicken Sie auf Weiter.

Back-End konfigurieren

Geben Sie im Feld Name den Wert http-lb ein.
Klicken Sie auf Back-End-Konfiguration.
Klicken Sie auf das Feld Back-End-Dienste und Back-End-Buckets und dann auf Back-End-Bucket erstellen.
Geben Sie im Feld Name des Back-End-Buckets den Wert cats ein.
Klicken Sie im Feld Cloud Storage-Bucket auf Durchsuchen.
Wählen Sie BUCKET_1_NAME aus und klicken Sie dann auf Auswählen. Wenn Sie den Back-End-Bucket cats zuerst erstellen, wird dieser zum Standard-Bucket, an den alle nicht übereinstimmenden Trafficanfragen weitergeleitet werden. Sie können die Weiterleitungsregeln eines Standard-Back-End-Buckets im Load-Balancer nicht ändern.
Klicken Sie auf Erstellen.
Verwenden Sie denselben Prozess, um einen Back-End-Bucket mit dem Namen dogs zu erstellen, und wählen Sie BUCKET_2_NAME aus.
Klicken Sie auf OK.

Routingregeln konfigurieren

Routingregeln bestimmen, wie Ihr Traffic weitergeleitet wird. Um das Routing zu konfigurieren, richten Sie Hostregeln und Pfad-Matcher ein, die Konfigurationskomponenten der URL-Zuordnung eines externen HTTP(S)-Load-Balancers sind. So richten Sie die Regeln für dieses Beispiel ein:

Klicken Sie auf Host- und Pfadregeln.
Geben Sie für dogs den Wert * im Feld Hosts und /love-to-fetch/* im Feld Pfade ein.

Front-End konfigurieren

Klicken Sie auf Front-End-Konfiguration.

Prüfen Sie, ob die folgenden Optionen mit diesen Werten konfiguriert sind:

Attribut	Wert (Wert eingeben bzw. Option auswählen)
Protokoll	HTTP
Netzwerkdienststufe	Premium
IP-Version	IPv4
IP-Adresse	Beispiel-IP
Port	80

Wenn Sie einen HTTPS-Load-Balancer statt eines HTTP-Load-Balancers erstellen möchten, benötigen Sie ein SSL-Zertifikat (gcloud compute ssl-certificates list) und müssen die Felder so ausfüllen:

Attribut	Wert (Wert eingeben bzw. Option auswählen)
Protokoll	HTTP(S)
Netzwerkdienststufe	Premium
IP-Version	IPv4
IP-Adresse	Beispiel-IP
Port	443
Wählen Sie ein Zertifikat aus oder erstellen Sie ein neues Zertifikat.
(Optional) HTTP-zu-HTTPS-Weiterleitung aktivieren	Klicken Sie dieses Kästchen an, um Weiterleitungen von Port 80 zu Port 443 zu aktivieren. Wenn Sie dieses Kästchen anklicken, wird ein zusätzlicher partieller HTTP-Load-Balancer erstellt, der dieselbe IP-Adresse wie Ihr HTTPS-Load-Balancer verwendet und die HTTP-Anfragen an das HTTPS-Front-End des Load-Balancers weiterleitet. Dieses Kästchen kann nur angeklickt werden, wenn das HTTPS-Protokoll ausgewählt ist und eine reservierte IP-Adresse verwendet wird.

Klicken Sie auf Fertig.

Konfiguration prüfen

Klicken Sie auf Prüfen und abschließen.
Prüfen Sie das Front-End, Host- und Pfadregeln sowie die Back-End-Buckets.
Klicken Sie auf Erstellen und warten Sie, bis der Load-Balancer erstellt ist.
Klicken Sie auf den Namen des Load-Balancers (http-lb).
Notieren Sie die IP-Adresse des Load-Balancers für die nächste Aufgabe. In diesem Leitfaden wird sie als IP_ADDRESS bezeichnet.

gcloud/gsutil

Back-End konfigurieren

gcloud compute backend-buckets create dogs \
    --gcs-bucket-name=BUCKET_1_NAME

gcloud compute backend-buckets create cats \
    --gcs-bucket-name=BUCKET_2_NAME

URL-Zuordnung konfigurieren

gcloud compute url-maps create http-lb \
    --default-backend-bucket=cats

gcloud compute url-maps add-path-matcher http-lb \
    --path-matcher-name=path-matcher-2 \
    --new-hosts=* \
    --backend-bucket-path-rules="/love-to-fetch/*=dogs" \
    --default-backend-bucket=cats

Zielproxy konfigurieren

gcloud compute target-http-proxies create http-lb-proxy \
    --url-map=http-lb

Weiterleitungsregel konfigurieren

gcloud compute forwarding-rules create http-lb-forwarding-rule \
    --load-balancing-scheme=EXTERNAL \
    --network-tier=PREMIUM \
    --address=example-ip \
    --global \
    --target-http-proxy=http-lb-proxy \
    --ports=80

Terraform

Verwenden Sie zum Erstellen des Load-Balancers die folgenden Terraform-Ressourcen.

Back-End konfigurieren

Verwenden Sie zum Erstellen des Back-Ends die Ressource google_compute_backend_bucket.

external_http_lb_bucket_backend/main.tf

Auf GitHub ansehen Feedback

# Create LB backend buckets
resource "google_compute_backend_bucket" "bucket_1" {
  name        = "cats"
  description = "Contains cat image"
  bucket_name = google_storage_bucket.bucket_1.name
}

resource "google_compute_backend_bucket" "bucket_2" {
  name        = "dogs"
  description = "Contains dog image"
  bucket_name = google_storage_bucket.bucket_2.name
}

URL-Zuordnung konfigurieren

Verwenden Sie zum Erstellen der URL-Zuordnung die Ressource google_compute_url_map.

external_http_lb_bucket_backend/main.tf

Auf GitHub ansehen Feedback

# Create url map
resource "google_compute_url_map" "default" {
  name = "http-lb"

  default_service = google_compute_backend_bucket.bucket_1.id

  host_rule {
    hosts        = ["*"]
    path_matcher = "path-matcher-2"
  }
  path_matcher {
    name            = "path-matcher-2"
    default_service = google_compute_backend_bucket.bucket_1.id

    path_rule {
      paths   = ["/love-to-fetch/*"]
      service = google_compute_backend_bucket.bucket_2.id
    }
  }
}

Zielproxy konfigurieren

Verwenden Sie zum Erstellen des Ziel-HTTP-Proxys die Ressource google_compute_target_http_proxy.

external_http_lb_bucket_backend/main.tf

Auf GitHub ansehen Feedback

# Create HTTP target proxy
resource "google_compute_target_http_proxy" "default" {
  name    = "http-lb-proxy"
  url_map = google_compute_url_map.default.id
}

Weiterleitungsregel konfigurieren

Verwenden Sie zum Erstellen der Weiterleitungsregel die Ressource google_compute_global_forwarding_rule.

external_http_lb_bucket_backend/main.tf

Auf GitHub ansehen Feedback

# Create forwarding rule
resource "google_compute_global_forwarding_rule" "default" {
  name                  = "http-lb-forwarding-rule"
  ip_protocol           = "TCP"
  load_balancing_scheme = "EXTERNAL_MANAGED"
  port_range            = "80"
  target                = google_compute_target_http_proxy.default.id
  ip_address            = google_compute_global_address.default.id
}

HINWEIS: Wenn Sie den Modus in einen globalen externen HTTP(S)-Load-Balancer (klassisch) ändern möchten, setzen Sie das Attribut load_balancing_scheme anstelle von "EXTERNAL_MANAGED" auf "EXTERNAL".

Informationen zum Anwenden oder Entfernen einer Terraform-Konfiguration finden Sie unter Grundlegende Terraform-Befehle.

Traffic an den Load-Balancer senden

Einige Minuten nach der Konfiguration des Load-Balancers können Sie Traffic an die IP-Adresse des Load-Balancers senden.

Console

Rufen Sie in einem Webbrowser die folgenden Adressen auf, um den Load-Balancer zu testen. Ersetzen Sie dabei IP_ADDRESS durch die IP-Adresse des Load-Balancers:

http://IP_ADDRESS/love-to-fetch/two-dogs.jpg
http://IP_ADDRESS/never-fetch/three-cats.jpg

Wenn Sie einen HTTP-Load-Balancer eingerichtet haben, achten Sie darauf, dass der Browser nicht automatisch zu HTTPS weiterleitet.

gcloud/gsutil

Verwenden Sie den Befehl curl, um die Antwort von den folgenden URLs zu testen. Ersetzen Sie IP_ADDRESS durch die IPv4-Adresse des Load-Balancers.

curl http://IP_ADDRESS/love-to-fetch/two-dogs.jpg

curl http://IP_ADDRESS/never-fetch/three-cats.jpg

Einschränkungen

Back-End-Buckets werden nur von globalen externen HTTP(S)-Load-Balancern und globalen externen HTTP(S)-Load-Balancern (klassisch) unterstützt. Sie werden nicht von regionalen externen HTTP(S)-Load-Balancern oder anderen Load-Balancer-Typen unterstützt.
Back-End-Buckets werden in Verbindung mit Identity-Aware Proxy nicht unterstützt.
Der globale externe HTTP(S)-Load-Balancer (klassisch) unterstützt keine Uploads in Cloud Storage-Buckets. Insbesondere werden alle Abfrageparameter in der Anfrage beim Hochladen in Cloud Storage gelöscht.
Nächste Schritte
Multiregionales Load-Balancing einrichten
Cloud CDN mit einem Back-End-Bucket einrichten
Beispiele für Terraform-Module für externe HTTP(S)-Load-Balancer

Globalen externen HTTP(S)-Load-Balancer (klassisch) mit Cloud Storage-Buckets einrichten

Cloud Storage-Buckets als Back-Ends des Load-Balancers

Hinweis

Standardprojekt festlegen

Console

gcloud/gsutil

Terraform

Berechtigungen

SSL-Zertifikatsressource einrichten

Cloud Storage-Buckets und Inhalte vorbereiten

Cloud Storage-Buckets erstellen

Console

gcloud/gsutil

Terraform

Inhalte in Cloud Storage-Buckets übertragen

gcloud/gsutil

Terraform

Cloud Storage-Buckets öffentlich lesbar machen

Console

gcloud/gsutil

Terraform

Externe IP-Adresse reservieren

Console

gcloud/gsutil

Terraform

Externen HTTP(S)-Load-Balancer mit Back-End-Buckets erstellen

Console

Konfiguration starten

Back-End konfigurieren

Routingregeln konfigurieren

Front-End konfigurieren

Konfiguration prüfen

gcloud/gsutil

Back-End konfigurieren

URL-Zuordnung konfigurieren

Zielproxy konfigurieren

Weiterleitungsregel konfigurieren

Terraform

Back-End konfigurieren

URL-Zuordnung konfigurieren

Zielproxy konfigurieren

Weiterleitungsregel konfigurieren

Traffic an den Load-Balancer senden

Console

gcloud/gsutil

Einschränkungen

Nächste Schritte