Crea un flusso di lavoro utilizzando Terraform

Crea un flusso di lavoro utilizzando Terraform

Questa guida rapida mostra come creare, eseguire il deployment ed eseguire il primo flusso di lavoro utilizzando Terraform. Terraform è uno strumento Infrastructure as Code che consente di creare, modificare e migliorare in modo prevedibile la tua infrastruttura cloud utilizzando codice. Scopri come utilizzare Terraform per eseguire il provisioning dell'infrastruttura su Google Cloud.

In questa guida rapida, il flusso di lavoro di esempio invia una richiesta a un'API pubblica e poi restituisce la risposta dell'API.

Dovrai completare le seguenti operazioni:

1. Abilita l'API Workflows utilizzando Terraform.
2. Creare un account di servizio per il flusso di lavoro utilizzando Terraform.
3. Definire ed eseguire il deployment di un flusso di lavoro utilizzando Terraform.
4. Esegui il flusso di lavoro utilizzando Google Cloud CLI.

Prima di iniziare

I vincoli di sicurezza definiti dalla tua organizzazione potrebbero impedirti di completare i passaggi seguenti. Per informazioni sulla risoluzione dei problemi, vedi Sviluppare applicazioni in un ambiente Google Cloud vincolato.

Tieni presente che Terraform ha già integrato in Cloud Shell. Se devi installare Terraform, consulta la documentazione di HashiCorp Terraform.

1. Accedi al tuo account Google Cloud. Se non conosci Google Cloud, crea un account per valutare le prestazioni dei nostri prodotti in scenari reali. I nuovi clienti ricevono anche 300 $di crediti gratuiti per l'esecuzione, il test e il deployment dei carichi di lavoro.
2. Installa Google Cloud CLI.

3. Per initialize gcloud CLI, esegui questo comando:

   gcloud init

4. Crea o seleziona un progetto Google Cloud.

   Nota: se non prevedi di conservare le risorse create in questa procedura, crea un progetto anziché selezionarne uno esistente. Dopo aver completato questi passaggi, puoi eliminare il progetto, rimuovendo tutte le risorse associate.

   • Crea un progetto Google Cloud:

     gcloud projects create PROJECT_ID

     Sostituisci PROJECT_ID con un nome per il progetto Google Cloud che stai creando.

   • Seleziona il progetto Google Cloud che hai creato:

     gcloud config set project PROJECT_ID

     Sostituisci PROJECT_ID con il nome del tuo progetto Google Cloud.

5. Assicurati che la fatturazione sia attivata per il tuo progetto Google Cloud.

6. Abilita le API Cloud Resource Manager and Identity and Access Management (IAM).

   gcloud services enable cloudresourcemanager.googleapis.com iam.googleapis.com

7. Installa Google Cloud CLI.

8. Per initialize gcloud CLI, esegui questo comando:

   gcloud init

9. Crea o seleziona un progetto Google Cloud.

   Nota: se non prevedi di conservare le risorse create in questa procedura, crea un progetto anziché selezionarne uno esistente. Dopo aver completato questi passaggi, puoi eliminare il progetto, rimuovendo tutte le risorse associate.

   • Crea un progetto Google Cloud:

     gcloud projects create PROJECT_ID

     Sostituisci PROJECT_ID con un nome per il progetto Google Cloud che stai creando.

   • Seleziona il progetto Google Cloud che hai creato:

     gcloud config set project PROJECT_ID

     Sostituisci PROJECT_ID con il nome del tuo progetto Google Cloud.

10. Assicurati che la fatturazione sia attivata per il tuo progetto Google Cloud.

11. Abilita le API Cloud Resource Manager and Identity and Access Management (IAM).

    gcloud services enable cloudresourcemanager.googleapis.com iam.googleapis.com

Crea un file di configurazione Terraform

Crea un file di configurazione Terraform denominato main.tf e includi le risorse del provider Google per Terraform utilizzate in questa guida rapida.

Tieni presente che puoi utilizzare l'interpolazione per sostituzioni, ad esempio variabili di riferimento, attributi delle risorse e funzioni di chiamata.

1. Crea una directory:

   mkdir terraform

2. Vai alla directory terraform:

   cd terraform

3. Aggiungi un nuovo file, main.tf, alla directory:

   nano main.tf

4. Aggiungi le seguenti risorse al file main.tf:

   1. Assegna l'ID del progetto:

      provider "google" {
      project = "PROJECT_ID"
      }

      Sostituisci PROJECT_ID con l'ID del progetto.

   2. Abilita l'API Workflows:

      # Enable Workflows API
      resource "google_project_service" "default" {
        service            = "workflows.googleapis.com"
        disable_on_destroy = false
      }

   3. Crea un account di servizio per il flusso di lavoro:

      # Create a dedicated service account
      resource "google_service_account" "default" {
        account_id   = "sample-workflows-sa"
        display_name = "Sample Workflows Service Account"
      }

   4. Definisci il flusso di lavoro utilizzando la risorsa google_workflows_workflow:

      Importante: quando definisci i flussi di lavoro in Terraform, le variabili devono essere precedute dal carattere $${...} e non con ${...}.

      # Create a workflow
      resource "google_workflows_workflow" "default" {
        name            = "sample-workflow"
        region          = "us-central1"
        description     = "A sample workflow"
        service_account = google_service_account.default.id
        labels = {
          env = "test"
        }
        user_env_vars = {
          url = "https://timeapi.io/api/Time/current/zone?timeZone=Europe/Amsterdam"
        }
        source_contents = <<-EOF
        # This is a sample workflow that you can replace with your source code
        #
        # The workflow does the following:
        # - Retrieves the current date from a public API and stores the
        #   response in `currentDate`
        # - Retrieves a list of Wikipedia articles from a public API related
        #   to the day of the week stored in `currentDate`
        # - Returns the list of articles in the workflow output
        #
        # Note that when you define workflows in Terraform, variables must be
        # escaped with two dollar signs ($$) and not a single sign ($)
      
        - getCurrentDate:
            call: http.get
            args:
                url: $${sys.get_env("url")}
            result: currentDate
        - readWikipedia:
            call: http.get
            args:
                url: https://en.wikipedia.org/w/api.php
                query:
                    action: opensearch
                    search: $${currentDate.body.dayOfWeek}
            result: wikiResult
        - returnOutput:
            return: $${wikiResult.body[1]}
      EOF
      
        depends_on = [google_project_service.default]
      }

      Nel flusso di lavoro di esempio vengono utilizzati i seguenti argomenti:

      • name: il nome del flusso di lavoro.
      • region: la posizione del flusso di lavoro.
      • description: una descrizione del flusso di lavoro.
      • service_account: l'indirizzo email o l'ID univoco dell'account di servizio associato alla versione più recente del flusso di lavoro. Questo account di servizio rappresenta l'identità del flusso di lavoro e determina le autorizzazioni del flusso di lavoro. Se non specifichi un account di servizio durante la creazione del flusso di lavoro, quest'ultimo utilizza l'account di servizio predefinito di Compute Engine per la propria identità. Per maggiori informazioni, consulta Concedere l'autorizzazione dei flussi di lavoro per l'accesso alle risorse Google Cloud.
      • labels: un elenco di coppie chiave-valore da assegnare a questo flusso di lavoro che ti aiuta a organizzare le istanze Google Cloud. Per scoprire di più, consulta la sezione Che cosa sono le etichette?
      • user_env_vars: variabili di ambiente definite dall'utente associate a questa revisione del flusso di lavoro. Per maggiori informazioni, consulta Utilizzare le variabili di ambiente.
      • source_contents: il codice di Workflows da eseguire. Per il limite di dimensione del file, consulta Limiti delle risorse.

      Altri argomenti facoltativi sono:

      • crypto_key_name: l'ID risorsa per una chiave Cloud Key Management Service nel formato seguente:

        projects/PROJECT_NAME/locations/LOCATION/keyRings/KEY_RING/cryptoKeys/KEY_NAME

        Per maggiori informazioni, consulta Utilizzare le chiavi di crittografia gestite dal cliente.

      • call_log_level: il livello di logging da applicare alle chiamate e alle risposte alle chiamate durante le esecuzioni di questo flusso di lavoro. I valori possibili sono:

        • CALL_LOG_LEVEL_UNSPECIFIED
        • LOG_ALL_CALLS
        • LOG_ERRORS_ONLY
        • LOG_NONE

        Per ulteriori informazioni, vedi Registrazione chiamate.

      • project: l'ID del progetto a cui appartiene la risorsa. Se non viene fornito, viene utilizzato il progetto del provider.

      • name_prefix: crea un nome univoco che inizia con il prefisso specificato. Se questo e name non vengono specificati, viene scelto un valore casuale per il nome.

Crea ed esegui il flusso di lavoro

Esegui il deployment delle tue risorse Terraform per creare il flusso di lavoro e quindi eseguirlo.

1. Inizializza Terraform nella directory:

   terraform init
   

2. Verifica che le modifiche che proponi con Terraform corrispondano al piano previsto:

   terraform plan
   

   Puoi ignorare la nota relativa al non utilizzo dell'opzione -out.

3. Crea il flusso di lavoro:

   terraform apply
   

4. Al prompt Inserisci un valore, digita yes per procedere con la creazione delle risorse.

5. Conferma la creazione di un flusso di lavoro:

   gcloud workflows list --location us-central1
   

   L'output dovrebbe essere simile al seguente:

   NAME                                                                    STATE   REVISION_ID  UPDATE_TIME
   projects/project-name/locations/us-central1/workflows/sample-workflow   ACTIVE  000001-f9a   2024-02-24T13:38:58.353765906Z
   

6. Facoltativamente, puoi eseguire il flusso di lavoro:

   gcloud workflows execute sample-workflow
   

Esegui la pulizia

Per evitare che al tuo account Google Cloud vengano addebitati costi relativi alle risorse utilizzate in questa pagina, elimina il progetto Google Cloud con le risorse.

1. Elimina tutte le risorse che hai creato con Terraform:

   terraform destroy

2. Elimina il flusso di lavoro creato:

   gcloud workflows delete sample-workflow

   Quando ti viene chiesto se vuoi continuare, digita y.
3. In alternativa, puoi eliminare il progetto Google Cloud per evitare addebiti. L'eliminazione del tuo progetto Google Cloud interrompe la fatturazione per tutte le risorse utilizzate all'interno di quel progetto.
   Attenzione: l'eliminazione di un progetto ha i seguenti effetti:
   • L'intero contenuto del progetto viene eliminato. Se hai utilizzato un progetto esistente per le attività in questo documento, quando lo elimini elimini anche qualsiasi altro lavoro svolto nel progetto.
   • Gli ID progetto personalizzati non sono più disponibili. Quando hai creato questo progetto, potresti aver creato un ID progetto personalizzato che vuoi utilizzare in futuro. Per conservare gli URL che utilizzano l'ID progetto, ad esempio un URL appspot.com, elimina le risorse selezionate all'interno del progetto anziché eliminare l'intero progetto.

   Elimina un progetto Google Cloud:

   gcloud projects delete PROJECT_ID

Passaggi successivi

• Controllo dell'ordine di esecuzione in un flusso di lavoro.

• Aggiornare un flusso di lavoro esistente.

• Esplora i flussi di lavoro di esempio.

• Scopri di più sulla sintassi di Workflows.