Diese Seite wurde von der Cloud Translation API übersetzt.

Selbstverwaltete SQL Server-Datenbank konfigurieren

In den folgenden Schritten wird beschrieben, wie Sie eine selbstverwaltete SQL Server-Datenbank konfigurieren zur Verwendung mit Datastream:

Aktivieren Sie CDC für Ihre Quelldatenbank. Stellen Sie dazu eine Verbindung in die Datenbank und führen Sie den folgenden Befehl an einer SQL-Eingabeaufforderung oder in einem Terminal aus:
```
USE [DATABASE_NAME]
GO
EXEC sys.sp_cdc_enable_db
GO
```
Ersetzen Sie DATABASE_NAME durch den Namen der Quelldatenbank.
Aktivieren Sie CDC für die Tabellen, für die Sie Änderungen erfassen müssen:
```
USE [DATABASE_NAME]
EXEC sys.sp_cdc_enable_table
@source_schema = N'SCHEMA_NAME',
@source_name = N'TABLE_NAME',
@role_name = NULL
GO
```
Hinweis: Sie müssen den Befehl für jede Tabelle ausführen, für die Sie CDC aktivieren möchten.

Ersetzen Sie Folgendes:
- DATABASE_NAME: der Name Ihrer Quelldatenbank
- SCHEMA_NAME: der Name des Schemas, zu dem die Tabellen gehören
- TABLE_NAME: der Name der Tabelle, für die Sie CDC aktivieren möchten
Starten Sie den SQL Server-Agent und sorgen Sie dafür, dass er immer ausgeführt wird. Wenn der SQL Server-Agent über einen längeren Zeitraum ausfällt, werden die Protokolle möglicherweise abgeschnitten, was zu einem dauerhaften Verlust der Änderungsdaten führt, die nicht von Datastream gelesen wurden.

Informationen zum Ausführen des SQL Server-Agents finden Sie unter Instanz des SQL Server-Agents starten, beenden oder neu starten.

Hinweis: Wir empfehlen, den automatischen Neustart für den SQL Server-Agent-Dienst zu aktivieren, damit der Agent nicht länger als nötig ausfällt.
Erstellen Sie einen Datastream-Nutzer:
1. Stellen Sie eine Verbindung zur Quelldatenbank her und geben Sie den folgenden Befehl ein:
```
USE DATABASE_NAME;
```
2. Erstellen Sie ein Log-in für die Einrichtung des Verbindungsprofils in Datastream.
```
CREATE LOGIN YOUR_LOGIN WITH PASSWORD = 'PASSWORD';
```
3. Erstellen Sie einen Nutzer:
```
CREATE USER USER_NAME FOR LOGIN YOUR_LOGIN;
```
4. Weisen Sie ihnen die Rolle db_datareader zu:
```
EXEC sp_addrolemember 'db_datareader', 'USER_NAME';
```
5. Gewähren Sie ihnen die Berechtigung VIEW DATABASE STATE:
```
GRANT VIEW DATABASE STATE TO 'USER_NAME';
```
6. Fügen Sie diesen Nutzer der Datenbank master hinzu:
```
USE master;
CREATE USER USER_NAME FOR LOGIN YOUR_LOGIN;
```

Zusätzliche erforderliche Schritte für die CDC-Methode der Transaktionslogs

Die in diesem Abschnitt beschriebenen Schritte sind nur erforderlich, wenn Sie Ihr SQL Server-Quelldatenbank zur Verwendung mit der CDC-Methode für Transaktionslogs.

Stellen Sie eine Verbindung zur Quelldatenbank her und weisen Sie dem Nutzer die Rollen db_owner und db_denydatawriter zu:

USE DATABASE_NAME;
EXEC sp_addrolemember 'db_owner', 'USER_NAME';
EXEC sp_addrolemember 'db_denydatawriter', 'USER_NAME';

Gewähren Sie SELECT-Berechtigungen für die Funktion sys.fn_dblog.
```
USE master;
GRANT SELECT ON sys.fn_dblog TO USER_NAME;
```

Fügen Sie den Nutzer zur Datenbank „msdb“ hinzu und weisen Sie ihm die folgenden Berechtigungen zu:

USE msdb;
CREATE USER USER_NAME FOR LOGIN YOUR_LOGIN;
GRANT SELECT ON dbo.sysjobs TO USER_NAME;

Weisen Sie dem Nutzer in der master-Datenbank die folgenden Berechtigungen zu:
```
  USE master;
  GRANT VIEW SERVER STATE TO YOUR_LOGIN;
```
Legen Sie die Aufbewahrungsdauer fest, für die die Änderungen in Ihrer Quelle verfügbar sein sollen.
```
USE [DATABASE_NAME]
EXEC sys.sp_cdc_change_job @job_type = 'capture' , @pollinginterval = 86399
EXEC sp_cdc_stop_job 'capture'
EXEC sp_cdc_start_job 'capture'
```
Der Parameter @pollinginterval wird in Sekunden gemessen. Der empfohlene Wert ist 86399. Das bedeutet, dass Änderungen im Transaktionsprotokoll 86.399 Sekunden (ein Tag) lang aufbewahrt werden. Durch die Ausführung der Prozedur sp_cdc_start_job 'capture wird die Einstellungen ändern.
Beenden Sie alle Bereinigungs- oder Erfassungsjobs in Ihrer Datenbank. Weitere Informationen finden Sie unter Change Data Capture verwalten und beobachten.

Richten Sie eine Absicherung gegen das Kürzen von Protokollen ein.

Um sicherzustellen, dass der CDC-Leser genügend Zeit hat, um die Protokolle zu lesen, während Kürzung von Protokollen, um zu verhindern, dass Speicherplatz belegt wird, können Sie diese Kürzung einrichten. Absicherung:

Stellen Sie eine Verbindung zur Datenbank über einen SQL Server-Client her.

Erstellen Sie eine gespeicherte Prozedur, die eine aktive Transaktion für einen Zeitraum ausführt, um das Abschneiden des Logs zu verhindern:

CREATE PROCEDURE dbo.DatastreamLogTruncationSafeguard @transaction_logs_retention_time INT
AS
BEGIN

DECLARE @transactionLog TABLE (beginLSN BINARY(10), endLSN BINARY(10))
INSERT @transactionLog EXEC sp_repltrans

DECLARE @currentDateTime DATETIME = GETDATE()
DECLARE @cutoffDateTime DATETIME = DATEADD(MINUTE, -@transaction_logs_retention_time, @currentDateTime)

DECLARE @firstValidLSN BINARY(10) = NULL
DECLARE @lastValidLSN BINARY(10) = NULL
DECLARE @firstTxnTime DATETIME = NULL
DECLARE @lastTxnTime DATETIME = NULL

SELECT TOP 1
    @lastTxnTime = t.logStartTime,
    @lastValidLSN = t.beginLSN
FROM (
  SELECT
    beginLSN AS beginLSN,
    (SELECT TOP 1 [begin time]
    FROM fn_dblog(stuff(stuff(CONVERT(CHAR(24), beginLSN, 1), 19, 0, ':'), 11, 0, ':'), DEFAULT)) AS logStartTime
  FROM @transactionLog
) t
ORDER BY t.beginLSN DESC

-- If all transactions are before cutoff, clear everything
IF (@lastTxnTime < @cutoffDateTime)
BEGIN
    EXEC sp_repldone NULL, NULL, 0, 0, 1
END
ELSE
BEGIN
    -- Find the earliest transaction
    SELECT TOP 1
      @firstTxnTime = t.logStartTime,
      @firstValidLSN = ISNULL(@firstValidLSN, t.beginLSN)
    FROM (
      SELECT
        beginLSN AS beginLSN,
        (SELECT TOP 1 [begin time]
        FROM fn_dblog(stuff(stuff(CONVERT(CHAR(24), beginLSN, 1), 19, 0, ':'), 11, 0, ':'), DEFAULT)) AS logStartTime
      FROM @transactionLog
    ) t
    ORDER BY t.beginLSN ASC

    IF (@firstTxnTime < @cutoffDateTime)
    BEGIN
        -- Identify the earliest and latest LSNs within VLogs before cutoff
        SELECT
          @firstValidLSN = SUBSTRING(MAX(t.lsnMarkers), 1, 10),
          @lastValidLSN = SUBSTRING(MAX(t.lsnMarkers), 11, 10)
        FROM (
          SELECT MIN(beginLSN + endLSN) AS lsnMarkers
          FROM @transactionLog
          GROUP BY SUBSTRING(beginLSN, 1, 4)
        ) t
        WHERE (
          SELECT TOP 1 [begin time]
          FROM fn_dblog(stuff(stuff(CONVERT(CHAR(24), t.lsnMarkers, 1), 19, 0, ':'), 11, 0, ':'), DEFAULT)
          WHERE Operation = 'LOP_BEGIN_XACT'
        ) < @cutoffDateTime

        EXEC sp_repldone @firstValidLSN, @lastValidLSN, 0, 0, 0
    END
  END
END;

Erstellen Sie eine weitere gespeicherte Prozedur. Dieses Mal erstellen Sie einen Job, der die im vorherigen Schritt erstellte gespeicherte Prozedur gemäß einer bestimmten Taktung ausführt:

CREATE PROCEDURE [dbo].[SetUpDatastreamJob] @transaction_logs_retention_time INT
AS
BEGIN

DECLARE @database_name VARCHAR(MAX)
  SET @database_name =  (SELECT DB_NAME());;

  DECLARE @command_str VARCHAR(MAX);
  SET @command_str = CONCAT('Use ', @database_name,'; exec dbo.DatastreamLogTruncationSafeguard @transaction_logs_retention_time = ' + CAST(@transaction_logs_retention_time AS VARCHAR(10)));

  DECLARE @job_name VARCHAR(MAX);
SET @job_name =
  CONCAT(@database_name, '_', 'DatastreamLogTruncationSafeguardJob1')
    DECLARE @current_time INT
  = CAST(FORMAT(GETDATE(), 'HHmmss') AS INT);

  -- Schedule the procedure to run after every 5 minutes.
  IF NOT EXISTS (
    SELECT * FROM msdb.dbo.sysjobs
    WHERE name = @job_name
  )
  BEGIN
    EXEC msdb.dbo.sp_add_job
    @job_name = @job_name,
    @enabled = 1,
    @description = N'Execute the procedure every 5 minutes.' ;

    EXEC msdb.dbo.sp_add_jobstep
    @job_name =  @job_name,
    @step_name = N'Execute_DatastreamLogTruncationSafeguard',
    @subsystem = N'TSQL',
    @command = @command_str;

      DECLARE @schedule_name_1 VARCHAR(MAX);
    SET @schedule_name_1 = CONCAT(@database_name, '_', 'DatastreamEveryFiveMinutesSchedule')

    EXEC msdb.dbo.sp_add_schedule
    @schedule_name = @schedule_name_1,
    @freq_type = 4,  -- daily start
    @freq_subday_type = 4,  -- every X minutes daily
    @freq_interval = 1,
    @freq_subday_interval = 5,
    @active_start_time = @current_time;

    EXEC msdb.dbo.sp_attach_schedule
    @job_name = @job_name,
    @schedule_name = @schedule_name_1 ;

    -- Add a schedule that runs the stored procedure on the SQL Server Agent startup.
    DECLARE @schedule_name_agent_startup VARCHAR(MAX);
    SET @schedule_name_agent_startup = CONCAT(@database_name, '_', 'DatastreamSqlServerAgentStartupSchedule')

    EXEC msdb.dbo.sp_add_schedule
    @schedule_name = @schedule_name_agent_startup,
    @freq_type = 64,  -- start on SQL Server Agent startup
    @active_start_time = @current_time;

    EXEC msdb.dbo.sp_attach_schedule
    @job_name = @job_name,
    @schedule_name = @schedule_name_agent_startup ;

    EXEC msdb.dbo.sp_add_jobserver
    @job_name = @job_name,
    @server_name = @@servername ;
  END
END;

Führen Sie die gespeicherte Prozedur aus, die den Datastream-Job erstellt.
```
DECLARE @transaction_logs_retention_time INT = (INT)
EXEC [dbo].[SetUpDatastreamJob] @transaction_logs_retention_time
```
Ersetzen Sie INT durch die Anzahl der Minuten, für die die Protokolle aufbewahrt werden sollen. Beispiel:
- Der Wert von 60 legt die Aufbewahrungsdauer auf 1 Stunde fest
- Mit dem Wert 24 * 60 wird die Aufbewahrungsdauer auf 1 Tag festgelegt.
- Der Wert von 3 * 24 * 60 legt die Aufbewahrungsdauer auf 3 Tage fest.

Nächste Schritte

Weitere Informationen zur Funktionsweise von Datastream mit SQL Server-Quellen