Questa pagina è stata tradotta dall'API Cloud Translation.

Gestisci il traffico da più regioni

Per restituire risposte più rapide agli utenti in tutto il mondo, devi eseguire il deployment dei servizi in più regioni e instradare gli utenti alla regione più vicina.

Poiché il deployment dei servizi Cloud Run viene eseguito in singole regioni, devi configurare un bilanciatore del carico delle applicazioni esterno per instradare gli utenti a diverse regioni del servizio.

Questa guida mostra come configurare un bilanciatore del carico delle applicazioni esterno con un dominio protetto con un certificato TLS gestito che rimandi a un indirizzo IP anycast globale, che instrada gli utenti al data center Google più vicino in cui è stato eseguito il deployment del servizio.

L'architettura descritta in questa guida non instrada automaticamente le richieste a una regione diversa quando un servizio Cloud Run a livello di regione non risponde o inizia a restituire errori. Per aumentare la disponibilità del tuo servizio multiregionale, puoi configurare il rilevamento outlier per identificare i servizi Cloud Run non integri in base alla percentuale di errori HTTP e divergere alcune richieste a un'altra regione.

Crea un bilanciatore del carico

La creazione di un bilanciatore del carico esterno comporta la creazione di varie risorse di networking e il loro collegamento:

Riga di comando

Prenota un indirizzo IP statico in modo da non dover aggiornare i record DNS quando ricrei il bilanciatore del carico.
```
gcloud compute addresses create --global SERVICE_IP
```
Nel comando precedente, sostituisci SERVICE_IP con un nome per la risorsa dell'indirizzo IP (ad es. myservice-ip).
Questo indirizzo IP è un indirizzo IPv4 anycast globale che instrada al data center o al punto di presenza di Google più vicino ai tuoi visitatori.
Crea un servizio di backend.
```
gcloud compute backend-services create --global BACKEND_NAME
```
Nel comando precedente, sostituisci BACKEND_NAME con il nome che vuoi assegnare al servizio di backend (ad es. myservice-backend).
Crea una mappa URL.
```
gcloud compute url-maps create URLMAP_NAME --default-service=BACKEND_NAME
```
Sostituisci URLMAP_NAME con il nome che vuoi assegnare alla mappa URL (ad es. myservice-urlmap).
Crea un certificato TLS gestito per il tuo dominio per gestire il traffico HTTPS. Sostituisci example.com con il tuo nome di dominio.
```
gcloud compute ssl-certificates create CERT_NAME \
  --domains=example.com
```
Sostituisci CERT_NAME con il nome che vuoi assegnare al certificato SSL gestito (ad es. myservice-cert).
Creare un proxy HTTPS di destinazione.
```
gcloud compute target-https-proxies create HTTPS_PROXY_NAME \
  --ssl-certificates=CERT_NAME \
  --url-map=URLMAP_NAME
```
Sostituisci HTTPS_PROXY_NAME con il nome che vuoi assegnare al proxy HTTPS di destinazione (ad es. myservice-https).
Creare una regola di forwarding che collega le risorse di rete create all'indirizzo IP.
```
gcloud compute forwarding-rules create --global FORWARDING_RULE_NAME \
  --target-https-proxy=HTTPS_PROXY_NAME \
  --address=SERVICE_IP \
  --ports=443
```
Sostituisci FORWARDING_RULE_NAME con il nome della risorsa della regola di forwarding che vuoi creare (ad es. myservice-lb).

Terraform

In alternativa ai passaggi descritti in questa sezione, puoi utilizzare il modulo Terraform del bilanciatore del carico HTTP globale.

Aggiungi quanto segue al file Terraform (ad esempio main.tf):

Configura l'indirizzo IP:

resource "google_compute_global_address" "lb_default" {
  provider = google-beta
  name     = "myservice-service-ip"

  # Use an explicit depends_on clause to wait until API is enabled
  depends_on = [
    google_project_service.compute_api
  ]
}
output "load_balancer_ip_addr" {
  value = google_compute_global_address.lb_default.address
}

Configura il nome della risorsa dell'indirizzo IP su myservice-service-ip. Puoi modificare l'impostazione impostando un valore personale. Questo indirizzo IP è un indirizzo IPv4 anycast globale che instrada al data center o al punto di presenza di Google più vicino ai tuoi visitatori.

Crea e configura il servizio di backend:

resource "google_compute_backend_service" "lb_default" {
  provider              = google-beta
  name                  = "myservice-backend"
  load_balancing_scheme = "EXTERNAL_MANAGED"

  backend {
    group = google_compute_region_network_endpoint_group.lb_default[0].id
  }

  backend {
    group = google_compute_region_network_endpoint_group.lb_default[1].id
  }

  # Use an explicit depends_on clause to wait until API is enabled
  depends_on = [
    google_project_service.compute_api,
  ]
}

Questa risorsa configura il servizio di backend in modo che venga denominato myservice-backend. Puoi modificare l'impostazione impostando un valore personale.

Configura la mappa URL:

resource "google_compute_url_map" "lb_default" {
  provider        = google-beta
  name            = "myservice-lb-urlmap"
  default_service = google_compute_backend_service.lb_default.id

  path_matcher {
    name            = "allpaths"
    default_service = google_compute_backend_service.lb_default.id
    route_rules {
      priority = 1
      url_redirect {
        https_redirect         = true
        redirect_response_code = "MOVED_PERMANENTLY_DEFAULT"
      }
    }
  }
}

Connette la risorsa del servizio di backend (myservice-backend) alla nuova risorsa della mappa URL (myservice-lb-urlmap). Puoi modificare questi valori inserendo i tuoi valori.

Crea un certificato TLS gestito per il tuo dominio per gestire il traffico HTTPS. Sostituisci example.com con il tuo nome di dominio nella risorsa google_compute_managed_ssl_certificate:
```
resource "google_compute_managed_ssl_certificate" "lb_default" {
  provider = google-beta
  name     = "myservice-ssl-cert"

  managed {
    domains = ["example.com"]
  }
}
```

Configura il proxy HTTPS:

resource "google_compute_target_https_proxy" "lb_default" {
  provider = google-beta
  name     = "myservice-https-proxy"
  url_map  = google_compute_url_map.lb_default.id
  ssl_certificates = [
    google_compute_managed_ssl_certificate.lb_default.name
  ]
  depends_on = [
    google_compute_managed_ssl_certificate.lb_default
  ]
}

Crea la risorsa google_compute_target_https_proxy con nome di destinazione myservice-https-proxy e connette le risorse di mappatura degli URL (myservice-lb-urlmap) e il certificato TLS (myservice-ssl-cert) creati in precedenza. Puoi modificare questi valori inserendo i tuoi valori.

Configura la regola di forwarding:

resource "google_compute_global_forwarding_rule" "lb_default" {
  provider              = google-beta
  name                  = "myservice-lb-fr"
  load_balancing_scheme = "EXTERNAL_MANAGED"
  target                = google_compute_target_https_proxy.lb_default.id
  ip_address            = google_compute_global_address.lb_default.id
  port_range            = "443"
  depends_on            = [google_compute_target_https_proxy.lb_default]
}

Crea la risorsa google_compute_global_forwarding_rule con nome di destinazione myservice-https-proxy e connette il target del proxy HTTPS (myservice-https-proxy) e la risorsa Indirizzo IP (myservice-service-ip) creati in precedenza. Puoi modificare questi valori inserendo i tuoi valori.

Applica questa configurazione:

Per applicare la tua configurazione Terraform a un progetto Google Cloud, completa i passaggi nelle sezioni seguenti.

Prepara Cloud Shell
1. Avvia Cloud Shell.
2. Imposta il progetto Google Cloud predefinito a cui vuoi applicare le configurazioni Terraform.
  
  Devi eseguire questo comando una sola volta per progetto e puoi eseguirlo in qualsiasi directory.
```
export GOOGLE_CLOUD_PROJECT=PROJECT_ID
```
  Le variabili di ambiente vengono sostituite se imposti valori espliciti nel file di configurazione Terraform.
Prepara la directory

Ogni file di configurazione Terraform deve avere la propria directory (chiamata anche modulo principale).
1. In Cloud Shell, crea una directory e un nuovo file al suo interno. Il nome del file deve avere l'estensione .tf, ad esempio main.tf. In questo tutorial, il file è denominato main.tf.
```
mkdir DIRECTORY && cd DIRECTORY && touch main.tf
```
2. Se stai seguendo un tutorial, puoi copiare il codice campione in ogni sezione o passaggio.
  
  Copia il codice campione nel nuovo oggetto main.tf.
  
  Facoltativamente, copia il codice da GitHub. Questa opzione è consigliata se lo snippet Terraform fa parte di una soluzione end-to-end.
3. Esamina e modifica i parametri di esempio da applicare al tuo ambiente.
4. Salva le modifiche.
5. Inizializza Terraform. Devi eseguire questa operazione una sola volta per directory.
```
terraform init
```
  Facoltativamente, per utilizzare la versione più recente del provider Google, includi l'opzione -upgrade:
```
terraform init -upgrade
```
Applica le modifiche
1. Esamina la configurazione e verifica che le risorse che Terraform creerà o aggiornerà soddisfino le tue aspettative:
```
terraform plan
```
  Apporta le correzioni necessarie alla configurazione.
2. Applica la configurazione Terraform eseguendo questo comando e inserendo yes al prompt:
```
terraform apply
```
  Attendi finché in Terraform non viene visualizzato il messaggio "Applicazione completata!".
3. Apri il progetto Google Cloud per visualizzare i risultati. Nella console Google Cloud, vai alle risorse nella UI per assicurarti che Terraform le abbia create o aggiornate.
Nota: gli esempi di Terraform in genere presuppongono che le API richieste siano abilitate nel tuo progetto Google Cloud.

Esegui il deployment in più regioni

Esegui il deployment del tuo servizio nelle regioni di Cloud Run disponibili. Per facilitare la gestione, puoi utilizzare lo stesso nome di servizio in più regioni.

Riga di comando

Scegli le regioni in cui vuoi rendere disponibile il servizio.
Eseguire il deployment del tuo servizio Cloud Run in singole regioni.
```
gcloud run deploy SERVICE_NAME \
--allow-unauthenticated \
--image=IMAGE_URL \
--region=REGION
```
Sostituisci le seguenti variabili:
- REGION con una delle regioni in cui vuoi eseguire il deployment.
- SERVICE_NAME con il nome del tuo servizio. L'utilizzo dello stesso nome di servizio in più regioni semplifica il monitoraggio dei deployment multiregionali.
- IMAGE_URL con un riferimento all'immagine container, ad esempio us-docker.pkg.dev/cloudrun/container/hello:latest. Se utilizzi Artifact Registry, il repository REPO_NAME deve essere già creato. L'URL ha la forma LOCATION-docker.pkg.dev/PROJECT_ID/REPO_NAME/PATH:TAG
Ripeti il passaggio precedente per ogni regione.

Terraform

Configura un servizio per ogni regione specificata nella variabile run_regions.

resource "google_cloud_run_v2_service" "run_default" {
  provider = google-beta
  count    = length(local.run_regions)
  name     = "myservice-run-app-${local.run_regions[count.index]}"
  location = local.run_regions[count.index]

  template {
    containers {
      image = "us-docker.pkg.dev/cloudrun/container/hello"
    }
  }

  # Use an explicit depends_on clause to wait until API is enabled
  depends_on = [
    google_project_service.run_api
  ]
}

Esegue il loop in tutte le regioni specificate nella variabile run_regions e assegna a ogni nuovo servizio il nome seguente: myservice-run-app-${var.run_regions[count.index]}. La definizione della località del servizio viene applicata in modo simile. Sostituisci l'immagine predefinita us-docker.pkg.dev/cloudrun/container/hello" con la tua immagine.

Località Cloud Run

Cloud Run è regionale, il che significa che l'infrastruttura che esegue i tuoi servizi Cloud Run si trova in una regione specifica ed è gestita da Google per essere disponibile in modo ridondante in tutte le zone all'interno della regione.

Soddisfare i requisiti di latenza, disponibilità o durabilità sono fattori principali per la selezione della regione in cui vengono eseguiti i servizi Cloud Run. In genere puoi selezionare la regione più vicina ai tuoi utenti, ma devi considerare la località degli altri prodotti Google Cloud utilizzati dal tuo servizio Cloud Run. L'utilizzo combinato di prodotti Google Cloud in più località può influire sulla latenza e sui costi del tuo servizio.

Cloud Run è disponibile nelle regioni seguenti:

Soggetto ai prezzi di Livello 1

asia-east1 (Taiwan)
asia-northeast1 (Tokyo)
asia-northeast2 (Osaka)
europe-north1 (Finlandia) A basse emissioni di CO₂
europe-southwest1 (Madrid)
europe-west1 (Belgio) A basse emissioni di CO₂
europe-west4 (Paesi Bassi)
europe-west8 (Milano)
europe-west9 (Parigi) A basse emissioni di CO₂
me-west1 (Tel Aviv)
us-central1 (Iowa) A basse emissioni di CO₂
us-east1 (Carolina del Sud)
us-east4 (Virginia del Nord)
us-east5 (Colombo)
us-south1 (Dallas)
us-west1 (Oregon) A basse emissioni di CO₂

Soggetto ai prezzi di Livello 2

africa-south1 (Johannesburg)
asia-east2 (Hong Kong)
asia-northeast3 (Seul, Corea del Sud)
asia-southeast1 (Singapore)
asia-southeast2 (Giacarta)
asia-south1 (Mumbai, India)
asia-south2 (Delhi, India)
australia-southeast1 (Sydney)
australia-southeast2 (Melbourne)
europe-central2 (Varsavia, Polonia)
europe-west10 (Berlino)
europe-west12 (Torino)
europe-west2 (Londra, Regno Unito) A basse emissioni di CO₂
europe-west3 (Francoforte, Germania) A basse emissioni di CO₂
europe-west6 (Zurigo, Svizzera) A basse emissioni di CO₂
me-central1 (Doha)
me-central2 (Dammam)
northamerica-northeast1 (Montreal) A basse emissioni di CO₂
northamerica-northeast2 (Toronto) A basse emissioni di CO₂
southamerica-east1 (San Paolo, Brasile) A basse emissioni di CO₂
southamerica-west1 (Santiago, Cile) A basse emissioni di CO₂
us-west2 (Los Angeles)
us-west3 (Salt Lake City)
us-west4 (Las Vegas)

Se hai già creato un servizio Cloud Run, puoi visualizzare la regione nella dashboard di Cloud Run all'interno della console Google Cloud.

Configura i gruppi di endpoint di rete a livello di regione

Per ogni regione in cui hai eseguito il deployment nel passaggio precedente, devi creare gruppi di endpoint di rete serverless (NEG) e aggiungerli al servizio di backend utilizzando le seguenti istruzioni:

Riga di comando

Crea un gruppo di endpoint di rete per il servizio Cloud Run in REGION:
```
gcloud compute network-endpoint-groups create NEG_NAME \
            --region=REGION \
            --network-endpoint-type=SERVERLESS \
            --cloud-run-service=SERVICE_NAME
```
Nel comando precedente, sostituisci:
- NEG_NAME con il nome della risorsa del gruppo di endpoint di rete. (ad es. "myservice-neg-uscentral1").
- REGION con la regione [region][loc] in cui è stato eseguito il deployment del tuo servizio.
- SERVICE_NAME con il nome del tuo servizio.

Aggiungi il gruppo di endpoint di rete al servizio di backend:

gcloud compute backend-services add-backend --global BACKEND_NAME \
          --network-endpoint-group-region=REGION \
          --network-endpoint-group=NEG_NAME

Specifica il valore NEG_NAME che hai creato nel passaggio precedente per la regione.

Ripeti i passaggi precedenti per ogni regione.

Terraform

Configura un gruppo di endpoint di rete denominato myservice-neg per il servizio Cloud Run per ogni regione specificata nella variabile run_regions:

resource "google_compute_region_network_endpoint_group" "lb_default" {
  provider              = google-beta
  count                 = length(local.run_regions)
  name                  = "myservice-neg"
  network_endpoint_type = "SERVERLESS"
  region                = local.run_regions[count.index]
  cloud_run {
    service = google_cloud_run_v2_service.run_default[count.index].name
  }
}

Configura un servizio di backend per collegare il gruppo di endpoint di rete (myservice-neg):

resource "google_compute_backend_service" "lb_default" {
  provider              = google-beta
  name                  = "myservice-backend"
  load_balancing_scheme = "EXTERNAL_MANAGED"

  backend {
    group = google_compute_region_network_endpoint_group.lb_default[0].id
  }

  backend {
    group = google_compute_region_network_endpoint_group.lb_default[1].id
  }

  # Use an explicit depends_on clause to wait until API is enabled
  depends_on = [
    google_project_service.compute_api,
  ]
}

Configura i record DNS sul tuo dominio

Per puntare il tuo nome di dominio alla regola di forwarding che hai creato, devi aggiornare i suoi record DNS con l'indirizzo IP che hai creato.

Trova l'indirizzo IP riservato del bilanciatore del carico eseguendo:
```
  gcloud compute addresses describe --global SERVICE_IP --format='value(address)'
```
Sostituisci SERVICE_IP con il nome dell'indirizzo IP creato in precedenza. Questo comando stamperà l'indirizzo IP nell'output.
Aggiorna i record DNS del tuo dominio aggiungendo un record A con questo indirizzo IP.

Configura un segmento di pubblico personalizzato se utilizzi servizi autenticati

I servizi autenticati sono protetti da IAM. Questi servizi Cloud Run richiedono l'autenticazione client che dichiara il destinatario previsto di una richiesta al momento della generazione delle credenziali (il pubblico).

Pubblico è in genere l'URL completo del servizio di destinazione. Per impostazione predefinita, per i servizi Cloud Run è un URL generato che termina con run.app. Tuttavia, in un deployment multiregionale, un client non può sapere in anticipo a quale servizio regionale verrà instradata la richiesta. Pertanto, per un deployment in più regioni, configura il servizio in modo da utilizzare i segmenti di pubblico personalizzati.

Attendi il provisioning del bilanciatore del carico

Dopo aver configurato il dominio con l'indirizzo IP del bilanciatore del carico, devi attendere un po' di tempo per la propagazione dei record DNS. Allo stesso modo, devi attendere un po' di tempo prima che il certificato TLS gestito venga emesso per il tuo dominio e sia pronto per iniziare a gestire il traffico HTTPS a livello globale.

Potrebbero essere necessari fino a 30 minuti prima che il bilanciatore del carico inizi a gestire il traffico.

Quando è pronto, visita l'URL del tuo sito web con il prefisso https:// per provarlo.

Verifica stato

Per verificare lo stato della propagazione del record DNS, utilizzando l'utilità a riga di comando dig:
```
dig A +short example.com
```
L'output dovrebbe mostrare l'indirizzo IP che hai configurato nei tuoi record DNS.
Controlla lo stato dell'emissione dei certificati gestiti ed esegui:
```
gcloud compute ssl-certificates describe CERT_NAME
```
Sostituisci CERT_NAME con il nome che hai scelto in precedenza per la risorsa del certificato SSL.

L'output dovrebbe mostrare una riga contenente status: ACTIVE.

Configurazione del reindirizzamento da HTTP a HTTPS

Per impostazione predefinita, una regola di forwarding gestisce un solo protocollo, pertanto le richieste agli endpoint http:// risponderanno con un errore 404 - Non trovato. Se hai bisogno che le richieste agli URL http:// vengano reindirizzate al protocollo https://, devi creare una mappa URL aggiuntiva e una regola di forwarding utilizzando le seguenti istruzioni:

Riga di comando

Crea una mappa URL con una regola di reindirizzamento.

gcloud compute url-maps import HTTP_URLMAP_NAME \
          --global \
          --source /dev/stdin <<EOF
        name: HTTP_URLMAP_NAME
        defaultUrlRedirect:
          redirectResponseCode: MOVED_PERMANENTLY_DEFAULT
          httpsRedirect: True
        EOF

Sostituisci HTTP_URLMAP_NAME con il nome della risorsa della mappa URL che creerai (ad es. myservice-httpredirect).

Creare un proxy HTTP di destinazione con la mappa URL.
```
gcloud compute target-http-proxies create HTTP_PROXY_NAME \
          --url-map=HTTP_URLMAP_NAME
```
Sostituisci HTTP_PROXY_NAME con il nome del proxy HTTP di destinazione che creerai (ad es. myservice-http).

Crea una regola di forwarding sulla porta 80 con lo stesso indirizzo IP riservato.

gcloud compute forwarding-rules create --global HTTP_FORWARDING_RULE_NAME \
          --target-http-proxy=HTTP_PROXY_NAME \
          --address=SERVICE_IP \
          --ports=80 \

Sostituisci HTTP_FORWARDING_RULE_NAME con il nome della nuova regola di forwarding che creerai (ad es. myservice-httplb).

Terraform

Crea una risorsa mappa URL con una regola di reindirizzamento:

resource "google_compute_url_map" "https_default" {
  provider = google-beta
  name     = "myservice-https-urlmap"

  default_url_redirect {
    redirect_response_code = "MOVED_PERMANENTLY_DEFAULT"
    https_redirect         = true
    strip_query            = false
  }
}

Crea un proxy HTTP di destinazione con la risorsa mappa URL appena creata (myservice-https-urlmap):

resource "google_compute_target_http_proxy" "https_default" {
  provider = google-beta
  name     = "myservice-http-proxy"
  url_map  = google_compute_url_map.https_default.id

  depends_on = [
    google_compute_url_map.https_default
  ]
}

Crea una regola di forwarding sulla porta 80 con la stessa risorsa di indirizzo IP riservata (myservice-http-proxy):

resource "google_compute_global_forwarding_rule" "https_default" {
  provider   = google-beta
  name       = "myservice-https-fr"
  target     = google_compute_target_http_proxy.https_default.id
  ip_address = google_compute_global_address.lb_default.id
  port_range = "80"
  depends_on = [google_compute_target_http_proxy.https_default]
}

Usa sottoscrizioni push di Pub/Sub autenticate con deployment multiregionale

Per impostazione predefinita, un servizio Pub/Sub recapita i messaggi agli endpoint push nella stessa regione Google Cloud in cui il servizio Pub/Sub archivia i messaggi. Per una soluzione alternativa a questo comportamento, consulta Utilizzo di un abbonamento push di Pub/Sub autenticato con un Cloud Rundeployment di più regioni.

Gestisci il traffico da più regioni

Crea un bilanciatore del carico

Riga di comando

Terraform

Prepara Cloud Shell

Prepara la directory

Applica le modifiche

Esegui il deployment in più regioni

Riga di comando

Terraform

Località Cloud Run

Soggetto ai prezzi di Livello 1

Soggetto ai prezzi di Livello 2

Configura i gruppi di endpoint di rete a livello di regione

Riga di comando

Terraform

Configura i record DNS sul tuo dominio

Configura un segmento di pubblico personalizzato se utilizzi servizi autenticati

Attendi il provisioning del bilanciatore del carico

Verifica stato

Configurazione del reindirizzamento da HTTP a HTTPS

Riga di comando

Terraform

Usa sottoscrizioni push di Pub/Sub autenticate con deployment multiregionale