使用 Terraform 创建环境

Cloud Composer 3 | Cloud Composer 2 | Cloud Composer 1

本页是介绍创建环境的主页面的补充内容。该教程演示了如何使用 Terraform 在现有 Google Cloud 项目中为此环境设置 Cloud Composer 环境和用户代管式服务账号。您可以先使用此页面，然后根据需要为您的环境添加更多配置参数。

Cloud Composer 专用 Terraform 模块简介

Google 维护适用于 Google Cloud的 Terraform 提供程序，其中包括 google_composer_environment 资源。这是 Terraform 的官方支持模块。

还有其他由开源社区维护的 Terraform 模块。如需解决此类模块的问题，您可以在 GitHub 上的相应代码库中创建问题。terraform-google-composer 模块就是一个在 GitHub 上维护的开源项目的示例，该模块属于适用于 Google Cloud的 Terraform 蓝图和模块。虽然 Google 为此项目做出了贡献，但该模块并非由 Google 维护，也不与 Google Cloud的 Terraform 提供程序相关。

准备工作

  • 本指南假定您有一个 Google Cloud 已配置结算系统的项目：

    • 您可以使用现有项目。
    • 您可以使用 Google Cloud 控制台、Google Cloud CLI、API 或 Python 客户端库创建新项目。
    • 您可以使用 Terraform 创建和管理项目。如需了解详情，请参阅 google_project 资源的 Terraform 文档。

  • 安装 gcloud CLI。

使用 Google Cloud进行身份验证

如需使用 Google Cloud进行身份验证，请运行以下命令：

gcloud auth application-default login

如需详细了解此命令，请参阅 gcloud auth application-default。

在 Terraform 中配置 Google 提供程序

指定现有的项目 ID 和资源的默认区域。您的 Cloud Composer 环境使用此区域。

google-beta 提供程序支持处于预览版阶段的 Cloud Composer 功能。如果您只想使用 Cloud Composer 的 GA 功能，请使用 google 提供程序，而不是 google-beta。

provider "google-beta" {
  project = "example-project"
  region  = "us-central1"
}

启用 Cloud Composer API

在您的项目中启用 Cloud Composer API：

resource "google_project_service" "composer_api" {
  provider = google-beta
  project = "example-project"
  service = "composer.googleapis.com"
  // Disabling Cloud Composer API might irreversibly break all other
  // environments in your project.
  // This parameter prevents automatic disabling
  // of the API when the resource is destroyed.
  // We recommend to disable the API only after all environments are deleted.
  disable_on_destroy = false
  // this flag is introduced in 5.39.0 version of Terraform. If set to true it will
  //prevent you from disabling composer_api through Terraform if any environment was
  //there in the last 30 days
  check_if_service_has_usage_on_destroy = true
}

在项目中创建环境的服务账号

本指南演示了如何创建环境的服务账号，该账号具有运行 Cloud Composer 环境所需的所有权限。

我们强烈建议您为 Cloud Composer 环境设置用户代管式服务，该账号仅具有在 DAG 中运行环境和操作所需的权限，如本指南中所述。

虽然我们不建议使用此方法，但如果您未指定环境的服务账号，则 Cloud Composer 环境将使用默认的 Compute Engine 服务账号。

您的环境的服务账号可能需要额外的权限才能访问项目中的其他资源。例如，如果您的 DAG 将数据转移到 BigQuery，此账号可能需要 BigQuery 专有的权限或角色。

定义具有以下角色和权限的自定义服务账号：

resource "google_service_account" "custom_service_account" {
  provider = google-beta
  account_id   = "custom-service-account"
  display_name = "Example Custom Service Account"
}

resource "google_project_iam_member" "custom_service_account" {
  provider = google-beta
  project  = "example-project"
  member   = format("serviceAccount:%s", google_service_account.custom_service_account.email)
  // Role for Public IP environments
  role     = "roles/composer.worker"
}

创建环境

使用 Terraform 创建环境。

该示例演示了如何创建使用自定义服务账号的环境。您可以添加更多参数来定义环境的其他配置参数，例如自定义规模和性能参数或其他 PyPI 软件包。

如需详细了解其他参数，请参阅创建环境。

resource "google_composer_environment" "example_environment" {
  provider = google-beta
  name = "example-environment"

  config {

    software_config {
      image_version = "composer-1.20.12-airflow-1.10.15"
    }

    node_config {
      service_account = google_service_account.custom_service_account.email
    }

  }
}

完整 Terraform 脚本

provider "google-beta" {
  project = "example-project"
  region  = "us-central1"
}

resource "google_project_service" "composer_api" {
  provider = google-beta
  project = "example-project"
  service = "composer.googleapis.com"
  // Disabling Cloud Composer API might irreversibly break all other
  // environments in your project.
  disable_on_destroy = false
  // this flag is introduced in 5.39.0 version of Terraform. If set to true it will
  //prevent you from disabling composer_api through Terraform if any environment was
  //there in the last 30 days
  check_if_service_has_usage_on_destroy = true
}

resource "google_service_account" "custom_service_account" {
  provider = google-beta
  account_id   = "custom-service-account"
  display_name = "Example Custom Service Account"
}

resource "google_project_iam_member" "custom_service_account" {
  provider = google-beta
  project  = "example-project"
  member   = format("serviceAccount:%s", google_service_account.custom_service_account.email)
  // Role for Public IP environments
  role     = "roles/composer.worker"
}

resource "google_composer_environment" "example_environment" {
  provider = google-beta
  name = "example-environment"

  config {

    software_config {
      image_version = "composer-1.20.12-airflow-1.10.15"
    }

    node_config {
      service_account = google_service_account.custom_service_account.email
    }

  }
}

后续步骤

如需了解如何使用 Terraform 配置环境，请参阅其他文档页面。例如：