Instructivo de Terraform

---

En este instructivo, se muestra cómo implementar una función HTTP mediante la carga de un archivo ZIP de código fuente de función a un bucket de Cloud Storage mediante Terraform para aprovisionar los recursos. Terraform es una herramienta de código abierto que te permite aprovisionar recursos de Google Cloud con archivos de configuración declarativos.

Este instructivo usa una función HTTP de Node.js como ejemplo, pero también se aplica a las funciones HTTP de Python, Go y Java. Las instrucciones son las mismas sin importar el entorno de ejecución que uses.

Cuando implementes con Terraform, debes subir el archivo fuente comprimido de tu función a un bucket de Cloud Storage (source_archive_bucket) y también especificar el nombre del objeto de Cloud Storage (source_archive_object) en la configuración de Terraform. Para obtener más información, consulta la guía de especificaciones de Terraform.

Las funciones de Cloud Run copian el archivo fuente que subes en source_archive_bucket a un bucket de tu proyecto con un nombre que sigue el formato gcf-v2-sources-PROJECT_NUMBER-REGION(funciones de Cloud Run) o gcf-sources-PROJECT_NUMBER-REGIONfunciones de Cloud Run (1ª gen.). Esta configuración varía según la dependencia de CMEK.

Objetivos

• Aprende a usar Terraform para implementar una función HTTP.

Costos

En este documento, usarás los siguientes componentes facturables de Google Cloud:

• Cloud Run functions
• Cloud Build
• Cloud Storage
• Artifact Registry

For details, see Cloud Run functions pricing.

Para generar una estimación de costos en función del uso previsto, usa la calculadora de precios. Es posible que los usuarios Google Cloud nuevos sean aptos para obtener una prueba gratuita.

Antes de comenzar

1. Sign in to your Google Cloud account. If you're new to Google Cloud, create an account to evaluate how our products perform in real-world scenarios. New customers also get $300 in free credits to run, test, and deploy workloads.

2. In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

   Note: If you don't plan to keep the resources that you create in this procedure, create a project instead of selecting an existing project. After you finish these steps, you can delete the project, removing all resources associated with the project.

   Go to project selector

3. Make sure that billing is enabled for your Google Cloud project.

4. Enable the Cloud Functions, Cloud Run, Cloud Build, Artifact Registry, and Cloud Storage APIs.

   Enable the APIs

5. Install the Google Cloud CLI.

6. If you're using an external identity provider (IdP), you must first sign in to the gcloud CLI with your federated identity.

7. To initialize the gcloud CLI, run the following command:

   gcloud init

8. In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

   Note: If you don't plan to keep the resources that you create in this procedure, create a project instead of selecting an existing project. After you finish these steps, you can delete the project, removing all resources associated with the project.

   Go to project selector

9. Make sure that billing is enabled for your Google Cloud project.

10. Enable the Cloud Functions, Cloud Run, Cloud Build, Artifact Registry, and Cloud Storage APIs.

    Enable the APIs

11. Install the Google Cloud CLI.

12. If you're using an external identity provider (IdP), you must first sign in to the gcloud CLI with your federated identity.

13. To initialize the gcloud CLI, run the following command:

    gcloud init

Si ya tienes instalado gcloud CLI, ejecuta el siguiente comando para actualizarla:

gcloud components update

14. Prepara tu entorno de desarrollo.
    

    Ir a la guía de configuración de Node.js

Roles obligatorios

• Los usuarios que implementan funciones deben tener el rol de IAM Desarrollador de Cloud Functions (roles/cloudfunctions.developer) o un rol que incluya los mismos permisos. Consulta también Configuración adicional para la implementación.

• Para obtener los permisos de acceso al bucket de Cloud Storage, pídele a tu administrador que otorgue a la identidad de IAM que implementa la función el rol de Administrador de almacenamiento (roles/storage.admin). Si deseas obtener más detalles sobre los roles y los permisos de Cloud Storage, consulta IAM para Cloud Storage.

Configura tu entorno

En este instructivo, ejecutarás comandos en Cloud Shell. Cloud Shell es un entorno de shell con Google Cloud CLI ya instalada, incluida Google Cloud CLI, y valores ya establecidos para el proyecto actual. La inicialización de Cloud Shell puede tomar varios minutos:

Abra Cloud Shell

Prepara la aplicación

En Cloud Shell, sigue los siguientes pasos:

1. Clona el repositorio de la app de muestra en tu instancia de Cloud Shell:

   git clone https://github.com/terraform-google-modules/terraform-docs-samples.git

2. Ve al directorio que contiene los ejemplos de código de muestra de las funciones de Cloud Run:

   cd terraform-docs-samples/functions/basic

   La muestra de Node.js que se usa en este instructivo es una función HTTP “Hello World” básica. Este es el archivo main.tf:

   terraform {
     required_providers {
       google = {
         source  = "hashicorp/google"
         version = ">= 4.34.0"
       }
     }
   }
   
   resource "random_id" "default" {
     byte_length = 8
   }
   
   resource "google_storage_bucket" "default" {
     name                        = "${random_id.default.hex}-gcf-source" # Every bucket name must be globally unique
     location                    = "US"
     uniform_bucket_level_access = true
   }
   
   data "archive_file" "default" {
     type        = "zip"
     output_path = "/tmp/function-source.zip"
     source_dir  = "functions/hello-world/"
   }
   resource "google_storage_bucket_object" "object" {
     name   = "function-source.zip"
     bucket = google_storage_bucket.default.name
     source = data.archive_file.default.output_path # Add path to the zipped function source code
   }
   
   resource "google_cloudfunctions2_function" "default" {
     name        = "function-v2"
     location    = "us-central1"
     description = "a new function"
   
     build_config {
       runtime     = "nodejs22"
       entry_point = "helloHttp" # Set the entry point
       source {
         storage_source {
           bucket = google_storage_bucket.default.name
           object = google_storage_bucket_object.object.name
         }
       }
     }
   
     service_config {
       max_instance_count = 1
       available_memory   = "256M"
       timeout_seconds    = 60
     }
   }
   
   resource "google_cloud_run_service_iam_member" "member" {
     location = google_cloudfunctions2_function.default.location
     service  = google_cloudfunctions2_function.default.name
     role     = "roles/run.invoker"
     member   = "allUsers"
   }
   
   output "function_uri" {
     value = google_cloudfunctions2_function.default.service_config[0].uri
   }

Inicializa Terraform

En el directorio terraform-docs-samples/functions/basic que contiene el archivo main.tf, ejecuta este comando para agregar los complementos necesarios y compilar el directorio .terraform:

terraform init

Aplica la configuración de Terraform

En el mismo directorio terraform-docs-samples/functions/basic que contiene el archivo main.tf, aplica la configuración para implementar la función. Cuando se te solicite, ingresa yes.

terraform apply

Pruebe la función

1. Cuando la función termine de implementarse, toma nota de la propiedad URI o búscala con el siguiente comando:

   gcloud functions describe function-v2 --gen2 --region=us-central1 --format="value(serviceConfig.uri)"
   

2. Realiza una solicitud a esta URL para ver el mensaje “Hello World” de tu función. Ten en cuenta que la función se implementa con el requisito de autenticación. Por lo tanto, debes proporcionar credenciales en tu solicitud:

   curl -H "Authorization: Bearer $(gcloud auth print-identity-token)" YOUR_FUNCTION_URL

Nota: Por motivos de seguridad, se recomienda solicitar la autenticación para la invocación de la función de HTTP. Si es necesario, puedes habilitar la invocación no autenticada después de implementar la función.

Limpia

Después de completar el instructivo, puedes borrar todo lo que creaste para no incurrir en más costos.

Terraform te permite quitar todos los recursos definidos en el archivo de configuración mediante la ejecución del comando terraform destroy en el directorio terraform-docs-samples/functions/basic que contiene tu archivo main.tf:

terraform destroy

Ingresa yes para permitir que Terraform borre tus recursos.