Creazione di una workstation amministrativa

Questa pagina spiega come creare la versione più recente di la macchina virtuale (VM) della workstation di amministrazione.

Per eseguire l'upgrade di una workstation di amministrazione esistente, vedi Upgrade di GKE On-Prem.

Panoramica

La workstation di amministrazione è una VM vSphere che contiene tutti gli strumenti necessari per creare e gestire i cluster GKE On-Prem. Per creare la workstation di amministrazione, esegui i passaggi descritti in questo argomento:

• Scarica il file OVA (Open Virtual Appliance) della workstation di amministrazione, un'immagine compressa della VM della workstation di amministrazione.
• Per importare l'OVA in vSphere come modello VM, utilizza govc, l'interfaccia a riga di comando per vSphere.
• Copia e compila i file di configurazione HashiCorp Terraform.
• Utilizza Terraform per creare la VM.

Prima di iniziare

1. Leggi la panoramica della workstation di amministrazione.
2. Completa la procedura descritta in Preparare l'installazione.
3. Verifica di avere installato govc.
4. Verifica di aver installato Terraform versione 0.11.

Scarica l'OVA della workstation di amministrazione

Scarica la versione più recente della workstation di amministrazione OVA dall'argomento Download. L'ultimo file OVA è:

gke-on-prem-admin-appliance-vsphere-1.1.2-gke.0.ova

dove 1.1.2-gke.0 è la versione più recente di GKE On-Prem. L'OVA include tutti i componenti del cluster, gli strumenti a riga di comando e altre entità necessarie per installare e gestire i cluster GKE On-Prem. L'OVA più recente include l'ultima versione di queste entità.

Salva il file in un punto del computer che utilizzi per creare la workstation di amministrazione.

Utilizzo di govc per importare l'OVA in vSphere e contrassegnarlo come modello di VM

Nelle seguenti sezioni:

1. Crea alcune variabili che dichiarano gli elementi del server vCenter e dell'ambiente vSphere.
2. Importa l'OVA della workstation di amministrazione in vSphere e contrassegnalo come modello di VM.

Creazione variabili per govc

Prima di importare l'OVA della workstation di amministrazione in vSphere, devi fornire govcalcune variabili che dichiarano gli elementi del tuo server vCenter e dell'ambiente vSphere:

Nota: puoi trovare molti di questi valori accedendo a vCenter Server.

export GOVC_URL=https://[VCENTER_SERVER_ADDRESS]/sdk
export GOVC_USERNAME=[VCENTER_SERVER_USERNAME]
export GOVC_PASSWORD=[VCENTER_SERVER_PASSWORD]
export GOVC_DATASTORE=[VSPHERE_DATASTORE]
export GOVC_DATACENTER=[VSPHERE_DATACENTER]
export GOVC_INSECURE=true

Puoi scegliere di utilizzare il pool di risorse predefinito vSphere o crearlo:

# If you want to use a resource pool you've configured yourself, export this variable:
export GOVC_RESOURCE_POOL=[VSPHERE_CLUSTER]/Resources/[VSPHERE_RESOURCE_POOL]

# If you want to use vSphere's default resource pool, export this variable instead:
export GOVC_RESOURCE_POOL=[VSPHERE_CLUSTER]/Resources

dove:

• [VCENTER_SERVER_ADDRESS] corrisponde all'indirizzo IP o al nome host del server vCenter.
• [VCENTER_SERVER_USERNAME] è il nome utente di un account che ha il ruolo Amministratore o privilegi equivalenti in vCenter Server.
• [VCENTER_SERVER_PASSWORD] è la password dell'account vCenter Server.
• [VSPHERE_DATASTORE] è il nome del datastore che hai configurato nel tuo ambiente vSphere.
• [VSPHERE_DATACENTER] è il nome del data center che hai configurato nell'ambiente vSphere.
• [VSPHERE_CLUSTER] è il nome del cluster che hai configurato nel tuo ambiente vSphere.
Per l'utilizzo di un pool di risorse non predefinito,
• [VSPHERE_RESOURCE_POOL] è il nome del pool di risorse che hai configurato per il tuo ambiente vSphere.

Importazione dell'OVA in vSphere: sensore standard

Se utilizzi uno vSphere Standard Switch, importa l'OVA in vSphere utilizzando questo comando:

govc import.ova -options - ~/gke-on-prem-admin-appliance-vsphere-1.1.2-gke.0.ova <<EOF
{
  "DiskProvisioning": "thin",
  "MarkAsTemplate": true
}
EOF

Importazione dell'OVA in vSphere: sensore distribuito

Se utilizzi uno scambio vSphere distribuito, importa l'OVA in vSphere utilizzando questo comando, dove [YOUR_DISTRIBUTED_PORT_GROUP_NAME] è il nome del tuo gruppo di porte distribuite:

govc import.ova -options - ~/gke-on-prem-admin-appliance-vsphere-1.1.2-gke.0.ova <<EOF
{
  "DiskProvisioning": "thin",
  "MarkAsTemplate": true,
  "NetworkMapping": [
      {
          "Name": "VM Network",
          "Network": "[YOUR_DISTRIBUTED_PORT_GROUP_NAME]"
      }
  ]
}
EOF

Copia dei file di configurazione Terraform

Nota: attualmente devi utilizzare Terraform versione 0.11 per questi file. I nomi file devono essere terraform.tf e terraform.tfvars, rispettivamente.

1. Crea una directory per i file Terraform:

   mkdir "[TERRAFORM_DIR]"
   

   dove [TERRAFORM_DIR] è il percorso di una directory in cui vuoi conservare i tuoi file Terraform.

2. Copia una delle seguenti configurazioni Terraform, a seconda che tu voglia specificare un indirizzo IP statico per la tua workstation di amministrazione o utilizzare un server DHCP per ottenere un indirizzo IP.

   Assicurati di copiare sia i file TF sia i file TFVARS. Il file TF è la configurazione HCL di Terraform che esegue la creazione della VM.

3. Salva le configurazioni rispettivamente in [TERRAFORM_DIR]/terraform.tf e [TERRAFORM_DIR]/terraform.tfvars.

DHCP

Fai clic sulla freccia di divulgazione per visualizzare i file Terraform per DHCP

terraform.tfvars

# vCenter Server username
vcenter_user = "[e-mail]"

# vCenter Server password
vcenter_password = ""

# vCenter Server IP or hostname
vcenter_server = ""

# Path in which the admin workstation's VM's public key should be saved
ssh_public_key_path = "~/.ssh/vsphere_workstation.pub"

# Hostname for the VM
vm_name = "admin-workstation"

# vSphere datastore to use for storage
datastore = ""

# vSphere datacenter in which to create the VM
datacenter = ""

# vSphere cluster in which to create the VM
cluster = ""

# vSphere resource pool in which to create VM, if you are using a non-default resource pool
# If you are using the default resource pool, provide a value like "CLUSTER-NAME/Resources"
resource_pool = ""

# vSphere network to use for the VM
network = "VM Network"

# Number of CPUs for this VM. Recommended minimum 4.
num_cpus = 4

# Memory in MB for this VM. Recommended minimum 8192.
memory = 8192

# The VM template (OVA) to clone. Change the version if you imported a different version of the OVA.
vm_template = "gke-on-prem-admin-appliance-vsphere-1.1.2-gke.0"

terraform.tf

#########################
####### VARIABLES #######
#########################

# The following variables are declared in the accompanying TFVARS file

# vCenter Server username
variable "vcenter_user" { }

# vCenter Server password
variable "vcenter_password" { }

# vCenter Server address
variable "vcenter_server" { }

# Path in which the VM's public key should be saved
variable "ssh_public_key_path" { default = "~/.ssh/vsphere_workstation.pub" }

# vSphere network to use for the VM
variable "network" { default = "VM Network"}

# Hostname for the VM
variable "vm_name" { default = "vsphere-workstation" }

# vSphere datacenter in which to create the admin workstation VM
variable "datacenter" { }

# vSphere datastore to use for storage
variable "datastore" { }

# vSphere cluster in which to create the VM
variable "cluster" { }

# vSphere resource pool in which to create the VM
variable "resource_pool" { }

# Number of CPUs for this VM. Recommended minimum 4.
variable "num_cpus" { default = 4 }

# Memory in MB for this VM. Recommended minimum 8192.
variable "memory" { default = 8192 }

# The VM template (OVA) to clone
variable "vm_template" { }

##########################
##########################

provider "vsphere" {
  version        = "~> 1.5"
  user           = "${var.vcenter_user}"
  password       = "${var.vcenter_password}"
  vcenter_server = "${var.vcenter_server}"

  # if you have a self-signed cert
  allow_unverified_ssl = true
}

### vSphere Data ###

data "vsphere_datastore" "datastore" {
  name          = "${var.datastore}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_datacenter" "dc" {
  name = "${var.datacenter}"
}

data "vsphere_compute_cluster" "cluster" {
  name          = "${var.cluster}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_resource_pool" "pool" {
  name          = "${var.resource_pool}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_network" "network" {
  name          = "${var.network}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_virtual_machine" "template_from_ovf" {
  name          = "${var.vm_template}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "template_file" "dhcp_ip_config" {
  template = <<EOF
network:
  version: 2
  ethernets:
    ens192:
      dhcp4: true
EOF
}

data "template_file" "user_data" {
  template = <<EOF
#cloud-config
apt:
  primary:
    - arches: [default]
      uri: http://us-west1.gce.archive.ubuntu.com/ubuntu/
write_files:
  - path: /etc/netplan/99-dhcp.yaml
    permissions: '0644'
    encoding: base64
    content: |
      $${dhcp_ip_config}
runcmd:
  - netplan apply
  - /var/lib/gke/guest-startup.sh
EOF
  vars = {
    dhcp_ip_config = "${base64encode(data.template_file.dhcp_ip_config.rendered)}"

  }
}

### vSphere Resources ###

resource "vsphere_virtual_machine" "vm" {
  name             = "${var.vm_name}"
  resource_pool_id = "${data.vsphere_resource_pool.pool.id}"
  datastore_id     = "${data.vsphere_datastore.datastore.id}"
  num_cpus         = "${var.num_cpus}"
  memory           = "${var.memory}"
  guest_id         = "${data.vsphere_virtual_machine.template_from_ovf.guest_id}"
  enable_disk_uuid = "true"
  scsi_type = "${data.vsphere_virtual_machine.template_from_ovf.scsi_type}"
  network_interface {
    network_id   = "${data.vsphere_network.network.id}"
    adapter_type = "${data.vsphere_virtual_machine.template_from_ovf.network_interface_types[0]}"
  }

  wait_for_guest_net_timeout = 15

  nested_hv_enabled = false
  cpu_performance_counters_enabled = false

  disk {
    label            = "disk0"
    size             = "${max(50, data.vsphere_virtual_machine.template_from_ovf.disks.0.size)}"
    eagerly_scrub    = "${data.vsphere_virtual_machine.template_from_ovf.disks.0.eagerly_scrub}"
    thin_provisioned = "${data.vsphere_virtual_machine.template_from_ovf.disks.0.thin_provisioned}"
  }

  cdrom {
    client_device = true
  }

  vapp {
    properties = {
      hostname    = "${var.vm_name}"
      public-keys = "${file(var.ssh_public_key_path)}"
      user-data   = "${base64encode(data.template_file.user_data.rendered)}"
    }
  }

  clone {
    template_uuid = "${data.vsphere_virtual_machine.template_from_ovf.id}"
  }
}

output "ip_address" {
  value = "${vsphere_virtual_machine.vm.default_ip_address}"
}

IP statico

Fai clic sulla freccia di divulgazione per visualizzare i file Terraform per IP statici.

terraform.tfvars

# vCenter Server username
vcenter_user = "[e-mail]"

# vCenter Server password
vcenter_password = ""

# vCenter Server IP or hostname
vcenter_server = ""

# Path in which the admin workstation's VM's public key should be saved
ssh_public_key_path = "~/.ssh/vsphere_workstation.pub"

# Hostname for the VM
vm_name = "admin-workstation"

# vSphere datastore to use for storage
datastore = ""

# vSphere datacenter in which to create the VM
datacenter = ""

# vSphere cluster in which to create the VM
cluster = ""

# vSphere resource pool in which to create VM, if you are using a non-default resource pool
# If you are using the default resource pool, provide a value like "CLUSTER-NAME/Resources"
resource_pool = ""

# vSphere network to use for the VM
network = "VM Network"

# Number of CPUs for this VM. Recommended minimum 4.
num_cpus = 4

# Memory in MB for this VM. Recommended minimum 8192.
memory = 8192

# The VM template (OVA) to clone. Change the version if you imported a different version of the OVA.
vm_template = "gke-on-prem-admin-appliance-vsphere-1.1.2-gke.0"

################################################
# Static IP settings                           #
################################################

# An IPv4 static IP for the admin workstataion; for example, 100.115.250.100
ipv4_address = "100.115.250.100"

# The netmask prefix length to use; for example, 22
ipv4_netmask_prefix_length = "22"

# The IPv4 gateway the admin workstation should use; for example, 100.115.251.254
ipv4_gateway = "100.115.251.254"

# Comma-delimited DNS servers
dns_nameservers = "8.8.8.8,8.8.4.4"

terraform.tf

#########################
####### VARIABLES #######
#########################

# The following variables are declared in the accompanying TFVARS file

# vCenter Server username
variable "vcenter_user" { }

# vCenter Server password
variable "vcenter_password" { }

# vCenter Server address
variable "vcenter_server" { }

# Path in which the VM's public key should be saved
variable "ssh_public_key_path" { default = "~/.ssh/vsphere_workstation.pub" }

# vSphere network to use for the VM
variable "network" { default = "VM Network"}

# Hostname for the VM
variable "vm_name" { default = "vsphere-workstation" }

# vSphere datacenter in which to create the admin workstation VM
variable "datacenter" { }

# vSphere datastore to use for storage
variable "datastore" { }

# vSphere cluster in which to create the VM
variable "cluster" { }

# vSphere resource pool in which to create the VM
variable "resource_pool" { }

# Number of CPUs for this VM. Recommended minimum 4.
variable "num_cpus" { default = 4 }

# Memory in MB for this VM. Recommended minimum 8192.
variable "memory" { default = 8192 }

# The VM template (OVA) to clone
variable "vm_template" { }

# The IP address to assign to the VM
variable "ipv4_address" { }

# Netmask prefix length
variable "ipv4_netmask_prefix_length" { }

# Default gateway to use
variable "ipv4_gateway" { }

# DNS resolvers to use
variable "dns_nameservers" { }

##########################
##########################

provider "vsphere" {
  version        = "~> 1.5"
  user           = "${var.vcenter_user}"
  password       = "${var.vcenter_password}"
  vcenter_server = "${var.vcenter_server}"

  # if you have a self-signed cert
  allow_unverified_ssl = true
}

### vSphere Data ###

data "vsphere_datastore" "datastore" {
  name          = "${var.datastore}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_datacenter" "dc" {
  name = "${var.datacenter}"
}

data "vsphere_compute_cluster" "cluster" {
  name          = "${var.cluster}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_resource_pool" "pool" {
  name          = "${var.resource_pool}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_network" "network" {
  name          = "${var.network}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_virtual_machine" "template_from_ovf" {
  name          = "${var.vm_template}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

##########################
### IF USING STATIC IP ###
##########################
data "template_file" "static_ip_config" {
  template = <<EOF
network:
  version: 2
  ethernets:
    ens192:
      dhcp4: no
      dhcp6: no
      addresses: ["${var.ipv4_address}/${var.ipv4_netmask_prefix_length}"]
      gateway4: ${var.ipv4_gateway}
      nameservers:
        addresses: [${var.dns_nameservers}]
EOF
}

data "template_file" "user_data" {
  template = <<EOF
#cloud-config
apt:
  primary:
    - arches: [default]
      uri: http://us-west1.gce.archive.ubuntu.com/ubuntu/
write_files:
  - path: /tmp/static-ip.yaml
    permissions: '0644'
    encoding: base64
    content: |
      $${static_ip_config}
runcmd:
  - /var/lib/gke/guest-startup.sh
EOF
  vars = {
    static_ip_config = "${base64encode(data.template_file.static_ip_config.rendered)}"

  }
}
##########################
### IF USING STATIC IP ###
##########################

### vSphere Resources ###

resource "vsphere_virtual_machine" "vm" {
  name             = "${var.vm_name}"
  resource_pool_id = "${data.vsphere_resource_pool.pool.id}"
  datastore_id     = "${data.vsphere_datastore.datastore.id}"
  num_cpus         = "${var.num_cpus}"
  memory           = "${var.memory}"
  guest_id         = "${data.vsphere_virtual_machine.template_from_ovf.guest_id}"
  enable_disk_uuid = "true"
  scsi_type = "${data.vsphere_virtual_machine.template_from_ovf.scsi_type}"
  network_interface {
    network_id   = "${data.vsphere_network.network.id}"
    adapter_type = "${data.vsphere_virtual_machine.template_from_ovf.network_interface_types[0]}"
  }

  wait_for_guest_net_timeout = 15

  nested_hv_enabled = false
  cpu_performance_counters_enabled = false

  disk {
    label            = "disk0"
    size             = "${max(50, data.vsphere_virtual_machine.template_from_ovf.disks.0.size)}"
    eagerly_scrub    = "${data.vsphere_virtual_machine.template_from_ovf.disks.0.eagerly_scrub}"
    thin_provisioned = "${data.vsphere_virtual_machine.template_from_ovf.disks.0.thin_provisioned}"
  }

  cdrom {
    client_device = true
  }

  vapp {
    properties = {
      hostname    = "${var.vm_name}"
      public-keys = "${file(var.ssh_public_key_path)}"
      user-data   = "${base64encode(data.template_file.user_data.rendered)}"
    }
  }

  clone {
    template_uuid = "${data.vsphere_virtual_machine.template_from_ovf.id}"
  }
}

output "ip_address" {
  value = "${vsphere_virtual_machine.vm.default_ip_address}"
}

Creazione di una chiave pubblica SSH

Crea una chiave pubblica SSH, in modo da poterti connettere alla workstation di amministrazione dal tuo laptop o workstation locale. Sui sistemi operativi basati su Linux, puoi utilizzare ssh-keygen:

ssh-keygen -t rsa -f ~/.ssh/vsphere_workstation -N ""

Modifica del file TFVARS

Apri terraform.tfvars in un editor di testo e fornisci i valori per le seguenti variabili. Puoi trovare molti di questi valori accedendo al client vCenter:

vcenter_user

Fornisci un account utente vCenter Server come stringa. L'account utente deve avere il ruolo Amministratore o privilegi equivalenti (vedi Requisiti di sistema). Ad esempio:

vcenter_user = "[e-mail]"

vcenter_password

Fornisci la password dell'account utente vCenter Server come stringa. Ad esempio:

vcenter_password = "#STyZ2T#Ko2o"

vcenter_server

Fornisci il tuo indirizzo vCenter Server (IP o nome host) come stringa. Ad esempio:

vcenter_server = "198.51.100.0"

ssh_public_key_path

Fornisci il percorso della chiave pubblica SSH. L'hai creato nel passaggio precedente:

ssh_public_key_path = "~/.ssh/vsphere_workstation.pub"

vm_name

Specifica un nome a tua scelta per la workstation di amministrazione:

vm_name = "admin-workstation"

datastore

Fornisci il nome del tuo datastore vSphere come stringa:

datastore = "MY-DATASTORE"

datacenter

Fornisci il nome del tuo data center vSphere come stringa:

datacenter = "MY-DATACENTER"

cluster

Fornisci il nome del cluster vSphere come stringa:

cluster = "MY-CLUSTER"

resource_pool

Se utilizzi un pool di risorse non predefinito, fornisci il nome del pool di risorse vSphere come stringa.

resource_pool = "MY-POOL"

Se utilizzi il pool di risorse predefinito, fornisci il seguente valore:

resource_pool = "MY-CLUSTER/Resources"

Consulta Specificare il pool di risorse root per un host autonomo.

network

Fornisci la rete vSphere in cui vuoi creare la tua workstation di amministrazione, sotto forma di stringa. Ad esempio:

network = "VM Network"

vm_template

Fornisci il nome del modello VM come stringa. Hai creato l'OVA e lo hai contrassegnato come modello in un passaggio precedente:

vm_template = "gke-on-prem-admin-appliance-vsphere-[VERSION]"

Utilizzare un indirizzo IP statico per la tua workstation di amministrazione

Se vuoi utilizzare un IP statico per la tua workstation di amministrazione, copia il file IP statico e TFVARS. Nel file TFVAR, inserisci i valori per le seguenti variabili:

ipv4_address

Fornisci un indirizzo IP statico IPv4 per la workstation di amministrazione. Ad esempio:

ipv4_address = "203.0.113.0"

ipv4_netmask_prefix_length

Fornisci il numero di bit nella subnet mask della rete in cui vuoi creare la workstation di amministrazione. Ad esempio:

ipv4_netmask_prefix_length = "22"

ipv4_gateway

Specifica il gateway della subnet in cui deve essere creata la workstation di amministrazione. Consulta la documentazione di VMware vSphere_virtual_machine.

Ad esempio:

ipv4_gateway = "198.51.100.0

dns_nameservers

Fornisci i server dei nomi DNS che devono essere utilizzati dalla workstation di amministrazione, separati da virgole. Ad esempio:

dns_nameservers = "8.8.8.8,8.8.4.4"

Creazione della workstation di amministrazione

Dopo aver completato i passaggi precedenti, puoi creare la VM di workstation di amministrazione:

1. Passa alla directory che contiene i file di configurazione Terraform (TF e TFVARS):

   cd [TERRAFORM_DIR]
   

2. Inizializza Terraform nella directory e applica la configurazione. L'operazione potrebbe richiedere alcuni minuti:

   terraform init && terraform apply -auto-approve -input=false

   Nota: il nome del file TFVARS deve essere terraform.tfvars. Altrimenti, devi passare il parametro --var-file e specificare il file TFVARS.

SSH nella workstation di amministrazione

1. Passa alla directory che contiene i file di configurazione di Terraform.

2. Recupera l'indirizzo IP della workstation di amministrazione:

   terraform output ip_address

   Prendi nota dell'indirizzo IP della workstation di amministrazione o esportalo come variabile nella tua shell.

3. Accedi tramite SSH alla workstation di amministrazione utilizzando la chiave generata e l'indirizzo IP:

   ssh -i ~/.ssh/vsphere_workstation ubuntu@$(terraform output ip_address)

   oppure, se vuoi usare solo il suo indirizzo:

   ssh -i ~/.ssh/vsphere_workstation ubuntu@[IP_ADDRESS]
   

Verifica che la workstation di amministrazione sia configurata correttamente

Verifica che gkectl e docker siano installati:

gkectl version
docker version

Configurazione del proxy per la workstation di amministrazione

Se il tuo ambiente è protetto da un proxy, segui le sezioni riportate di seguito per configurare l'interfaccia a riga di comando di Google Cloud e Docker per utilizzare il proxy.

Configurazione dell'interfaccia a riga di comando di Google Cloud in modo che utilizzi il proxy

Completa i passaggi seguenti della VM della workstation di amministrazione.

Se utilizzi un proxy per connetterti a Internet dal tuo laptop o dalla tua workstation, devi configurare l'interfaccia a riga di comando di Google Cloud per il proxy, in modo da poter eseguire i comandi gcloud e gsutil. Per le istruzioni, consulta la sezione relativa alla configurazione dell'interfaccia a riga di comando gcloud da utilizzare dietro un proxy/firewall.

Configurazione di un registro Docker per il pull del proxy

Completa i passaggi seguenti della VM della workstation di amministrazione.

Se vuoi utilizzare un registro Docker e la tua rete viene eseguita dietro un proxy, devi configurare il daemon Docker in esecuzione sulla tua workstation di amministrazione per eseguire il pull delle immagini tramite il proxy:

1. Raccogli gli indirizzi dei proxy HTTP e HTTPS.

2. Raccogli gli indirizzi IP e i nomi host di ogni host che devi contattare senza proxy, tra cui:

   • L'indirizzo IP del server vCenter.
   • Gli indirizzi IP di tutti gli host ESXi.
   • Indirizzi IP che intendi configurare sul tuo bilanciatore del carico.
   • L'intervallo 192.168.0.0/16.

   Nella workstation di amministrazione, aggiungi questi indirizzi alla variabile no_proxy:

   printf -v no_proxy '%s,' [ADDRESSES];
   

   Facoltativamente, puoi esportare l'intervallo in una variabile di ambiente per un utilizzo futuro. Tieni presente che le applicazioni e i processi potrebbero utilizzare questa variabile:

   export no_proxy="${no_proxy%,}";

3. Apri il file di configurazione di Docker, archiviato in /root/.docker/config.json, /home/[USER]/.docker/config.json o altrove, a seconda della configurazione.

4. All'interno di config.json, aggiungi le seguenti righe:

   "proxies": {
   
   "default": {
          "httpProxy": "[HTTP_PROXY]",
          "httpsProxy": "[HTTPS_PROXY]",
          "noProxy": "[ADDRESSES]"
              }
   }

   dove:

   • [HTTP_PROXY] è il tuo proxy HTTP, se ne hai uno.
   • [HTTPS_PROXY] è il tuo proxy HTTPS, se ne hai uno.
   • [ADDRESSES] è un elenco di indirizzi e nomi host delimitati da virgole che devi contattare senza proxy.

5. Riavvia Docker per rendere effettive le modifiche:

   sudo systemctl restart docker

Risolvere i problemi

Per ulteriori informazioni, consulta la sezione Risoluzione dei problemi.

Limite sessione del provider Terraform vSphere

GKE On-Prem utilizza il provider vSphere di Terraform per richiamare le VM nel tuo ambiente vSphere. Il limite per le sessioni del provider è 1000. L'implementazione corrente non chiude le sessioni attive dopo l'utilizzo. Se hai troppe sessioni in esecuzione, potresti visualizzare errori 503.

Le sessioni vengono chiuse automaticamente dopo 300 secondi.

Sintomi

Se sono in esecuzione troppe sessioni, potrebbe verificarsi il seguente errore:

Error connecting to CIS REST endpoint: Login failed: body:
  {"type":"com.vmware.vapi.std.errors.service_unavailable","value":
  {"messages":[{"args":["1000","1000"],"default_message":"Sessions count is
  limited to 1000. Existing sessions are 1000.",
  "id":"com.vmware.vapi.endpoint.failedToLoginMaxSessionCountReached"}]}},
  status: 503 Service Unavailable

Potenziali cause

Nel tuo ambiente sono in esecuzione troppe sessioni del provider Terraform.

Risoluzione

Attualmente funziona come previsto. Le sessioni vengono chiuse automaticamente dopo 300 secondi. Per ulteriori informazioni, consulta il problema di GitHub #618.

Utilizzo di un proxy per Docker: oauth2: cannot fetch token

Sintomi

Quando utilizzi un proxy ricevi il seguente errore:

oauth2: cannot fetch token: Post https://oauth2.googleapis.com/token: proxyconnect tcp: tls: oversized record received with length 20527

Potenziali cause

È possibile che tu abbia fornito un proxy HTTPS anziché HTTP.

Risoluzione

Nella configurazione Docker, modifica l'indirizzo proxy in http:// anziché in https://.

Verifica della validità delle licenze

Ricorda che devi verificare la validità delle licenze, soprattutto se utilizzi licenze di prova. Se le licenze F5, ESXi dell'host o vCenter sono scadute, potresti riscontrare errori imprevisti.

openssl non può convalidare l'OVA della workstation di amministrazione

Sintomi

L'esecuzione di openssl dgst nel file OVA della workstation di amministrazione non restituisce Verified OK

Potenziali cause

Nel file OVA è presente un problema che impedisce una convalida riuscita.

Risoluzione

Prova a scaricare e a eseguire il deployment dell'OVA della workstation di amministrazione, come indicato nell'articolo Scaricare l'OVA della workstation di amministrazione. Se il problema persiste, contatta Google per ricevere assistenza.

Passaggi successivi

• Installazione tramite DHCP.
• Installazione con IP statici.