Cloud Storage バケットを使用して従来のアプリケーションロードバランサを設定する

このドキュメントでは、外部アプリケーションロードバランサを作成して静的コンテンツのリクエストを Cloud Storage バケットに転送する方法について説明します。バックエンドバケットを使用してロードバランサを構成すると、ユーザーのリージョンに関係なく、/love-to-fetch で始まる URL パスへのリクエストは us-east1 Cloud Storage バケットに送信され、その他のリクエストはすべて europe-north1 Cloud Storage バケットに送信されます。

バックエンドが HTTP(S) で動的コンテンツを配信する場合は、バックエンドバケットの代わりにバックエンドサービスの使用を検討してください。

このタスクを Google Cloud コンソールで直接行う際の順を追ったガイダンスについては、「ガイドを表示」をクリックしてください。

ガイドを表示

ロードバランサバックエンドとしての Cloud Storage バケット

外部アプリケーションロードバランサは、URL マップを使用して、指定された URL パスからトラフィックをバックエンドに転送します。

次の図では、ロードバランサが /love-to-fetch/ のパスを含むトラフィックを us-east1 リージョンの Cloud Storage バケットに送信しています。他のすべてのリクエストは、europe-north1 リージョンの Cloud Storage バケットに送信されます。

Cloud Storage バックエンドにトラフィックを送信するロードバランサ。 — Cloud Storage へのトラフィックの分散

デフォルトで Cloud Storage では、Cloud CDN が使用するものと同じキャッシュを使用します。バックエンドバケットで Cloud CDN を有効にすると、コンテンツで Cloud CDN コントロールを使用できます。Cloud CDN のコントロールには、キャッシュモード、署名付き URL、無効化などがあります。Cloud CDN では、サイズの大きいコンテンツ（10 MB 超）をキャッシュに保存することもできます。バックエンドバケットで Cloud CDN を有効にしない場合は、Cloud Storage メタデータで設定されたように、送信元の Cache-Control ヘッダーを使用して、小規模なコンテンツのキャッシュ保存を制御することのみ可能です。

始める前に

設定が次の前提条件を満たしていることを確認します。gcloud storage ユーティリティを使用している場合は、gcloud ツールを使用してオブジェクトストレージを検出するの手順に沿ってインストールできます。

デフォルトプロジェクトを設定する

コンソール

Sign in to your Google Cloud account. If you're new to Google Cloud, create an account to evaluate how our products perform in real-world scenarios. New customers also get $300 in free credits to run, test, and deploy workloads.

In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

Go to project selector

Make sure that billing is enabled for your Google Cloud project.

In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

Go to project selector

Make sure that billing is enabled for your Google Cloud project.

gcloud

gcloud config set project PROJECT_ID

PROJECT_ID は、このガイドで使用しているプロジェクトに置き換えます。

Terraform

export GOOGLE_CLOUD_PROJECT=PROJECT_ID

権限

このガイドを使用する前に、プロジェクトで Cloud Storage バケットとロードバランサを作成する必要があります。そのためには、プロジェクトのオーナーまたは編集者であるか、次の Compute Engine IAM のロールが必要です。

タスク	必要なロール
ロードバランサのコンポーネントを作成する	ネットワーク管理者
Cloud Storage バケットを作成する	ストレージオブジェクト管理者

詳細については、次のガイドをご覧ください。

SSL 証明書リソースを設定する

HTTPS ロードバランサの場合、SSL 証明書リソースは、次のドキュメントの説明のように作成します。

Google マネージド証明書を使用することをおすすめします。

この例では、SSL 証明書リソース www-ssl-cert をすでに利用していることを前提としています。

Cloud Storage バケットとコンテンツを準備する

Cloud Storage バケットを準備するプロセスは次のとおりです。

バケットを作成します。
コンテンツをバケットにコピーします。
バケットに公開アクセス権を設定します。

Cloud Storage バケットを作成する

この例では、ロードバランサがアクセスする 2 つの Cloud Storage バケットを作成します。本番環境のデプロイでは、複数の Google Cloud リージョンにオブジェクトを自動的に複製するマルチリージョンバケットを選択することをおすすめします。これにより、コンテンツの可用性が高まり、アプリケーション全体のフォールトトレラントが向上します。

作成する Cloud Storage バケットの名前をメモします。この名前は後で使用します。このガイドでは、これらを BUCKET_1_NAME および BUCKET_2_NAME と呼びます。

コンソール

Google Cloud コンソールで、Cloud Storage の [バケット] ページに移動します。

Cloud Storage の [バケット] に移動
[バケットを作成] をクリックします。
[バケットに名前を付ける] ボックスに、命名ガイドラインに沿ったグローバルに一意の名前を入力します。
[データの保存場所の選択] をクリックします。
[ロケーションタイプ] を [リージョン] に設定します。
[ロケーション] を europe-north1 に設定します。このガイドでは BUCKET_1_NAME です。
[作成] をクリックします。
[バケット] をクリックして Cloud Storage の [バケット] ページに戻ります。次の手順で 2 番目のバケットを作成しますが、[ロケーション] は us-east1 に設定します。このガイドでは BUCKET_2_NAME です。

gcloud

gcloud storage buckets create gs://BUCKET_1_NAME --project=PROJECT_ID --default-storage-class=standard --location=europe-north1 --uniform-bucket-level-access

gcloud storage buckets create gs://BUCKET_2_NAME --project=PROJECT_ID --default-storage-class=standard --location=us-east1 --uniform-bucket-level-access

BUCKET_1_NAME と BUCKET_2_NAME は、作成するバケットの名前に置き換えます。

Terraform

バケットを作成するには、google_storage_bucket リソースを使用します。

# Create Cloud Storage buckets
resource "random_id" "bucket_prefix" {
  byte_length = 8
}

resource "google_storage_bucket" "bucket_1" {
  name                        = "${random_id.bucket_prefix.hex}-bucket-1"
  location                    = "us-east1"
  uniform_bucket_level_access = true
  storage_class               = "STANDARD"
  // delete bucket and contents on destroy.
  force_destroy = true
}

resource "google_storage_bucket" "bucket_2" {
  name                        = "${random_id.bucket_prefix.hex}-bucket-2"
  location                    = "us-east1"
  uniform_bucket_level_access = true
  storage_class               = "STANDARD"
  // delete bucket and contents on destroy.
  force_destroy = true
}

Terraform 構成を適用または削除する方法については、基本的な Terraform コマンドをご覧ください。

Cloud Storage バケットにコンテンツを転送する

セットアップを後でテストするために、Cloud Storage の公開バケットから独自の Cloud Storage バケットに次の画像をコピーします。

gcloud

「 Cloud Shell をアクティブにする」をクリックします。
Cloud Shell で次のコマンドを実行します。バケット名の変数は Cloud Storage バケット名に置き換えます。

gcloud storage cp gs://gcp-external-http-lb-with-bucket/three-cats.jpg gs://BUCKET_1_NAME/never-fetch/

gcloud storage cp gs://gcp-external-http-lb-with-bucket/two-dogs.jpg gs://BUCKET_2_NAME/love-to-fetch/

Terraform

アイテムをバケットにコピーするには、google_storage_bucket_object リソースを使用します。

resource "google_storage_bucket_object" "cat_image" {
  name         = "never-fetch/three-cats.jpg"
  source       = "images/three-cats.jpg"
  content_type = "image/jpeg"

  bucket = google_storage_bucket.bucket_1.name
}

resource "google_storage_bucket_object" "dog_image" {
  name         = "love-to-fetch/two-dogs.jpg"
  source       = "images/two-dogs.jpg"
  content_type = "image/jpeg"

  bucket = google_storage_bucket.bucket_2.name
}

または、null_resource リソースを使用します。

resource "null_resource" "upload_cat_image" {
provisioner "local-exec" {
  command = "gcloud storage cp gs://gcp-external-http-lb-with-bucket/three-cats.jpg gs://${google_storage_bucket.bucket_1.name}/never-fetch/"
}
}

resource "null_resource" "upload_dog_image" {
provisioner "local-exec" {
  command = "gcloud storage cp gs://gcp-external-http-lb-with-bucket/two-dogs.jpg gs://${google_storage_bucket.bucket_2.name}/love-to-fetch/"
}
}

Google Cloud コンソールで、各バケットの詳細ページの [更新] をクリックし、ファイルが正常にコピーされたことを確認します。

Cloud Storage バケットを公開する

Cloud Storage バケットを公開読み取り可能にすると、インターネット上の誰でもオブジェクトの一覧の取得と表示、メタデータ（ACL を除く）の表示を行えるようになります。公開バケットに機密情報を含めないでください。

機密情報が誤って公開される可能性を減らすため、公開オブジェクトと機密データを同じバケットに保存しないでください。

コンソール

バケット内のすべてのオブジェクトに対するアクセス権をすべてのユーザーに付与するには、バケットごとに次の手順を繰り返します。

Google Cloud コンソールで、Cloud Storage の [バケット] ページに移動します。

Cloud Storage の [バケット] に移動
バケット名をクリックし、[権限] タブをクリックします。
[追加] をクリックします。
[新しいプリンシパル] ボックスに「allUsers」と入力します。
[ロールを選択] ボックスで、[Cloud Storage] > [Storage オブジェクト閲覧者] を選択します。
[保存] をクリックします。
[一般公開アクセスを許可] をクリックします。

gcloud

バケット内のオブジェクトを表示する権限をすべてのユーザーに付与するには、次のコマンドを実行します。

gcloud storage buckets add-iam-policy-binding gs://BUCKET_1_NAME --member=allUsers --role=roles/storage.objectViewer

gcloud storage buckets add-iam-policy-binding gs://BUCKET_2_NAME --member=allUsers --role=roles/storage.objectViewer

Terraform

バケット内のオブジェクトを表示する権限をすべてのユーザーに付与するには、google_storage_bucket_iam_member リソースを使用して、メンバーに allUsers を指定します。

# Make buckets public
resource "google_storage_bucket_iam_member" "bucket_1" {
  bucket = google_storage_bucket.bucket_1.name
  role   = "roles/storage.objectViewer"
  member = "allUsers"
}

resource "google_storage_bucket_iam_member" "bucket_2" {
  bucket = google_storage_bucket.bucket_2.name
  role   = "roles/storage.objectViewer"
  member = "allUsers"
}

外部 IP アドレスを予約する

Cloud Storage バケットを設定したら、オーディエンスがロードバランサにアクセスするために使用するグローバル静的外部 IP アドレスを予約できます。

この手順は省略可能ですが、静的外部 IP アドレスはドメインを指定するための単一アドレスを提供するため、行うことをおすすめします。

コンソール

Google Cloud コンソールで、[外部 IP アドレス] ページに移動します。

[外部 IP アドレス] に移動
[静的アドレスを予約] をクリックします。
[名前] ボックスに「example-ip」と入力します。
[ネットワークサービス階層] を [プレミアム] に設定します。
[IP バージョン] で [IPv4] をオンにします。
[タイプ] で [グローバル] をオンにします。
[予約] をクリックします。

gcloud

gcloud compute addresses create example-ip \
    --network-tier=PREMIUM \
    --ip-version=IPV4 \
    --global

予約された IPv4 アドレスをメモします。

gcloud compute addresses describe example-ip \
    --format="get(address)" \
    --global

Terraform

外部 IP アドレスを予約するには、google_compute_global_address リソースを使用します。

# Reserve IP address
resource "google_compute_global_address" "default" {
  name = "example-ip"
}

バックエンドバケットを使用する外部アプリケーションロードバランサを作成する

ここでは、HTTP または HTTPS ロードバランサの作成手順について説明します。HTTPS ロードバランサを作成するには、ロードバランサのフロントエンドに SSL 証明書リソースを追加する必要があります。詳細については、SSL 証明書の概要をご覧ください。

コンソール

構成を開始する

Google Cloud コンソールで、[ロードバランシング] ページに移動します。

[ロードバランシング] に移動
[ロードバランサを作成] をクリックします。
[ロードバランサの種類] で [アプリケーションロードバランサ（HTTP / HTTPS）] を選択し、[次へ] をクリックします。
[インターネット接続または内部] で [インターネット接続（外部）] を選択し、[次へ] をクリックします。
[グローバルまたはシングルリージョンのデプロイ] で [グローバルワークロードに最適] を選択し、[次へ] をクリックします。
[ロードバランサの世代] で [従来のアプリケーションロードバランサ] を選択し、[次へ] をクリックします。
[構成] をクリックします。

基本構成

[名前] ボックスに「http-lb」と入力します。

バックエンドを構成する

[バックエンドの構成] をクリックします。
[Backend services and backend buckets] ボックスをクリックし、[バックエンドバケットを作成] をクリックします。
[バックエンドバケット名] ボックスに「cats」と入力します。
[Cloud Storage バケット] ボックスで、[参照] をクリックします。
[BUCKET_1_NAME] を選択して、[選択] をクリックします。最初に cats バックエンドバケットを作成すると、これがデフォルトになります。これにより、一致しないトラフィックリクエストがすべて転送されます。ロードバランサでデフォルトのバックエンドバケットのリダイレクトルールを変更することはできません。
[作成] をクリックします。
同じプロセスを使用して、dogs という名前のバックエンドバケットを作成し、BUCKET_2_NAME を選択します。
[OK] をクリックします。

ルーティングルールを構成する

ルーティングルールは、トラフィックの転送方法を決定します。ルーティングを構成するには、ホストルールとパスマッチャーを設定します。これは外部アプリケーションロードバランサの URL マップの構成要素です。この例のルールを設定するには:

[ホストとパスのルール] をクリックします。
dogs で、[ホスト] フィールドに「*」、[パス] フィールドに「/love-to-fetch/*」と入力します。

フロントエンドを構成する

[フロントエンドの構成] をクリックします。

以下のオプションが次の値で構成されていることを確認します。

プロパティ	値（値を入力するか、指定されたオプションを選択）
プロトコル	HTTP
ネットワークサービス階層	プレミアム
IP バージョン	IPv4
IP アドレス	example-ip
ポート	80

HTTP ロードバランサの代わりに HTTPS ロードバランサを作成する場合は、SSL 証明書（gcloud compute ssl-certificates list）が必要です。また、次のようにフィールドに入力する必要があります。

プロパティ	値（値を入力するか、指定されたオプションを選択）
プロトコル	HTTP(S)
ネットワークサービス階層	プレミアム
IP バージョン	IPv4
IP アドレス	example-ip
ポート	443
証明書	SSL 証明書リソースの設定で作成した `www-ssl-cert` 証明書を選択するか、新しい証明書を作成します。
省略可: HTTP から HTTPS へのリダイレクトを有効にする	リダイレクトを有効にするには、このチェックボックスをオンにします。このチェックボックスをオンにすると、HTTPS ロードバランサと同じ IP アドレスを使用し、HTTP リクエストをロードバランサの HTTPS フロントエンドにリダイレクトする追加の部分的な HTTP ロードバランサが作成されます。このチェックボックスは、HTTPS プロトコルが選択されていて、予約済みの IP アドレスが使用されている場合にのみ選択できます。

[完了] をクリックします。

構成を確認する

[確認と完了] をクリックします。
[フロントエンド]、[ホストとパスのルール]、[バックエンドバケット] を確認します。
[作成] をクリックし、ロードバランサが作成されるのを待ちます。
ロードバランサの名前（http-lb）をクリックします。
ロードバランサの IP アドレスをメモします（次のタスクで使用します）。このガイドではこれを IP_ADDRESS と呼びます。

gcloud

バックエンドを構成する

gcloud compute backend-buckets create cats \
  --gcs-bucket-name=BUCKET_1_NAME

gcloud compute backend-buckets create dogs \
  --gcs-bucket-name=BUCKET_2_NAME

URL マップを構成する

gcloud compute url-maps create http-lb \
  --default-backend-bucket=cats

gcloud compute url-maps add-path-matcher http-lb \
  --path-matcher-name=path-matcher-2 \
  --new-hosts=* \
  --backend-bucket-path-rules="/love-to-fetch/*=dogs" \
  --default-backend-bucket=cats

ターゲットプロキシを構成する

gcloud compute target-http-proxies create http-lb-proxy \
  --url-map=http-lb

転送ルールを構成する

gcloud compute forwarding-rules create http-lb-forwarding-rule \
  --load-balancing-scheme=EXTERNAL \
  --network-tier=PREMIUM \
  --address=example-ip \
  --global \
  --target-http-proxy=http-lb-proxy \
  --ports=80

Terraform

ロードバランサを作成するには、次の Terraform リソースを使用します。

バックエンドを構成する

バックエンドを作成するには、google_compute_backend_bucket リソースを使用します。

# Create LB backend buckets
resource "google_compute_backend_bucket" "bucket_1" {
  name        = "cats"
  description = "Contains cat image"
  bucket_name = google_storage_bucket.bucket_1.name
}

resource "google_compute_backend_bucket" "bucket_2" {
  name        = "dogs"
  description = "Contains dog image"
  bucket_name = google_storage_bucket.bucket_2.name
}

URL マップを構成する

URL マップを作成するには、google_compute_url_map リソースを使用します。

# Create url map
resource "google_compute_url_map" "default" {
  name = "http-lb"

  default_service = google_compute_backend_bucket.bucket_1.id

  host_rule {
    hosts        = ["*"]
    path_matcher = "path-matcher-2"
  }
  path_matcher {
    name            = "path-matcher-2"
    default_service = google_compute_backend_bucket.bucket_1.id

    path_rule {
      paths   = ["/love-to-fetch/*"]
      service = google_compute_backend_bucket.bucket_2.id
    }
  }
}

ターゲットプロキシを構成する

ターゲット HTTP プロキシを作成するには、google_compute_target_http_proxy リソースを使用します。

# Create HTTP target proxy
resource "google_compute_target_http_proxy" "default" {
  name    = "http-lb-proxy"
  url_map = google_compute_url_map.default.id
}

転送ルールを構成する

転送ルールを作成するには、google_compute_global_forwarding_rule リソースを使用します。

# Create forwarding rule
resource "google_compute_global_forwarding_rule" "default" {
  name                  = "http-lb-forwarding-rule"
  ip_protocol           = "TCP"
  load_balancing_scheme = "EXTERNAL_MANAGED"
  port_range            = "80"
  target                = google_compute_target_http_proxy.default.id
  ip_address            = google_compute_global_address.default.id
}

注: モードを従来のアプリケーションロードバランサに変更するには、load_balancing_scheme 属性を "EXTERNAL_MANAGED" ではなく "EXTERNAL" に設定します。

Terraform 構成を適用または削除する方法については、基本的な Terraform コマンドをご覧ください。

ロードバランサにトラフィックを送信する

ロードバランサの構成から数分後、ロードバランサの IP アドレスへのトラフィックの送信を開始できます。

コンソール

ウェブブラウザで次のアドレスに移動してロードバランサをテストします。IP_ADDRESS は、ロードバランサの IP アドレスに置き換えます。

http://IP_ADDRESS/love-to-fetch/two-dogs.jpg
http://IP_ADDRESS/never-fetch/three-cats.jpg

HTTP ロードバランサを設定した場合は、ブラウザが HTTPS に自動的にリダイレクトしていないことを確認してください。

gcloud

curl コマンドを使用して、次の URL からのレスポンスをテストします。IP_ADDRESS は、ロードバランサの IPv4 アドレスに置き換えます。

curl http://IP_ADDRESS/love-to-fetch/two-dogs.jpg

curl http://IP_ADDRESS/never-fetch/three-cats.jpg

Cloud Storage XML API のクエリ文字列パラメータ

特定のクエリ文字列パラメータがアプリケーションロードバランサを介してバックエンドバケットに送信されるリクエストに含まれていると、クライアントは「サポートされていないクエリパラメータ」エラーを含む HTTP 404 レスポンスを受け取ります。このエラーは、リクエストがアプリケーションロードバランサから送信された際に、Cloud Storage XML API でこれらのパラメータがサポートされていないため発生します。

次の表では、リクエストがアプリケーションロードバランサを介して転送されたときに、Cloud Storage XML API がさまざまなクエリパラメータに対してどのように応答するかをまとめています。パラメータは実際の動作ごとにグループ化されており、これによってサポートされるパラメータ、無視されるパラメータ、拒否されるパラメータが判別できるようになっています。

パラメータのタイプ	パラメータ	実際の動作
サポートされるパラメータ	`generation`、`prefix`、`marker`、`max-keys`	これらのパラメータを（適切な値を指定して）追加すると、Cloud Storage XML API ドキュメントに記載されているとおりに動作します。API は標準の HTTP レスポンスを返します。
無視されるパラメータ	`acl`、`billing`、`compose`、`delimiter`、`encryption`、`encryptionConfig`、`response-content-disposition`、`response-content-type`、`tagging`、`versions`、`websiteConfig`	これらのパラメータを追加しても影響はありません。ロードバランサがこれらのパラメータを Cloud Storage に渡すと、Cloud Storage XML API はパラメータを無視して、パラメータが存在しないかのように応答します。
拒否されるパラメータ	`cors`、`lifecycle`、`location`、`logging`、`storageClass`、`versioning`	Cloud Storage XML API は「サポートされていないクエリパラメータ」エラーを返します。

制限事項

バックエンドバケットは、グローバル外部アプリケーションロードバランサと従来のアプリケーションロードバランサでのみサポートされます。リージョン外部アプリケーションロードバランサやその他の種類のロードバランサではサポートされません。
Identity-Aware Proxy ではバックエンドバケットはサポートされていません。* 従来のアプリケーションロードバランサは、Cloud Storage バケットへのアップロードに完全には対応していません。具体的には、Cloud Storage にアップロードすると、リクエストのすべてのクエリパラメータが削除されます。
次のステップ

Cloud Storage バケットを使用して従来のアプリケーション ロードバランサを設定する コレクションでコンテンツを整理 必要に応じて、コンテンツの保存と分類を行います。

ロードバランサ バックエンドとしての Cloud Storage バケット

始める前に

デフォルト プロジェクトを設定する

コンソール

gcloud

Terraform

権限

SSL 証明書リソースを設定する

Cloud Storage バケットとコンテンツを準備する

Cloud Storage バケットを作成する

コンソール

gcloud

Terraform

Cloud Storage バケットにコンテンツを転送する

gcloud

Terraform

Cloud Storage バケットを公開する

コンソール

gcloud

Terraform

外部 IP アドレスを予約する

コンソール

gcloud

Terraform

バックエンド バケットを使用する外部アプリケーション ロードバランサを作成する

コンソール

構成を開始する

基本構成

バックエンドを構成する

ルーティング ルールを構成する

フロントエンドを構成する

構成を確認する

gcloud

バックエンドを構成する

URL マップを構成する

ターゲット プロキシを構成する

転送ルールを構成する

Terraform

バックエンドを構成する

URL マップを構成する

ターゲット プロキシを構成する

転送ルールを構成する

ロードバランサにトラフィックを送信する

コンソール

gcloud

Cloud Storage XML API のクエリ文字列パラメータ

制限事項

次のステップ

Cloud Storage バケットを使用して従来のアプリケーションロードバランサを設定する

ロードバランサバックエンドとしての Cloud Storage バケット

デフォルトプロジェクトを設定する

バックエンドバケットを使用する外部アプリケーションロードバランサを作成する

ルーティングルールを構成する

ターゲットプロキシを構成する

ターゲットプロキシを構成する