バージョン 1.1このバージョンは、Anthos バージョンサポートポリシーに記載のとおり、サポートを終了しています。Anthos clusters on VMware (GKE on-prem) に影響するセキュリティの脆弱性、露出、問題に対する最新のパッチとアップデートを適用するには、サポート対象のバージョンにアップグレードしてください。最新バージョンはこちらで確認できます。

利用可能なバージョン

管理ワークステーションの作成

このページでは、管理ワークステーション仮想マシン（VM）の最新バージョンを作成する方法について説明します。

既存の管理ワークステーションをアップグレードするには、GKE On-Prem のアップグレードをご覧ください。

概要

管理ワークステーションは、GKE On-Prem クラスタを作成して管理するために必要なすべてのツールを備えた、vSphere VM です。管理ワークステーションを作成するには、このトピックで説明される次の手順を行います。

管理ワークステーション VM の圧縮イメージである管理ワークステーション Open Virtual Appliance（OVA）ファイルをダウンロードします。
vSphere へのコマンドラインインターフェースである govc を使用して、OVA を vSphere に VM テンプレートとしてインポートします。
HashiCorp Terraform 構成ファイルをコピーして入力します。
Terraform を使用して VM を作成します。

始める前に

管理ワークステーションの概要を確認します。
インストールの準備の手順を完了します。
govc がインストール済みであることを確認します。
Terraform バージョン 0.11 がインストールされていることを確認します。

管理ワークステーション OVA をダウンロードする

ダウンロードトピックから、最新バージョンの管理ワークステーション OVA をダウンロードします。最新の OVA ファイルは次のとおりです。

gke-on-prem-admin-appliance-vsphere-1.1.2-gke.0.ova

ここで、1.1.2-gke.0 は最新の GKE On-Prem バージョンです。OVA には、GKE On-Prem クラスタをインストールして管理するために必要なすべてのクラスタコンポーネント、コマンドラインツールなどのエンティティが含まれます。最新の OVA には、これらのエンティティの最新バージョンが含まれています。

このファイルを、管理ワークステーションの作成に使用しているコンピュータのどこかに保存します。

`govc` を使用して OVA を vSphere にインポートし、VM テンプレートとしてマークする

以降のセクションでは、以下を行います。

vCenter Server と vSphere 環境の要素を宣言する変数を作成する。
管理ワークステーションの OVA を vSphere にインポートし、VM テンプレートとしてマークする。

`govc` の変数を作成する

管理ワークステーション OVA を vSphere にインポートする前に、vCenter Server と vSphere 環境の要素を宣言する変数を govc に指定する必要があります。

export GOVC_URL=https://[VCENTER_SERVER_ADDRESS]/sdk
export GOVC_USERNAME=[VCENTER_SERVER_USERNAME]
export GOVC_PASSWORD=[VCENTER_SERVER_PASSWORD]
export GOVC_DATASTORE=[VSPHERE_DATASTORE]
export GOVC_DATACENTER=[VSPHERE_DATACENTER]
export GOVC_INSECURE=true

次のように、vSphere のデフォルトのリソースプールを使用することも、独自のリソースプールを作成することもできます。

# If you want to use a resource pool you've configured yourself, export this variable:
export GOVC_RESOURCE_POOL=[VSPHERE_CLUSTER]/Resources/[VSPHERE_RESOURCE_POOL]

# If you want to use vSphere's default resource pool, export this variable instead:
export GOVC_RESOURCE_POOL=[VSPHERE_CLUSTER]/Resources

ここで

[VCENTER_SERVER_ADDRESS] は、vCenter Server の IP アドレスまたはホスト名です。
[VCENTER_SERVER_USERNAME] は、vCenter Server で管理者のロールまたは同等の権限を持つアカウントのユーザー名です。
[VCENTER_SERVER_PASSWORD] は、vCenter Server アカウントのパスワードです。
[VSPHERE_DATASTORE] は、vSphere 環境で構成したデータストアの名前です。
[VSPHERE_DATACENTER] は、vSphere 環境で構成したデータセンターの名前です。
[VSPHERE_CLUSTER] は、vSphere 環境で構成したクラスタの名前です。
[VSPHERE_RESOURCE_POOL] は、vSphere 環境で構成したリソースプールの名前です。

OVA を vSphere（標準スイッチ）にインポートする

vSphere 標準スイッチを使用している場合、次のコマンドを使用して OVA を vSphere にインポートします。

govc import.ova -options - ~/gke-on-prem-admin-appliance-vsphere-1.1.2-gke.0.ova <<EOF
{
  "DiskProvisioning": "thin",
  "MarkAsTemplate": true
}
EOF

OVA を vSphere（分散スイッチ）にインポートする

vSphere 分散スイッチを使用している場合、このコマンドを実行して OVA を vSphere にインポートします。ここで、[YOUR_DISTRIBUTED_PORT_GROUP_NAME] は分散ポートグループの名前です。

govc import.ova -options - ~/gke-on-prem-admin-appliance-vsphere-1.1.2-gke.0.ova <<EOF
{
  "DiskProvisioning": "thin",
  "MarkAsTemplate": true,
  "NetworkMapping": [
      {
          "Name": "VM Network",
          "Network": "[YOUR_DISTRIBUTED_PORT_GROUP_NAME]"
      }
  ]
}
EOF

Terraform 構成ファイルをコピーする

Terraform ファイルのディレクトリを作成します。
```
mkdir "[TERRAFORM_DIR]"
```
[TERRAFORM_DIR] は、Terraform ファイルを保持するディレクトリのパスです。
管理ワークステーションに静的 IP アドレスを指定するか、DHCP サーバーを使用して IP アドレスを取得するかによって、次のいずれかの Terraform 構成をコピーします。

TF ファイルと TFVARS ファイルの両方をコピーしてください。TF ファイルは、VM 作成を実行する Terraform HCL config です。
構成をそれぞれ [TERRAFORM_DIR]/terraform.tf と [TERRAFORM_DIR]/terraform.tfvars に保存します。

DHCP

開示矢印をクリックすると、DHCP の Terraform ファイルが表示されます。

terraform.tfvars

# vCenter Server username
vcenter_user = "administrator@vsphere.local"

# vCenter Server password
vcenter_password = ""

# vCenter Server IP or hostname
vcenter_server = ""

# Path in which the admin workstation's VM's public key should be saved
ssh_public_key_path = "~/.ssh/vsphere_workstation.pub"

# Hostname for the VM
vm_name = "admin-workstation"

# vSphere datastore to use for storage
datastore = ""

# vSphere datacenter in which to create the VM
datacenter = ""

# vSphere cluster in which to create the VM
cluster = ""

# vSphere resource pool in which to create VM, if you are using a non-default resource pool
# If you are using the default resource pool, provide a value like "CLUSTER-NAME/Resources"
resource_pool = ""

# vSphere network to use for the VM
network = "VM Network"

# Number of CPUs for this VM. Recommended minimum 4.
num_cpus = 4

# Memory in MB for this VM. Recommended minimum 8192.
memory = 8192

# The VM template (OVA) to clone. Change the version if you imported a different version of the OVA.
vm_template = "gke-on-prem-admin-appliance-vsphere-1.1.2-gke.0"

terraform.tf

#########################
####### VARIABLES #######
#########################

# The following variables are declared in the accompanying TFVARS file

# vCenter Server username
variable "vcenter_user" { }

# vCenter Server password
variable "vcenter_password" { }

# vCenter Server address
variable "vcenter_server" { }

# Path in which the VM's public key should be saved
variable "ssh_public_key_path" { default = "~/.ssh/vsphere_workstation.pub" }

# vSphere network to use for the VM
variable "network" { default = "VM Network"}

# Hostname for the VM
variable "vm_name" { default = "vsphere-workstation" }

# vSphere datacenter in which to create the admin workstation VM
variable "datacenter" { }

# vSphere datastore to use for storage
variable "datastore" { }

# vSphere cluster in which to create the VM
variable "cluster" { }

# vSphere resource pool in which to create the VM
variable "resource_pool" { }

# Number of CPUs for this VM. Recommended minimum 4.
variable "num_cpus" { default = 4 }

# Memory in MB for this VM. Recommended minimum 8192.
variable "memory" { default = 8192 }

# The VM template (OVA) to clone
variable "vm_template" { }

##########################
##########################

provider "vsphere" {
  version        = "~> 1.5"
  user           = "${var.vcenter_user}"
  password       = "${var.vcenter_password}"
  vcenter_server = "${var.vcenter_server}"

  # if you have a self-signed cert
  allow_unverified_ssl = true
}

### vSphere Data ###

data "vsphere_datastore" "datastore" {
  name          = "${var.datastore}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_datacenter" "dc" {
  name = "${var.datacenter}"
}

data "vsphere_compute_cluster" "cluster" {
  name          = "${var.cluster}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_resource_pool" "pool" {
  name          = "${var.resource_pool}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_network" "network" {
  name          = "${var.network}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_virtual_machine" "template_from_ovf" {
  name          = "${var.vm_template}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "template_file" "dhcp_ip_config" {
  template = <<EOF
network:
  version: 2
  ethernets:
    ens192:
      dhcp4: true
EOF
}

data "template_file" "user_data" {
  template = <<EOF
#cloud-config
apt:
  primary:
    - arches: [default]
      uri: http://us-west1.gce.archive.ubuntu.com/ubuntu/
write_files:
  - path: /etc/netplan/99-dhcp.yaml
    permissions: '0644'
    encoding: base64
    content: |
      $${dhcp_ip_config}
runcmd:
  - netplan apply
  - /var/lib/gke/guest-startup.sh
EOF
  vars = {
    dhcp_ip_config = "${base64encode(data.template_file.dhcp_ip_config.rendered)}"

  }
}

### vSphere Resources ###

resource "vsphere_virtual_machine" "vm" {
  name             = "${var.vm_name}"
  resource_pool_id = "${data.vsphere_resource_pool.pool.id}"
  datastore_id     = "${data.vsphere_datastore.datastore.id}"
  num_cpus         = "${var.num_cpus}"
  memory           = "${var.memory}"
  guest_id         = "${data.vsphere_virtual_machine.template_from_ovf.guest_id}"
  enable_disk_uuid = "true"
  scsi_type = "${data.vsphere_virtual_machine.template_from_ovf.scsi_type}"
  network_interface {
    network_id   = "${data.vsphere_network.network.id}"
    adapter_type = "${data.vsphere_virtual_machine.template_from_ovf.network_interface_types[0]}"
  }

  wait_for_guest_net_timeout = 15

  nested_hv_enabled = false
  cpu_performance_counters_enabled = false

  disk {
    label            = "disk0"
    size             = "${max(50, data.vsphere_virtual_machine.template_from_ovf.disks.0.size)}"
    eagerly_scrub    = "${data.vsphere_virtual_machine.template_from_ovf.disks.0.eagerly_scrub}"
    thin_provisioned = "${data.vsphere_virtual_machine.template_from_ovf.disks.0.thin_provisioned}"
  }

  cdrom {
    client_device = true
  }

  vapp {
    properties = {
      hostname    = "${var.vm_name}"
      public-keys = "${file(var.ssh_public_key_path)}"
      user-data   = "${base64encode(data.template_file.user_data.rendered)}"
    }
  }

  clone {
    template_uuid = "${data.vsphere_virtual_machine.template_from_ovf.id}"
  }
}

output "ip_address" {
  value = "${vsphere_virtual_machine.vm.default_ip_address}"
}

静的 IP

開示矢印をクリックすると、静的 IP の Terraform ファイルが表示されます。

terraform.tfvars

# vCenter Server username
vcenter_user = "administrator@vsphere.local"

# vCenter Server password
vcenter_password = ""

# vCenter Server IP or hostname
vcenter_server = ""

# Path in which the admin workstation's VM's public key should be saved
ssh_public_key_path = "~/.ssh/vsphere_workstation.pub"

# Hostname for the VM
vm_name = "admin-workstation"

# vSphere datastore to use for storage
datastore = ""

# vSphere datacenter in which to create the VM
datacenter = ""

# vSphere cluster in which to create the VM
cluster = ""

# vSphere resource pool in which to create VM, if you are using a non-default resource pool
# If you are using the default resource pool, provide a value like "CLUSTER-NAME/Resources"
resource_pool = ""

# vSphere network to use for the VM
network = "VM Network"

# Number of CPUs for this VM. Recommended minimum 4.
num_cpus = 4

# Memory in MB for this VM. Recommended minimum 8192.
memory = 8192

# The VM template (OVA) to clone. Change the version if you imported a different version of the OVA.
vm_template = "gke-on-prem-admin-appliance-vsphere-1.1.2-gke.0"

################################################
# Static IP settings                           #
################################################

# An IPv4 static IP for the admin workstataion; for example, 100.115.250.100
ipv4_address = "100.115.250.100"

# The netmask prefix length to use; for example, 22
ipv4_netmask_prefix_length = "22"

# The IPv4 gateway the admin workstation should use; for example, 100.115.251.254
ipv4_gateway = "100.115.251.254"

# Comma-delimited DNS servers
dns_nameservers = "8.8.8.8,8.8.4.4"

terraform.tf

#########################
####### VARIABLES #######
#########################

# The following variables are declared in the accompanying TFVARS file

# vCenter Server username
variable "vcenter_user" { }

# vCenter Server password
variable "vcenter_password" { }

# vCenter Server address
variable "vcenter_server" { }

# Path in which the VM's public key should be saved
variable "ssh_public_key_path" { default = "~/.ssh/vsphere_workstation.pub" }

# vSphere network to use for the VM
variable "network" { default = "VM Network"}

# Hostname for the VM
variable "vm_name" { default = "vsphere-workstation" }

# vSphere datacenter in which to create the admin workstation VM
variable "datacenter" { }

# vSphere datastore to use for storage
variable "datastore" { }

# vSphere cluster in which to create the VM
variable "cluster" { }

# vSphere resource pool in which to create the VM
variable "resource_pool" { }

# Number of CPUs for this VM. Recommended minimum 4.
variable "num_cpus" { default = 4 }

# Memory in MB for this VM. Recommended minimum 8192.
variable "memory" { default = 8192 }

# The VM template (OVA) to clone
variable "vm_template" { }

# The IP address to assign to the VM
variable "ipv4_address" { }

# Netmask prefix length
variable "ipv4_netmask_prefix_length" { }

# Default gateway to use
variable "ipv4_gateway" { }

# DNS resolvers to use
variable "dns_nameservers" { }

##########################
##########################

provider "vsphere" {
  version        = "~> 1.5"
  user           = "${var.vcenter_user}"
  password       = "${var.vcenter_password}"
  vcenter_server = "${var.vcenter_server}"

  # if you have a self-signed cert
  allow_unverified_ssl = true
}

### vSphere Data ###

data "vsphere_datastore" "datastore" {
  name          = "${var.datastore}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_datacenter" "dc" {
  name = "${var.datacenter}"
}

data "vsphere_compute_cluster" "cluster" {
  name          = "${var.cluster}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_resource_pool" "pool" {
  name          = "${var.resource_pool}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_network" "network" {
  name          = "${var.network}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_virtual_machine" "template_from_ovf" {
  name          = "${var.vm_template}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

##########################
### IF USING STATIC IP ###
##########################
data "template_file" "static_ip_config" {
  template = <<EOF
network:
  version: 2
  ethernets:
    ens192:
      dhcp4: no
      dhcp6: no
      addresses: ["${var.ipv4_address}/${var.ipv4_netmask_prefix_length}"]
      gateway4: ${var.ipv4_gateway}
      nameservers:
        addresses: [${var.dns_nameservers}]
EOF
}

data "template_file" "user_data" {
  template = <<EOF
#cloud-config
apt:
  primary:
    - arches: [default]
      uri: http://us-west1.gce.archive.ubuntu.com/ubuntu/
write_files:
  - path: /tmp/static-ip.yaml
    permissions: '0644'
    encoding: base64
    content: |
      $${static_ip_config}
runcmd:
  - /var/lib/gke/guest-startup.sh
EOF
  vars = {
    static_ip_config = "${base64encode(data.template_file.static_ip_config.rendered)}"

  }
}
##########################
### IF USING STATIC IP ###
##########################

### vSphere Resources ###

resource "vsphere_virtual_machine" "vm" {
  name             = "${var.vm_name}"
  resource_pool_id = "${data.vsphere_resource_pool.pool.id}"
  datastore_id     = "${data.vsphere_datastore.datastore.id}"
  num_cpus         = "${var.num_cpus}"
  memory           = "${var.memory}"
  guest_id         = "${data.vsphere_virtual_machine.template_from_ovf.guest_id}"
  enable_disk_uuid = "true"
  scsi_type = "${data.vsphere_virtual_machine.template_from_ovf.scsi_type}"
  network_interface {
    network_id   = "${data.vsphere_network.network.id}"
    adapter_type = "${data.vsphere_virtual_machine.template_from_ovf.network_interface_types[0]}"
  }

  wait_for_guest_net_timeout = 15

  nested_hv_enabled = false
  cpu_performance_counters_enabled = false

  disk {
    label            = "disk0"
    size             = "${max(50, data.vsphere_virtual_machine.template_from_ovf.disks.0.size)}"
    eagerly_scrub    = "${data.vsphere_virtual_machine.template_from_ovf.disks.0.eagerly_scrub}"
    thin_provisioned = "${data.vsphere_virtual_machine.template_from_ovf.disks.0.thin_provisioned}"
  }

  cdrom {
    client_device = true
  }

  vapp {
    properties = {
      hostname    = "${var.vm_name}"
      public-keys = "${file(var.ssh_public_key_path)}"
      user-data   = "${base64encode(data.template_file.user_data.rendered)}"
    }
  }

  clone {
    template_uuid = "${data.vsphere_virtual_machine.template_from_ovf.id}"
  }
}

output "ip_address" {
  value = "${vsphere_virtual_machine.vm.default_ip_address}"
}

SSH 公開鍵の作成

ローカルのノートパソコンやワークステーションから管理ワークステーションに SSH 接続できるように、SSH 公開鍵を作成します。Linux ベースのオペレーティングシステムでは、ssh-keygen を使用できます。

ssh-keygen -t rsa -f ~/.ssh/vsphere_workstation -N ""

TFVARS ファイルを変更する

テキストエディタで terraform.tfvars を開き、次の変数の値を指定します。これらの値のほとんどは、vCenter Client にログインすることで確認できます。

`vcenter_user`

vCenter Server ユーザーアカウントを文字列として指定します。ユーザーアカウントには管理者のロールか、それと同等の権限が必要です（システム要件をご覧ください）。例:

vcenter_user = "administrator@vsphere.local"

`vcenter_password`

vCenter Server ユーザーアカウントのパスワードを文字列で指定します。例:

vcenter_password = "#STyZ2T#Ko2o"

`vcenter_server`

vCenter Server のアドレス（IP またはホスト名）を文字列として指定します。例:

vcenter_server = "198.51.100.0"

`ssh_public_key_path`

SSH 公開鍵へのパスを指定します。これは前の手順で作成しています。

ssh_public_key_path = "~/.ssh/vsphere_workstation.pub"

`vm_name`

管理ワークステーションの名前を指定します。

vm_name = "admin-workstation"

`datastore`

次のように、vSphere データストアの名前を文字列として指定します。

datastore = "MY-DATASTORE"

`datacenter`

次のように、vSphere データセンターの名前を文字列として指定します。

datacenter = "MY-DATACENTER"

`cluster`

次のように、vSphere クラスタの名前を文字列として指定します。

cluster = "MY-CLUSTER"

`resource_pool`

デフォルト以外のリソースプールを使用している場合は、vSphere リソースプールの名前を文字列として指定します。

resource_pool = "MY-POOL"

デフォルトのリソースプールを使用している場合は、次の値を指定します。

resource_pool = "MY-CLUSTER/Resources"

スタンドアロンホストのルートリソースプールの指定をご覧ください。

`network`

管理ワークステーションを作成する vSphere ネットワークを文字列で指定します。例:

network = "VM Network"

`vm_template`

VM テンプレート名を文字列として指定します。前の手順で OVA をインポートし、テンプレートとしてマークしました。

vm_template = "gke-on-prem-admin-appliance-vsphere-[VERSION]"

管理ワークステーションに静的 IP アドレスを使用する

管理ワークステーションに静的 IP を使用する場合は、静的 IP TF と TFVARS ファイルをコピーします。TFVAR ファイルで、次の変数の値を入力します。

`ipv4_address`

管理ワークステーションの IPv4 静的 IP アドレスを指定します。例:

ipv4_address = "203.0.113.0"

`ipv4_netmask_prefix_length`

管理ワークステーションを作成するネットワークのサブネットマスクのビット数を指定します。次に例を示します。

ipv4_netmask_prefix_length = "22"

`ipv4_gateway`

管理ワークステーションを作成するサブネットのゲートウェイを指定します。VMware の vsphere_virtual_machine のドキュメントをご覧ください。

例:

ipv4_gateway = "198.51.100.0

`dns_nameservers`

管理ワークステーションで使用する DNS ネームサーバーをカンマで区切って指定します。例:

dns_nameservers = "8.8.8.8,8.8.4.4"

管理ワークステーションを作成する

上記の手順を完了すると、管理ワークステーション VM を作成する準備が整います。

Terraform 構成ファイル（TF および TFVARS）を含むディレクトリに移動します。
```
cd [TERRAFORM_DIR]
```
ディレクトリで Terraform を初期化し、構成を適用します。これには、数分かかることがあります。
```
terraform init && terraform apply -auto-approve -input=false
```
注: TFVARS ファイルの名前は terraform.tfvars にする必要があります。それ以外の場合は、--var-file パラメータを渡して TFVARS ファイルを指定する必要があります。

管理ワークステーションに SSH 接続する

Terraform 構成ファイルを含むディレクトリに移動します。
管理ワークステーションの IP アドレスを取得します。
```
terraform output ip_address
```
管理ワークステーションの IP アドレスをメモするか、シェルで変数としてエクスポートします。
生成された鍵と IP アドレスを使用して、管理ワークステーションに SSH 接続します。
```
ssh -i ~/.ssh/vsphere_workstation ubuntu@$(terraform output ip_address)
```
アドレスを使用する場合は、次のようにします。
```
ssh -i ~/.ssh/vsphere_workstation ubuntu@[IP_ADDRESS]
```

管理ワークステーションが正しく設定されていることを確認する

gkectl と docker がインストールされていることを確認します。

gkectl version
docker version

管理ワークステーション用のプロキシの構成

環境がプロキシの背後にある場合は、以下のセクションに従って、プロキシを使用するように Google Cloud CLI と Docker を構成します。

プロキシを使用するように Google Cloud CLI を構成する

管理ワークステーション VM から次の手順を実行します。

プロキシを使用してノートパソコンやワークステーションからインターネットに接続している場合は、プロキシ用に Google Cloud CLI を構成する必要があります。そうすると、gcloud コマンドとgsutil コマンドを実行できるようになります。手順については、プロキシ / ファイアウォールの背後で gcloud CLI を使用する場合の構成をご覧ください。

プロキシを介して pull するように Docker レジストリを構成する

管理ワークステーション VM から次の手順に沿って進めます。

Docker レジストリを使用し、ネットワークがプロキシの背後で実行されている場合は、管理ワークステーションで実行されている Docker デーモンを構成して、プロキシ経由でイメージを pull する必要があります。

HTTP プロキシと HTTPS プロキシのアドレスを収集します。
プロキシを使用せずに接続する必要があるすべてのホストの IP アドレスとホスト名を収集します。
- vCenter Server の IP アドレス。
- すべての ESXi ホストの IP アドレス。
- ロードバランサに構成する IP アドレス。
- 192.168.0.0/16 の範囲。
管理ワークステーションで、これらのアドレスを no_proxy 変数に追加します。
```
printf -v no_proxy '%s,' [ADDRESSES];
```
必要に応じて、後で参照できるように範囲を環境変数にエクスポートできます。アプリケーションとプロセスは、この変数を使用する場合があります。
```
export no_proxy="${no_proxy%,}";
```
/root/.docker/config.json、/home/[ユーザー]/.docker/config.json、または設定に応じた場所に保存された Open Docker の構成ファイル。
config.json 内で、次の行を追加します。
```
"proxies": {

"default": {
       "httpProxy": "[HTTP_PROXY]",
       "httpsProxy": "[HTTPS_PROXY]",
       "noProxy": "[ADDRESSES]"
           }
}
```
ここで
- [HTTP_PROXY] は HTTP プロキシです（存在する場合）。
- [HTTPS_PROXY] は HTTPS プロキシです（存在する場合）。
- [ADDRESSES] は、プロキシなしで接続する必要があるアドレスとホスト名のカンマ区切りのリストです。
Docker を再起動して変更を反映します。
```
sudo systemctl restart docker
```

トラブルシューティング

詳しくは、トラブルシューティングをご覧ください。

Terraform の vSphere プロバイダのセッション数の上限

GKE On-Prem は Terraform の vSphere プロバイダを使用して、vSphere 環境で VM を起動します。プロバイダのセッション数は最大 1,000 です。現在の実装では、使用後にアクティブなセッションが終了しません。実行中のセッションが多すぎると、503 エラーが発生する可能性があります。

セッションは 300 秒後に自動的に終了します。

現象

実行中のセッションが多すぎると、次のエラーが発生します。

Error connecting to CIS REST endpoint: Login failed: body:
  {"type":"com.vmware.vapi.std.errors.service_unavailable","value":
  {"messages":[{"args":["1000","1000"],"default_message":"Sessions count is
  limited to 1000. Existing sessions are 1000.",
  "id":"com.vmware.vapi.endpoint.failedToLoginMaxSessionCountReached"}]}},
  status: 503 Service Unavailable

考えられる原因

環境内で実行されている Terraform プロバイダのセッションが多すぎます。

解決策

現時点で、これは意図したとおりに機能しています。セッションは 300 秒後に自動的に終了します。詳細については、GitHub の問題 #618 をご覧ください。

Docker 用のプロキシの使用: `oauth2: cannot fetch token`

現象

プロキシの使用中に次のエラーが発生します。

oauth2: cannot fetch token: Post https://oauth2.googleapis.com/token: proxyconnect tcp: tls: oversized record received with length 20527

考えられる原因

HTTP ではなく HTTPS プロキシを指定した可能性があります。

解決策

Docker の構成で、プロキシアドレスを https:// ではなく http:// に変更します。

ライセンスが有効であることを確認する

特に試用版ライセンスを使用している場合は、ライセンスが有効であることを確認してください。F5、ESXi ホスト、または vCenter ライセンスの有効期限が切れた場合、予期しないエラーが発生することがあります。

`openssl` で管理ワークステーション OVA を検証できない

現象: 管理ワークステーションの OVA ファイルに対して openssl dgst を実行しても Verified OK が返されない
考えられる原因: OVA ファイルに問題があるため、正常な検証ができません。
解決策: 管理ワークステーション OVA をダウンロードするの説明に従って、管理ワークステーションの OVA をもう一度ダウンロードしてデプロイしてみてください。問題が解決しない場合は、Google にお問い合わせください。

管理ワークステーションの作成

概要

始める前に

管理ワークステーション OVA をダウンロードする

govc を使用して OVA を vSphere にインポートし、VM テンプレートとしてマークする

govc の変数を作成する

OVA を vSphere（標準スイッチ）にインポートする

OVA を vSphere（分散スイッチ）にインポートする

Terraform 構成ファイルをコピーする

DHCP

開示矢印をクリックすると、DHCP の Terraform ファイルが表示されます。

terraform.tfvars

terraform.tf

静的 IP

開示矢印をクリックすると、静的 IP の Terraform ファイルが表示されます。

terraform.tfvars

terraform.tf

SSH 公開鍵の作成

TFVARS ファイルを変更する

vcenter_user

vcenter_password

vcenter_server

ssh_public_key_path

vm_name

datastore

datacenter

cluster

resource_pool

network

vm_template

管理ワークステーションに静的 IP アドレスを使用する

ipv4_address

ipv4_netmask_prefix_length

ipv4_gateway

dns_nameservers

管理ワークステーションを作成する

管理ワークステーションに SSH 接続する

管理ワークステーションが正しく設定されていることを確認する

管理ワークステーション用のプロキシの構成

プロキシを使用するように Google Cloud CLI を構成する

プロキシを介して pull するように Docker レジストリを構成する

トラブルシューティング

Terraform の vSphere プロバイダのセッション数の上限

Docker 用のプロキシの使用: oauth2: cannot fetch token

ライセンスが有効であることを確認する

openssl で管理ワークステーション OVA を検証できない

次のステップ

`govc` を使用して OVA を vSphere にインポートし、VM テンプレートとしてマークする

`govc` の変数を作成する

`vcenter_user`

`vcenter_password`

`vcenter_server`

`ssh_public_key_path`

`vm_name`

`datastore`

`datacenter`

`cluster`

`resource_pool`

`network`

`vm_template`

`ipv4_address`

`ipv4_netmask_prefix_length`

`ipv4_gateway`

`dns_nameservers`

Docker 用のプロキシの使用: `oauth2: cannot fetch token`

`openssl` で管理ワークステーション OVA を検証できない