Cloud Composer 1 | Cloud Composer 2 | Cloud Composer 3
En esta página, se describe cómo supervisar el estado y el rendimiento general del entorno de Cloud Composer con métricas clave en el panel de Monitoring.
Introducción
En este instructivo, nos enfocaremos en las métricas clave de supervisión de Cloud Composer que pueden proporcionar una buena descripción general del estado y el rendimiento a nivel del entorno.
Cloud Composer ofrece varias métricas que describen el estado general del entorno. Los lineamientos de supervisión de este instructivo se basan en las métricas expuestas en el panel de Monitoring de tu entorno de Cloud Composer.
En este instructivo, aprenderás sobre las métricas clave que funcionan como los principales indicadores de problemas con el rendimiento y el estado de tu entorno, además de los lineamientos para interpretar cada métrica en acciones correctivas para mantener el entorno en buen estado. También configurarás reglas de alerta para cada métrica, ejecutarás el DAG de ejemplo y usarás estas métricas y alertas para optimizar el rendimiento de tu entorno.
Objetivos
Costos
En este instructivo, se usan los siguientes componentes facturables de Google Cloud:
- Cloud Composer (consulta costos adicionales)
- Cloud Monitoring
Cuando finalices este instructivo, puedes borrar los recursos creados para evitar que se te siga facturando. Para obtener más detalles, consulta Realiza una limpieza.
Antes de comenzar
En esta sección, se describen las acciones necesarias antes de comenzar el instructivo.
Crea y configura un proyecto
Para este instructivo, necesitas un proyecto de Google Cloud. Configura el proyecto de la siguiente manera:
En la consola de Google Cloud, selecciona o crea un proyecto:
Asegúrate de tener habilitada la facturación para tu proyecto. Obtén más información para verificar si la facturación está habilitada en un proyecto.
Asegúrate de que el usuario de tu proyecto de Google Cloud tenga los siguientes roles para crear los recursos necesarios:
- Administrador de objetos de almacenamiento y entorno (
roles/composer.environmentAndStorageObjectAdmin) - Administrador de Compute (
roles/compute.admin) - Editor de Monitoring (
roles/monitoring.editor)
- Administrador de objetos de almacenamiento y entorno (
Habilita las API para tu proyecto.
Habilita la API de Cloud Composer.
Crea tu entorno de Cloud Composer
Crea un entorno de Cloud Composer 2.
Como parte de este procedimiento, otorgas la función de extensión de agente de servicio de la API de Cloud Composer v2 (roles/composer.ServiceAgentV2Ext) a la cuenta del agente de servicio de Composer. Cloud Composer usa esta cuenta para realizar operaciones en tu proyecto de Google Cloud.
Explora las métricas clave del estado y el rendimiento a nivel del entorno
En este instructivo, nos enfocaremos en las métricas clave que pueden brindarte una buena descripción general del estado y rendimiento generales de tu entorno.
El panel de Monitoring en la consola de Google Cloud contiene una variedad de métricas y gráficos que permiten supervisar las tendencias en tu entorno y, también, identificar problemas con los componentes de Airflow y los recursos de Cloud Composer.
Cada entorno de Cloud Composer tiene su propio panel de Monitoring.
Familiarízate con las métricas clave que se muestran a continuación y ubica cada una de ellas en el panel de Monitoring:
En la consola de Google Cloud, ve a la página Entornos.
En la lista de entornos, haz clic en el nombre de tu entorno. Se abrirá la página Detalles del entorno.
Ve a la pestaña Monitoring.
Selecciona la sección Descripción general, ubica el elemento Descripción general del entorno en el panel y observa la métrica Estado del entorno (DAG de supervisión de Airflow).
En este cronograma, se muestra el estado del entorno de Cloud Composer. El color verde de la barra de estado del entorno indica que el entorno está en buen estado, mientras que el de mal estado se indica con color rojo.
Cada pocos minutos, Cloud Composer ejecuta un DAG de funcionamiento llamado
airflow_monitoring. Si la ejecución del DAG en funcionamiento finaliza correctamente, el estado esTrue. Si la ejecución del DAG en funcionamiento falla (por ejemplo, debido a la expulsión del Pod, la finalización del proceso externo o el mantenimiento), el estado esFalse.
Selecciona la sección Base de datos SQL, ubica el elemento Estado de la base de datos en el panel y observa la métrica Estado de la base de datos.
En este cronograma se muestra el estado de la conexión a la instancia de Cloud SQL de tu entorno. La barra verde de estado de la base de datos indica conectividad, mientras que las fallas de conexión se indican con color rojo.
El Pod de supervisión de Airflow hace ping a la base de datos de forma periódica y, luego, informa el estado como
Truesi se puede establecer una conexión o comoFalsesi no lo es.
En el elemento Estado de la base de datos, observa las métricas Uso de CPU de la base de datos y Uso de memoria de la base de datos.
El gráfico de uso de CPU de la base de datos indica el uso de núcleos de CPU por parte de las instancias de base de datos de Cloud SQL de tu entorno en comparación con el límite de CPU total disponible de la base de datos.
En el gráfico de uso de memoria de la base de datos, se muestra el uso de memoria por parte de las instancias de base de datos de Cloud SQL de tu entorno en comparación con el límite total disponible de memoria de la base de datos.
Selecciona la sección Programadores, ubica el elemento Señal de monitoreo de funcionamiento del programador en el panel y observa la métrica Señal de monitoreo de funcionamiento del programador.
En este cronograma se muestra el estado del programador de Airflow. Verifica las áreas rojas para identificar los problemas del programador de Airflow. Si tu entorno tiene más de un programador, el estado de la señal de monitoreo de funcionamiento estará en buen estado, siempre y cuando al menos uno de los programadores esté respondiendo.
Se considera que el programador está en mal estado si la última señal de monitoreo de funcionamiento se recibió más de 30 segundos (valor predeterminado) antes de la hora actual.
Selecciona la sección Estadísticas de DAG, ubica el elemento Zombie Tasks killed en el panel y observa la métrica Zombie Tasks killed.
Este gráfico indica la cantidad de tareas zombi que se finalizaron en un período breve. A menudo, las tareas zombi se deben a la finalización externa de los procesos de Airflow (como cuando se cierra el proceso de una tarea).
El programador de Airflow finaliza las tareas zombi de forma periódica, lo que se refleja en este gráfico.
Selecciona la sección Trabajadores, ubica el elemento Reinicios de contenedor de trabajadores en el panel y observa la métrica Reinicios de contenedor de trabajadores.
- En un gráfico, se indica la cantidad total de reinicios de contenedores de trabajadores individuales. Demasiados reinicios del contenedor pueden afectar la disponibilidad de tu servicio o de otros servicios posteriores que lo usen como dependencia.
Conoce comparativas y posibles medidas correctivas para métricas clave
En la siguiente lista, se describen los valores comparativos que pueden indicar problemas y se proporcionan medidas correctivas que puedes tomar para solucionarlos.
Estado del entorno (DAG de supervisión de Airflow)
Tasa de éxito inferior al 90% en un período de 4 horas
Las fallas pueden significar expulsiones de Pods o cierres de trabajadores debido a que el entorno está sobrecargado o funciona mal. Las áreas rojas en el cronograma de estado del entorno suelen correlacionarse con áreas rojas en las otras barras de estado de los componentes individuales del entorno. Identifica la causa raíz mediante la revisión de otras métricas en el panel de Monitoring.
Estado de la base de datos
Tasa de éxito inferior al 95% en un período de 4 horas
Las fallas significan que hay problemas con la conectividad a la base de datos de Airflow, que podrían ser el resultado de una falla o un tiempo de inactividad de la base de datos debido a que esta está sobrecargada (por ejemplo, debido al alto uso de CPU o memoria, o a una latencia mayor durante la conexión a la base de datos). Con mayor frecuencia, estos síntomas se deben a DAG subóptimos, como cuando los DAG usan muchas variables de entorno o Airflow definidas a nivel global. Para identificar la causa raíz, revisa las métricas de uso de recursos de la base de datos SQL. También puedes inspeccionar los registros del programador en busca de errores relacionados con la conectividad de la base de datos.
Uso de memoria y CPU de la base de datos
Más del 80% en el uso promedio de CPU o memoria en un período de 12 horas
Es posible que la base de datos esté sobrecargada. Analiza la correlación entre las ejecuciones de DAG y los aumentos repentinos en el uso de memoria o CPU de la base de datos.
Puedes reducir la carga de la base de datos mediante DAG más eficientes con consultas y conexiones en ejecución optimizadas o si distribuyes la carga de manera más uniforme con el tiempo.
Como alternativa, puedes asignar más CPU o memoria a la base de datos. Los recursos de base de datos se controlan con la propiedad de tamaño de entorno de tu entorno, que debe escalarse a un tamaño más grande.
Señal de monitoreo de funcionamiento del programador
Tasa de éxito inferior al 90% en un período de 4 horas
Asigna más recursos al programador o aumenta la cantidad de programadores de 1 a 2 (recomendado).
Procesos zombi eliminados
Más de una tarea zombi por 24 horas
El motivo más común de las tareas zombi es la escasez de recursos de CPU o memoria en el clúster de tu entorno. Revisa los gráficos de uso de recursos de los trabajadores y asigna más recursos a tus trabajadores o aumenta el tiempo de espera de las tareas zombi para que el programador espere más tiempo antes de considerar una tarea como zombi.
Reinicios del contenedor de trabajadores
Más de un reinicio cada 24 horas
El motivo más común es la falta de memoria o almacenamiento de los trabajadores. Observa el consumo de recursos de los trabajadores y asigna más memoria o almacenamiento a tus trabajadores. Si la falta de recursos no es el motivo, revisa la solución de problemas de incidentes de reinicio de trabajadores y usa las consultas de Logging para descubrir los motivos de los reinicios del trabajador.
Crea canales de notificaciones
Sigue las instrucciones que se describen en Crea un canal de notificaciones para crear un canal de notificaciones por correo electrónico.
Para obtener más información sobre los canales de notificación, consulta Cómo administrar los canales de notificación.
Crea políticas de alertas
Crea políticas de alertas basadas en las comparativas proporcionadas en las secciones anteriores de este instructivo para supervisar de forma continua los valores de las métricas y recibir notificaciones cuando esas métricas infrinjan una condición.
Console
Si deseas configurar alertas para cada métrica que se presenta en el panel de Monitoring, haz clic en el ícono de campana en la esquina del elemento correspondiente:
Busca cada métrica que deseas supervisar en el panel de Monitoring y haz clic en el ícono de campana en la esquina del elemento de la métrica. Se abrirá la página Crear política de alertas.
En la sección Transforma los datos, sigue estos pasos:
Configura la sección Dentro de cada serie temporal como se describe en la configuración de las políticas de alertas para la métrica.
Haz clic en Siguiente y, luego, configura la sección Configurar activador de alertas como se describe en la configuración de las políticas de alertas para la métrica.
Haz clic en Siguiente.
Configura las notificaciones. Expande el menú Canales de notificaciones y selecciona los canales de notificación que creaste en el paso anterior.
Haz clic en OK.
En la sección Nombre de la política de alertas, completa el campo Nombre de la política de alertas. Usa un nombre descriptivo para cada métrica. Usa el valor “Asigna un nombre a la política de alertas” como se describe en la configuración de las políticas de alertas para la métrica.
Haz clic en Siguiente.
Revisa la política de alertas y haz clic en Crear política.
Métrica de estado del entorno (DAG de supervisión de Airflow): parámetros de configuración de políticas de alertas
- Nombre de la métrica: Entorno de Cloud Composer: en buen estado
- API: composer.googleapis.com/environment/healthy
Filtros:
environment_name = [ENVIRONMENT_NAME] location = [CLUSTER_LOCATION]Transforma los datos > Dentro de cada serie temporal:
- Ventana progresiva: Personalizado
- Valor personalizado: 4
- Unidades personalizadas: horas
- Función analítica progresiva: fracción verdadera
Configura el activador de alertas:
- Tipos de condiciones: Umbral
- Activador de la alerta: Cualquier serie temporal es una infracción
- Posición del umbral: Por debajo del umbral
- Valor del umbral: 90
- Nombre de la condición: Condición de estado del entorno
Configura las notificaciones y finaliza la alerta:
- Asígnale un nombre a la política de alertas: Estado del entorno de Airflow
Métrica de estado de la base de datos: parámetros de configuración de políticas de alertas
- Nombre de la métrica: Entorno de Cloud Composer: base de datos en buen estado
- API: composer.googleapis.com/environment/database_health
Filtros:
environment_name = [ENVIRONMENT_NAME] location = [CLUSTER_LOCATION]Transforma los datos > Dentro de cada serie temporal:
- Ventana progresiva: Personalizado
- Valor personalizado: 4
- Unidades personalizadas: horas
- Función analítica progresiva: fracción verdadera
Configura el activador de alertas:
- Tipos de condiciones: Umbral
- Activador de la alerta: Cualquier serie temporal es una infracción
- Posición del umbral: Por debajo del umbral
- Valor del umbral: 95
- Nombre de la condición: Estado de la base de datos
Configura las notificaciones y finaliza la alerta:
- Asigna un nombre a la política de alertas: Estado de la base de datos de Airflow
Métrica de uso de CPU de la base de datos: parámetros de configuración de la política de alertas
- Nombre de la métrica: Entorno de Cloud Composer - Uso de CPU de la base de datos
- API: composer.googleapis.com/environment/database/cpu/utilization
Filtros:
environment_name = [ENVIRONMENT_NAME] location = [CLUSTER_LOCATION]Transforma los datos > Dentro de cada serie temporal:
- Ventana progresiva: Personalizado
- Valor personalizado: 12
- Unidades personalizadas: horas
- Función analítica progresiva: media
Configura el activador de alertas:
- Tipos de condiciones: Umbral
- Activador de la alerta: Cualquier serie temporal es una infracción
- Posición del umbral: por encima del umbral
- Valor del umbral: 80
- Nombre de la condición: Condición de uso de CPU de la base de datos
Configura las notificaciones y finaliza la alerta:
- Asigna un nombre a la política de alertas: Uso de CPU de la base de datos de Airflow
Métrica de uso de CPU de la base de datos: parámetros de configuración de la política de alertas
- Nombre de la métrica: Entorno de Cloud Composer - Uso de memoria de la base de datos
- API: composer.googleapis.com/environment/database/memory/utilization
Filtros:
environment_name = [ENVIRONMENT_NAME] location = [CLUSTER_LOCATION]Transforma los datos > Dentro de cada serie temporal:
- Ventana progresiva: Personalizado
- Valor personalizado: 12
- Unidades personalizadas: horas
- Función analítica progresiva: media
Configura el activador de alertas:
- Tipos de condiciones: Umbral
- Activador de la alerta: Cualquier serie temporal es una infracción
- Posición del umbral: por encima del umbral
- Valor del umbral: 80
- Nombre de la condición: Condición de uso de memoria de la base de datos
Configura las notificaciones y finaliza la alerta:
- Asigna un nombre a la política de alertas: Uso de memoria de la base de datos de Airflow
Métrica de señales de monitoreo del programador: configuración de la política de alertas
- Nombre de la métrica: Entorno de Cloud Composer: señales de monitoreo de funcionamiento del programador
- API: composer.googleapis.com/environment/scheduler_heartbeat_count
Filtros:
environment_name = [ENVIRONMENT_NAME] location = [CLUSTER_LOCATION]Transforma los datos > Dentro de cada serie temporal:
- Ventana progresiva: Personalizado
- Valor personalizado: 4
- Unidades personalizadas: horas
- Función analítica progresiva: count
Configura el activador de alertas:
- Tipos de condiciones: Umbral
- Activador de la alerta: Cualquier serie temporal es una infracción
- Posición del umbral: Por debajo del umbral
Valor del umbral: 216
- Para obtener este número, ejecuta una consulta que agregue el valor
_scheduler_heartbeat_count_meanen el editor de consultas del Explorador de métricas.
- Para obtener este número, ejecuta una consulta que agregue el valor
Nombre de la condición: Condición de señal de monitoreo de funcionamiento del programador
Configura las notificaciones y finaliza la alerta:
- Asigna un nombre a la política de alertas: Señal de monitoreo de funcionamiento de Airflow Scheduler
Métrica de tareas zombi que finalizaron: configuración de la política de alertas
- Nombre de la métrica: Entorno de Cloud Composer: tareas zombi finalizadas
- API: composer.googleapis.com/environment/zombie_task_killed_count
Filtros:
environment_name = [ENVIRONMENT_NAME] location = [CLUSTER_LOCATION]Transforma los datos > Dentro de cada serie temporal:
- Período móvil: 1 día
- Función analítica progresiva: sum
Configura el activador de alertas:
- Tipos de condiciones: Umbral
- Activador de la alerta: Cualquier serie temporal es una infracción
- Posición del umbral: por encima del umbral
- Valor del umbral: 1
- Nombre de la condición: Condición de tareas zombi
Configura las notificaciones y finaliza la alerta:
- Asigna un nombre a la política de alertas: Airflow Zombie Tasks
El contenedor de trabajadores reinicia métricas: configuraciones de políticas de alertas
- Nombre de la métrica: Entorno de Cloud Composer: tareas zombi finalizadas
- API: composer.googleapis.com/environment/zombie_task_killed_count
Filtros:
environment_name = [ENVIRONMENT_NAME] location = [CLUSTER_LOCATION]Transforma los datos > Dentro de cada serie temporal:
- Período móvil: 1 día
- Función analítica progresiva: sum
Configura el activador de alertas:
- Tipos de condiciones: Umbral
- Activador de la alerta: Cualquier serie temporal es una infracción
- Posición del umbral: por encima del umbral
- Valor del umbral: 1
- Nombre de la condición: Condición de tareas zombi
Configura las notificaciones y finaliza la alerta:
- Asigna un nombre a la política de alertas: Airflow Zombie Tasks
Terraform
Ejecuta una secuencia de comandos de Terraform que crea un canal de notificaciones por correo electrónico y sube las políticas de alertas para las métricas clave que se proporcionan en este instructivo según sus respectivas comparativas:
- Guarda el archivo de Terraform de ejemplo en tu computadora local.
Reemplaza lo siguiente:
PROJECT_ID: Es el ID del proyecto. Por ejemplo,example-project.EMAIL_ADDRESS: Es la dirección de correo electrónico a la que se debe notificar en caso de que se active una alerta.ENVIRONMENT_NAME: Es el nombre de tu entorno de Cloud Composer. Por ejemplo,example-composer-environmentCLUSTER_NAME: Es el nombre del clúster de tu entorno que se puede encontrar en Configuración del entorno > Recursos > Clúster de GKE en la consola de Google Cloud.
resource "google_monitoring_notification_channel" "basic" {
project = "PROJECT_ID"
display_name = "Test Notification Channel"
type = "email"
labels = {
email_address = "EMAIL_ADDRESS"
}
# force_delete = false
}
resource "google_monitoring_alert_policy" "environment_health_metric" {
project = "PROJECT_ID"
display_name = "Airflow Environment Health"
combiner = "OR"
notification_channels = [google_monitoring_notification_channel.basic.name] // To manually add a notification channel add it with the syntax "projects/[PROJECT_ID]/notificationChannels/[CHANNEL_ID]"
conditions {
display_name = "Environment health condition"
condition_threshold {
filter = "resource.type = \"cloud_composer_environment\" AND metric.type=\"composer.googleapis.com/environment/healthy\" AND resource.label.environment_name=\"ENVIRONMENT_NAME\""
duration = "60s"
comparison = "COMPARISON_LT"
threshold_value = 0.9
aggregations {
alignment_period = "14400s"
per_series_aligner = "ALIGN_FRACTION_TRUE"
}
}
}
}
resource "google_monitoring_alert_policy" "database_health_metric" {
project = "PROJECT_ID"
display_name = "Airflow Database Health"
combiner = "OR"
notification_channels = [google_monitoring_notification_channel.basic.name] // To manually add a notification channel add it with the syntax "projects/[PROJECT_ID]/notificationChannels/[CHANNEL_ID]"
conditions {
display_name = "Database health condition"
condition_threshold {
filter = "resource.type = \"cloud_composer_environment\" AND metric.type=\"composer.googleapis.com/environment/database_health\" AND resource.label.environment_name=\"ENVIRONMENT_NAME\""
duration = "60s"
comparison = "COMPARISON_LT"
threshold_value = 0.95
aggregations {
alignment_period = "14400s"
per_series_aligner = "ALIGN_FRACTION_TRUE"
}
}
}
}
resource "google_monitoring_alert_policy" "alert_database_cpu_usage" {
project = "PROJECT_ID"
display_name = "Airflow Database CPU Usage"
combiner = "OR"
notification_channels = [google_monitoring_notification_channel.basic.name] // To manually add a notification channel add it with the syntax "projects/[PROJECT_ID]/notificationChannels/[CHANNEL_ID]"
conditions {
display_name = "Database CPU usage condition"
condition_threshold {
filter = "resource.type = \"cloud_composer_environment\" AND metric.type=\"composer.googleapis.com/environment/database/cpu/utilization\" AND resource.label.environment_name=\"ENVIRONMENT_NAME\""
duration = "60s"
comparison = "COMPARISON_GT"
threshold_value = 80
aggregations {
alignment_period = "43200s"
per_series_aligner = "ALIGN_MEAN"
}
}
}
}
resource "google_monitoring_alert_policy" "alert_database_memory_usage" {
project = "PROJECT_ID"
display_name = "Airflow Database Memory Usage"
combiner = "OR"
notification_channels = [google_monitoring_notification_channel.basic.name] // To manually add a notification channel add it with the syntax "projects/[PROJECT_ID]/notificationChannels/[CHANNEL_ID]"
conditions {
display_name = "Database memory usage condition"
condition_threshold {
filter = "resource.type = \"cloud_composer_environment\" AND metric.type=\"composer.googleapis.com/environment/database/memory/utilization\" AND resource.label.environment_name=\"ENVIRONMENT_NAME\""
duration = "60s"
comparison = "COMPARISON_GT"
threshold_value = 80
aggregations {
alignment_period = "43200s"
per_series_aligner = "ALIGN_MEAN"
}
}
}
}
resource "google_monitoring_alert_policy" "alert_scheduler_heartbeat" {
project = "PROJECT_ID"
display_name = "Airflow Scheduler Heartbeat"
combiner = "OR"
notification_channels = [google_monitoring_notification_channel.basic.name] // To manually add a notification channel add it with the syntax "projects/[PROJECT_ID]/notificationChannels/[CHANNEL_ID]"
conditions {
display_name = "Scheduler heartbeat condition"
condition_threshold {
filter = "resource.type = \"cloud_composer_environment\" AND metric.type=\"composer.googleapis.com/environment/scheduler_heartbeat_count\" AND resource.label.environment_name=\"ENVIRONMENT_NAME\""
duration = "60s"
comparison = "COMPARISON_LT"
threshold_value = 216 // Threshold is 90% of the average for composer.googleapis.com/environment/scheduler_heartbeat_count metric in an idle environment
aggregations {
alignment_period = "14400s"
per_series_aligner = "ALIGN_COUNT"
}
}
}
}
resource "google_monitoring_alert_policy" "alert_zombie_task" {
project = "PROJECT_ID"
display_name = "Airflow Zombie Tasks"
combiner = "OR"
notification_channels = [google_monitoring_notification_channel.basic.name] // To manually add a notification channel add it with the syntax "projects/[PROJECT_ID]/notificationChannels/[CHANNEL_ID]"
conditions {
display_name = "Zombie tasks condition"
condition_threshold {
filter = "resource.type = \"cloud_composer_environment\" AND metric.type=\"composer.googleapis.com/environment/zombie_task_killed_count\" AND resource.label.environment_name=\"ENVIRONMENT_NAME\""
duration = "60s"
comparison = "COMPARISON_GT"
threshold_value = 1
aggregations {
alignment_period = "86400s"
per_series_aligner = "ALIGN_SUM"
}
}
}
}
resource "google_monitoring_alert_policy" "alert_worker_restarts" {
project = "PROJECT_ID"
display_name = "Airflow Worker Restarts"
combiner = "OR"
notification_channels = [google_monitoring_notification_channel.basic.name] // To manually add a notification channel add it with the syntax "projects/[PROJECT_ID]/notificationChannels/[CHANNEL_ID]"
conditions {
display_name = "Worker container restarts condition"
condition_threshold {
filter = "resource.type = \"k8s_container\" AND (resource.labels.cluster_name = \"CLUSTER_NAME\" AND resource.labels.container_name = monitoring.regex.full_match(\"airflow-worker|base\") AND resource.labels.pod_name = monitoring.regex.full_match(\"airflow-worker-.*|airflow-k8s-worker-.*\")) AND metric.type = \"kubernetes.io/container/restart_count\""
duration = "60s"
comparison = "COMPARISON_GT"
threshold_value = 1
aggregations {
alignment_period = "86400s"
per_series_aligner = "ALIGN_RATE"
}
}
}
}
Prueba las políticas de alertas
En esta sección, se describe cómo probar las políticas de alertas creadas y, también, interpretar los resultados.
Sube un DAG de muestra
El DAG de muestra memory_consumption_dag.py que se proporciona en este instructivo imita el uso intensivo de memoria de trabajador. El DAG contiene 4 tareas, cada una de las cuales escribe datos en una string de muestra, lo que consume 380 MB de memoria. El DAG de muestra está programado para ejecutarse cada 2 minutos y comenzará a ejecutarse de forma automática una vez que lo subas a tu entorno de Composer.
Sube el siguiente DAG de muestra al entorno que creaste en los pasos anteriores:
from datetime import datetime
import sys
import time
from airflow import DAG
from airflow.operators.python import PythonOperator
def ram_function():
data = ""
start = time.time()
for i in range(38):
data += "a" * 10 * 1000**2
time.sleep(0.2)
print(f"{i}, {round(time.time() - start, 4)}, {sys.getsizeof(data) / (1000 ** 3)}")
print(f"Size={sys.getsizeof(data) / (1000 ** 3)}GB")
time.sleep(30 - (time.time() - start))
print(f"Complete in {round(time.time() - start, 2)} seconds!")
with DAG(
dag_id="memory_consumption_dag",
start_date=datetime(2023, 1, 1, 1, 1, 1),
schedule="1/2 * * * *",
catchup=False,
) as dag:
for i in range(4):
PythonOperator(
task_id=f"task_{i+1}",
python_callable=ram_function,
retries=0,
dag=dag,
)
Interpretar alertas y métricas en Monitoring
Espera unos 10 minutos después de que el DAG de muestra comience a ejecutarse y evalúa los resultados de la prueba:
Revisa tu buzón de correo electrónico para verificar que hayas recibido una notificación de las alertas de Google Cloud con el asunto que comienza con
[ALERT]. El contenido de este mensaje incluye los detalles del incidente de la política de alertas.Haz clic en el botón Ver incidente en la notificación por correo electrónico. Se te redireccionará al Explorador de métricas. Revisa los detalles del incidente de alerta:
Figura 2: Detalles del incidente de alerta (haz clic para ampliar) El gráfico de métricas de incidentes indica que las métricas que creaste superaron el umbral de 1, lo que significa que Airflow detectó y finalizó más de 1 tarea zombi.
En tu entorno de Cloud Composer, ve a la pestaña Supervisión, abre la sección Estadísticas de DAG y busca el gráfico Tareas zombi eliminadas:
Figura 3: Gráfico de tareas zombi (haz clic para ampliar) En el gráfico, se indica que Airflow acaba de finalizar unas 20 tareas zombi en solo los primeros 10 minutos de ejecutar el DAG de muestra.
Según las comparativas y las acciones correctivas, el motivo más común de las tareas zombi es la falta de memoria de trabajador o CPU. Identifica la causa raíz de las tareas zombi mediante el análisis del uso de recursos de trabajadores.
Abre la sección Trabajadores en tu panel de Monitoring y revisa las métricas de uso de memoria y CPU de los trabajadores:
Figura 4: Métricas de uso de memoria y CPU del trabajador (haz clic para ampliar) En el gráfico de uso total de CPU de los trabajadores, se indica que el uso de CPU de los trabajadores estuvo por debajo del 50% del límite total disponible en todo momento, por lo que la CPU disponible es suficiente. En el gráfico de Uso de memoria total de trabajadores, se muestra que ejecutar el DAG de muestra alcanzó el límite de memoria asignable, que equivale a casi el 75% del límite total de memoria que se muestra en el gráfico (GKE reserva el 25% de los primeros 4 GiB de memoria y 100 MiB de memoria adicionales en cada nodo para controlar la expulsión del Pod).
Puedes concluir que los trabajadores no tienen los recursos de memoria para ejecutar correctamente el DAG de muestra.
Optimiza tu entorno y evalúa su rendimiento
Según el análisis del uso de recursos de trabajadores, debes asignar más memoria a tus trabajadores para que todas las tareas del DAG tengan éxito.
En tu entorno de Composer, abre la pestaña DAG, haz clic en el nombre del DAG de muestra (
memory_consumption_dag) y, luego, en Pausar DAG.Asigna memoria de trabajador adicional:
En la pestaña Configuración del entorno, busca la configuración Recursos > Cargas de trabajo y haz clic en Editar.
En el elemento Worker, aumenta el límite de Memory. En este instructivo, usarás 3.25 GB.
Guarda los cambios y espera varios minutos para que se reinicie el trabajador.
Abre la pestaña DAG, haz clic en el nombre del DAG de muestra (
memory_consumption_dag) y, luego, en Reanudar DAG.
Ve a Monitoring y verifica que no haya aparecido tareas nuevas de zombis después de actualizar los límites de recursos de trabajadores:
Resumen
En este instructivo, aprendiste sobre las métricas clave de estado y rendimiento a nivel de entorno, cómo configurar políticas de alertas para cada métrica y cómo interpretar cada métrica en acciones correctivas. Luego, ejecutaste un DAG de muestra, identificaste la causa raíz de los problemas de estado del entorno con la ayuda de alertas y gráficos de Monitoring, y optimizaste tu entorno mediante la asignación de más memoria a tus trabajadores. Sin embargo, se recomienda optimizar los DAG para reducir el consumo de recursos de los trabajadores, ya que no es posible aumentar los recursos más allá de un umbral determinado.
Limpia
Para evitar que se apliquen cargos a tu cuenta de Google Cloud por los recursos que se usaron en este instructivo, borra el proyecto que contiene los recursos o conserva el proyecto y borra los recursos individuales.
Borra el proyecto
- En la consola de Google Cloud, ve a la página Administrar recursos.
- En la lista de proyectos, elige el proyecto que quieres borrar y haz clic en Borrar.
- En el diálogo, escribe el ID del proyecto y, luego, haz clic en Cerrar para borrar el proyecto.
Borra los recursos individuales
Si planeas explorar varios instructivos y guías de inicio rápido, la reutilización de proyectos puede ayudarte a evitar exceder los límites de las cuotas del proyecto.
Console
- Borra el entorno de Cloud Composer. También debes borrar el bucket del entorno durante este procedimiento.
- Borra cada una de las políticas de alertas que creaste en Cloud Monitoring.
Terraform
- Asegúrate de que la secuencia de comandos de Terraform no contenga entradas de recursos que tu proyecto aún necesita. Por ejemplo, es posible que desees mantener algunas APIs habilitadas y los permisos de IAM aún asignados (si agregaste esas definiciones a tu secuencia de comandos de Terraform).
- Ejecuta
terraform destroy. - Borra el bucket del entorno de forma manual. Cloud Composer no lo borra automáticamente. Puedes hacerlo desde la consola de Google Cloud o Google Cloud CLI.