Esta página se ha traducido con Cloud Translation API.

Configurar una base de datos de SQL Server autogestionada para CDC

En esta página se describe cómo configurar la captura de datos de cambios (CDC) para transmitir datos desde una base de datos de SQL Server autogestionada a un destino admitido, como BigQuery o Cloud Storage.

Habilita CDC en tu base de datos de origen. Para hacerlo, conéctate a la base de datos y ejecuta el siguiente comando en una petición de SQL o en un terminal:
```
USE [DATABASE_NAME]
GO
EXEC sys.sp_cdc_enable_db
GO
```
Sustituye DATABASE_NAME por el nombre de tu base de datos de origen.
Habilita CDC en las tablas de las que necesites capturar cambios:
```
USE [DATABASE_NAME]
EXEC sys.sp_cdc_enable_table
@source_schema = N'SCHEMA_NAME',
@source_name = N'TABLE_NAME',
@role_name = NULL
GO
```
Nota: Debes ejecutar el comando para cada tabla en la que quieras habilitar CDC.

Haz los cambios siguientes:
- DATABASE_NAME: el nombre de la base de datos de origen
- SCHEMA_NAME: el nombre del esquema al que pertenecen las tablas.
- TABLE_NAME: el nombre de la tabla en la que quieres habilitar CDC
Inicia el agente de SQL Server y asegúrate de que se esté ejecutando en todo momento. Si el agente de SQL Server permanece inactivo durante un periodo prolongado, es posible que los registros se trunquen, lo que provocaría la pérdida permanente de los datos de cambios que Datastream no haya leído.

Para obtener información sobre cómo ejecutar el Agente SQL Server, consulta Iniciar, detener o reiniciar una instancia del Agente SQL Server.

Nota: Te recomendamos que actives el reinicio automático del servicio Agente de SQL Server para evitar que el agente esté inactivo durante más tiempo.
Habilita el aislamiento de instantáneas.

Cuando rellenas datos de tu base de datos de SQL Server, es importante que las copias de seguridad sean coherentes. Si no aplica los ajustes descritos en esta sección, los cambios realizados en la base de datos durante el proceso de relleno pueden provocar duplicados o resultados incorrectos, sobre todo en las tablas sin claves principales.

Si habilita el aislamiento de la captura, se creará una vista temporal de su base de datos al inicio del proceso de relleno. De esta forma, los datos que se copian siguen siendo coherentes, aunque otros usuarios hagan cambios en las tablas activas al mismo tiempo. Habilitar el aislamiento de instantáneas puede afectar ligeramente al rendimiento, pero es esencial para extraer datos de forma fiable.

Para habilitar el aislamiento de la captura, sigue estos pasos:
1. Conéctate a tu base de datos con un cliente de SQL Server.
2. Ejecuta el siguiente comando:
```
ALTER DATABASE DATABASE_NAME SET ALLOW_SNAPSHOT_ISOLATION ON;
```
Sustituye DATABASE_NAME por el nombre de tu base de datos.
Crea un usuario de Datastream:
1. Conéctate a la base de datos de origen e introduce el siguiente comando:
```
USE DATABASE_NAME;
```
2. Crea un inicio de sesión para usarlo al configurar el perfil de conexión en Datastream.
```
CREATE LOGIN YOUR_LOGIN WITH PASSWORD = 'PASSWORD';
```
3. Crea un usuario:
```
CREATE USER USER_NAME FOR LOGIN YOUR_LOGIN;
```
4. Asigna el rol db_datareader a los usuarios:
```
EXEC sp_addrolemember 'db_datareader', 'USER_NAME';
```
5. Concédele el permiso VIEW DATABASE STATE:
```
GRANT VIEW DATABASE STATE TO USER_NAME;
```
6. Añade este usuario a la base de datos master:
```
USE master;
CREATE USER USER_NAME FOR LOGIN YOUR_LOGIN;
```

Pasos adicionales necesarios para el método de CDC de los registros de transacciones

Los pasos descritos en esta sección solo son necesarios cuando se configura la base de datos de origen de SQL Server para usarla con el método de CDC de los registros de transacciones.

Conéctate a la base de datos de origen y asigna los roles db_owner y db_denydatawriter a tu usuario:

USE DATABASE_NAME;
EXEC sp_addrolemember 'db_owner', 'USER_NAME';
EXEC sp_addrolemember 'db_denydatawriter', 'USER_NAME';

Concede permisos a SELECT para la función sys.fn_dblog.

USE master;
GRANT SELECT ON sys.fn_dblog TO USER_NAME;

Añade tu usuario a la base de datos msdb y asígnale los siguientes permisos:

USE msdb;
CREATE USER USER_NAME FOR LOGIN YOUR_LOGIN;
GRANT SELECT ON dbo.sysjobs TO USER_NAME;

Asigna los siguientes permisos a tu usuario en la base de datos master:
```
  USE master;
  GRANT VIEW SERVER STATE TO YOUR_LOGIN;
```
Define el periodo de conservación durante el que quieres que los cambios estén disponibles en tu fuente.
```
USE [DATABASE_NAME]
EXEC sys.sp_cdc_change_job @job_type = 'capture' , @pollinginterval = 86399
EXEC sp_cdc_stop_job 'capture'
EXEC sp_cdc_start_job 'capture'
```
El parámetro @pollinginterval se mide en segundos y tiene un valor recomendado de 86399. Esto significa que el registro de transacciones conserva los cambios durante 86.399 segundos (un día). Al ejecutar el procedimiento sp_cdc_start_job 'capture, se inician los ajustes.
Si hay alguna tarea de limpieza o captura en ejecución en tu base de datos, deténla. Para obtener más información, consulta Administrar y monitorizar la captura de datos de cambios.

Configura una protección para evitar que se trunquen los registros.

Para asegurarte de que el lector de CDC tenga tiempo suficiente para leer los registros y, al mismo tiempo, permitir que se trunquen los registros para evitar que se agote el espacio de almacenamiento, puedes configurar una medida de protección para la truncación de registros:

Conéctate a la base de datos mediante un cliente de SQL Server.

Crea un procedimiento almacenado que ejecute una transacción activa durante un periodo que especifiques para evitar que se trunque el registro:

CREATE PROCEDURE dbo.DatastreamLogTruncationSafeguard @transaction_logs_retention_time INT
AS
BEGIN

DECLARE @transactionLog TABLE (beginLSN BINARY(10), endLSN BINARY(10))
INSERT @transactionLog EXEC sp_repltrans

DECLARE @currentDateTime DATETIME = GETDATE()
DECLARE @cutoffDateTime DATETIME = DATEADD(MINUTE, -@transaction_logs_retention_time, @currentDateTime)

DECLARE @firstValidLSN BINARY(10) = NULL
DECLARE @lastValidLSN BINARY(10) = NULL
DECLARE @firstTxnTime DATETIME = NULL
DECLARE @lastTxnTime DATETIME = NULL

SELECT TOP 1
    @lastTxnTime = t.logStartTime,
    @lastValidLSN = t.beginLSN
FROM (
  SELECT
    beginLSN AS beginLSN,
    (SELECT TOP 1 [begin time]
    FROM fn_dblog(stuff(stuff(CONVERT(CHAR(24), beginLSN, 1), 19, 0, ':'), 11, 0, ':'), DEFAULT)) AS logStartTime
  FROM @transactionLog
) t
ORDER BY t.beginLSN DESC

-- If all transactions are before cutoff, clear everything
IF (@lastTxnTime < @cutoffDateTime)
BEGIN
    EXEC sp_repldone NULL, NULL, 0, 0, 1
END
ELSE
BEGIN
    -- Find the earliest transaction
    SELECT TOP 1
      @firstTxnTime = t.logStartTime,
      @firstValidLSN = ISNULL(@firstValidLSN, t.beginLSN)
    FROM (
      SELECT
        beginLSN AS beginLSN,
        (SELECT TOP 1 [begin time]
        FROM fn_dblog(stuff(stuff(CONVERT(CHAR(24), beginLSN, 1), 19, 0, ':'), 11, 0, ':'), DEFAULT)) AS logStartTime
      FROM @transactionLog
    ) t
    ORDER BY t.beginLSN ASC

    IF (@firstTxnTime < @cutoffDateTime)
    BEGIN
        -- Identify the earliest and latest LSNs within VLogs before cutoff
        SELECT
          @firstValidLSN = SUBSTRING(MAX(t.lsnMarkers), 1, 10),
          @lastValidLSN = SUBSTRING(MAX(t.lsnMarkers), 11, 10)
        FROM (
          SELECT MIN(beginLSN + endLSN) AS lsnMarkers
          FROM @transactionLog
          GROUP BY SUBSTRING(beginLSN, 1, 4)
        ) t
        WHERE (
          SELECT TOP 1 [begin time]
          FROM fn_dblog(stuff(stuff(CONVERT(CHAR(24), t.lsnMarkers, 1), 19, 0, ':'), 11, 0, ':'), DEFAULT)
          WHERE Operation = 'LOP_BEGIN_XACT'
        ) < @cutoffDateTime

        EXEC sp_repldone @firstValidLSN, @lastValidLSN, 0, 0, 0
    END
  END
END;

Crea otro procedimiento almacenado. Esta vez, crearás un trabajo que ejecute el procedimiento almacenado que creaste en el paso anterior según una cadencia especificada:

CREATE PROCEDURE [dbo].[SetUpDatastreamJob] @transaction_logs_retention_time INT
AS
BEGIN

DECLARE @database_name VARCHAR(MAX)
  SET @database_name =  (SELECT DB_NAME());;

  DECLARE @command_str VARCHAR(MAX);
  SET @command_str = CONCAT('Use ', @database_name,'; exec dbo.DatastreamLogTruncationSafeguard @transaction_logs_retention_time = ' + CAST(@transaction_logs_retention_time AS VARCHAR(10)));

  DECLARE @job_name VARCHAR(MAX);
SET @job_name =
  CONCAT(@database_name, '_', 'DatastreamLogTruncationSafeguardJob1')
    DECLARE @current_time INT
  = CAST(FORMAT(GETDATE(), 'HHmmss') AS INT);

  -- Schedule the procedure to run after every 5 minutes.
  IF NOT EXISTS (
    SELECT * FROM msdb.dbo.sysjobs
    WHERE name = @job_name
  )
  BEGIN
    EXEC msdb.dbo.sp_add_job
    @job_name = @job_name,
    @enabled = 1,
    @description = N'Execute the procedure every 5 minutes.' ;

    EXEC msdb.dbo.sp_add_jobstep
    @job_name =  @job_name,
    @step_name = N'Execute_DatastreamLogTruncationSafeguard',
    @subsystem = N'TSQL',
    @command = @command_str;

      DECLARE @schedule_name_1 VARCHAR(MAX);
    SET @schedule_name_1 = CONCAT(@database_name, '_', 'DatastreamEveryFiveMinutesSchedule')

    EXEC msdb.dbo.sp_add_schedule
    @schedule_name = @schedule_name_1,
    @freq_type = 4,  -- daily start
    @freq_subday_type = 4,  -- every X minutes daily
    @freq_interval = 1,
    @freq_subday_interval = 5,
    @active_start_time = @current_time;

    EXEC msdb.dbo.sp_attach_schedule
    @job_name = @job_name,
    @schedule_name = @schedule_name_1 ;

    -- Add a schedule that runs the stored procedure on the SQL Server Agent startup.
    DECLARE @schedule_name_agent_startup VARCHAR(MAX);
    SET @schedule_name_agent_startup = CONCAT(@database_name, '_', 'DatastreamSqlServerAgentStartupSchedule')

    EXEC msdb.dbo.sp_add_schedule
    @schedule_name = @schedule_name_agent_startup,
    @freq_type = 64,  -- start on SQL Server Agent startup
    @active_start_time = @current_time;

    EXEC msdb.dbo.sp_attach_schedule
    @job_name = @job_name,
    @schedule_name = @schedule_name_agent_startup ;

    EXEC msdb.dbo.sp_add_jobserver
    @job_name = @job_name,
    @server_name = @@servername ;
  END
END;

Ejecuta el procedimiento almacenado que crea el trabajo de Datastream.
```
DECLARE @transaction_logs_retention_time INT = (INT)
EXEC [dbo].[SetUpDatastreamJob] @transaction_logs_retention_time
```
Sustituye INT por el número de minutos durante los que quieras conservar los registros. Por ejemplo:
- El valor de 60 define el tiempo de conservación en 1 hora.
- El valor de 24 * 60 define el tiempo de conservación en 1 día
- El valor de 3 * 24 * 60 establece el tiempo de conservación en 3 días.

Siguientes pasos

Consulta más información sobre cómo funciona Datastream con las fuentes de SQL Server.

Configurar una base de datos de SQL Server autogestionada para CDC Organízate con las colecciones Guarda y clasifica el contenido según tus preferencias.

Pasos adicionales necesarios para el método de CDC de los registros de transacciones

Siguientes pasos

Configurar una base de datos de SQL Server autogestionada para CDC