Diese Seite wurde von der Cloud Translation API übersetzt.

Best Practices für die Verwendung von DM Convert

Best Practices für die Umstellung auf Terraform

Status

Die Zustandsdatei enthält Informationen zu den von Terraform verwalteten Ressourcen. Standardmäßig speichert Terraform den Status lokal auf dem Laufwerk. Wenn Sie den Zustand remote speichern, können Sie eine verteilte Zusammenarbeit ermöglichen, vertrauliche Informationen schützen und Terraform in der Continuous Integration (CI) ausführen.

Nachdem Sie Ihre Deployment Manager-Vorlage in Terraform konvertiert und optional Ressourcen importiert haben, empfehlen wir Ihnen, die Schritte zum Speichern des Status aus der Ferne in Cloud Storage auszuführen.

Module

Wenn Sie die Komplexität reduzieren, für Konsistenz sorgen und die Wiederverwendbarkeit Ihrer Konfiguration fördern möchten, können Sie Terraform-Module verwenden, um Ressourcensammlungen zu kapseln.

Sie haben folgende Möglichkeiten, Module zu verwenden:

Erstellen Sie ein benutzerdefiniertes Modul aus den von DM Convert exportierten Ressourcen. So haben Sie die größte Flexibilität.
Verwenden Sie ein veröffentlichtes Modul aus der Sammlung der offiziellen Module von Google Cloudoder der Terraform Registry.

Für die meisten Anwendungsfälle empfehlen wir, ein veröffentlichtes Modul zu verwenden.

Benutzerdefiniertes Modul erstellen

Nachdem Sie Ihre Konfiguration konvertiert haben, legen Sie fest, welche Ressourcen Sie in ein Modul verschieben möchten.

Verschieben Sie die Konfigurationen dieser Ressourcen in ein Modulverzeichnis und wandeln Sie die erforderlichen Variablen in Parameter um.

Das folgende Beispiel zeigt, wie Sie google_bigquery_dataset und google_bigquery_table in ein Modul verschieben:

# bq-module/main.tf
resource "google_bigquery_dataset" "bigquerydataset" {
  provider = google-beta

  default_table_expiration_ms = 36000000
  location = "us-west1"
  dataset_id = var.dataset_id
  project = var.project_id
}

resource "google_bigquery_table" "bigquerytable" {
  provider = google-beta

  labels = {
    data-source = "external"
    schema-type = "auto-junk"
  }
  dataset_id = var.dataset_id
  project = var.project_id
  table_id = var.table_id

  depends_on = [
    google_bigquery_dataset.bigquerydataset
  ]
}

# bq-module/variables.tf
variable "project_id" {
  description = "Project ID"
  type = string
}

variable "dataset_id" {
  description = "Dataset ID"
  type = string
}

variable "table_id" {
  description = "Table ID"
  type = string
}

Ersetzen Sie in der exportierten main.tf-Datei die ursprüngliche Konfiguration durch das von Ihnen erstellte Modul.

Das folgende Beispiel zeigt diesen Ersatz mit dem Modul, das im Beispiel aus dem vorherigen Schritt erstellt wurde.
```
# main.tf
module "bq" {
  source = "./bq-module"

  project_id = "PROJECT_ID"
  dataset_id = "bigquerydataset"
  table_id   = "bigquerytable"
}
```
Führen Sie den folgenden Befehl aus, um das lokale Modul zu initialisieren:
```
terraform init
```

Verschieben Sie den mit den Ressourcen verknüpften Terraform-Zustand in die Modulinstanz.

Führen Sie den folgenden Befehl aus, um das Modul aus dem Beispiel im vorherigen Schritt zu verschieben:

terraform state mv google_bigquery_dataset.bigquerydataset module.bq.google_bigquery_dataset.bigquerydataset
terraform state mv google_bigquery_table.bigquerytable module.bq.google_bigquery_table.bigquerytable

In diesem Beispiel sieht die Ausgabe des Verschiebens so aus:

Move "google_bigquery_dataset.bigquerydataset" to "module.bq.google_bigquery_dataset.bigquerydataset"
Successfully moved 1 object(s).
Move "google_bigquery_table.bigquerytable" to "module.bq.google_bigquery_table.bigquerytable"
Successfully moved 1 object(s).

Prüfen Sie mit dem folgenden Befehl, ob sich keine Ressourcen geändert haben:
```
terraform plan
```
Im folgenden Beispiel sehen Sie die Ausgabe, die Sie nach Ausführung des Befehls erhalten:
```
No changes. Your infrastructure matches the configuration.
```

Veröffentlichtes Modul verwenden

Nachdem Sie Ihre Konfiguration konvertiert haben, wählen Sie ein veröffentlichtes Modul und die Ressourcen aus, die Sie in das Modul verschieben möchten.
Lesen Sie die Dokumentation des Moduls, um die Konfigurationsoptionen zu ermitteln.

Erstellen Sie eine Instanz des Moduls, die für Ihre aktuelle Ressourcenkonfiguration konfiguriert ist.

Wenn Sie beispielsweise google_bigquery_dataset und google_bigquery_table in das offizielle BigQuery-Modul verschieben möchten, könnte Ihr Modul so aussehen:

module "bq" {
  source  = "terraform-google-modules/bigquery/google"
  version = "~> 5.0"

  project_id          = "PROJECT_ID"
  dataset_id          = "bigquerydataset"
  location            = "us-west1"
  deletion_protection = true

  tables = [
    {
      table_id           = "bigquerytable",
      friendly_name      = "bigquerytable"
      time_partitioning  = null,
      range_partitioning = null,
      expiration_time    = null,
      clustering         = [],
      schema             = null,
      labels = {
        data-source = "external"
        schema-type = "auto-junk"
      },
    }
  ]
}

Führen Sie den folgenden Befehl aus, um das lokale Modul zu initialisieren:
```
terraform init
```

Lesen Sie den Quellcode des Moduls, um Ressourcenadressen im Upstream-Modul zu ermitteln und die move-Befehle zu erstellen.

terraform state mv google_bigquery_dataset.bigquerydataset  module.bq.google_bigquery_dataset.main
terraform state mv google_bigquery_table.bigquerytable 'module.bq.google_bigquery_table.main["bigquerytable"]'

Führen Sie den folgenden Befehl aus, um Änderungen an der Konfiguration aufzurufen:
```
terraform plan
```

Wenn das ausgewählte veröffentlichte Modul andere Standardeinstellungen hat oder anders konfiguriert ist als Ihre Konfiguration, werden in der Ausgabe des Befehls möglicherweise Unterschiede hervorgehoben.

Betätigung

Wir empfehlen, ein CI-System (Continuous Integration) wie Cloud Build, Jenkins oder GitHub Actions zu verwenden, um die Ausführung von Terraform im großen Maßstab zu automatisieren. Weitere Informationen finden Sie unter Infrastruktur als Code mit Terraform, Cloud Build und GitOps verwalten.

Wenn Sie die Erstellung von Triggern vereinfachen und die Authentifizierung beschleunigen möchten, können Sie die Cloud Build-Workspace-Vorlage verwenden.

Struktur

Jede mit DM Convert konvertierte Konfiguration ist eine einzelne Root-Konfiguration, die einer einzelnen Statusdatei zugeordnet ist. Wir empfehlen nicht, eine einzelne Statusdatei für eine große Anzahl von Ressourcen einzurichten. Nachdem Sie Ihre Konfiguration konvertiert haben, sollten Sie prüfen, ob sie den Best Practices für Stammmodule entspricht.