Configura un bucket di backend

Cloud CDN utilizza la tua scelta tra il bilanciatore del carico delle applicazioni esterno globale o il bilanciatore del carico delle applicazioni classico per fornire supporto per routing, controllo di integrità e supporto IP anycast. Poiché i bilanciatori del carico delle applicazioni esterni globali possono avere più istanza di backend backend (istanze VM di Compute Engine, pod di Google Kubernetes Engine, bucket Cloud Storage o backend esterni al di fuori di Google Cloud), puoi scegliere per quali backend (origini) abilitare Cloud CDN.

Questa guida alla configurazione mostra come creare un bilanciatore del carico delle applicazioni esterno con Cloud CDN abilitato. L'esempio utilizza le seguenti risorse:

• La rete Virtual Private Cloud (VPC) predefinita
• Una mappa URL predefinita
• Un indirizzo IP esterno riservato
• Un bucket Cloud Storage come backend.
• Un singolo bucket di backend del bilanciatore del carico che agisce da wrapper intorno al bucket Cloud Storage.

Un bucket di backend supporta quanto segue:

• Bucket Cloud Storage di qualsiasi classe di archiviazione, inclusi bucket multiregionali
• Criteri di Cloud CDN per la memorizzazione nella cache dei contenuti sul perimetro globale di Google

Per informazioni sul funzionamento di Cloud CDN, consulta la panoramica di Cloud CDN.

Per impostazione predefinita, Cloud Storage utilizza la stessa cache usata da Cloud CDN. Se abiliti Cloud CDN nel bucket di backend, puoi utilizzare i controlli di Cloud CDN sui tuoi contenuti. I controlli di Cloud CDN includono, ad esempio, modalità cache, URL firmati e invalidazioni. Cloud CDN consente anche di memorizzare nella cache contenuti di grandi dimensioni (> 10 MB). Se non abiliti Cloud CDN nel bucket di backend, puoi utilizzare solo le intestazioni origine Cache-Control per controllare la memorizzazione nella cache di contenuti più piccoli, come impostato dai metadati di Cloud Storage.

Backend bilanciatore del carico

Un bilanciatore del carico delle applicazioni esterno utilizza una mappa URL per indirizzare il traffico dagli URL specificati ai servizi specificati. La seguente tabella riassume i tipi di backend in cui puoi ospitare contenuti e servizi.

Configurazione del backend del bilanciatore del carico	Tipo di media tipico	Tipi di backend
Servizio di backend	Dinamico (ad es. dati)	Gruppi di istanze non gestite gruppi di istanze gestite Gruppi di endpoint di rete interni a Google Cloud Gruppi di endpoint di rete esterni a Google Cloud
Bucket di backend	Statico (ad esempio immagini)	Bucket Cloud Storage (esaminati in questa pagina)

Prima di iniziare

• Se utilizzi HTTPS per il frontend, crea un certificato SSL autogestito o gestito da Google. Ti consigliamo di utilizzare un certificato gestito da Google.
• Se utilizzi Google Cloud CLI, consulta Scopri l'archiviazione di oggetti con lo strumento gcloud per installarla.

• Imposta un progetto predefinito.

Console

Nota: per i bilanciatori del carico delle applicazioni esterni globali, la console Google Cloud non è supportata.

1. Nella console Google Cloud, vai alla home page.

   Vai alla home page di Google Cloud

2. A destra di Google Cloud, seleziona un progetto dal menu a discesa.

gcloud

     gcloud config set project PROJECT_ID
   

Sostituisci PROJECT_ID con l'ID del tuo progetto Google Cloud.

Terraform

    export GOOGLE_CLOUD_PROJECT=PROJECT_ID
   

Crea un bucket Cloud Storage

Se hai un bucket Cloud Storage esistente non ancora assegnato a un bilanciatore del carico, puoi andare al passaggio successivo.

Quando crei un bucket Cloud Storage da utilizzare come backend per un bilanciatore del carico delle applicazioni esterno con Cloud CDN, ti consigliamo di scegliere un bucket multiregionale, che replica automaticamente gli oggetti in più regioni Google Cloud. In questo modo puoi migliorare la disponibilità dei tuoi contenuti e la tolleranza agli errori in tutta l'applicazione.

Console

Nota: per i bilanciatori del carico delle applicazioni esterni globali, la console Google Cloud non è supportata.

1. Nella console Google Cloud, apri la pagina Bucket Cloud Storage.

   Apri la pagina Bucket

2. Fai clic su Crea bucket.

3. Specifica i valori per i campi nella seguente tabella lasciando le impostazioni predefinite per gli altri.

   Proprietà	Valore (digita il valore o seleziona un'opzione come specificato)
   Nome	Per ciascun bucket, inserisci un nome globalmente univoco. Se il nome che inserisci non è univoco, verrà visualizzato un messaggio che ti chiede di provare con un altro nome.
   Tipo di posizione	Più regioni
   Località	Seleziona una regione, ad esempio us (più regioni negli Stati Uniti).
   Classe di archiviazione predefinita	Standard
   Controllo dell'accesso	Uniforme

4. Fai clic su Crea.

5. Prendi nota del nome del bucket Cloud Storage appena creato per il passaggio successivo.

gcloud

gcloud storage buckets create gs://BUCKET_NAME --project=PROJECT_ID --default-storage-class=standard --location=us-east1 --uniform-bucket-level-access

Terraform

Per creare un bucket, utilizza la risorsa google_storage_bucket.

# Cloud Storage bucket
resource "random_id" "bucket_prefix" {
  byte_length = 8
}

resource "google_storage_bucket" "default" {
  name                        = "${random_id.bucket_prefix.hex}-my-bucket"
  location                    = "us-east1"
  uniform_bucket_level_access = true
  storage_class               = "STANDARD"
  // delete bucket and contents on destroy.
  force_destroy = true
  // Assign specialty files
  website {
    main_page_suffix = "index.html"
    not_found_page   = "404.html"
  }
}

Per scoprire come applicare o rimuovere una configurazione Terraform, vedi Comandi Terraform di base.

Copia un file grafico nel bucket Cloud Storage

Per consentirti di testare la configurazione, copia un file grafico da un bucket Cloud Storage pubblico al tuo bucket Cloud Storage.

gcloud

Esegui questo comando in Cloud Shell. Sostituisci BUCKET_NAME con il nome univoco del tuo bucket Cloud Storage:

gcloud storage cp gs://gcp-external-http-lb-with-bucket/three-cats.jpg gs://BUCKET_NAME/never-fetch/

Terraform

Per copiare l'oggetto, utilizza local-exec Provisioner con il comando gcloud storage cp.

resource "null_resource" "upload_image" {
  provisioner "local-exec" {
    command = "gcloud storage cp gs://gcp-external-http-lb-with-bucket/three-cats.jpg gs://${google_storage_bucket.default.name}/never-fetch/ --recursive"
  }
}

In alternativa, per caricare un oggetto, utilizza la risorsa google_storage_bucket_object.

# image object for testing, try to access http://<your_lb_ip_address>/test.jpg
resource "google_storage_bucket_object" "test_image" {
  name = "test-object"
  # Uncomment and add valid path to an object.
  #  source       = "/path/to/an/object"
  #  content_type = "image/jpeg"

  # Delete after uncommenting above source and content_type attributes
  content      = "Data as string to be uploaded"
  content_type = "text/plain"

  bucket = google_storage_bucket.default.name
}

Per scoprire come applicare o rimuovere una configurazione Terraform, vedi Comandi Terraform di base.

Nella console Google Cloud, fai clic su Aggiorna per verificare che il file grafico sia copiato.

Rendi pubblico il bucket Cloud Storage

Questo esempio rende il bucket Cloud Storage leggibile pubblicamente. Questo è l'approccio consigliato per i contenuti pubblici. Con questa impostazione, chiunque su internet può visualizzare ed elencare gli oggetti e i relativi metadati, esclusi gli ACL. Per ridurre il rischio di esposizione accidentale dei dati, in genere è consigliabile dedicare bucket Cloud Storage specifici agli oggetti pubblici.

Importante: quando gli oggetti vengono pubblicati da un bucket Cloud Storage pubblico, per impostazione predefinita viene applicata un'intestazione della risposta Cache-Control: public, max-age=3600. In questo modo gli oggetti possono essere memorizzati nella cache quando Cloud CDN è abilitato.

Le seguenti sono alternative per rendere pubblico un intero bucket Cloud Storage:

• Utilizza le cartelle gestite per rendere pubblica una parte di un bucket.

• Rendi i singoli oggetti leggibili pubblicamente all'interno di un bucket Cloud Storage. Sconsigliamo di usare questo approccio.

• Utilizza URL firmati.

La seguente procedura concede a tutti gli utenti l'accesso per visualizzare gli oggetti nel bucket Cloud Storage, rendendo il bucket leggibile pubblicamente.

Console

Nota: per i bilanciatori del carico delle applicazioni esterni globali, la console Google Cloud non è supportata.

1. Nella console Google Cloud, apri la pagina Bucket Cloud Storage.

   Apri la pagina Bucket

2. Vai al bucket e fai clic sulla scheda Autorizzazioni.
3. Fai clic su Aggiungi entità.
4. In Nuove entità, inserisci allUsers.
5. Per il ruolo, seleziona Cloud Storage > Visualizzatore oggetti Storage.
6. Fai clic su Salva.

gcloud

gcloud storage buckets add-iam-policy-binding gs://BUCKET_NAME --member=allUsers --role=roles/storage.objectViewer

Terraform

Per rendere pubblico il bucket Cloud Storage, utilizza la risorsa google_storage_bucket_iam_member.

# make bucket public
resource "google_storage_bucket_iam_member" "default" {
  bucket = google_storage_bucket.default.name
  role   = "roles/storage.objectViewer"
  member = "allUsers"
}

Per scoprire come applicare o rimuovere una configurazione Terraform, vedi Comandi Terraform di base.

Prenotare un indirizzo IP esterno

Ora che il bucket Cloud Storage è in esecuzione, configura un indirizzo IP esterno statico globale, utilizzato dai clienti per raggiungere il bilanciatore del carico.

Questo passaggio è facoltativo ma consigliato, perché un indirizzo IP esterno statico fornisce un unico indirizzo a cui puntare il dominio.

Nota: puoi saltare questo passaggio e chiedere a Google Cloud di associare un indirizzo IP temporaneo alla regola di forwarding del bilanciatore del carico. Un indirizzo IP temporaneo rimane costante finché esiste la regola di forwarding. Se devi eliminare la regola di forwarding e aggiungerla di nuovo, la regola di forwarding potrebbe ricevere un nuovo indirizzo IP.

Console

Nota: per i bilanciatori del carico delle applicazioni esterni globali, la console Google Cloud non è supportata.

1. Nella console Google Cloud, vai alla pagina Indirizzi IP esterni.

   Vai alla pagina Indirizzi IP esterni

2. Per prenotare un indirizzo IPv4, fai clic su Prenota indirizzo statico.
3. Assegna il nome di example-ip.
4. Imposta Network Service Tier su Premium.
5. Imposta la versione IP su IPv4.
6. Imposta il Tipo su Globale.
7. Fai clic su Prenota.

gcloud

gcloud compute addresses create example-ip \
    --network-tier=PREMIUM \
    --ip-version=IPV4 \
    --global

Prendi nota dell'indirizzo IPv4 riservato:

gcloud compute addresses describe example-ip \
    --format="get(address)" \
    --global

Terraform

Per prenotare un indirizzo IP, utilizza la risorsa google_compute_global_address.

# reserve IP address
resource "google_compute_global_address" "default" {
  name = "example-ip"
}

Per scoprire come applicare o rimuovere una configurazione Terraform, vedi Comandi Terraform di base.

Crea il bilanciatore del carico delle applicazioni esterno

In questa procedura, creerai il bucket di backend del bilanciatore del carico, che funge da wrapper per il tuo bucket Cloud Storage. Quando crei o modifichi un bucket di backend, puoi abilitare Cloud CDN.

Console

Avvia il processo di configurazione del bilanciatore del carico delle applicazioni esterno

1. Nella console Google Cloud, vai alla pagina Bilanciamento del carico.

   Vai alla pagina Bilanciamento del carico

2. In Bilanciamento del carico HTTP(S), fai clic su Avvia configurazione.
3. Seleziona Da internet alle mie VM e poi fai clic su Continua.
4. In Gestione avanzata del traffico, seleziona una delle seguenti opzioni:
   • Per i bilanciatori del carico delle applicazioni classici, seleziona Bilanciatore del carico HTTP(S) classico.
   • Per i bilanciatori del carico delle applicazioni esterni globali, seleziona Bilanciatore del carico HTTP(S) con gestione avanzata del traffico.
5. Imposta Nome su http-lb, quindi vai al passaggio successivo.

Configura il backend e abilita Cloud CDN

Crea il bucket di backend del bilanciatore del carico, che funge da wrapper per il bucket Cloud Storage. Quando crei o modifichi un bucket di backend, puoi abilitare Cloud CDN.

1. Fai clic su Configurazione backend.
2. In Servizi e bucket di backend, fai clic su Crea o seleziona servizi e bucket di backend, quindi fai clic su Bucket di backend > Crea un bucket di backend.
3. Imposta il Nome su cat-backend-bucket. Questo nome non deve essere univoco a livello globale e può essere diverso dal nome del bucket Cloud Storage effettivo.
4. In Bucket Cloud Storage, fai clic su Sfoglia.
5. Seleziona l'account Cloud Storage univoco a livello globale BUCKET_NAME che hai creato, quindi fai clic su Seleziona.

6. Fai clic su Abilita Cloud CDN.

   Importante: assicurati di selezionare Abilita Cloud CDN in questo passaggio. Se non lo fai, gli oggetti vengono pubblicati direttamente dal bucket Cloud Storage e non dalle cache CDN globali di Google.

7. (Facoltativo) Modifica le impostazioni modalità cache e TTL.

8. Fai clic su Crea.

Configura regole host e matcher percorso

Le regole host e i matcher percorso sono componenti di configurazione della mappa URL di un bilanciatore del carico delle applicazioni esterno.

In Regole host e percorso, puoi mantenere le impostazioni predefinite.

Per un esempio di configurazione personalizzata, consulta Aggiunta di bucket di backend ai bilanciatori del carico.

Per scoprire di più sulle regole dell'host e sui matcher percorso, consulta Panoramica delle mappe URL.

Configura il frontend

1. Fai clic su Configurazione frontend.

2. Verifica che le opzioni siano configurate con questi valori.

   Proprietà	Valore (digita un valore o seleziona un'opzione come specificato)
   Protocollo	HTTP
   Livello di servizio di rete	Premium
   Versione IP	IPv4
   Indirizzo IP	example-ip
   Porta	80

   Se vuoi creare un bilanciatore del carico HTTPS anziché un bilanciatore del carico HTTP, devi disporre di un certificato SSL (gcloud compute ssl-certificates list) e devi compilare i campi come segue.

   Proprietà	Valore (digita un valore o seleziona un'opzione come specificato)
   Protocollo	HTTPS
   Livello di servizio di rete	Premium
   Versione IP	IPv4
   Indirizzo IP	example-ip
   Porta	443
   Certificato	Seleziona un certificato o Crea un nuovo certificato

3. Fai clic su Fine.

Rivedi la configurazione

1. Fai clic su Esamina e finalizza.
2. Esamina le sezioni Bucket di backend, Regole host e percorso e Frontend.
3. Fai clic su Crea.
4. Attendi che la creazione del bilanciatore del carico sia completa.
5. Fai clic sul nome del bilanciatore del carico (http-lb).
6. Prendi nota dell'indirizzo IP del bilanciatore del carico, che utilizzerai nella prossima attività. Si chiama IP_ADDRESS.

gcloud

Configura il backend

gcloud compute backend-buckets create cat-backend-bucket \
    --gcs-bucket-name=BUCKET_NAME \
    --enable-cdn \
    --cache-mode=CACHE_MODE

Imposta la modalità cache sostituendo CACHE_MODE con uno dei seguenti valori:

• CACHE_ALL_STATIC o USE_ORIGIN_HEADERS: utilizza le intestazioni impostate in base ai metadati di controllo della cache in Cloud Storage. Cloud Storage fornisce sempre un'intestazione Cache-Control a Cloud CDN. Se non viene scelto esplicitamente un valore, ne viene inviato uno predefinito.

• FORCE_CACHE_ALL: memorizza nella cache tutti i contenuti, ignorando eventuali istruzioni private, no-store o no-cache nelle intestazioni delle risposte di Cache-Control inviate da Cloud Storage.

Configura la mappa URL

gcloud compute url-maps create http-lb \
    --default-backend-bucket=cat-backend-bucket

Configura il proxy di destinazione

gcloud compute target-http-proxies create http-lb-proxy \
    --url-map=http-lb

Configura la regola di forwarding

• Per un bilanciatore del carico delle applicazioni esterno globale, utilizza il comando gcloud CLI con load-balancing-scheme=EXTERNAL_MANAGED. Questa impostazione offre funzionalità di gestione avanzata del traffico.
• Per un bilanciatore del carico delle applicazioni classico, utilizza load-balancing-scheme=EXTERNAL.

gcloud compute forwarding-rules create http-lb-forwarding-rule \
    --load-balancing-scheme=LOAD_BALANCING_SCHEME \
    --network-tier=PREMIUM \
    --address=example-ip \
    --global \
    --target-http-proxy=http-lb-proxy \
    --ports=80

Terraform

Configura il backend

Per configurare il backend, utilizza la risorsa google_compute_backend_bucket.

# backend bucket with CDN policy with default ttl settings
resource "google_compute_backend_bucket" "default" {
  name        = "cat-backend-bucket"
  description = "Contains beautiful images"
  bucket_name = google_storage_bucket.default.name
  enable_cdn  = true
  cdn_policy {
    cache_mode        = "CACHE_ALL_STATIC"
    client_ttl        = 3600
    default_ttl       = 3600
    max_ttl           = 86400
    negative_caching  = true
    serve_while_stale = 86400
  }
}

Configura la mappa URL

Per configurare il backend, utilizza la risorsa google_compute_url_map.

# url map
resource "google_compute_url_map" "default" {
  name            = "http-lb"
  default_service = google_compute_backend_bucket.default.id
}

Configura il proxy di destinazione

Per configurare il proxy di destinazione, utilizza la risorsa google_compute_target_http_proxy o la risorsa google_compute_target_https_proxy.

# http proxy
resource "google_compute_target_http_proxy" "default" {
  name    = "http-lb-proxy"
  url_map = google_compute_url_map.default.id
}

Configura la regola di forwarding

Per configurare la regola di forwarding, utilizza la risorsa google_compute_global_forwarding_rule.

# forwarding rule
resource "google_compute_global_forwarding_rule" "default" {
  name                  = "http-lb-forwarding-rule"
  ip_protocol           = "TCP"
  load_balancing_scheme = "EXTERNAL"
  port_range            = "80"
  target                = google_compute_target_http_proxy.default.id
  ip_address            = google_compute_global_address.default.id
}

• Per un bilanciatore del carico delle applicazioni esterno globale, utilizza load_balancing_scheme="EXTERNAL_MANAGED". Questa impostazione offre funzionalità di gestione avanzata del traffico.
• Per un bilanciatore del carico delle applicazioni classico, utilizza load_balancing_scheme="EXTERNAL".

Per scoprire come applicare o rimuovere una configurazione Terraform, vedi Comandi Terraform di base.

Invia traffico al bucket di backend

Dopo aver creato la regola di forwarding globale, potrebbero essere necessari diversi minuti prima che la configurazione si propaghi a livello mondiale. Dopo alcuni minuti, puoi iniziare a inviare traffico all'indirizzo IP del bilanciatore del carico.

Console

Nota: per i bilanciatori del carico delle applicazioni esterni globali, la console Google Cloud non è supportata.

1. Nella console Google Cloud, vai alla pagina Bilanciamento del carico.

   Vai alla pagina Bilanciamento del carico

2. Fai clic su http-lb per espandere il bilanciatore del carico che hai appena creato.

   Nella sezione Backend, verifica che il bucket di backend sia integro. Dovresti vedere un segno di spunta verde accanto al bucket di backend. Se la risposta è diversa, prova innanzitutto a ricaricare la pagina. Possono essere necessari alcuni minuti prima che la console Google Cloud indichi che i backend sono in stato integro.

3. Quando la console Google Cloud indica che il bucket di backend è in stato integro, puoi testare il bilanciatore del carico utilizzando un browser web da http://IP_ADDRESS/never-fetch/three-cats.jpg. Sostituisci IP_ADDRESS con l'indirizzo IP del bilanciatore del carico. Il browser dovrebbe visualizzare una pagina con contenuti che mostrano il file grafico.

gcloud

Utilizza il comando curl per testare la risposta dall'URL. Sostituisci IP_ADDRESS con l'indirizzo IPv4 del bilanciatore del carico.

Prendi nota dell'indirizzo IPv4 riservato:

gcloud compute addresses describe example-ip \
    --format="get(address)" \
    --global

Invia una richiesta curl:

curl http://IP_ADDRESS/never-fetch/three-cats.jpg

Verificare il funzionamento di Cloud CDN

Se ricarichi la pagina http://IP_ADDRESS/never-fetch/three-cats.jpg diverse volte in rapida successione, dovrebbero essere presenti diversi hit della cache.

La seguente voce di log mostra un successo della cache. Puoi visualizzare i successi della cache nella console Google Cloud aprendo Esplora log e filtrando in base al nome della regola di forwarding.

Apri Esplora log

Nota: se non specifichi un nome per la regola di forwarding quando configuri il bilanciatore del carico, il nome della regola di forwarding è il nome del bilanciatore del carico più -forwarding-rule. In questo caso, http-lb-forwarding-rule.

Esplora log

{
    insertId: "1oek5rg3l3fxj7"
    jsonPayload: {
        @type: "type.googleapis.com/google.cloud.loadbalancing.type.LoadBalancerLogEntry"
        cacheId: "SFO-fbae48ad"
        statusDetails: "response_from_cache"
    }
    httpRequest: {
        requestMethod: "GET"
        requestUrl: "http://LOAD_BALANCER_IP_ADDRESS/never-fetch/three-cats.jpg"
        requestSize: "577"
        status: 254
        responseSize: "157"
        userAgent: "Mozilla/5.0 (Macintosh; Intel Mac OS X 10_14_6) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/83.0.4103.61 Safari/537.36"
        remoteIp: "CLIENT_IP_ADDRESS"
        cacheHit: true
        cacheLookup: true
    }
    resource: {
        type: "http_load_balancer"
        labels: {
            zone: "global"
            url_map_name: "URL_MAP_NAME"
            forwarding_rule_name: "FORWARDING_RULE_NAME"
            target_proxy_name: "TARGET_PROXY_NAME"
            backend_service_name: ""
            project_id: "PROJECT_ID"
        }
    }
    timestamp: "2020-06-08T23:41:25.078651Z"
    severity: "INFO"
    logName: "projects/PROJECT_ID/logs/requests"
    trace: "projects/PROJECT_ID/traces/241d69833e64b3bf83fabac8c873d992"
    receiveTimestamp: "2020-06-08T23:41:25.588272510Z"
    spanId: "7b6537d3672e08e1"
}

Console

Nota: per i bilanciatori del carico delle applicazioni esterni globali, la console Google Cloud non è supportata.

1. Nella console Google Cloud, vai alla pagina Bilanciamento del carico.

   Vai alla pagina Bilanciamento del carico

2. Fai clic su http-lb per espandere il bilanciatore del carico che hai appena creato.

   Nella sezione Backend, verifica che il bucket di backend sia integro. Dovresti vedere un segno di spunta verde accanto al bucket di backend. Se la risposta è diversa, prova innanzitutto a ricaricare la pagina. Possono essere necessari alcuni minuti prima che la console Google Cloud indichi che i backend sono in stato integro.

3. Quando la console Google Cloud indica che il bucket di backend è in stato integro, puoi testare il bilanciatore del carico utilizzando un browser web da http://IP_ADDRESS/never-fetch/three-cats.jpg. Sostituisci IP_ADDRESS con l'indirizzo IP del bilanciatore del carico. Il browser dovrebbe visualizzare una pagina con contenuti che mostrano il file grafico.

gcloud

Utilizza il comando curl per testare la risposta dall'URL. Sostituisci IP_ADDRESS con l'indirizzo IPv4 del bilanciatore del carico.

Prendi nota dell'indirizzo IPv4 riservato:

gcloud compute addresses describe example-ip \
    --format="get(address)" \
    --global

Invia una richiesta curl:

curl -D- -o /dev/null /dev/null http://IP_ADDRESS/never-fetch/three-cats.jpg

I contenuti vengono recuperati da Cloud Storage, memorizzati nella cache da Cloud CDN, quindi convalidati e recuperati di nuovo quando scadono o vengono altrimenti rimossi dalla cache.

I contenuti della cache hanno un'intestazione Age maggiore di zero.

I contenuti che devono essere aggiornati prima del TTL possono essere invalidati e recuperati di nuovo da Cloud Storage.

Disabilita Cloud CDN

Console

Nota: per i bilanciatori del carico delle applicazioni esterni globali, la console Google Cloud non è supportata.

Disabilita Cloud CDN per un singolo bucket di backend

1. Nella console Google Cloud, vai alla pagina Cloud CDN.

   Vai alla pagina di Cloud CDN

2. Sul lato destro della riga dell'origine, fai clic su Menu e seleziona Modifica.
3. Deseleziona le caselle di controllo dei bucket di backend che non vuoi più usare.
4. Fai clic su Update (Aggiorna).

Rimuovi Cloud CDN per tutti i bucket di backend per un'origine

1. Nella console Google Cloud, vai alla pagina Cloud CDN.

   Vai alla pagina di Cloud CDN

2. Sul lato destro della riga dell'origine, fai clic su Menu e seleziona Rimuovi.
3. Fai clic su Rimuovi per confermare.

gcloud

gcloud compute backend-buckets update BACKEND_BUCKET_NAME \
    --no-enable-cdn

La disabilitazione di Cloud CDN non annulla o elimina definitivamente le cache. Se disattivi e riattivi Cloud CDN, la maggior parte o tutti i contenuti memorizzati nella cache potrebbero comunque essere memorizzati nella cache. Per impedire che i contenuti vengano utilizzati dalle cache, devi invalidali.

Passaggi successivi

• Per informazioni sui contenuti memorizzati nella cache, consulta Panoramica della memorizzazione nella cache.
• Per utilizzare Cloud CDN in GKE, consulta Funzionalità Ingress.
• Per verificare se Cloud CDN fornisce risposte dalla cache, consulta Visualizzazione dei log.
• Per trovare informazioni sui problemi più comuni e le relative soluzioni, consulta la sezione Risoluzione dei problemi.
• Per configurare i criteri di filtro e controllo dell'accesso per i tuoi contenuti, consulta i criteri di sicurezza Edge.