Servidor cliente NoSQL

+

O servidor cliente NoSQL configura e cria duas instâncias do Compute Engine:

• Servidor, que vai executar o MongoDB
• Cliente: que executa uma aplicação Go personalizada que comunica com o MongoDB e, em seguida, expõe uma API onde consome dados do MongoDB

---

Começar

Clique no seguinte link para aceder a uma cópia do código fonte no Cloud Shell. Quando estiver lá, um único comando vai iniciar uma cópia funcional da aplicação no seu projeto.

Ponto-chave: se clicar no seguinte link, abre uma sessão do Cloud Shell e transfere código do GitHub. Tem de autorizar a execução do DeployStack. Não vão ser tomadas medidas até que o faça.

Veja o código fonte no GitHub

---

Componentes de servidor cliente NoSQL

A arquitetura de servidor cliente NoSQL usa um produto essencial. O seguinte realça esse produto, juntamente com mais informações, incluindo links para vídeos relacionados, documentação do produto e explicações interativas.

			Vídeo	Docs	Instruções passo a passo
	Compute Engine	O Compute Engine é a tecnologia virtual do Google Cloud. Com ele, pode criar muitas configurações diferentes de VMs para se adequarem às suas necessidades de computação.

---

Scripts

O script de instalação usa um executável escrito em go e ferramentas da CLI do Terraform para usar um projeto vazio e instalar a aplicação no mesmo. A saída deve ser uma aplicação funcional e um URL para o endereço IP de equilíbrio de carga.

Nota: segue-se uma discriminação dos comandos executados quando implementa o servidor cliente NoSQL. Não precisa de executar cada comando individualmente. Clique no botão Abrir no Cloud Shell na secção Introdução e execute todos os comandos.

./main.tf

Ative os serviços

Os serviços Google Cloud estão desativados num projeto por predefinição. Para usar qualquer uma das soluções aqui, temos de ativar o seguinte:

• Compute Engine: máquinas virtuais e redes

variable "gcp_service_list" {
    description = "The list of apis necessary for the project"
    type        = list(string)
    default = [
        "compute.googleapis.com",
    ]
}

resource "google_project_service" "all" {
  for_each                   = toset(var.gcp_service_list)
  project                    = var.project_number
  service                    = each.key
  disable_dependent_services = false
  disable_on_destroy         = false
}

Crie uma regra de firewall

Cria uma regra que abre a porta 80 na firewall e, em seguida, aplica-a a qualquer máquina etiquetada como http-server

resource "google_compute_firewall" "default-allow-http" {
  name    = "deploystack-allow-http"
  project = var.project_number
  network = "projects/${var.project_id}/global/networks/default"

  allow {
    protocol = "tcp"
    ports    = ["80"]
  }

  source_ranges = ["0.0.0.0/0"]

  target_tags = ["http-server"]
}

Crie uma instância de servidor

Inicia uma VM que funciona como o servidor e disponibiliza o MongoDB

# Create Instances
resource "google_compute_instance" "server" {
  name         = "server"
  zone         = var.zone
  project      = var.project_id
  machine_type = "e2-standard-2"
  tags         = ["http-server"]


  boot_disk {
    auto_delete = true
    device_name = "server"
    initialize_params {
      image = "family/ubuntu-1804-lts"
      size  = 10
      type  = "pd-standard"
    }
  }

  network_interface {
    network = "default"
    access_config {
      // Ephemeral public IP
    }
  }

  metadata_startup_script = <<SCRIPT
    apt-get update
    apt-get install -y mongodb
    service mongodb stop
    sed -i 's/bind_ip = 127.0.0.1/bind_ip = 0.0.0.0/' /etc/mongodb.conf
    iptables -t nat -A PREROUTING -p tcp --dport 80 -j REDIRECT --to-port 27017
    service mongodb start
  SCRIPT
  depends_on              = [google_project_service.all]
}

Crie uma instância de cliente

Cria uma VM que vai atuar como cliente e consumir dados do MongoDB

resource "google_compute_instance" "client" {
  name         = "client"
  zone         = var.zone
  project      = var.project_id
  machine_type = "e2-standard-2"
  tags         = ["http-server", "https-server"]

  boot_disk {
    auto_delete = true
    device_name = "client"
    initialize_params {
      image = "family/ubuntu-1804-lts"
      size  = 10
      type  = "pd-standard"
    }
  }

  network_interface {
    network = "default"

    access_config {
      // Ephemeral public IP
    }
  }

  metadata_startup_script = <<SCRIPT
    add-apt-repository ppa:longsleep/golang-backports -y && \
    apt update -y && \
    apt install golang-go -y
    mkdir /modcache
    mkdir /go
    mkdir /app && cd /app
    curl https://raw.githubusercontent.com/GoogleCloudPlatform/golang-samples/main/compute/quickstart/compute_quickstart_sample.go --output main.go
    go mod init exec
    GOPATH=/go GOMODCACHE=/modcache GOCACHE=/modcache go mod tidy
    GOPATH=/go GOMODCACHE=/modcache GOCACHE=/modcache go get -u 
    sed -i 's/mongoport = "80"/mongoport = "27017"/' /app/main.go
    echo "GOPATH=/go GOMODCACHE=/modcache GOCACHE=/modcache HOST=${google_compute_instance.server.network_interface.0.network_ip} go run main.go"
    GOPATH=/go GOMODCACHE=/modcache GOCACHE=/modcache HOST=${google_compute_instance.server.network_interface.0.network_ip} go run main.go &
  SCRIPT

  depends_on = [google_project_service.all]
}

---

Conclusão

Depois de executado, deve ter uma API de servidor cliente a usar o MongoDB em execução em duas instâncias do Compute Engine. Além disso, deve ter todo o código para modificar ou expandir esta solução de forma a adequar-se ao seu ambiente.