Configura un bilanciatore del carico delle applicazioni classico con i bucket Cloud Storage

Questo documento illustra come creare un bilanciatore del carico delle applicazioni esterno per inoltrare le richieste di contenuti statici ai bucket Cloud Storage. Dopo configurare un bilanciatore del carico con i bucket di backend, le richieste ai percorsi degli URL iniziano con /love-to-fetch vengono inviati a us-east1 nel bucket Cloud Storage e tutte le altre richieste vengono inviate europe-north1 Bucket Cloud Storage, indipendentemente dalla regione dell'utente.

Se i tuoi backend pubblicano contenuti dinamici su HTTP(S), valuta l'utilizzo servizi di backend anziché di backend.

Per seguire le indicazioni dettagliate per questa attività direttamente nella console Google Cloud, fai clic su Procedura guidata:

Procedura guidata

Bucket Cloud Storage come backend dei bilanciatori del carico

Un bilanciatore del carico delle applicazioni esterno utilizza una mappa URL per indirizzare il traffico dai percorsi dell'URL specificati a dai tuoi backend.

Nel diagramma seguente, il bilanciatore del carico invia il traffico con un percorso /love-to-fetch/ in un bucket Cloud Storage nella zona us-east1 regione. Tutte le altre richieste vengono inviate a un bucket Cloud Storage nella regione europe-north1.

Il bilanciatore del carico invia il traffico a un backend Cloud Storage.
Distribuzione del traffico in Cloud Storage

Per impostazione predefinita, Cloud Storage utilizza la stessa cache di Cloud CDN. Se abiliti Cloud CDN sul backend puoi utilizzare i controlli di Cloud CDN sui tuoi contenuti. I controlli di Cloud CDN includono, ad esempio, modalità cache, URL firmati e o l'annullamento della convalida. Cloud CDN ti consente anche di memorizzare nella cache contenuti di grandi dimensioni (> 10 MB). Se non abiliti Cloud CDN sul tuo bucket di backend, puoi usare solo intestazioni Cache-Control di origine per controllare la memorizzazione nella cache per contenuti più piccoli, come impostato dai metadati di Cloud Storage.

Prima di iniziare

Assicurati che la configurazione soddisfi i seguenti prerequisiti. Se utilizzi l'utilità gcloud storage, puoi installarla seguendo le istruzioni in Scopri l'archiviazione di oggetti con lo strumento gcloud.

Imposta un progetto predefinito

Console

  1. Sign in to your Google Cloud account. If you're new to Google Cloud, create an account to evaluate how our products perform in real-world scenarios. New customers also get $300 in free credits to run, test, and deploy workloads.

  2. In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

    Go to project selector

  3. Make sure that billing is enabled for your Google Cloud project.

  4. In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

    Go to project selector

  5. Make sure that billing is enabled for your Google Cloud project.

gcloud 

gcloud config set project PROJECT_ID

Sostituisci PROJECT_ID con il progetto che utilizzi per questa guida.

Terraform 

export GOOGLE_CLOUD_PROJECT=PROJECT_ID

Autorizzazioni

Per seguire questa guida, devi creare bucket Cloud Storage e con il bilanciatore del carico di rete in un progetto. Devi essere un proprietario o un editor del progetto oppure disporre dei seguenti ruoli IAM di Compute Engine:

Attività Ruolo richiesto
crea i componenti del bilanciatore del carico Amministratore rete
Creazione di bucket di Cloud Storage Storage Object Admin

Per ulteriori informazioni, consulta le seguenti guide:

Configura una risorsa del certificato SSL

Per un bilanciatore del carico HTTPS, crea una risorsa del certificato SSL come descritto nella seguente documentazione:

Ti consigliamo di utilizzare un certificato gestito da Google.

In questo esempio si presuppone che tu abbia già una risorsa del certificato SSL denominata www-ssl-cert.

Prepara i bucket e i contenuti di Cloud Storage

Il processo per preparare i bucket Cloud Storage è il seguente:

  • Crea i bucket.

  • Copia il contenuto nei bucket.

  • Fornisci l'accesso pubblico ai bucket.

Creazione di bucket di Cloud Storage

In questo esempio, crei due bucket Cloud Storage a cui deve accedere il bilanciatore del carico. Per i deployment di produzione, ti consigliamo di scegliere una bucket multiregionale, che esegue automaticamente replica gli oggetti in più regioni Google Cloud. In questo modo puoi migliorare la disponibilità dei contenuti e la tolleranza agli errori nell'applicazione.

Prendi nota dei nomi dei bucket Cloud Storage che crei, perché verranno utilizzate in seguito. In questa guida, vengono indicati come BUCKET_1_NAME e BUCKET_2_NAME.

Console

  1. Nella console Google Cloud, vai a Cloud Storage Bucket.

    Vai ai bucket Cloud Storage

  2. Fai clic su Crea bucket.

  3. Nella casella Assegna un nome al bucket, inserisci un nome univoco globale che rispetti le linee guida per l'assegnazione dei nomi.

  4. Fai clic su Scegli dove archiviare i tuoi dati.

  5. Imposta Tipo di località su Area geografica.

  6. Imposta Località su europe-north1. Questo è BUCKET_1_NAME in questa guida.

  7. Fai clic su Crea.

  8. Fai clic su Bucket per tornare alla pagina Bucket Cloud Storage. Utilizza queste istruzioni per creare un secondo bucket, ma imposta il valore Da Località a us-east1. Si tratta di BUCKET_2_NAME in questa guida.

gcloud 

gcloud storage buckets create gs://BUCKET_1_NAME --project=PROJECT_ID --default-storage-class=standard --location=europe-north1 --uniform-bucket-level-access

gcloud storage buckets create gs://BUCKET_2_NAME --project=PROJECT_ID --default-storage-class=standard --location=us-east1 --uniform-bucket-level-access

Sostituisci BUCKET_1_NAME e BUCKET_2_NAME con i nomi dei bucket che vuoi creare.

Terraform

Per creare i bucket, utilizza la risorsa google_storage_bucket.

# Create Cloud Storage buckets
resource "random_id" "bucket_prefix" {
  byte_length = 8
}

resource "google_storage_bucket" "bucket_1" {
  name                        = "${random_id.bucket_prefix.hex}-bucket-1"
  location                    = "us-east1"
  uniform_bucket_level_access = true
  storage_class               = "STANDARD"
  // delete bucket and contents on destroy.
  force_destroy = true
}

resource "google_storage_bucket" "bucket_2" {
  name                        = "${random_id.bucket_prefix.hex}-bucket-2"
  location                    = "us-east1"
  uniform_bucket_level_access = true
  storage_class               = "STANDARD"
  // delete bucket and contents on destroy.
  force_destroy = true
}

Per scoprire come applicare o rimuovere una configurazione Terraform, consulta Comandi Terraform di base.

Trasferisci i contenuti nei bucket Cloud Storage

Per poter testare la configurazione in un secondo momento, copia le seguenti immagini da un nei tuoi bucket Cloud Storage.

gcloud

  1. Fai clic su Attivare Cloud Shell.

  2. Esegui i comandi seguenti in Cloud Shell, sostituendo le variabili dei nomi dei bucket con i nomi dei bucket Cloud Storage:

gcloud storage cp gs://gcp-external-http-lb-with-bucket/three-cats.jpg gs://BUCKET_1_NAME/never-fetch/

gcloud storage cp gs://gcp-external-http-lb-with-bucket/two-dogs.jpg gs://BUCKET_2_NAME/love-to-fetch/

Terraform

Per copiare elementi nel bucket, puoi utilizzare la risorsa google_storage_bucket_object.

resource "google_storage_bucket_object" "cat_image" {
  name         = "never-fetch/three-cats.jpg"
  source       = "images/three-cats.jpg"
  content_type = "image/jpeg"

  bucket = google_storage_bucket.bucket_1.name
}

resource "google_storage_bucket_object" "dog_image" {
  name         = "love-to-fetch/two-dogs.jpg"
  source       = "images/two-dogs.jpg"
  content_type = "image/jpeg"

  bucket = google_storage_bucket.bucket_2.name
}

In alternativa, utilizza la risorsa null_resource.

resource "null_resource" "upload_cat_image" {
provisioner "local-exec" {
  command = "gcloud storage cp gs://gcp-external-http-lb-with-bucket/three-cats.jpg gs://${google_storage_bucket.bucket_1.name}/never-fetch/"
}
}

resource "null_resource" "upload_dog_image" {
provisioner "local-exec" {
  command = "gcloud storage cp gs://gcp-external-http-lb-with-bucket/two-dogs.jpg gs://${google_storage_bucket.bucket_2.name}/love-to-fetch/"
}
}

Nella console Google Cloud, fai clic su Aggiorna nei dettagli di ciascun bucket pagina per verificare che il file sia stato copiato correttamente.

Rendi pubblicamente leggibili i bucket Cloud Storage

Quando rendi i bucket Cloud Storage pubblicamente leggibili, chiunque su internet può elencare e visualizzare gli oggetti e i relativi metadati (esclusi gli ACL). Non includere informazioni sensibili nei bucket pubblici.

Per ridurre la probabilità di esposizione accidentale di informazioni sensibili, non memorizzare oggetti pubblici e dati sensibili nello stesso bucket.

Console

Per concedere a tutti gli utenti l'accesso in visualizzazione agli oggetti nei bucket, ripeti la seguente procedura per ogni bucket:

  1. Nella console Google Cloud, vai alla pagina Bucket Cloud Storage.

    Vai a Bucket Cloud Storage

  2. Fai clic sul nome del bucket, quindi sulla scheda Autorizzazioni.

  3. Fai clic su Aggiungi.

  4. Nella casella Nuove entità, inserisci allUsers.

  5. Nella casella Seleziona un ruolo, seleziona Cloud Storage > Visualizzatore oggetti Storage.

  6. Fai clic su Salva.

  7. Fai clic su Consenti accesso pubblico.

gcloud

Per concedere a tutti gli utenti l'accesso per visualizzare gli oggetti nei bucket, esegui questo comando :

gcloud storage buckets add-iam-policy-binding gs://BUCKET_1_NAME --member=allUsers --role=roles/storage.objectViewer

gcloud storage buckets add-iam-policy-binding gs://BUCKET_2_NAME --member=allUsers --role=roles/storage.objectViewer

Terraform

Per concedere a tutti gli utenti l'accesso per visualizzare gli oggetti nei bucket, utilizza google_storage_bucket_iam_member risorsa e specifica allUsers .

# Make buckets public
resource "google_storage_bucket_iam_member" "bucket_1" {
  bucket = google_storage_bucket.bucket_1.name
  role   = "roles/storage.objectViewer"
  member = "allUsers"
}

resource "google_storage_bucket_iam_member" "bucket_2" {
  bucket = google_storage_bucket.bucket_2.name
  role   = "roles/storage.objectViewer"
  member = "allUsers"
}

Prenotare un indirizzo IP esterno

Dopo aver configurato i bucket Cloud Storage, puoi prenotare un indirizzo IP esterno statico globale utilizzato dal pubblico per raggiungere il bilanciatore del carico.

Questo passaggio è facoltativo ma consigliato, in quanto un indirizzo IP esterno statico fornisce un singolo indirizzo a cui puntare il dominio.

Console

  1. Nella console Google Cloud, vai alla pagina Indirizzi IP esterni.

    Vai a Indirizzi IP esterni

  2. Fai clic su Prenota indirizzo statico.

  3. Nella casella Nome, inserisci example-ip.

  4. Imposta Network Service Tier su Premium.

  5. Imposta la versione IP su IPv4.

  6. Imposta il Tipo su Globale.

  7. Fai clic su Prenota.

gcloud 

gcloud compute addresses create example-ip \
    --network-tier=PREMIUM \
    --ip-version=IPV4 \
    --global

Prendi nota dell'indirizzo IPv4 riservato:

gcloud compute addresses describe example-ip \
    --format="get(address)" \
    --global

Terraform

Per prenotare un indirizzo IP esterno, utilizza la google_compute_global_address risorsa.

# Reserve IP address
resource "google_compute_global_address" "default" {
  name = "example-ip"
}

Creare un bilanciatore del carico delle applicazioni esterno con bucket di backend

Queste istruzioni riguardano la creazione di un bilanciatore del carico HTTP o HTTPS. A Per creare un bilanciatore del carico HTTPS, è necessario aggiungere una risorsa il frontend del bilanciatore del carico. Per ulteriori informazioni, consulta la panoramica dei certificati SSL.

Console

Avvia la configurazione

  1. Nella console Google Cloud, vai alla pagina Bilanciamento del carico.

    Vai a Bilanciamento del carico

  2. Fai clic su Crea bilanciatore del carico.
  3. In Tipo di bilanciatore del carico, seleziona Bilanciatore del carico delle applicazioni (HTTP/HTTPS) e fai clic su Avanti.
  4. In Pubblico o interno, seleziona Pubblico (esterno) e fai clic su Avanti.
  5. Per Deployment globale o in una regione singola, seleziona Ideale per carichi di lavoro e fai clic su Avanti.
  6. Per Generazione del bilanciatore del carico, seleziona Classica Bilanciatore del carico delle applicazioni e fai clic su Avanti.
  7. Fai clic su Configura.

Configurazione di base

  1. Nella casella Nome, inserisci http-lb.

Configura il backend

  1. Fai clic su Configurazione backend.

  2. Fai clic sulla casella Servizi di backend e bucket di backend, quindi su Crea un bucket di backend.

  3. Nella casella Nome bucket di backend, inserisci cats.

  4. Nella casella Bucket Cloud Storage, fai clic su Sfoglia.

  5. Seleziona BUCKET_1_NAME, quindi fai clic su Seleziona. Quando si crea il bucket di backend cats, viene impostato come predefinito e vi vengono indirizzate tutte le richieste di traffico senza corrispondenza. Non puoi modificare le regole di reindirizzamento di un bucket di backend predefinito nel bilanciatore del carico.

  6. Fai clic su Crea.

  7. Utilizza la stessa procedura per creare un bucket di backend denominato dogs e seleziona BUCKET_2_NAME.

  8. Fai clic su OK.

Configura le regole di routing

Le regole di routing determinano come viene indirizzato il traffico. Per configurare il routing, configurerai le regole host e i matcher percorso, che sono componenti di configurazione della mappa URL di un bilanciatore del carico delle applicazioni esterno. Per impostare le regole per questo esempio:

  1. Fai clic su Regole host e percorso.
  2. Per dogs, inserisci * nel campo Host, e /love-to-fetch/* nel campo Percorsi.

Configura il frontend

  1. Fai clic su Configurazione frontend.

  2. Verifica che le seguenti opzioni siano configurate con questi valori:

    Proprietà Valore (digita un valore o seleziona un'opzione come specificato)
    Protocollo HTTP
    Livello di servizio di rete Premium
    Versione IP IPv4
    Indirizzo IP example-ip
    Porta 80

    Se vuoi creare un bilanciatore del carico HTTPS anziché un bilanciatore del carico HTTP, devi disporre di un certificato SSL (gcloud compute ssl-certificates list) e devi compilare i campi come segue:

    Proprietà Valore (digita un valore o seleziona un'opzione come specificato)
    Protocollo HTTP(S)
    Livello di servizio di rete Premium
    Versione IP IPv4
    Indirizzo IP example-ip
    Porta 443
    Certificato Seleziona il certificato www-ssl-cert che hai creato nella sezione Configura una risorsa del certificato SSL oppure crea un nuovo certificato.
    (Facoltativo) Attiva il reindirizzamento da HTTP a HTTPS Utilizza questa casella di controllo per attivare i reindirizzamenti.

    L'attivazione di questa casella di controllo crea un carico HTTP parziale aggiuntivo che utilizza lo stesso indirizzo IP del bilanciatore del carico HTTPS e reindirizza le richieste HTTP al protocollo HTTPS e il frontend di Google Cloud.

    Questa casella di controllo può essere selezionata solo se è selezionato il protocollo HTTPS e viene utilizzato un indirizzo IP riservato.

  3. Fai clic su Fine.

Rivedi la configurazione

  1. Fai clic su Esamina e finalizza.

  2. Esamina le regole di frontend, host e percorso e i bucket di backend.

  3. Fai clic su Crea e attendi che venga creato il bilanciatore del carico.

  4. Fai clic sul nome del bilanciatore del carico (http-lb).

  5. Prendi nota dell'indirizzo IP del bilanciatore del carico, che utilizzerai nella prossima attività. In questa guida, viene indicato come IP_ADDRESS.

gcloud

Configura il backend

gcloud compute backend-buckets create cats \
  --gcs-bucket-name=BUCKET_1_NAME

gcloud compute backend-buckets create dogs \
  --gcs-bucket-name=BUCKET_2_NAME

Configura la mappa URL

gcloud compute url-maps create http-lb \
  --default-backend-bucket=cats

gcloud compute url-maps add-path-matcher http-lb \
  --path-matcher-name=path-matcher-2 \
  --new-hosts=* \
  --backend-bucket-path-rules="/love-to-fetch/*=dogs" \
  --default-backend-bucket=cats

Configura il proxy di destinazione

gcloud compute target-http-proxies create http-lb-proxy \
  --url-map=http-lb

Configura la regola di forwarding

gcloud compute forwarding-rules create http-lb-forwarding-rule \
  --load-balancing-scheme=EXTERNAL \
  --network-tier=PREMIUM \
  --address=example-ip \
  --global \
  --target-http-proxy=http-lb-proxy \
  --ports=80

Terraform

Per creare il bilanciatore del carico, utilizza le seguenti risorse Terraform.

Configura il backend

Per creare il backend, utilizza la risorsa google_compute_backend_bucket.

# Create LB backend buckets
resource "google_compute_backend_bucket" "bucket_1" {
  name        = "cats"
  description = "Contains cat image"
  bucket_name = google_storage_bucket.bucket_1.name
}

resource "google_compute_backend_bucket" "bucket_2" {
  name        = "dogs"
  description = "Contains dog image"
  bucket_name = google_storage_bucket.bucket_2.name
}

Configura la mappa URL

Per creare la mappa URL, utilizza la risorsa google_compute_url_map.

# Create url map
resource "google_compute_url_map" "default" {
  name = "http-lb"

  default_service = google_compute_backend_bucket.bucket_1.id

  host_rule {
    hosts        = ["*"]
    path_matcher = "path-matcher-2"
  }
  path_matcher {
    name            = "path-matcher-2"
    default_service = google_compute_backend_bucket.bucket_1.id

    path_rule {
      paths   = ["/love-to-fetch/*"]
      service = google_compute_backend_bucket.bucket_2.id
    }
  }
}

Configura il proxy di destinazione

Per creare il proxy HTTP di destinazione, utilizza la risorsa google_compute_target_http_proxy.

# Create HTTP target proxy
resource "google_compute_target_http_proxy" "default" {
  name    = "http-lb-proxy"
  url_map = google_compute_url_map.default.id
}

Configura la regola di forwarding

Per creare la regola di forwarding, utilizza la risorsa google_compute_global_forwarding_rule.

# Create forwarding rule
resource "google_compute_global_forwarding_rule" "default" {
  name                  = "http-lb-forwarding-rule"
  ip_protocol           = "TCP"
  load_balancing_scheme = "EXTERNAL_MANAGED"
  port_range            = "80"
  target                = google_compute_target_http_proxy.default.id
  ip_address            = google_compute_global_address.default.id
}

NOTA: per cambiare la modalità in Application Load Balancer classico, imposta l'attributo load_balancing_scheme su "EXTERNAL" anziché "EXTERNAL_MANAGED".

Per scoprire come applicare o rimuovere una configurazione Terraform, consulta: Comandi Terraform di base.

Invia traffico al bilanciatore del carico

Diversi minuti dopo aver configurato il bilanciatore del carico, puoi iniziare inviando traffico all'indirizzo IP del bilanciatore del carico.

Console

In un browser web, vai ai seguenti indirizzi per testare il bilanciatore del carico: sostituendo IP_ADDRESS con indirizzo IP del bilanciatore del carico:

  • http://IP_ADDRESS/love-to-fetch/two-dogs.jpg

  • http://IP_ADDRESS/never-fetch/three-cats.jpg

Se hai configurato un bilanciatore del carico HTTP, assicurati che il browser non reindirizzano automaticamente a HTTPS.

gcloud

Utilizza il comando curl per testare la risposta dai seguenti URL. Sostituisci IP_ADDRESS con l'indirizzo IPv4 del bilanciatore del carico:

curl http://IP_ADDRESS/love-to-fetch/two-dogs.jpg

curl http://IP_ADDRESS/never-fetch/three-cats.jpg

Limitazioni