Crea ambienti con Terraform

Cloud Composer 1 | Cloud Composer 2 | Cloud Composer 3

Questa pagina è un'integrazione della pagina principale su la creazione di ambienti. Spiega come impostare un Ambiente Cloud Composer e un account di servizio gestito dall'utente per questo ambiente in un progetto Google Cloud esistente Terraform. Puoi usare questa pagina come inizio, poi aggiungerne altre parametri di configurazione per il tuo ambiente, se necessario.

Prima di iniziare

• Questa guida presuppone che tu abbia un progetto Google Cloud con fatturazione configurata:

  • Puoi usare un progetto esistente.
  • Puoi creare un nuovo progetto utilizzando la console Google Cloud, Google Cloud CLI, l'API o una libreria client Python.
  • Puoi creare e gestire il progetto utilizzando Terraform. Per maggiori informazioni consulta la documentazione di Terraform per google_project.

• Installa gcloud CLI.

Autenticazione con Google Cloud

Per eseguire l'autenticazione con Google Cloud, esegui:

gcloud auth application-default login

Per ulteriori informazioni su questo comando, gcloud auth application-default

Configura il provider Google in Terraform

Specifica il tuo ID progetto esistente e una regione predefinita per le risorse. Il tuo Cloud Composer utilizza questa regione.

Nota: il provider google-beta supporta le funzionalità di Cloud Composer in anteprima. Se vuoi utilizzare solo le funzioni GA di Cloud Composer, usa il provider google anziché google-beta.

provider "google-beta" {
  project = "example-project"
  region  = "us-central1"
}

Abilita l'API Cloud Composer

Abilita l'API Cloud Composer nel tuo progetto:

resource "google_project_service" "composer_api" {
  provider = google-beta
  project = "example-project"
  service = "composer.googleapis.com"
  // Disabling Cloud Composer API might irreversibly break all other
  // environments in your project.
  // This parameter prevents automatic disabling
  // of the API when the resource is destroyed.
  // We recommend to disable the API only after all environments are deleted.
  disable_on_destroy = false
}

Crea un account di servizio personalizzato nel progetto

Per impostazione predefinita, gli ambienti Cloud Composer utilizzano il valore predefinito Compute Engine. Questa guida illustra un altro approccio, creando un nuovo account di servizio che dispone di tutte le autorizzazioni necessarie per eseguire nell'ambiente Cloud Composer.

Nota: questo account di servizio potrebbe richiedere autorizzazioni aggiuntive per accedere ad altri le risorse del tuo progetto. Ad esempio, se i DAG trasferiscono dati BigQuery, questo account potrebbe aver bisogno di autorizzazioni o ruoli specifici a BigQuery.

Definisci un account di servizio personalizzato con i ruoli e le autorizzazioni seguenti. Per Per ulteriori informazioni sulle autorizzazioni per gli account di servizio dell'ambiente, vedi Controllo dell'accesso con IAM.

resource "google_service_account" "custom_service_account" {
  provider = google-beta
  account_id   = "custom-service-account"
  display_name = "Example Custom Service Account"
}

resource "google_project_iam_member" "custom_service_account" {
  provider = google-beta
  project  = "example-project"
  member   = format("serviceAccount:%s", google_service_account.custom_service_account.email)
  // Role for Public IP environments
  role     = "roles/composer.worker"
}

Concedi le autorizzazioni necessarie all'account di servizio di Cloud Composer

Nota: per ulteriori informazioni su come Cloud Composer utilizza questo ruolo, vedi Concedi ruoli all'account dell'agente di servizio di Cloud Composer.

Aggiungi una nuova associazione dei ruoli all'account di servizio dell'ambiente criteri di autorizzazione.

Aggiungi l'account dell'agente di servizio Cloud Composer come nuova entità sull'account di servizio del tuo ambiente e concedi l'API Cloud Composer v2 il ruolo Estensione agente di servizio.

Se non usi Terraform per definire il criterio di autorizzazione del tuo progetto, non usare l'esempio che segue. Aggiungi invece questa associazione utilizzando altre di machine learning.

resource "google_service_account_iam_member" "custom_service_account" {
  provider = google-beta
  service_account_id = google_service_account.custom_service_account.name
  role = "roles/composer.ServiceAgentV2Ext"
  member = "serviceAccount:[e-mail]"
}

Creazione di un ambiente

Crea il tuo ambiente utilizzando Terraform.

L'esempio mostra come creare un ambiente che utilizza un modello l'account di servizio. Puoi aggiungere altri parametri che definiscono altre configurazioni parametri del tuo ambiente, come scalabilità e prestazioni personalizzate o altri pacchetti PyPI.

Per ulteriori informazioni su altri parametri, consulta Crea ambienti.

Attenzione: se utilizzi alias di versione in image_version, il tuo ambiente potrebbe eseguire l'upgrade a una versione quando esegui terraform apply. Per evitare che ciò accada, usa una versione specifica in questo parametro.

resource "google_composer_environment" "example_environment" {
  provider = google-beta
  name = "example-environment"

  config {

    software_config {
      image_version = "composer-2.8.6-airflow-2.7.3"
    }

    node_config {
      service_account = google_service_account.custom_service_account.email
    }

  }
}

Script Terraform completo (parametri predefiniti)

provider "google-beta" {
  project = "example-project"
  region  = "us-central1"
}

resource "google_project_service" "composer_api" {
  provider = google-beta
  project = "example-project"
  service = "composer.googleapis.com"
  // Disabling Cloud Composer API might irreversibly break all other
  // environments in your project.
  disable_on_destroy = false
}

resource "google_project_iam_member" "service_agent_role" {
  provider = google-beta
  project  = "example-project"
  member   = "serviceAccount:[e-mail]"
  role     = "roles/composer.ServiceAgentV2Ext"
}

resource "google_composer_environment" "example_environment" {
  provider = google-beta
  name = "example-environment"

  config {

    // Add your environment configuration here

    software_config {
      image_version = "composer-2.8.6-airflow-2.7.3"
    }

  }
}

Script Terraform completo (account di servizio personalizzato)

provider "google-beta" {
  project = "example-project"
  region  = "us-central1"
}

resource "google_project_service" "composer_api" {
  provider = google-beta
  project = "example-project"
  service = "composer.googleapis.com"
  // Disabling Cloud Composer API might irreversibly break all other
  // environments in your project.
  disable_on_destroy = false
}

resource "google_service_account" "custom_service_account" {
  provider = google-beta
  account_id   = "custom-service-account"
  display_name = "Example Custom Service Account"
}

resource "google_project_iam_member" "custom_service_account" {
  provider = google-beta
  project  = "example-project"
  member   = format("serviceAccount:%s", google_service_account.custom_service_account.email)
  // Role for Public IP environments
  role     = "roles/composer.worker"
}

resource "google_service_account_iam_member" "custom_service_account" {
  provider = google-beta
  service_account_id = google_service_account.custom_service_account.name
  role = "roles/composer.ServiceAgentV2Ext"
  member = "serviceAccount:[e-mail]"
}

resource "google_composer_environment" "example_environment" {
  provider = google-beta
  name = "example-environment"

  config {

    software_config {
      image_version = "composer-2.8.6-airflow-2.7.3"
    }

    node_config {
      service_account = google_service_account.custom_service_account.email
    }

  }
}

Passaggi successivi

Consulta le altre pagine della documentazione per informazioni sulla configurazione dell'ambiente con Terraform. Ad esempio:

• Crea ambienti
• Esegui l'override delle opzioni di configurazione di Airflow
• Impostare le variabili di ambiente
• Installa le dipendenze Python
• Ambienti di scalabilità