Pub/Sub-Anleitung für Terraform

---

Hinweis: Dieser Inhalt gilt nur für Cloud Run-Funktionen, früher Cloud Functions (2. Generation).

In dieser Anleitung wird gezeigt, wie Sie eine Pub/Sub-Funktion bereitstellen. Dazu laden Sie eine ZIP-Datei mit dem Funktionsquellcode in einen Cloud Storage-Bucket hoch und verwenden Terraform zum Bereitstellen der Ressourcen. Terraform ist ein Open-Source-Tool, mit dem Sie Google Cloud-Ressourcen mit deklarativen Konfigurationsdateien bereitstellen können.

In dieser Anleitung wird als Beispiel eine Funktion von Node.js verwendet. Sie funktioniert jedoch auch mit Python-, Go- und Java-Funktionen. Die Anleitungen sind identisch, unabhängig davon, welche dieser Laufzeiten Sie verwenden.

Ziele

• Erfahren Sie, wie Sie mit Terraform eine Pub/Sub-Funktion bereitstellen.

Kosten

In diesem Dokument verwenden Sie die folgenden kostenpflichtigen Komponenten von Google Cloud:

• Cloud Run functions
• Cloud Build
• Cloud Storage
• Artifact Registry

For details, see Cloud Run functions pricing.

Mit dem Preisrechner können Sie eine Kostenschätzung für Ihre voraussichtliche Nutzung vornehmen. Neuen Google Cloud-Nutzern steht möglicherweise eine kostenlose Testversion zur Verfügung.

Hinweise

1. Sign in to your Google Cloud account. If you're new to Google Cloud, create an account to evaluate how our products perform in real-world scenarios. New customers also get $300 in free credits to run, test, and deploy workloads.

2. In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

   Note: If you don't plan to keep the resources that you create in this procedure, create a project instead of selecting an existing project. After you finish these steps, you can delete the project, removing all resources associated with the project.

   Go to project selector

3. Make sure that billing is enabled for your Google Cloud project.

4. Enable the Cloud Functions, Cloud Build, Artifact Registry, and Cloud Storage APIs.

   Enable the APIs

5. Install the Google Cloud CLI.

6. To initialize the gcloud CLI, run the following command:

   gcloud init

7. In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

   Note: If you don't plan to keep the resources that you create in this procedure, create a project instead of selecting an existing project. After you finish these steps, you can delete the project, removing all resources associated with the project.

   Go to project selector

8. Make sure that billing is enabled for your Google Cloud project.

9. Enable the Cloud Functions, Cloud Build, Artifact Registry, and Cloud Storage APIs.

   Enable the APIs

10. Install the Google Cloud CLI.

11. To initialize the gcloud CLI, run the following command:

    gcloud init

Wenn Sie die gcloud CLI bereits installiert haben, aktualisieren Sie sie mit dem folgenden Befehl:

gcloud components update

12. Bereiten Sie die Entwicklungsumgebung vor.
    

    Einrichtungsleitfaden für Node.js aufrufen

Umgebung einrichten

In dieser Anleitung führen Sie Befehle in Cloud Shell aus. Cloud Shell ist eine Shell-Umgebung, in der das Google Cloud CLI einschließlich der Google Cloud-Befehlszeile vorinstalliert ist. Auch die Werte für Ihr aktuelles Projekt sind bereits festgelegt. Die Initialisierung von Cloud Shell kann mehrere Minuten dauern:

Cloud Shell öffnen

Anwendung vorbereiten

Führen Sie in Cloud Shell folgende Schritte aus:

1. Klonen Sie das Repository der Beispielanwendung in Ihre Cloud Shell-Instanz:

   git clone https://github.com/GoogleCloudPlatform/nodejs-docs-samples.git

2. Wechseln Sie in das Verzeichnis, das den Beispielcode für Cloud Run-Funktionen enthält:

   cd nodejs-docs-samples/functions/v2/helloPubSub/

   Das in dieser Anleitung verwendete Node.js-Beispiel ist eine grundlegende Pub/Sub-Funktion "Hello World".

3. Erstellen Sie eine ZIP-Datei mit dem Quellcode der Funktion, den Terraform in einen Cloud Storage-Bucket hochlädt:

   zip -r function-source.zip .
   

   Beachten Sie, dass das Stammverzeichnis der ZIP-Datei das Stammverzeichnis Ihres Quellcodes der Funktion sein muss. Der obige Befehl enthält also die Dateien im Verzeichnis helloworld, aber nicht das Verzeichnis selbst.

   Hinweis: Für die Produktion wird empfohlen, nur die erforderlichen Funktionsquelldateien aufzunehmen.

Erstellen Sie die Datei main.tf:

1. Erstellen Sie im Verzeichnis nodejs-docs-samples/functions/ eine main.tf-Datei für die Terraform-Konfiguration:

   touch main.tf
   

2. Kopieren Sie diese Terraform-Konfiguration in Ihre main.tf-Datei:

   terraform {
     required_providers {
       google = {
         source  = "hashicorp/google"
         version = ">= 4.34.0"
       }
     }
   }
   
   resource "random_id" "bucket_prefix" {
     byte_length = 8
   }
   
   
   resource "google_service_account" "default" {
     account_id   = "test-gcf-sa"
     display_name = "Test Service Account"
   }
   
   resource "google_pubsub_topic" "default" {
     name = "functions2-topic"
   }
   
   resource "google_storage_bucket" "default" {
     name                        = "${random_id.bucket_prefix.hex}-gcf-source" # Every bucket name must be globally unique
     location                    = "US"
     uniform_bucket_level_access = true
   }
   
   data "archive_file" "default" {
     type        = "zip"
     output_path = "/tmp/function-source.zip"
     source_dir  = "function-source/"
   }
   
   resource "google_storage_bucket_object" "default" {
     name   = "function-source.zip"
     bucket = google_storage_bucket.default.name
     source = data.archive_file.default.output_path # Path to the zipped function source code
   }
   
   resource "google_cloudfunctions2_function" "default" {
     name        = "function"
     location    = "us-central1"
     description = "a new function"
   
     build_config {
       runtime     = "nodejs16"
       entry_point = "helloPubSub" # Set the entry point
       environment_variables = {
         BUILD_CONFIG_TEST = "build_test"
       }
       source {
         storage_source {
           bucket = google_storage_bucket.default.name
           object = google_storage_bucket_object.default.name
         }
       }
     }
   
     service_config {
       max_instance_count = 3
       min_instance_count = 1
       available_memory   = "256M"
       timeout_seconds    = 60
       environment_variables = {
         SERVICE_CONFIG_TEST = "config_test"
       }
       ingress_settings               = "ALLOW_INTERNAL_ONLY"
       all_traffic_on_latest_revision = true
       service_account_email          = google_service_account.default.email
     }
   
     event_trigger {
       trigger_region = "us-central1"
       event_type     = "google.cloud.pubsub.topic.v1.messagePublished"
       pubsub_topic   = google_pubsub_topic.default.id
       retry_policy   = "RETRY_POLICY_RETRY"
     }
   }

3. Bearbeiten Sie die Datei main.tf, um sicherzustellen, dass sie die richtigen Werte für die folgenden Elemente enthält. Sie müssen diese Datei bearbeiten, wenn sich Ihre Konfiguration ändert, z. B. um eine andere Laufzeit zu verwenden oder eine andere Funktion bereitzustellen:

   • Laufzeit: In diesem Beispiel lautet die Laufzeit nodejs16.
   • Funktionseinstiegspunkt: In diesem Beispiel ist der Funktionseinstiegspunkt helloPubSub.
   • Pfad zur ZIP-Datei: Wenn Sie Ihre main.tf-Datei wie oben beschrieben im Verzeichnis nodejs-docs-samples/functions/ abgelegt haben, lautet der Pfad ./v2/helloPubSub/function-source.zip.

Hinweis: Die Datei main.tf sollte zuverlässig einen eindeutigen Bucket-Namen generieren, wenn Sie die Konfiguration anwenden. Wenn Sie jedoch den Fehler "Ressource ist bereits vorhanden" erhalten, müssen Sie main.tf bearbeiten, um einen anderen Bucket-Namen anzugeben, der global eindeutig ist.

Terraform initialisieren

1. Führen Sie in Cloud Shell den folgenden Befehl aus, um Terraform zu initialisieren:

   docker run -v $(pwd):/app -w /app hashicorp/terraform:0.12.0 init
   

   Sie verwenden das öffentliche Docker-Image für Terraform. Docker ist bereits in Cloud Shell installiert. Das aktuelle Arbeitsverzeichnis wird als Volume bereitgestellt, damit der Docker-Container die Terraform-Konfigurationsdatei lesen kann.

2. Führen Sie diesen Befehl aus, um die erforderlichen Plug-ins hinzuzufügen und das Verzeichnis .terraform zu erstellen:

   terraform init
   

Terraform-Konfiguration validieren

Sehen Sie sich eine Vorschau der Terraform-Konfiguration an. Dieser Schritt ist optional, aber Sie können prüfen, ob die Syntax von main.tf korrekt ist. Dieser Befehl zeigt eine Vorschau der erstellten Ressourcen an:

terraform plan

Wenden Sie die Terraform-Konfiguration an:

Stellen Sie die Funktion bereit, indem Sie die Konfiguration anwenden. Geben Sie bei Aufforderung yes ein.

terraform apply

Funktion auslösen

So testen Sie die Pub/Sub-Funktion:

1. Veröffentlichen Sie eine Nachricht zum Thema (in diesem Beispiel lautet der Themenname functions2-topic):

   gcloud pubsub topics publish TOPIC_NAME --message="Friend"

2. Lesen Sie die Funktionslogs, um das Ergebnis anzuzeigen, wobei FUNCTION_NAME der Name Ihrer Funktion ist (in diesem Beispiel lautet der Funktionsname einfach function):

   gcloud beta functions logs read FUNCTION_NAME --gen2

   Die Logging-Ausgabe sollte die neue Nachricht "Friend" enthalten.

   Hinweis: Es kann etwas dauern, bis die Logs angezeigt werden. Wenn Sie sie nicht sofort sehen, versuchen Sie es in ein oder zwei Minuten noch einmal.

Bereinigen

Nachdem Sie die Anleitung abgeschlossen haben, können Sie alle erstellten Elemente löschen, sodass keine weiteren Kosten anfallen.

Mit Terraform können Sie alle in der Konfigurationsdatei definierten Ressourcen mit dem Befehl terraform destroy entfernen:

terraform destroy

Geben Sie yes ein, damit Terraform Ihre Ressourcen löschen kann.