Se usó la API de Cloud Translation para traducir esta página.

Configura una base de datos de Cloud SQL para SQL Server

En las siguientes secciones, se explica cómo configurar una base de datos de Cloud SQL para SQL Server.

Conectarte a tu instancia de Cloud SQL Puedes hacerlo mediante el comando gcloud sql connect en el prompt de Cloud Shell.
Habilita la CDC en la base de datos con la ejecución del siguiente comando:
```
EXEC msdb.dbo.gcloudsql_cdc_enable_db 'DATABASE_NAME'
```
Reemplaza DATABASE_NAME por el nombre de la base de datos de origen.
Habilita la CDC en las tablas para las que necesitas capturar cambios:
```
USE [DATABASE_NAME]
EXEC sys.sp_cdc_enable_table
@source_schema = N'SCHEMA_NAME',
@source_name = N'TABLE_NAME',
@role_name = NULL
GO
```
Nota: Debes ejecutar el comando para cada tabla en la que desees habilitar las CDC.
Inicia el agente de SQL Server y asegúrate de que se ejecute en todo momento. Si el agente de SQL Server permanece inactivo durante un período prolongado, es posible que los registros se trunquen, lo que generaría una pérdida permanente de los datos de cambio que Datastream no leyó.

Para obtener información sobre cómo ejecutar el agente de SQL Server, consulta Inicia, detén o reinicia una instancia del agente de SQL Server.

Nota: Recomendamos configurar el reinicio automático para el servicio del agente de SQL Server a fin de evitar que el agente quede inactivo durante más tiempo.
Establece el período de retención durante el que deseas que los cambios estén disponibles en tu fuente:
```
USE [DATABASE_NAME]
EXEC sys.sp_cdc_change_job @job_type = 'capture' , @pollinginterval = 86399
EXEC sp_cdc_stop_job 'capture'
EXEC sp_cdc_start_job 'capture'
```
El parámetro @pollinginterval se mide en segundos con un valor recomendado establecido en 86399. Esto significa que el registro de transacciones retiene los cambios durante 86,399 segundos (un día). Cuando se ejecuta el procedimiento sp_cdc_start_job 'capture, se inicia la configuración.
Habilita el aislamiento de instantánea:

Cuando reabasteces datos desde tu base de datos de SQL Server, es importante garantizar instantáneas coherentes. Si no aplicas la configuración que se describe más adelante en esta sección, los cambios realizados en la base de datos durante el proceso de reabastecimiento pueden generar duplicados o resultados incorrectos, en particular, para tablas sin claves primarias.

Si habilitas el aislamiento de instantánea, se creará una vista temporal de tu base de datos al comienzo del proceso de reabastecimiento. Esto garantiza que los datos que se copian sigan siendo coherentes, incluso si otros usuarios realizan cambios en las tablas activas al mismo tiempo. Habilitar el aislamiento de instantáneas puede tener un ligero impacto en el rendimiento, pero es esencial para una extracción de datos confiable.

Para habilitar el aislamiento de instantánea, haz lo siguiente:
1. Conéctate a tu base de datos con un cliente de SQL Server.
2. Ejecuta el siguiente comando:
```
ALTER DATABASE DATABASE_NAME SET ALLOW_SNAPSHOT_ISOLATION ON;
```
Reemplaza DATABASE_NAME por el nombre de tu base de datos.

Configura una protección de truncamiento de registros

A fin de asegurarte de que el lector de CDC tenga tiempo suficiente para leer los registros y, al mismo tiempo, permitir que se trunque el registro para evitar que se use el espacio de almacenamiento, puedes configurar una protección de truncamiento de registros:

Conéctate a la base de datos con un cliente de SQL Server.

Crea una tabla ficticia en la base de datos:

USE [DATABASE_NAME];
CREATE TABLE dbo.gcp_datastream_truncation_safeguard (
  [id] INT IDENTITY(1,1) PRIMARY KEY,
  CreatedDate DATETIME DEFAULT GETDATE(),
  [char_column] CHAR(8)
  );

Reemplaza DATABASE_NAME por el nombre de la base de datos en la que deseas crear tu tabla ficticia.

Crea un procedimiento almacenado que ejecute una transacción activa durante un período de 24 horas para evitar el truncamiento de registros:

CREATE PROCEDURE dbo.DatastreamLogTruncationSafeguard
AS
BEGIN
  -- Start a new transaction
  BEGIN TRANSACTION;
  INSERT INTO dbo.gcp_datastream_truncation_safeguard (char_column) VALUES ('a')
  -- Wait for one day before ending the transaction
  WAITFOR DELAY '23:59';
  -- Commit the transaction
  COMMIT TRANSACTION;
END;

Crea otro procedimiento almacenado. Esta vez, crearás un trabajo que ejecute el procedimiento almacenado que creaste en el paso anterior a diario:

CREATE PROCEDURE dbo.SetUpDatastreamJob AS
BEGIN

  DECLARE @database_name VARCHAR(MAX)
  Set @database_name =  (SELECT DB_NAME());;

  DECLARE @command_str VARCHAR(MAX);
  Set @command_str = CONCAT('Use [', @database_name,']; exec dbo.DatastreamLogTruncationSafeguard')

  DECLARE @job_name_1 VARCHAR(MAX);
  Set @job_name_1 = CONCAT(@database_name, '_', 'DatastreamLogTruncationSafeguardJob1')
  -- Schedule the procedure to run again tomorrow
  IF NOT EXISTS (
    select * from msdb.dbo.sysjobs
    WHERE name = @job_name_1
  )
  BEGIN
    EXEC msdb.dbo.sp_add_job
    @job_name = @job_name_1,
    @enabled = 1,
    @description = N'Execute the procedure every day' ;

    EXEC msdb.dbo.sp_add_jobstep
    @job_name =  @job_name_1,
    @step_name = N'Execute_DatastreamLogTruncationSafeguard1',
    @subsystem = N'TSQL',
    @command = @command_str;

    -- Add a schedule that runs the stored procedure every day.
    DECLARE @start_time_1 time;
    SET @start_time_1 = DATEADD(MINUTE, 1, GETDATE());

    DECLARE @schedule_name_1 VARCHAR(MAX);
    Set @schedule_name_1 = CONCAT(@database_name, '_', 'DatastreamEverydaySchedule1')

    DECLARE @formatted_start_time_1 INT;
    SET @formatted_start_time_1 = CONVERT(INT, REPLACE(CONVERT(VARCHAR(8), @start_time_1, 114), ':' ,''));

    EXEC msdb.dbo.sp_add_schedule
    @schedule_name = @schedule_name_1,
    @freq_type = 4,  -- daily start
    @freq_interval = 1,
    @active_start_time = @formatted_start_time_1;

    EXEC msdb.dbo.sp_attach_schedule
    @job_name = @job_name_1,
    @schedule_name = @schedule_name_1 ;

    -- Add a schedule that runs the stored procedure on the SQL Server Agent startup.
    DECLARE @schedule_name_agent_startup VARCHAR(MAX);
    Set @schedule_name_agent_startup = CONCAT(@database_name, '_', 'DatastreamSqlServerAgentStartupSchedule')

    EXEC msdb.dbo.sp_add_schedule
    @schedule_name = @schedule_name_agent_startup,
    @freq_type = 64,  -- start on SQL Server Agent startup
    @active_start_time = @formatted_start_time_1;

    EXEC msdb.dbo.sp_attach_schedule
    @job_name = @job_name_1,
    @schedule_name = @schedule_name_agent_startup ;

    EXEC msdb.dbo.sp_add_jobserver
    @job_name = @job_name_1,
    @server_name = @@servername ;
  END

  DECLARE @job_name_2 VARCHAR(MAX);
  Set @job_name_2 = CONCAT(@database_name, '_', 'DatastreamLogTruncationSafeguardJob2')

  IF NOT EXISTS (
    select * from msdb.dbo.sysjobs
    WHERE name = @job_name_2
  )
  BEGIN
    EXEC msdb.dbo.sp_add_job
    @job_name = @job_name_2,
    @enabled = 1,
    @description = N'Procedure execution every day' ;

    EXEC msdb.dbo.sp_add_jobstep
    @job_name =  @job_name_2,
    @step_name = N'Execute_DatastreamLogTruncationSafeguard2',
    @subsystem = N'TSQL',
    @command = @command_str;

    DECLARE @start_time_2 time;
    SET @start_time_2 = DATEADD(HOUR, 12, GETDATE());
    DECLARE @formatted_start_time_2 INT;
    SET @formatted_start_time_2 = CONVERT(INT, REPLACE(CONVERT(VARCHAR(8), @start_time_2, 114), ':' ,''));
    DECLARE @schedule_name_2 VARCHAR(MAX);
    Set @schedule_name_2 = CONCAT(@database_name, '_', 'DatastreamEverydaySchedule2')

    EXEC msdb.dbo.sp_add_schedule
    @schedule_name = @schedule_name_2,
    @freq_type = 4,  -- daily start
    @freq_interval = 1,
    @active_start_time = @formatted_start_time_2;

    EXEC msdb.dbo.sp_attach_schedule
    @job_name = @job_name_2,
    @schedule_name = @schedule_name_2 ;

    EXEC msdb.dbo.sp_add_jobserver
    @job_name = @job_name_2,
   @server_name = @@servername ;
  END
End;

Ejecuta el procedimiento almacenado que crea el trabajo de Datastream.

EXEC dbo.SetUpDatastreamJob

Crea un usuario de Datastream:
1. En la consola de Google Cloud, ve a la página Instancias de Cloud SQL.
  
  Ir a Instancias de Cloud SQL
2. Crea un usuario.
3. Asigna los roles db_owner y db_denydatawriter a tu usuario:
```
EXEC sp_addrolemember 'db_owner', 'USER_NAME';
EXEC sp_addrolemember 'db_denydatawriter', 'USER_NAME';
```