Tutorial do Pub/Sub no Terraform

---

Observação: este conteúdo se aplica apenas às funções do Cloud Run, anteriormente chamadas de Cloud Functions (2ª geração).

Neste tutorial, você vai aprender a implantar uma função do Pub/Sub fazendo upload de um arquivo ZIP do código-fonte da função em um bucket do Cloud Storage usando o Terraform para provisionar os recursos. O Terraform é uma ferramenta de código aberto que permite provisionar Google Cloud recursos com arquivos de configuração declarativos.

Neste tutorial, usamos uma função Node.js como exemplo, mas ela também funciona com funções Python, Go e Java. As instruções são as mesmas, independentemente do ambiente de execução usado. Consulte as páginas de referência do Hashicorp para mais detalhes sobre como usar o Terraform com a API Cloud Functions v2.

Objetivos

• Saiba como usar o Terraform para implantar uma função Pub/Sub.

Custos

Neste documento, você usará os seguintes componentes faturáveis do Google Cloud:

• Cloud Run functions
• Cloud Build
• Cloud Storage
• Artifact Registry

For details, see Cloud Run functions pricing.

Para gerar uma estimativa de custo baseada na projeção de uso deste tutorial, use a calculadora de preços. Novos usuários do Google Cloud podem estar qualificados para uma avaliação gratuita.

Antes de começar

1. Sign in to your Google Cloud account. If you're new to Google Cloud, create an account to evaluate how our products perform in real-world scenarios. New customers also get $300 in free credits to run, test, and deploy workloads.

2. In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

   Note: If you don't plan to keep the resources that you create in this procedure, create a project instead of selecting an existing project. After you finish these steps, you can delete the project, removing all resources associated with the project.

   Go to project selector

3. Make sure that billing is enabled for your Google Cloud project.

4. Enable the Cloud Functions, Cloud Build, Artifact Registry, and Cloud Storage APIs.

   Enable the APIs

5. Install the Google Cloud CLI.

6. To initialize the gcloud CLI, run the following command:

   gcloud init

7. In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

   Note: If you don't plan to keep the resources that you create in this procedure, create a project instead of selecting an existing project. After you finish these steps, you can delete the project, removing all resources associated with the project.

   Go to project selector

8. Make sure that billing is enabled for your Google Cloud project.

9. Enable the Cloud Functions, Cloud Build, Artifact Registry, and Cloud Storage APIs.

   Enable the APIs

10. Install the Google Cloud CLI.

11. To initialize the gcloud CLI, run the following command:

    gcloud init

Se a gcloud CLI já estiver instalada, atualize-a executando o seguinte comando:

gcloud components update

12. Conceda roles/run.invoker e o roles/cloudbuild.builds.builder à conta de serviço de computação padrão.
13. Prepare seu ambiente de desenvolvimento.
    

    Acessar o guia de configuração do Node.js

Como configurar o ambiente

Neste tutorial, você executa comandos no Cloud Shell. O Cloud Shell é um ambiente com a Google Cloud CLI pré-instalada, incluindo a Google Cloud CLI e os valores já definidos para o projeto atual. O Cloud Shell pode demorar vários minutos para ser inicializado.

Abra o Cloud Shell

Como preparar o aplicativo

No Cloud Shell, execute as seguintes etapas:

1. Clone o repositório de aplicativos de amostra para sua instância do Cloud Shell:

   git clone https://github.com/GoogleCloudPlatform/nodejs-docs-samples.git

2. Mude para o diretório que contém o código de amostra das funções do Cloud Run:

   cd nodejs-docs-samples/functions/v2/helloPubSub/

   A amostra Node.js usada neste tutorial é uma função básica do Pub/Sub "Hello World".

3. Crie um arquivo ZIP com o código-fonte da função que o Terraform enviará para um bucket do Cloud Storage:

   zip -r function-source.zip .

   A raiz do arquivo ZIP precisa ser o diretório raiz do código-fonte da função. Portanto, o comando acima inclui os arquivos no diretório helloworld, mas não inclui o próprio diretório.

   Observação: para produção, recomendamos incluir apenas arquivos de origem de função necessários.

Crie seu arquivo main.tf.

1. No diretório nodejs-docs-samples/functions/, crie um arquivo main.tf para a configuração do Terraform:

   touch main.tf
   

2. Copie esta configuração do Terraform para seu arquivo main.tf:

   terraform {
     required_providers {
       google = {
         source  = "hashicorp/google"
         version = ">= 4.34.0"
       }
     }
   }
   
   resource "random_id" "bucket_prefix" {
     byte_length = 8
   }
   
   
   resource "google_service_account" "default" {
     account_id   = "test-gcf-sa"
     display_name = "Test Service Account"
   }
   
   resource "google_pubsub_topic" "default" {
     name = "functions2-topic"
   }
   
   resource "google_storage_bucket" "default" {
     name                        = "${random_id.bucket_prefix.hex}-gcf-source" # Every bucket name must be globally unique
     location                    = "US"
     uniform_bucket_level_access = true
   }
   
   data "archive_file" "default" {
     type        = "zip"
     output_path = "/tmp/function-source.zip"
     source_dir  = "function-source/"
   }
   
   resource "google_storage_bucket_object" "default" {
     name   = "function-source.zip"
     bucket = google_storage_bucket.default.name
     source = data.archive_file.default.output_path # Path to the zipped function source code
   }
   
   resource "google_cloudfunctions2_function" "default" {
     name        = "function"
     location    = "us-central1"
     description = "a new function"
   
     build_config {
       runtime     = "nodejs16"
       entry_point = "helloPubSub" # Set the entry point
       environment_variables = {
         BUILD_CONFIG_TEST = "build_test"
       }
       source {
         storage_source {
           bucket = google_storage_bucket.default.name
           object = google_storage_bucket_object.default.name
         }
       }
     }
   
     service_config {
       max_instance_count = 3
       min_instance_count = 1
       available_memory   = "256M"
       timeout_seconds    = 60
       environment_variables = {
         SERVICE_CONFIG_TEST = "config_test"
       }
       ingress_settings               = "ALLOW_INTERNAL_ONLY"
       all_traffic_on_latest_revision = true
       service_account_email          = google_service_account.default.email
     }
   
     event_trigger {
       trigger_region = "us-central1"
       event_type     = "google.cloud.pubsub.topic.v1.messagePublished"
       pubsub_topic   = google_pubsub_topic.default.id
       retry_policy   = "RETRY_POLICY_RETRY"
     }
   }

3. Edite o arquivo main.tf para garantir que ele tenha os valores corretos dos itens a seguir. Você precisa editar esse arquivo sempre que a configuração mudar (por exemplo, para usar um ambiente de execução diferente ou implantar uma função diferente):

   • Ambiente de execução: neste exemplo, o ambiente de execução é nodejs16.
   • Ponto de entrada da função: neste exemplo, o ponto de entrada da função é helloPubSub.
   • Caminho para o arquivo ZIP: neste exemplo, se você colocou o arquivo main.tf no diretório nodejs-docs-samples/functions/, conforme descrito acima, o caminho é ./v2/helloPubSub/function-source.zip.

Observação: o arquivo main.tf precisa gerar um nome de bucket exclusivo sempre que a configuração for aplicada. No entanto, se você receber o erro "O recurso já existe", edite main.tf para fornecer um nome de bucket diferente que vai ser totalmente exclusivo.

Inicialize o Terraform

1. No Cloud Shell, execute o seguinte comando para inicializar o Terraform:

   docker run -v $(pwd):/app -w /app hashicorp/terraform:0.12.0 init
   

   A imagem de Docker pública do Terraform será usada. O Docker já está instalado no Cloud Shell. O diretório de trabalho atual é montado como um volume para que o contêiner do Docker possa ler o arquivo de configuração do Terraform.

2. Execute este comando para adicionar os plug-ins necessários e criar o diretório .terraform:

   terraform init
   

Validar a configuração do Terraform

Visualizar a configuração do Terraform. Essa etapa é opcional, mas permite verificar se a sintaxe de main.tf está correta. Este comando mostra uma prévia dos recursos que serão criados:

terraform plan

Aplique a configuração do Terraform:

Implante a função aplicando a configuração. Quando solicitado, digite yes.

terraform apply

Como acionar a função

Para testar a função do Pub/Sub:

1. Publique uma mensagem no tópico. Neste exemplo, o nome do tópico é functions2-topic:

   gcloud pubsub topics publish TOPIC_NAME --message="Friend"

2. Leia os registros da função para ver o resultado, em que FUNCTION_NAME é o nome da função. Neste exemplo, o nome da função é apenas function:

   gcloud beta functions logs read FUNCTION_NAME --gen2

   Você verá a saída de geração de registros que inclui a nova mensagem "Friend".

   Observação: os registros podem demorar alguns instantes para aparecer. Se eles não aparecerem imediatamente, verifique outra vez em um minuto ou dois.

Limpar

Depois de concluir o tutorial, exclua tudo o que foi criado para que você não tenha custos adicionais.

O Terraform permite remover todos os recursos definidos no arquivo de configuração executando o comando terraform destroy:

terraform destroy

Digite yes para permitir que o Terraform exclua seus recursos.