Ops Agent

+

O agente de operações cria uma máquina virtual e instala o agente de operações para integração com os serviços de monitorização e registo. Usa:

• Compute Engine
• Monitorização
• Registo

O exemplo configura uma única máquina virtual simples e associa-a para comunicar ao Logging.

---

Começar

Clique no seguinte link para aceder a uma cópia do código fonte no Cloud Shell. Quando estiver lá, um único comando vai iniciar uma cópia funcional da aplicação no seu projeto.

Ponto-chave: se clicar no seguinte link, abre uma sessão do Cloud Shell e transfere código do GitHub. Tem de autorizar a execução do DeployStack. Não vão ser tomadas medidas até que o faça.

Veja o código fonte no GitHub

---

Componentes do Ops Agent

A arquitetura do agente de operações usa vários produtos. A lista seguinte apresenta os componentes, juntamente com mais informações sobre os componentes, incluindo links para vídeos relacionados, documentação do produto e visitas guiadas interativas.

			Vídeo	Docs	Instruções passo a passo
	Compute Engine	O Compute Engine é a tecnologia virtual do Google Cloud. Com ele, pode criar muitas configurações diferentes de VMs para se adequarem às suas necessidades de computação.
	Cloud Monitoring	O Cloud Monitoring expõe a visibilidade do desempenho, da disponibilidade e do estado das suas aplicações e infraestrutura
	Cloud Logging	O Cloud Logging oferece gestão de registos em tempo real totalmente gerida com armazenamento, pesquisa, análise e alertas à escala de exabytes.

---

Scripts

O script de instalação usa um executável escrito em go e ferramentas da CLI do Terraform para usar um projeto vazio e instalar a aplicação no mesmo. A saída deve ser uma aplicação funcional e um URL para o endereço IP de equilíbrio de carga.

Nota: segue-se uma discriminação dos comandos executados quando implementa o agente de operações. Não precisa de executar cada comando individualmente. Clique no botão Abrir no Cloud Shell na secção Introdução e execute todos os comandos.

./main.tf

Ative os serviços

Os serviços Google Cloud estão desativados num projeto por predefinição. Para usar qualquer uma das soluções aqui, temos de ativar o seguinte:

• Compute Engine: máquinas virtuais e redes

variable "gcp_service_list" {
    description = "The list of apis necessary for the project"
    type        = list(string)
    default = [
        "compute.googleapis.com",
    ]
}

resource "google_project_service" "all" {
  for_each                   = toset(var.gcp_service_list)
  project                    = var.project_number
  service                    = each.key
  disable_dependent_services = false
  disable_on_destroy         = false
}

Crie uma máquina virtual

Cria uma VM.

resource "google_compute_instance" "default" {
  project      = var.project_id
  name         = "${var.basename}-instance"
  machine_type = "f1-micro"
  zone         = var.zone

  boot_disk {
    initialize_params {
      image = "centos-cloud/centos-8-v20210817"
    }
  }
  labels = {
    env        = "prod"
    app        = "myproduct"
    created_by = "terraform"
  }

  network_interface {
    network = "default"

    access_config {
      // Include this section to give the VM an external ip address
    }
  }
  service_account {
    // Google recommends custom service accounts that have cloud-platform scope and permissions granted via IAM Roles.
    // This non production example uses the default compute service account.
    email  = local.sacompute
    scopes = ["cloud-platform"]
  }
}

Instale o Ops Agent

O agente de operações é o agente principal para recolher telemetria das suas instâncias do Compute Engine. Este artigo mostra-lhe como instalá-lo através do Terraform.

module "agent_policy" {
    source  = "terraform-google-modules/cloud-operations/google//modules/agent-policy"
    version = "~> 0.1.0"
    
    project_id = var.project_id
    policy_id  = "ops-agents-example-policy"
    agent_rules = [
        {
        type               = "ops-agent"
        version            = "current-major"
        package_state      = "installed"
        enable_autoupgrade = true
        },
    ]
    group_labels = [
        {
        env        = "prod"
        app        = "myproduct"
        created_by = "terraform"
        }
    ]
    
    os_types = [
        {
        short_name = "centos"
        version    = "8"
        },
    ]
}

---

Conclusão

Depois de executado, deve ter uma VM configurada corretamente para registar eventos no Google Cloud Logging. Além disso, deve ter todo o código para modificar ou expandir esta solução de forma a adequar-se ao seu ambiente.