Terraform でアラートを構成する

Terraform を使用している場合は、Personalized Service Health に表示されるサービス ヘルス イベントのアラートを設定できます。このドキュメントでは、その方法について説明します。

始める前に

  1. アラートを作成するプロジェクトで Service Health API を有効にします。
  2. Terraform 構成で通知チャンネルが定義されている。詳細については、google_monitoring_notification_channel リソースのドキュメントをご覧ください。

構成の例

次の Terraform 構成の例では、すべての新しいインシデントおよびすべての更新に対して Personalized Service Health とアラートを有効にします。

provider "google" {
  project = "PROJECT_ID"
}

resource "google_project_service" "project" {
  service = "servicehealth.googleapis.com"
}

resource "google_monitoring_alert_policy" "alert_policy_all" {
  display_name = "All incidents, all updates"
  combiner     = "OR"
  enabled      = "true"
  conditions {
    display_name = "test condition"
    condition_matched_log {
      filter     = "resource.type = \"servicehealth.googleapis.com/Event\" AND jsonPayload.category = \"INCIDENT\" AND jsonPayload.@type = \"type.googleapis.com/google.cloud.servicehealth.logging.v1.EventLog\""
      label_extractors = {
          state = "EXTRACT(jsonPayload.state)"
          description = "EXTRACT(jsonPayload.description)"
          impactedProducts = "EXTRACT(jsonPayload.impactedProducts)"
          startTime = "EXTRACT(jsonPayload.startTime)"
          title = "EXTRACT(jsonPayload.title)"
          impactedLocations = "EXTRACT(jsonPayload.impactedLocations)"
      }
    }
  }

  documentation {
    content = "### $${log.extracted_label.title}\nCheck out [Personalized Service Health dashboard](https://console.cloud.google.com/servicehealth/incidentDetails/projects%2F${resource.labels.resource_container}%2Flocations%2F${resource.labels.location}%2Fevents%2F${resource.labels.event_id}?project=${resource.labels.resource_container}) for more details.<br><br>  Description: $${log.extracted_label.description}<br><br>  Impacted products: $${log.extracted_label.impactedProducts}<br><br> Impacted locations: $${log.extracted_label.impactedLocations}<br><br>  Incident start time: $${log.extracted_label.startTime}<br><br>  State: $${log.extracted_label.state}"
    mime_type = "text/markdown"
  }
  alert_strategy {
    notification_rate_limit {
      period = "300s"
    }
  }

  notification_channels =  ["projects/PROJECT_ID/notificationChannels/NOTIFICATION_CHANNEL"]

  user_labels = {  # Add any extra labels that might be helpful
    scope = "all"
  }
}

サービス servicehealth.googleapis.com は Personalized Service Health を指し、フィルタはすべてのイベントを取得します。設定できるフィールドについては、Service Health API リファレンスをご覧ください。

前の構成は、Service Health ダッシュボードでアラートを設定するときに [すべてのインシデント、すべての更新] オプションを選択した場合と同じです。

アラート ポリシーで設定できるフィールドの詳細については、次のページをご覧ください。