Servidor cliente NoSQL

El servidor de cliente NoSQL configurará y creará dos instancias de Compute Engine:

• Server: Ejecutará MongoDB.
• Cliente: Ejecuta la aplicación personalizada de Go que se comunica con MongoDB y, luego, expone una API en la que consumes datos de MongoDB.

---

Comenzar

Haz clic en el siguiente vínculo para obtener una copia del código fuente en Cloud Shell. Una vez ahí, un solo comando iniciará una copia de trabajo de la aplicación en tu proyecto...

Punto clave: Si haces clic en el siguiente vínculo, se abrirá una sesión de Cloud Shell. descargar el código de GitHub. Deberás autorizar a DeployStack para que se ejecute. No se realizarán acciones hasta que lo hagas.

Consulta el código fuente en GitHub

---

Componentes de NoSQL Client Server

La arquitectura de servidor cliente NoSQL utiliza un producto clave. Lo siguiente destaca ese producto, junto con más información, incluidos vínculos a videos relacionados, documentación del producto y videos instructivos.

			Video	Documentos	Explicaciones
	Compute Engine	Compute Engine es la tecnología virtual de Google Cloud. Con él, puedes iniciar muchas configuraciones diferentes de VM para que se adapten a cualquier necesidad de procesamiento que tengas.

---

Secuencias de comandos

La secuencia de comandos de instalación usa un ejecutable escrito en go y las herramientas de la CLI de Terraform para tomar un proyecto vacío y, luego, instalar la aplicación en él. El resultado debe ser una y una URL para la dirección IP del balanceo de cargas.

Nota: A continuación, se presenta un desglose de los comandos que se ejecutan cuando se implementa un servidor cliente NoSQL. No es necesario que ejecutes cada comando de forma individual. Haz clic en el botón Abrir en Cloud Shell de la sección Primeros pasos y ejecuta todos los comandos.

./main.tf

Habilitar servicios

Los servicios de Google Cloud están inhabilitados en un proyecto de forma predeterminada. Para usar cualquier de estas soluciones, debemos activar lo siguiente:

• Compute Engine: Máquinas virtuales y redes

variable "gcp_service_list" {
    description = "The list of apis necessary for the project"
    type        = list(string)
    default = [
        "compute.googleapis.com",
    ]
}

resource "google_project_service" "all" {
  for_each                   = toset(var.gcp_service_list)
  project                    = var.project_number
  service                    = each.key
  disable_dependent_services = false
  disable_on_destroy         = false
}

Crear regla de firewall

Crea una regla que abre el puerto 80 en el firewall y, luego, la aplica a cualquier máquina etiquetada como http-server

resource "google_compute_firewall" "default-allow-http" {
  name    = "deploystack-allow-http"
  project = var.project_number
  network = "projects/${var.project_id}/global/networks/default"

  allow {
    protocol = "tcp"
    ports    = ["80"]
  }

  source_ranges = ["0.0.0.0/0"]

  target_tags = ["http-server"]
}

Crear instancia de servidor

Inicia una VM que actuará como el servidor y entrega MongoDB.

# Create Instances
resource "google_compute_instance" "server" {
  name         = "server"
  zone         = var.zone
  project      = var.project_id
  machine_type = "e2-standard-2"
  tags         = ["http-server"]


  boot_disk {
    auto_delete = true
    device_name = "server"
    initialize_params {
      image = "family/ubuntu-1804-lts"
      size  = 10
      type  = "pd-standard"
    }
  }

  network_interface {
    network = "default"
    access_config {
      // Ephemeral public IP
    }
  }

  metadata_startup_script = <<SCRIPT
    apt-get update
    apt-get install -y mongodb
    service mongodb stop
    sed -i 's/bind_ip = 127.0.0.1/bind_ip = 0.0.0.0/' /etc/mongodb.conf
    iptables -t nat -A PREROUTING -p tcp --dport 80 -j REDIRECT --to-port 27017
    service mongodb start
  SCRIPT
  depends_on              = [google_project_service.all]
}

Crear instancia de cliente

Inicia una VM que actuará como el cliente y consumirá datos de MongoDB.

resource "google_compute_instance" "client" {
  name         = "client"
  zone         = var.zone
  project      = var.project_id
  machine_type = "e2-standard-2"
  tags         = ["http-server", "https-server"]

  boot_disk {
    auto_delete = true
    device_name = "client"
    initialize_params {
      image = "family/ubuntu-1804-lts"
      size  = 10
      type  = "pd-standard"
    }
  }

  network_interface {
    network = "default"

    access_config {
      // Ephemeral public IP
    }
  }

  metadata_startup_script = <<SCRIPT
    add-apt-repository ppa:longsleep/golang-backports -y && \
    apt update -y && \
    apt install golang-go -y
    mkdir /modcache
    mkdir /go
    mkdir /app && cd /app
    curl https://raw.githubusercontent.com/GoogleCloudPlatform/golang-samples/main/compute/quickstart/compute_quickstart_sample.go --output main.go
    go mod init exec
    GOPATH=/go GOMODCACHE=/modcache GOCACHE=/modcache go mod tidy
    GOPATH=/go GOMODCACHE=/modcache GOCACHE=/modcache go get -u 
    sed -i 's/mongoport = "80"/mongoport = "27017"/' /app/main.go
    echo "GOPATH=/go GOMODCACHE=/modcache GOCACHE=/modcache HOST=${google_compute_instance.server.network_interface.0.network_ip} go run main.go"
    GOPATH=/go GOMODCACHE=/modcache GOCACHE=/modcache HOST=${google_compute_instance.server.network_interface.0.network_ip} go run main.go &
  SCRIPT

  depends_on = [google_project_service.all]
}

---

Conclusión

Una vez ejecutada, deberías tener una API de servidor de cliente que use MongoDB ejecutándose en dos instancias de Compute Engine. Además, debes contar con todo el código para modificar o ampliar esta solución de modo que se adapte a tu entorno.