여러 리전의 트래픽 제공

전 세계 사용자에게 더 빠르게 응답을 반환하려면 여러 리전에 서비스를 배포하고 사용자를 가장 가까운 리전으로 라우팅해야 합니다.

Cloud Run 서비스는 개별 리전에 배포되므로 사용자를 서비스의 다른 리전으로 라우팅하도록 외부 애플리케이션 부하 분산기를 구성해야 합니다.

이 가이드에서는 외부 애플리케이션 부하 분산기를 전역 Anycast IP 주소(서비스가 배포된 가장 가까운 Google 데이터 센터로 사용자를 라우팅함)를 가리키면서 관리형 TLS 인증서를 사용하여 보호되는 도메인과 함께 구성하는 방법을 보여줍니다.

이 가이드에서 설명하는 아키텍처는 리전 Cloud Run 서비스가 응답하지 않거나 오류를 반환하기 시작할 때 요청을 다른 리전으로 자동 라우팅하지 않습니다. 멀티 리전 서비스의 가용성을 높이려면 이상점 감지를 구성하여 HTTP 오류율을 기준으로 비정상 Cloud Run 서비스를 식별하고 일부 요청을 다른 리전으로 우회할 수 있습니다.

부하 분산기 만들기

외부 부하 분산기를 만들려면 다양한 네트워킹 리소스를 만들고 서로 연결해야 합니다.

명령줄

  1. 부하 분산기를 다시 만들 때 DNS 레코드를 업데이트할 필요가 없도록 고정 IP 주소를 예약합니다.
    gcloud compute addresses create --global SERVICE_IP
    위의 명령어에서 SERVICE_IP를 IP 주소 리소스 이름(예: myservice-ip)으로 바꿉니다.

    이 IP 주소는 Google 데이터 센터 또는 방문자와 가장 가까운 접속 지점으로 라우팅하는 전역 Anycast IPv4 주소입니다.

  2. 백엔드 서비스를 만듭니다.
    gcloud compute backend-services create --global BACKEND_NAME

    위 명령어에서 BACKEND_NAME를 백엔드 서비스에 지정할 이름으로 바꿉니다(예: myservice-backend).

  3. URL 맵을 만듭니다.
    gcloud compute url-maps create URLMAP_NAME --default-service=BACKEND_NAME

    URLMAP_NAME을 URL 맵에 지정할 이름으로 바꿉니다(예: myservice-urlmap).

  4. 도메인에서 HTTPS 트래픽을 제공하도록 관리형 TLS 인증서를 만듭니다. example.com을 도메인 이름으로 바꿉니다.
    gcloud compute ssl-certificates create CERT_NAME \
      --domains=example.com

    CERT_NAME을 관리형 SSL 인증서에 사용할 이름으로 바꿉니다(예: myservice-cert).

  5. 대상 HTTPS 프록시를 만듭니다.
    gcloud compute target-https-proxies create HTTPS_PROXY_NAME \
      --ssl-certificates=CERT_NAME \
      --url-map=URLMAP_NAME

    HTTPS_PROXY_NAME을 대상 HTTPS 프록시에 지정할 이름으로 바꿉니다(예: myservice-https).

  6. 생성한 네트워킹 리소스를 IP 주소에 연결하는 전달 규칙을 만듭니다.
    gcloud compute forwarding-rules create --global FORWARDING_RULE_NAME \
      --target-https-proxy=HTTPS_PROXY_NAME \
      --address=SERVICE_IP \
      --ports=443

    FORWARDING_RULE_NAME을 만들려는 전달 규칙 리소스의 이름으로 바꿉니다(예: myservice-lb).

Terraform

이 섹션에 설명된 단계 대신 전역 HTTP 부하 분산기 Terraform 모듈을 사용할 수 있습니다.

Terraform 파일에 다음을 추가합니다(예: main.tf).

  1. IP 주소를 구성:

    resource "google_compute_global_address" "lb_default" {
      provider = google-beta
      name     = "myservice-service-ip"
    
      # Use an explicit depends_on clause to wait until API is enabled
      depends_on = [
        google_project_service.compute_api
      ]
    }
    output "load_balancer_ip_addr" {
      value = google_compute_global_address.lb_default.address
    }

    IP 주소 리소스 이름을 myservice-service-ip로 구성합니다. 이 값을 자신에게 해당하는 값으로 변경할 수 있습니다. 이 IP 주소는 Google 데이터 센터 또는 방문자와 가장 가까운 접속 지점으로 라우팅하는 전역 Anycast IPv4 주소입니다.

  2. 백엔드 서비스를 만들고 구성합니다.

    resource "google_compute_backend_service" "lb_default" {
      provider              = google-beta
      name                  = "myservice-backend"
      load_balancing_scheme = "EXTERNAL_MANAGED"
    
      backend {
        group = google_compute_region_network_endpoint_group.lb_default[0].id
      }
    
      backend {
        group = google_compute_region_network_endpoint_group.lb_default[1].id
      }
    
      # Use an explicit depends_on clause to wait until API is enabled
      depends_on = [
        google_project_service.compute_api,
      ]
    }

    이 리소스는 백엔드 서비스의 이름을 myservice-backend로 구성합니다. 이 값을 자신에게 해당하는 값으로 변경할 수 있습니다.

  3. URL 맵을 구성합니다.

    resource "google_compute_url_map" "lb_default" {
      provider        = google-beta
      name            = "myservice-lb-urlmap"
      default_service = google_compute_backend_service.lb_default.id
    
      path_matcher {
        name            = "allpaths"
        default_service = google_compute_backend_service.lb_default.id
        route_rules {
          priority = 1
          url_redirect {
            https_redirect         = true
            redirect_response_code = "MOVED_PERMANENTLY_DEFAULT"
          }
        }
      }
    }

    백엔드 서비스 리소스(myservice-backend)를 새 URL 맵 리소스(myservice-lb-urlmap)에 연결합니다. 이 값을 자신에게 해당하는 값으로 변경할 수 있습니다.

  4. 도메인에서 HTTPS 트래픽을 제공할 수 있도록 관리형 TLS 인증서를 만듭니다. example.comgoogle_compute_managed_ssl_certificate 리소스의 도메인 이름으로 바꿉니다.

    resource "google_compute_managed_ssl_certificate" "lb_default" {
      provider = google-beta
      name     = "myservice-ssl-cert"
    
      managed {
        domains = ["example.com"]
      }
    }
  5. HTTPS 프록시를 구성합니다.

    resource "google_compute_target_https_proxy" "lb_default" {
      provider = google-beta
      name     = "myservice-https-proxy"
      url_map  = google_compute_url_map.lb_default.id
      ssl_certificates = [
        google_compute_managed_ssl_certificate.lb_default.name
      ]
      depends_on = [
        google_compute_managed_ssl_certificate.lb_default
      ]
    }

    대상 이름이 myservice-https-proxygoogle_compute_target_https_proxy 리소스를 만들고 이전에 만든 TLS 인증서(myservice-ssl-cert) 및 URL 매핑 리소스(myservice-lb-urlmap)를 연결합니다. 이 값을 자신에게 해당하는 값으로 변경할 수 있습니다.

  6. 전달 규칙을 구성합니다.

    resource "google_compute_global_forwarding_rule" "lb_default" {
      provider              = google-beta
      name                  = "myservice-lb-fr"
      load_balancing_scheme = "EXTERNAL_MANAGED"
      target                = google_compute_target_https_proxy.lb_default.id
      ip_address            = google_compute_global_address.lb_default.id
      port_range            = "443"
      depends_on            = [google_compute_target_https_proxy.lb_default]
    }

    대상 이름이 myservice-https-proxygoogle_compute_global_forwarding_rule 리소스를 만들고 이전에 만든 HTTPS 프록시 대상(myservice-https-proxy) 및 IP 주소 리소스(myservice-service-ip)를 연결합니다. 이 값을 자신에게 해당하는 값으로 변경할 수 있습니다.

  7. 이 구성을 적용합니다.

    Google Cloud 프로젝트에 Terraform 구성을 적용하려면 다음 섹션의 단계를 완료하세요.

    Cloud Shell 준비

    1. Cloud Shell을 실행합니다.
    2. Terraform 구성을 적용할 기본 Google Cloud 프로젝트를 설정합니다.

      이 명령어는 프로젝트당 한 번만 실행하면 되며 어떤 디렉터리에서도 실행할 수 있습니다.

      export GOOGLE_CLOUD_PROJECT=PROJECT_ID

      Terraform 구성 파일에서 명시적 값을 설정하면 환경 변수가 재정의됩니다.

    디렉터리 준비

    각 Terraform 구성 파일에는 자체 디렉터리(루트 모듈이라고도 함)가 있어야 합니다.

    1. Cloud Shell에서 디렉터리를 만들고 해당 디렉터리 내에 새 파일을 만드세요. 파일 이름에는 .tf 확장자가 있어야 합니다(예: main.tf). 이 튜토리얼에서는 파일을 main.tf라고 합니다.
      mkdir DIRECTORY && cd DIRECTORY && touch main.tf
    2. 튜토리얼을 따라 하는 경우 각 섹션이나 단계에서 샘플 코드를 복사할 수 있습니다.

      샘플 코드를 새로 만든 main.tf에 복사합니다.

      필요한 경우 GitHub에서 코드를 복사합니다. 이는 Terraform 스니펫이 엔드 투 엔드 솔루션의 일부인 경우에 권장됩니다.

    3. 환경에 적용할 샘플 매개변수를 검토하고 수정합니다.
    4. 변경사항을 저장합니다.
    5. Terraform을 초기화합니다. 이 작업은 디렉터리당 한 번만 수행하면 됩니다.
      terraform init

      원하는 경우 최신 Google 공급업체 버전을 사용하려면 -upgrade 옵션을 포함합니다.

      terraform init -upgrade

    변경사항 적용

    1. 구성을 검토하고 Terraform에서 만들거나 업데이트할 리소스가 예상과 일치하는지 확인합니다.
      terraform plan

      필요에 따라 구성을 수정합니다.

    2. 다음 명령어를 실행하고 프롬프트에 yes를 입력하여 Terraform 구성을 적용합니다.
      terraform apply

      Terraform에 '적용 완료' 메시지가 표시될 때까지 기다립니다.

    3. 결과를 보려면 Google Cloud 프로젝트를 엽니다. Google Cloud 콘솔에서 UI의 리소스로 이동하여 Terraform이 리소스를 만들었거나 업데이트했는지 확인합니다.

여러 리전에 배포

사용 가능한 Cloud Run 리전에 서비스를 배포합니다. 손쉬운 관리를 위해 여러 리전에서 동일한 서비스 이름을 사용할 수 있습니다.

명령줄

  1. 서비스를 제공할 리전을 선택합니다.
  2. Cloud Run 서비스를 개별 리전에 배포합니다.
  3. gcloud run deploy SERVICE_NAME \
    --allow-unauthenticated \
    --image=IMAGE_URL \
    --region=REGION

    다음 변수를 바꿉니다.

    • REGION을 배포할 리전 중 하나로 바꿉니다.
    • SERVICE_NAME를 서비스 이름으로 바꿉니다. 여러 리전에서 동일한 서비스 이름을 사용하면 멀티 리전 배포를 더 쉽게 추적할 수 있습니다.
    • IMAGE_URL을 컨테이너 이미지에 대한 참조(예: us-docker.pkg.dev/cloudrun/container/hello:latest)로 바꿉니다. Artifact Registry를 사용하는 경우 저장소 REPO_NAME이 이미 생성되어 있어야 합니다. URL의 형식은 REGION-docker.pkg.dev/PROJECT_ID/REPO_NAME/PATH:TAG입니다.
  4. 각 리전에 대해 이전 단계를 반복합니다.

Terraform

run_regions 변수에 지정된 각 리전마다 서비스를 구성합니다.

resource "google_cloud_run_v2_service" "run_default" {
  provider = google-beta
  count    = length(local.run_regions)
  name     = "myservice-run-app-${local.run_regions[count.index]}"
  location = local.run_regions[count.index]

  template {
    containers {
      image = "us-docker.pkg.dev/cloudrun/container/hello"
    }
  }

  # Use an explicit depends_on clause to wait until API is enabled
  depends_on = [
    google_project_service.run_api
  ]
}

run_regions 변수에 지정된 모든 리전에 반복하고 각각의 새로운 서비스에 myservice-run-app-${var.run_regions[count.index]}와 같은 이름을 지정합니다. 서비스 위치 정의도 유사하게 적용됩니다. 기본 이미지 us-docker.pkg.dev/cloudrun/container/hello"를 자체 이미지로 바꿉니다.

Cloud Run 위치

Cloud Run은 리전을 기반으로 합니다. 즉, Cloud Run 서비스를 실행하는 인프라가 특정 리전에 위치해 있으며 해당 리전 내의 모든 영역에서 중복으로 사용할 수 있도록 Google이 관리합니다.

Cloud Run 서비스를 실행하는 리전을 선택하는 데 있어 중요한 기준은 지연 시간, 가용성 또는 내구성 요구사항입니다. 일반적으로 사용자와 가장 가까운 리전을 선택할 수 있지만 Cloud Run 서비스에서 사용하는 다른 Google Cloud 제품 위치도 고려해야 합니다. 여러 위치에서 Google Cloud 제품을 함께 사용하면 서비스 지연 시간과 비용에 영향을 미칠 수 있습니다.

Cloud Run은 다음 리전에서 사용할 수 있습니다.

등급 1 가격 적용

  • asia-east1(타이완)
  • asia-northeast1(도쿄)
  • asia-northeast2(오사카)
  • europe-north1(핀란드) 잎 아이콘 낮은 CO2
  • europe-southwest1(마드리드)
  • europe-west1(벨기에) 잎 아이콘 낮은 CO2
  • europe-west4(네덜란드)
  • europe-west8(밀라노)
  • europe-west9(파리) 잎 아이콘 낮은 CO2
  • me-west1(텔아비브)
  • us-central1(아이오와) 잎 아이콘 낮은 CO2
  • us-east1(사우스캐롤라이나)
  • us-east4(북 버지니아)
  • us-east5(콜럼버스)
  • us-south1(댈러스)
  • us-west1(오리건) 잎 아이콘 낮은 CO2

등급 2 가격 적용

  • africa-south1(요하네스버그)
  • asia-east2(홍콩)
  • asia-northeast3(대한민국 서울)
  • asia-southeast1(싱가포르)
  • asia-southeast2 (자카르타)
  • asia-south1(인도 뭄바이)
  • asia-south2(인도 델리)
  • australia-southeast1(시드니)
  • australia-southeast2(멜버른)
  • europe-central2(폴란드 바르샤바)
  • europe-west10(베를린)
  • europe-west12(토리노)
  • europe-west2(영국 런던) 잎 아이콘 낮은 CO2
  • europe-west3(독일 프랑크푸르트) 잎 아이콘 낮은 CO2
  • europe-west6(스위스 취리히) 잎 아이콘 낮은 CO2
  • me-central1(도하)
  • me-central2(담맘)
  • northamerica-northeast1(몬트리올) 잎 아이콘 낮은 CO2
  • northamerica-northeast2(토론토) 잎 아이콘 낮은 CO2
  • southamerica-east1(브라질 상파울루) 잎 아이콘 낮은 CO2
  • southamerica-west1(칠레 산티아고) 잎 아이콘 낮은 CO2
  • us-west2(로스앤젤레스)
  • us-west3(솔트레이크시티)
  • us-west4(라스베이거스)

Cloud Run 서비스를 이미 만들었다면 Google Cloud 콘솔의 Cloud Run 대시보드에서 리전을 확인할 수 있습니다.

리전 네트워크 엔드포인트 그룹 구성

이전 단계에서 배포한 각 리전에 대해 다음 안내에 따라 서버리스 네트워크 엔드포인트 그룹(NEG)을 만들고 백엔드 서비스에 추가해야 합니다.

명령줄

  1. REGION에서 Cloud Run 서비스의 네트워크 엔드포인트 그룹을 만듭니다.

    gcloud compute network-endpoint-groups create NEG_NAME \
                --region=REGION \
                --network-endpoint-type=SERVERLESS \
                --cloud-run-service=SERVICE_NAME

    위의 명령어에서 다음과 같이 바꿉니다.

    • NEG_NAME을 네트워크 엔드포인트 그룹 리소스의 이름으로 바꿉니다 (예: `myservice-neg-uscentral1`)
    • REGION을 서비스가 배포된 [region][loc]로 바꿉니다.
    • SERVICE_NAME를 서비스 이름으로 바꿉니다.
  2. 백엔드 서비스에 네트워크 엔드포인트 그룹을 추가합니다.

    gcloud compute backend-services add-backend --global BACKEND_NAME \
              --network-endpoint-group-region=REGION \
              --network-endpoint-group=NEG_NAME

    이전 단계에서 만든 리전의 NEG_NAME을 지정합니다.

  3. 각 리전에 대해 위의 단계를 반복합니다.

Terraform

  1. run_regions 변수에 지정된 각 리전마다 Cloud Run 서비스에 대한 이름이 myservice-neg인 네트워크 엔드포인트 그룹을 구성합니다.

    resource "google_compute_region_network_endpoint_group" "lb_default" {
      provider              = google-beta
      count                 = length(local.run_regions)
      name                  = "myservice-neg"
      network_endpoint_type = "SERVERLESS"
      region                = local.run_regions[count.index]
      cloud_run {
        service = google_cloud_run_v2_service.run_default[count.index].name
      }
    }
  2. 네트워크 엔드포인트 그룹(myservice-neg)을 연결하도록 백엔드 서비스를 구성합니다.

    resource "google_compute_backend_service" "lb_default" {
      provider              = google-beta
      name                  = "myservice-backend"
      load_balancing_scheme = "EXTERNAL_MANAGED"
    
      backend {
        group = google_compute_region_network_endpoint_group.lb_default[0].id
      }
    
      backend {
        group = google_compute_region_network_endpoint_group.lb_default[1].id
      }
    
      # Use an explicit depends_on clause to wait until API is enabled
      depends_on = [
        google_project_service.compute_api,
      ]
    }

도메인에 DNS 레코드 구성

도메인 이름이 앞에서 만든 전달 규칙을 가리키도록 하려면 앞에서 만든 IP 주소를 사용하여 DNS 레코드를 업데이트해야 합니다.

  1. 다음을 실행하여 부하 분산기의 예약된 IP 주소를 찾습니다.

      gcloud compute addresses describe --global SERVICE_IP --format='value(address)'

    SERVICE_IP를 이전에 만든 IP 주소의 이름으로 바꿉니다. 이 명령어는 IP 주소를 출력에 인쇄합니다.

  2. 이 IP 주소로 A 레코드를 추가하여 도메인의 DNS 레코드를 업데이트합니다.

인증된 서비스를 사용하는 경우 커스텀 대상 구성

인증된 서비스는 IAM으로 보호됩니다. 이러한 Cloud Run 서비스에는 사용자 인증 정보 생성 시 요청의 의도된 수신자(대상)를 선언하는 클라이언트 인증이 필요합니다.

대상은 일반적으로 타겟 서비스의 전체 URL이며, 기본적으로 Cloud Run 서비스의 경우 run.app으로 끝나는 생성 URL입니다. 하지만 멀티 리전 배포에서는 클라이언트가 요청이 라우팅될 리전 서비스를 미리 알 수 없습니다. 따라서 멀티 리전 배포의 경우 커스텀 대상을 사용하도록 서비스를 구성합니다.

부하 분산기 프로비저닝 대기

부하 분산기 IP 주소로 도메인을 구성한 후 DNS 레코드가 적용될 때까지 기다려야 합니다. 마찬가지로 도메인에서 관리형 TLS 인증서가 발급될 때까지 기다린 후 HTTPS 트래픽을 전역적으로 제공할 준비를 해야 합니다.

부하 분산기가 트래픽을 제공하기까지 데 최대 30분이 걸릴 수 있습니다.

준비가 되면 https:// 프리픽스가 있는 웹사이트의 URL을 방문하여 직접 사용해 보세요.

상태 확인

  1. DNS 레코드 전파의 상태를 확인하려면 dig 명령줄 유틸리티를 사용합니다.

    dig A +short example.com

    출력에 DNS 레코드에서 구성한 IP 주소가 표시됩니다.

  2. 관리형 인증서 발급 상태를 확인하고 다음 명령어를 실행합니다.

    gcloud compute ssl-certificates describe CERT_NAME

    CERT_NAME을 이전에 SSL 인증서 리소스에 대해 선택한 이름으로 바꿉니다.

    출력에 status: ACTIVE가 포함된 줄이 표시됩니다.

HTTP에서 HTTPS로 리디렉션 설정

기본적으로 전달 규칙은 단일 프로토콜만 처리하므로 http:// 엔드포인트에 대한 요청은 404 Not Found로 응답합니다. http:// URL에 대한 요청을 https:// 프로토콜로 리디렉션해야 하는 경우 다음 안내에 따라 추가 URL 맵 및 전달 규칙을 만들어야 합니다.

명령줄

  1. 리디렉션 규칙을 사용하여 URL 맵을 만듭니다.

    gcloud compute url-maps import HTTP_URLMAP_NAME \
              --global \
              --source /dev/stdin <<EOF
            name: HTTP_URLMAP_NAME
            defaultUrlRedirect:
              redirectResponseCode: MOVED_PERMANENTLY_DEFAULT
              httpsRedirect: True
            EOF

    HTTP_URLMAP_NAME을 만들려는 URL 맵 리소스의 이름으로 바꿉니다(예: myservice-httpredirect).

  2. URL 맵을 사용하여 대상 HTTP 프록시를 만듭니다.

    gcloud compute target-http-proxies create HTTP_PROXY_NAME \
              --url-map=HTTP_URLMAP_NAME

    HTTP_PROXY_NAME을 만들려는 대상 HTTP 프록시의 이름으로 바꿉니다(예: myservice-http).

  3. 포트 80에 예약된 IP 주소가 동일한 전달 규칙을 만듭니다.

    gcloud compute forwarding-rules create --global HTTP_FORWARDING_RULE_NAME \
              --target-http-proxy=HTTP_PROXY_NAME \
              --address=SERVICE_IP \
              --ports=80 \
            

    HTTP_FORWARDING_RULE_NAME을 만들려는 새 전달 규칙의 이름으로 바꿉니다(예: myservice-httplb).

Terraform

  1. 리디렉션 규칙을 사용하여 URL 맵 리소스를 만듭니다.

    resource "google_compute_url_map" "https_default" {
      provider = google-beta
      name     = "myservice-https-urlmap"
    
      default_url_redirect {
        redirect_response_code = "MOVED_PERMANENTLY_DEFAULT"
        https_redirect         = true
        strip_query            = false
      }
    }
  2. 새로 만든 URL 맵 리소스(myservice-https-urlmap)로 대상 HTTP 프록시를 만듭니다.

    resource "google_compute_target_http_proxy" "https_default" {
      provider = google-beta
      name     = "myservice-http-proxy"
      url_map  = google_compute_url_map.https_default.id
    
      depends_on = [
        google_compute_url_map.https_default
      ]
    }
  3. 포트 80에 예약된 IP 주소 리소스(myservice-http-proxy)가 동일한 전달 규칙을 만듭니다.

    resource "google_compute_global_forwarding_rule" "https_default" {
      provider   = google-beta
      name       = "myservice-https-fr"
      target     = google_compute_target_http_proxy.https_default.id
      ip_address = google_compute_global_address.lb_default.id
      port_range = "80"
      depends_on = [google_compute_target_http_proxy.https_default]
    }

멀티 리전 배포에서 인증된 Pub/Sub 푸시 구독 사용

기본적으로 Pub/Sub 서비스는 Pub/Sub 서비스가 메시지를 저장하는 위치와 동일한 Google Cloud 리전의 푸시 엔드포인트에 메시지를 전달합니다. 이 동작에 대한 해결 방법은 멀티 리전 Cloud Run 배포에 인증된 Pub/Sub 푸시 구독 사용을 참조하세요.