Trigger mit Terraform erstellen

In diesem Dokument wird beschrieben, wie Sie mithilfe von Google Cloud-Ressourcen in Terraform Eventarc-Trigger mit den google_eventarc_trigger-Ressourcen für die folgenden Ziele erstellen:

• Cloud Run: Verwenden Sie die Terraform-Ressource google_cloud_run_v2_service.
• Google Kubernetes Engine: Verwenden Sie die Terraform-Ressource google_container_cluster.
• Workflows: Verwenden Sie die Terraform-Ressource google_workflows_workflow.

In den Beispielen dieser Anleitung werden direkte Ereignisse aus Cloud Storage verwendet. Sie können jedoch für jeden Ereignisanbieter angepasst werden. Für die Zwecke dieser Anleitung werden neue Ressourcen als Quelle von Ereignissen erstellt.

Ressourcen und Anleitungen zur Verwendung von Terraform finden Sie in der Dokumentation zu Terraform in Google Cloud.

Hinweise

1. Melden Sie sich bei Ihrem Google Cloud-Konto an. Wenn Sie mit Google Cloud noch nicht vertraut sind, erstellen Sie ein Konto, um die Leistungsfähigkeit unserer Produkte in der Praxis sehen und bewerten zu können. Neukunden erhalten außerdem ein Guthaben von 300 $, um Arbeitslasten auszuführen, zu testen und bereitzustellen.

2. Wählen Sie in der Google Cloud Console auf der Seite der Projektauswahl ein Google Cloud-Projekt aus oder erstellen Sie eines.

   Hinweis: Wenn Sie die Ressourcen, die Sie in diesem Verfahren erstellen, nicht behalten möchten, erstellen Sie ein Projekt, anstatt ein vorhandenes Projekt auszuwählen. Wenn Sie fertig sind, können Sie das Projekt löschen und dadurch alle mit dem Projekt verknüpften Ressourcen entfernen.

   Zur Projektauswahl

3. Die Abrechnung für das Google Cloud-Projekt muss aktiviert sein.

4. Wählen Sie in der Google Cloud Console auf der Seite der Projektauswahl ein Google Cloud-Projekt aus oder erstellen Sie eines.

   Hinweis: Wenn Sie die Ressourcen, die Sie in diesem Verfahren erstellen, nicht behalten möchten, erstellen Sie ein Projekt, anstatt ein vorhandenes Projekt auszuwählen. Wenn Sie fertig sind, können Sie das Projekt löschen und dadurch alle mit dem Projekt verknüpften Ressourcen entfernen.

   Zur Projektauswahl

5. Die Abrechnung für das Google Cloud-Projekt muss aktiviert sein.

6. Resource Manager and Identity and Access Management (IAM) APIs aktivieren.

   Aktivieren Sie die APIs

7. Aktivieren Sie Cloud Shell in der Google Cloud Console.

   Cloud Shell aktivieren

   Unten in der Google Cloud Console wird eine Cloud Shell-Sitzung gestartet und eine Eingabeaufforderung angezeigt. Cloud Shell ist eine Shell-Umgebung, in der das Google Cloud CLI bereits installiert ist und Werte für Ihr aktuelles Projekt bereits festgelegt sind. Das Initialisieren der Sitzung kann einige Sekunden dauern.

Cloud Shell ist eine Shell-Umgebung, in die Terraform bereits integriert ist.

Eventarc-Trigger erstellen

Sie können Eventarc-Trigger mit Terraform für verschiedene Ziele erstellen.

In diesem Beispiel wird die Interpolation für Substitutionen wie Referenzvariablen, Ressourcenattribute und Aufruffunktionen verwendet.

Cloud Run

Stellen Sie Ihre Ressourcen mit Cloud Shell mit Terraform bereit, um Eventarc-Trigger zu erstellen.

1. APIs aktivieren

Verwenden Sie den folgenden Code, um die erforderlichen APIs zu aktivieren:

# Enable Cloud Run API
resource "google_project_service" "run" {
  service            = "run.googleapis.com"
  disable_on_destroy = false
}

# Enable Eventarc API
resource "google_project_service" "eventarc" {
  service            = "eventarc.googleapis.com"
  disable_on_destroy = false
}

# Enable Pub/Sub API
resource "google_project_service" "pubsub" {
  service            = "pubsub.googleapis.com"
  disable_on_destroy = false
}

2. Dienstkonto erstellen und IAM konfigurieren

Verwenden Sie den folgenden Code, um ein dediziertes Dienstkonto und IAM-Rollen zu erstellen:

# Used to retrieve project information later
data "google_project" "project" {}

# Create a dedicated service account
resource "google_service_account" "eventarc" {
  account_id   = "eventarc-trigger-sa"
  display_name = "Eventarc Trigger Service Account"
}

# Grant permission to receive Eventarc events
resource "google_project_iam_member" "eventreceiver" {
  project = data.google_project.project.id
  role    = "roles/eventarc.eventReceiver"
  member  = "serviceAccount:${google_service_account.eventarc.email}"
}

# Grant permission to invoke Cloud Run services
resource "google_project_iam_member" "runinvoker" {
  project = data.google_project.project.id
  role    = "roles/run.invoker"
  member  = "serviceAccount:${google_service_account.eventarc.email}"
}

Wenn Sie den Pub/Sub-Dienst-Agent am oder vor dem 8. April 2021 aktiviert haben, weisen Sie dem von Google verwalteten Dienstkonto die Rolle iam.serviceAccountTokenCreator zu.

resource "google_project_iam_member" "tokencreator" {
   project  = data.google_project.project.id
   role     = "roles/iam.serviceAccountTokenCreator"
   member   = "serviceAccount:service-${data.google_project.project.number}@gcp-sa-pubsub.iam.gserviceaccount.com"
}

3. Cloud Storage-Bucket als Ereignisanbieter erstellen

Verwenden Sie den folgenden Code, um einen Cloud Storage-Bucket mit Eventarc-bezogenen Berechtigungen zu erstellen:

# Cloud Storage bucket names must be globally unique
resource "random_id" "bucket_name_suffix" {
  byte_length = 4
}

# Create a Cloud Storage bucket
resource "google_storage_bucket" "default" {
  name          = "trigger-cloudrun-${data.google_project.project.name}-${random_id.bucket_name_suffix.hex}"
  location      = google_cloud_run_v2_service.default.location
  force_destroy = true

  uniform_bucket_level_access = true
}

# Grant the Cloud Storage service account permission to publish pub/sub topics
data "google_storage_project_service_account" "gcs_account" {}
resource "google_project_iam_member" "pubsubpublisher" {
  project = data.google_project.project.id
  role    = "roles/pubsub.publisher"
  member  = "serviceAccount:${data.google_storage_project_service_account.gcs_account.email_address}"
}

4. Cloud Run-Dienst als Ereignisziel definieren

Erstellen Sie einen Cloud Run-Dienst als Ereignisziel für den Trigger. Verwenden Sie die Ressource google_cloud_run_v2_service, um einen Cloud Run-Dienst zu definieren:

# Deploy Cloud Run service
resource "google_cloud_run_v2_service" "default" {
  name     = "hello-events"
  location = "us-central1"

  template {
    containers {
      # This container will log received events
      image = "us-docker.pkg.dev/cloudrun/container/hello"
    }
    service_account = google_service_account.eventarc.email
  }

  depends_on = [google_project_service.run]
}

5. Eventarc-Trigger definieren

Ein Eventarc-Trigger verbindet den Ereignisanbieter mit einem Ereignisziel. Verwenden Sie die Ressource google_eventarc_trigger, um den direkten Ereignisanbieter von Cloud Storage zu definieren, der an ein Cloud Run-Ziel sendet.

Sie können mehrere matching_criteria mit CloudEvents-Attributen definieren, die von Eventarc unterstützt werden und die wie die event-filters funktionieren, die Sie beim Erstellen eines Triggers angeben. Weitere Informationen finden Sie in der Anleitung zum Erstellen eines Triggers für einen bestimmten Anbieter und Ereignistyp und ein bestimmtes Cloud Run-Ziel. Ereignisse, die mit allen Filtern übereinstimmen, werden an das Ziel gesendet.

# Create an Eventarc trigger, routing Cloud Storage events to Cloud Run
resource "google_eventarc_trigger" "default" {
  name     = "trigger-storage-cloudrun-tf"
  location = google_cloud_run_v2_service.default.location

  # Capture objects changed in the bucket
  matching_criteria {
    attribute = "type"
    value     = "google.cloud.storage.object.v1.finalized"
  }
  matching_criteria {
    attribute = "bucket"
    value     = google_storage_bucket.default.name
  }

  # Send events to Cloud Run
  destination {
    cloud_run_service {
      service = google_cloud_run_v2_service.default.name
      region  = google_cloud_run_v2_service.default.location
    }
  }

  service_account = google_service_account.eventarc.email
  depends_on = [
    google_project_service.eventarc,
    google_project_iam_member.pubsubpublisher
  ]
}

6. Änderungen anwenden

Informationen zum Anwenden oder Entfernen einer Terraform-Konfiguration finden Sie unter Grundlegende Terraform-Befehle.

Führen Sie die Schritte in den folgenden Abschnitten aus, um Ihre Terraform-Konfiguration auf ein Google Cloud-Projekt anzuwenden.

Cloud Shell vorbereiten

1. Rufen Sie Cloud Shell auf.

2. Legen Sie das Google Cloud-Standardprojekt fest, auf das Sie Ihre Terraform-Konfigurationen anwenden möchten.

   Sie müssen diesen Befehl nur einmal pro Projekt und in jedem beliebigen Verzeichnis ausführen.

   export GOOGLE_CLOUD_PROJECT=PROJECT_ID

   Umgebungsvariablen werden überschrieben, wenn Sie in der Terraform-Konfigurationsdatei explizite Werte festlegen.

Verzeichnis vorbereiten

Jede Terraform-Konfigurationsdatei muss ein eigenes Verzeichnis haben (auch als Stammmodul bezeichnet).

1. Erstellen Sie in Cloud Shell ein Verzeichnis und eine neue Datei in diesem Verzeichnis. Der Dateiname muss die Erweiterung .tf haben, z. B. main.tf. In dieser Anleitung wird die Datei als main.tf bezeichnet.

   mkdir DIRECTORY && cd DIRECTORY && touch main.tf

2. Wenn Sie einer Anleitung folgen, können Sie den Beispielcode in jedem Abschnitt oder Schritt kopieren.

   Kopieren Sie den Beispielcode in das neu erstellte main.tf.

   Kopieren Sie optional den Code aus GitHub. Dies wird empfohlen, wenn das Terraform-Snippet Teil einer End-to-End-Lösung ist.

3. Prüfen und ändern Sie die Beispielparameter, die auf Ihre Umgebung angewendet werden sollen.
4. Speichern Sie die Änderungen.
5. Initialisieren Sie Terraform. Dies ist nur einmal für jedes Verzeichnis erforderlich.

   terraform init

   Fügen Sie optional die Option -upgrade ein, um die neueste Google-Anbieterversion zu verwenden:

   terraform init -upgrade

Änderungen anwenden

1. Prüfen Sie die Konfiguration und prüfen Sie, ob die Ressourcen, die Terraform erstellen oder aktualisieren wird, Ihren Erwartungen entsprechen:

   terraform plan

   Korrigieren Sie die Konfiguration nach Bedarf.

2. Wenden Sie die Terraform-Konfiguration an. Führen Sie dazu den folgenden Befehl aus und geben Sie yes an der Eingabeaufforderung ein:

   terraform apply

   Warten Sie, bis Terraform die Meldung „Apply complete“ anzeigt.

3. Öffnen Sie Ihr Google Cloud-Projekt, um die Ergebnisse aufzurufen. Rufen Sie in der Google Cloud Console Ihre Ressourcen in der Benutzeroberfläche auf, um sicherzustellen, dass Terraform sie erstellt oder aktualisiert hat.

Hinweis: Bei Terraform-Beispielen wird in der Regel davon ausgegangen, dass die erforderlichen APIs in Ihrem Google Cloud-Projekt aktiviert sind.

Hinweis: Es kann ein paar Minuten dauern, bis alle erforderlichen Berechtigungen an den Eventarc-Dienst-Agent weitergegeben wurden. Wenn dieses Problem auftritt, warten Sie einige Minuten und führen Sie dann terraform apply noch einmal aus.

7. Erstellung von Ressourcen prüfen

So prüfen Sie, ob der Dienst erstellt wurde:

gcloud run services list --region us-central1

So prüfen Sie, ob der Trigger erstellt wurde:

gcloud eventarc triggers list --location us-central1

Die Ausgabe sollte in etwa so aussehen:

NAME: trigger-storage-cloudrun-tf
TYPE: google.cloud.storage.object.v1.finalized
DESTINATION: Cloud Run service: hello-events
ACTIVE: Yes
LOCATION: us-central1

Hinweis: Der Trigger wird zwar sofort erstellt, es kann jedoch bis zu zwei Minuten dauern, bis er wirksam wird und Ereignisse filtert.

GKE

Stellen Sie Ihre Ressourcen mit Cloud Shell mit Terraform bereit, um Eventarc-Trigger zu erstellen.

Für den Eventarc-Trigger ist ein Google Kubernetes Engine-Dienst erforderlich. Um diese Anleitung zu vereinfachen, konfigurieren Sie diesen Dienst außerhalb von Terraform, zwischen der Anwendung von Terraform-Konfigurationen.

1. GKE-Cluster erstellen

Verwenden Sie den folgenden Code, um die erforderlichen APIs zu aktivieren:

# Enable GKE API
resource "google_project_service" "container" {
  service            = "container.googleapis.com"
  disable_on_destroy = false
}

# Enable Eventarc API
resource "google_project_service" "eventarc" {
  service            = "eventarc.googleapis.com"
  disable_on_destroy = false
}

# Enable Pub/Sub API
resource "google_project_service" "pubsub" {
  service            = "pubsub.googleapis.com"
  disable_on_destroy = false
}

Erstellen Sie einen GKE-Cluster mit folgendem Code:

# Create an auto-pilot GKE cluster
resource "google_container_cluster" "gke_cluster" {
  name     = "eventarc-cluster"
  location = "us-central1"

  enable_autopilot = true

  depends_on = [
    google_project_service.container
  ]
}

2. Änderungen anwenden

Informationen zum Anwenden oder Entfernen einer Terraform-Konfiguration finden Sie unter Grundlegende Terraform-Befehle.

Führen Sie die Schritte in den folgenden Abschnitten aus, um Ihre Terraform-Konfiguration auf ein Google Cloud-Projekt anzuwenden.

Cloud Shell vorbereiten

1. Rufen Sie Cloud Shell auf.

2. Legen Sie das Google Cloud-Standardprojekt fest, auf das Sie Ihre Terraform-Konfigurationen anwenden möchten.

   Sie müssen diesen Befehl nur einmal pro Projekt und in jedem beliebigen Verzeichnis ausführen.

   export GOOGLE_CLOUD_PROJECT=PROJECT_ID

   Umgebungsvariablen werden überschrieben, wenn Sie in der Terraform-Konfigurationsdatei explizite Werte festlegen.

Verzeichnis vorbereiten

Jede Terraform-Konfigurationsdatei muss ein eigenes Verzeichnis haben (auch als Stammmodul bezeichnet).

1. Erstellen Sie in Cloud Shell ein Verzeichnis und eine neue Datei in diesem Verzeichnis. Der Dateiname muss die Erweiterung .tf haben, z. B. main.tf. In dieser Anleitung wird die Datei als main.tf bezeichnet.

   mkdir DIRECTORY && cd DIRECTORY && touch main.tf

2. Wenn Sie einer Anleitung folgen, können Sie den Beispielcode in jedem Abschnitt oder Schritt kopieren.

   Kopieren Sie den Beispielcode in das neu erstellte main.tf.

   Kopieren Sie optional den Code aus GitHub. Dies wird empfohlen, wenn das Terraform-Snippet Teil einer End-to-End-Lösung ist.

3. Prüfen und ändern Sie die Beispielparameter, die auf Ihre Umgebung angewendet werden sollen.
4. Speichern Sie die Änderungen.
5. Initialisieren Sie Terraform. Dies ist nur einmal für jedes Verzeichnis erforderlich.

   terraform init

   Fügen Sie optional die Option -upgrade ein, um die neueste Google-Anbieterversion zu verwenden:

   terraform init -upgrade

Änderungen anwenden

1. Prüfen Sie die Konfiguration und prüfen Sie, ob die Ressourcen, die Terraform erstellen oder aktualisieren wird, Ihren Erwartungen entsprechen:

   terraform plan

   Korrigieren Sie die Konfiguration nach Bedarf.

2. Wenden Sie die Terraform-Konfiguration an. Führen Sie dazu den folgenden Befehl aus und geben Sie yes an der Eingabeaufforderung ein:

   terraform apply

   Warten Sie, bis Terraform die Meldung „Apply complete“ anzeigt.

3. Öffnen Sie Ihr Google Cloud-Projekt, um die Ergebnisse aufzurufen. Rufen Sie in der Google Cloud Console Ihre Ressourcen in der Benutzeroberfläche auf, um sicherzustellen, dass Terraform sie erstellt oder aktualisiert hat.

Hinweis: Bei Terraform-Beispielen wird in der Regel davon ausgegangen, dass die erforderlichen APIs in Ihrem Google Cloud-Projekt aktiviert sind.

3. GKE konfigurieren

Stellen Sie einen Kubernetes-Dienst in GKE bereit, der HTTP-Anfragen und Logereignisse mithilfe des vordefinierten Cloud Run-Images us-docker.pkg.dev/cloudrun/container/hello empfängt:

1. Rufen Sie die Anmeldedaten für die Authentifizierung ab, um mit dem Cluster zu interagieren:

   gcloud container clusters get-credentials eventarc-cluster \
      --region=us-central1
   

2. Erstellen Sie ein Deployment mit dem Namen hello-gke:

   kubectl create deployment hello-gke \
      --image=us-docker.pkg.dev/cloudrun/container/hello
   

3. Geben Sie das Deployment als Kubernetes-Dienst frei:

   kubectl expose deployment hello-gke \
      --type ClusterIP --port 80 --target-port 8080
   

4. Prüfen Sie, ob der Pod ausgeführt wird:

   kubectl get pods
   

   Die Ausgabe sollte in etwa so aussehen:

   NAME                        READY   STATUS
   hello-gke-df6469d4b-5vv22   1/1     Running
   

   Wenn STATUS Pending ist, wird der Pod bereitgestellt. Warten Sie eine Minute, bis das Deployment abgeschlossen ist, und prüfen Sie den Status noch einmal.

5. Achten Sie darauf, dass der Dienst ausgeführt wird:

   kubectl get svc
   

   Die Ausgabe sollte in etwa so aussehen:

   NAME         TYPE        CLUSTER-IP       EXTERNAL-IP   PORT(S)   AGE
   hello-gke    ClusterIP   34.118.226.144   <none>        80/TCP
   kubernetes   ClusterIP   34.118.224.1     <none>        443/TCP
   

4. Eventarc erstellen und konfigurieren

Verwenden Sie die folgende Konfiguration, um ein Dienstkonto einzurichten und ihm bestimmte Rollen zuzuweisen, damit Eventarc Ereignisse für GKE verwalten kann.

# Create a service account to be used by GKE trigger
resource "google_service_account" "eventarc_gke_trigger_sa" {
  account_id   = "eventarc-gke-trigger-sa"
  display_name = "Evenarc GKE Trigger Service Account"
}

# Grant permission to receive Eventarc events
resource "google_project_iam_member" "eventreceiver" {
  project = data.google_project.project.id
  role    = "roles/eventarc.eventReceiver"
  member  = "serviceAccount:${google_service_account.eventarc_gke_trigger_sa.email}"
}

# Grant permission to subscribe to Pub/Sub topics
resource "google_project_iam_member" "pubsubscriber" {
  project = data.google_project.project.id
  role    = "roles/pubsub.subscriber"
  member  = "serviceAccount:${google_service_account.eventarc_gke_trigger_sa.email}"
}

Verwenden Sie den folgenden Code, um einen Cloud Storage-Bucket mit Eventarc-bezogenen Berechtigungen zu erstellen:

# Cloud Storage bucket names must be globally unique
resource "random_id" "bucket_name_suffix" {
  byte_length = 4
}

# Create a Cloud Storage bucket
resource "google_storage_bucket" "default" {
  name          = "trigger-gke-${data.google_project.project.name}-${random_id.bucket_name_suffix.hex}"
  location      = "us-central1"
  force_destroy = true

  uniform_bucket_level_access = true
}

# Grant the Cloud Storage service account permission to publish pub/sub topics
data "google_storage_project_service_account" "gcs_account" {}
resource "google_project_iam_member" "pubsubpublisher" {
  project = data.google_project.project.id
  role    = "roles/pubsub.publisher"
  member  = "serviceAccount:${data.google_storage_project_service_account.gcs_account.email_address}"
}

Verwenden Sie die folgende Konfiguration, um die erforderlichen APIs zu aktivieren und die GKE-Zieldienste von Eventarc zu initialisieren:

# Used to retrieve project_number later
data "google_project" "project" {}

# Enable Eventarc to manage GKE clusters
# This is usually done with: gcloud eventarc gke-destinations init
#
# Eventarc creates a separate Event Forwarder pod for each trigger targeting a
# GKE service, and  requires explicit permissions to make changes to the
# cluster. This is done by granting permissions to a special service account
# (the Eventarc P4SA) to manage resources in the cluster. This needs to be done
# once per Google Cloud project.

# This identity is created with: gcloud beta services identity create --service eventarc.googleapis.com
# This local variable is used for convenience
locals {
  eventarc_sa = "serviceAccount:service-${data.google_project.project.number}@gcp-sa-eventarc.iam.gserviceaccount.com"
}

resource "google_project_iam_member" "computeViewer" {
  project = data.google_project.project.id
  role    = "roles/compute.viewer"
  member  = local.eventarc_sa
}

resource "google_project_iam_member" "containerDeveloper" {
  project = data.google_project.project.id
  role    = "roles/container.developer"
  member  = local.eventarc_sa
}

resource "google_project_iam_member" "serviceAccountAdmin" {
  project = data.google_project.project.id
  role    = "roles/iam.serviceAccountAdmin"
  member  = local.eventarc_sa
}

Erstellen Sie einen Eventarc-Trigger, der Pub/Sub-Ereignisse an den GKE-Dienst hello-gke weiterleitet

Sie können mehrere matching_criteria mit CloudEvents-Attributen definieren, die von Eventarc unterstützt werden und die wie die event-filters funktionieren, die Sie beim Erstellen eines Triggers angeben. Weitere Informationen finden Sie in der Anleitung zum Erstellen eines Triggers für einen bestimmten Anbieter und Ereignistyp und ein bestimmtes GKE-Ziel. Ereignisse, die mit allen Filtern übereinstimmen, werden an das Ziel gesendet.

# Create an Eventarc trigger, routing Storage events to GKE
resource "google_eventarc_trigger" "default" {
  name     = "trigger-storage-gke-tf"
  location = "us-central1"

  # Capture objects changed in the bucket
  matching_criteria {
    attribute = "type"
    value     = "google.cloud.storage.object.v1.finalized"
  }
  matching_criteria {
    attribute = "bucket"
    value     = google_storage_bucket.default.name
  }

  # Send events to GKE service
  destination {
    gke {
      cluster   = "eventarc-cluster"
      location  = "us-central1"
      namespace = "default"
      path      = "/"
      service   = "hello-gke"
    }
  }

  service_account = google_service_account.eventarc_gke_trigger_sa.email
}

5. Zusätzliche Änderungen anwenden

Führen Sie die folgenden Schritte aus, um die zusätzliche Terraform-Konfiguration in einem Google Cloud-Projekt anzuwenden:

1. Erstellen Sie das Eventarc-Identitätskonto:

   gcloud beta services identity create --service eventarc.googleapis.com
   

2. Fügen Sie der Datei main.tf den neuen Terraform-Code aus dem vorherigen Schritt hinzu.

3. Wenden Sie die aktualisierten Terraform-Konfigurationen an:

   terraform plan
   terraform apply
   

   Warten Sie, bis Terraform die Meldung „Apply complete“ anzeigt.

   Hinweis: Es kann ein paar Minuten dauern, bis alle erforderlichen Berechtigungen an den Eventarc-Dienst-Agent weitergegeben wurden. Wenn dieses Problem auftritt, warten Sie einige Minuten und führen Sie dann terraform apply noch einmal aus.

4. Öffnen Sie Ihr Google Cloud-Projekt, um die Ergebnisse aufzurufen. Rufen Sie in der Google Cloud Console Ihre Ressourcen in der Benutzeroberfläche auf, um sicherzustellen, dass Terraform sie erstellt oder aktualisiert hat.

Workflows

Stellen Sie Ihre Ressourcen mit Cloud Shell mit Terraform bereit, um einen Workflow und einen Eventarc-Trigger zu erstellen.

1. APIs aktivieren

Verwenden Sie den folgenden Code, um die erforderlichen APIs zu aktivieren:

# Enable Eventarc API
resource "google_project_service" "eventarc" {
  service            = "eventarc.googleapis.com"
  disable_on_destroy = false
}

# Enable Workflows API
resource "google_project_service" "workflows" {
  service            = "workflows.googleapis.com"
  disable_on_destroy = false
}

# Enable Pub/Sub API
resource "google_project_service" "pubsub" {
  service            = "pubsub.googleapis.com"
  disable_on_destroy = false
}

2. Dienstkonto erstellen und IAM konfigurieren

Verwenden Sie den folgenden Code, um ein dediziertes Dienstkonto zu erstellen und IAM-Rollen hinzuzufügen:

# Used to retrieve project information later
data "google_project" "project" {}

# Create a service account for Eventarc trigger and Workflows
resource "google_service_account" "eventarc" {
  account_id   = "eventarc-workflows-sa"
  display_name = "Eventarc Workflows Service Account"
}

# Grant permission to invoke workflows
resource "google_project_iam_member" "workflowsinvoker" {
  project = data.google_project.project.id
  role    = "roles/workflows.invoker"
  member  = "serviceAccount:${google_service_account.eventarc.email}"
}

# Grant permission to receive events
resource "google_project_iam_member" "eventreceiver" {
  project = data.google_project.project.id
  role    = "roles/eventarc.eventReceiver"
  member  = "serviceAccount:${google_service_account.eventarc.email}"
}

Wenn Sie den Pub/Sub-Dienst-Agent am oder vor dem 8. April 2021 aktiviert haben, weisen Sie dem von Google verwalteten Dienstkonto die Rolle iam.serviceAccountTokenCreator zu.

resource "google_project_iam_member" "tokencreator" {
   project  = data.google_project.project.id
   role     = "roles/iam.serviceAccountTokenCreator"
   member   = "serviceAccount:service-${data.google_project.project.number}@gcp-sa-pubsub.iam.gserviceaccount.com"
}

3. Cloud Storage-Bucket als Ereignisanbieter erstellen

Verwenden Sie den folgenden Code, um einen Cloud Storage-Bucket mit Eventarc-bezogenen Berechtigungen zu erstellen:

# Cloud Storage bucket names must be globally unique
resource "random_id" "bucket_name_suffix" {
  byte_length = 4
}

# Create a Cloud Storage bucket
resource "google_storage_bucket" "default" {
  name          = "trigger-workflows-${data.google_project.project.name}-${random_id.bucket_name_suffix.hex}"
  location      = google_workflows_workflow.default.region
  force_destroy = true

  uniform_bucket_level_access = true
}

# Grant the Cloud Storage service account permission to publish Pub/Sub topics
data "google_storage_project_service_account" "gcs_account" {}
resource "google_project_iam_member" "pubsubpublisher" {
  project = data.google_project.project.id
  role    = "roles/pubsub.publisher"
  member  = "serviceAccount:${data.google_storage_project_service_account.gcs_account.email_address}"
}

4. Workflow erstellen und bereitstellen

Definieren Sie einen Workflow, der ausgeführt wird, wenn ein Objekt im erstellten Bucket aktualisiert wird, und stellen Sie ihn bereit:

# Create a workflow
resource "google_workflows_workflow" "default" {
  name        = "storage-workflow-tf"
  region      = "us-central1"
  description = "Workflow that returns information about storage events"

  # Note that $$ is needed for Terraform
  source_contents = <<EOF
  main:
    params: [event]
    steps:
      - log_event:
          call: sys.log
          args:
            text: $${event}
            severity: INFO
      - gather_data:
          assign:
            - bucket: $${event.data.bucket}
            - name: $${event.data.name}
            - message: $${"Received event " + event.type + " - " + bucket + ", " + name}
      - return_data:
          return: $${message}
  EOF

  depends_on = [
    google_project_service.workflows
  ]
}

5. Eventarc-Trigger erstellen

Erstellen Sie einen Eventarc-Trigger, der direkte Ereignisse für den erstellten Bucket an Workflows weiterleitet. Verwenden Sie die Ressource google_eventarc_trigger, um die Eventarc-Trigger-Ressource zu definieren.

Sie können mehrere matching_criteria mit CloudEvents-Attributen definieren, die von Eventarc unterstützt werden und die wie die event-filters funktionieren, die Sie beim Erstellen eines Triggers angeben. Weitere Informationen finden Sie in der Anleitung zum Erstellen eines Triggers für einen bestimmten Anbieter und Ereignistyp und ein bestimmtes Workflows-Ziel.

Ereignisse, die mit allen Filtern übereinstimmen, werden an das Ziel gesendet.

# Create an Eventarc trigger, routing Cloud Storage events to Workflows
resource "google_eventarc_trigger" "default" {
  name     = "trigger-storage-workflows-tf"
  location = google_workflows_workflow.default.region

  # Capture objects changed in the bucket
  matching_criteria {
    attribute = "type"
    value     = "google.cloud.storage.object.v1.finalized"
  }
  matching_criteria {
    attribute = "bucket"
    value     = google_storage_bucket.default.name
  }

  # Send events to Workflows
  destination {
    workflow = google_workflows_workflow.default.id
  }

  service_account = google_service_account.eventarc.email

  depends_on = [
    google_project_service.eventarc,
    google_project_service.workflows,
  ]
}

6. Änderungen anwenden

Informationen zum Anwenden oder Entfernen einer Terraform-Konfiguration finden Sie unter Grundlegende Terraform-Befehle.

Führen Sie die Schritte in den folgenden Abschnitten aus, um Ihre Terraform-Konfiguration auf ein Google Cloud-Projekt anzuwenden.

Cloud Shell vorbereiten

1. Rufen Sie Cloud Shell auf.

2. Legen Sie das Google Cloud-Standardprojekt fest, auf das Sie Ihre Terraform-Konfigurationen anwenden möchten.

   Sie müssen diesen Befehl nur einmal pro Projekt und in jedem beliebigen Verzeichnis ausführen.

   export GOOGLE_CLOUD_PROJECT=PROJECT_ID

   Umgebungsvariablen werden überschrieben, wenn Sie in der Terraform-Konfigurationsdatei explizite Werte festlegen.

Verzeichnis vorbereiten

Jede Terraform-Konfigurationsdatei muss ein eigenes Verzeichnis haben (auch als Stammmodul bezeichnet).

1. Erstellen Sie in Cloud Shell ein Verzeichnis und eine neue Datei in diesem Verzeichnis. Der Dateiname muss die Erweiterung .tf haben, z. B. main.tf. In dieser Anleitung wird die Datei als main.tf bezeichnet.

   mkdir DIRECTORY && cd DIRECTORY && touch main.tf

2. Wenn Sie einer Anleitung folgen, können Sie den Beispielcode in jedem Abschnitt oder Schritt kopieren.

   Kopieren Sie den Beispielcode in das neu erstellte main.tf.

   Kopieren Sie optional den Code aus GitHub. Dies wird empfohlen, wenn das Terraform-Snippet Teil einer End-to-End-Lösung ist.

3. Prüfen und ändern Sie die Beispielparameter, die auf Ihre Umgebung angewendet werden sollen.
4. Speichern Sie die Änderungen.
5. Initialisieren Sie Terraform. Dies ist nur einmal für jedes Verzeichnis erforderlich.

   terraform init

   Fügen Sie optional die Option -upgrade ein, um die neueste Google-Anbieterversion zu verwenden:

   terraform init -upgrade

Änderungen anwenden

1. Prüfen Sie die Konfiguration und prüfen Sie, ob die Ressourcen, die Terraform erstellen oder aktualisieren wird, Ihren Erwartungen entsprechen:

   terraform plan

   Korrigieren Sie die Konfiguration nach Bedarf.

2. Wenden Sie die Terraform-Konfiguration an. Führen Sie dazu den folgenden Befehl aus und geben Sie yes an der Eingabeaufforderung ein:

   terraform apply

   Warten Sie, bis Terraform die Meldung „Apply complete“ anzeigt.

3. Öffnen Sie Ihr Google Cloud-Projekt, um die Ergebnisse aufzurufen. Rufen Sie in der Google Cloud Console Ihre Ressourcen in der Benutzeroberfläche auf, um sicherzustellen, dass Terraform sie erstellt oder aktualisiert hat.

Hinweis: Bei Terraform-Beispielen wird in der Regel davon ausgegangen, dass die erforderlichen APIs in Ihrem Google Cloud-Projekt aktiviert sind.

Hinweis: Es kann einige Minuten dauern, bis Eventarc alle erforderlichen Berechtigungen an den Dienst-Agent weitergegeben hat. Wenn dieses Problem auftritt, warten Sie einige Minuten und führen Sie dann terraform apply noch einmal aus.

7. Erstellung des Workflows prüfen

Führen Sie folgenden Befehl aus, um zu prüfen, ob der Workflow erstellt wird:

gcloud workflows list --location us-central1

8. Erstellung des Eventarc-Triggers prüfen

Führen Sie folgenden Befehl aus, um zu prüfen, ob der Eventarc-Trigger erstellt wurde:

gcloud eventarc triggers list --location us-central1

Die Ausgabe sollte in etwa so aussehen:

NAME: trigger-storage-workflows-tf
TYPE: google.cloud.storage.object.v1.finalized
DESTINATION: Workflows: storage-workflow-tf
ACTIVE: Yes
LOCATION: us-central1

Ereignis erstellen und abrufen

Sie können ein Ereignis generieren und prüfen, ob der Eventarc-Trigger wie erwartet funktioniert.

Cloud Run

1. So erstellen Sie ein Ereignis:

   Laden Sie eine Datei in Cloud Storage hoch:

   echo "Hello World" > random.txt
   gsutil cp random.txt gs://trigger-cloudrun-PROJECT_ID/random.txt
   

   Beim Upload wird ein Ereignis erstellt und der Cloud Run-Dienst loggt die Nachricht des Ereignisses.

2. So prüfen Sie, ob ein Ereignis empfangen wurde:

   1. So rufen Sie die ereignisbezogenen Logeinträge auf, die von Ihrem Dienst erstellt wurden:

   gcloud logging read "resource.type=cloud_run_revision \
       AND resource.labels.service_name=hello-events"
   

   Alternativ können Sie die Google Cloud Console aufrufen, die Cloud Run-Ressource aufrufen und die Logs aufrufen.

   1. Suchen Sie nach einem Logeintrag wie dem Folgenden:

   Received event of type google.cloud.storage.object.v1.finalized.
   Event data: { "kind": "storage#object", "id": "trigger-cloudrun-PROJECT_ID/random.txt", ...}
   

   Hinweis: Wenn kein Logeintrag angezeigt wird, warten Sie einige Minuten und führen Sie den Befehl gcloud logging read noch einmal aus. Nach dem Erstellen des Triggers kann es bis zu zwei Minuten dauern, bis Ereignisse gefiltert werden können.

GKE

1. So erstellen Sie ein Ereignis:

   Laden Sie eine Datei in Cloud Storage hoch:

   echo "Hello World" > random.txt
   gsutil cp random.txt gs://trigger-gke-PROJECT_ID/random.txt
   

   Beim Upload wird ein Ereignis erstellt und der Cloud Run-Dienst loggt die Nachricht des Ereignisses.

2. So prüfen Sie, ob ein Ereignis empfangen wurde:

   1. Suchen Sie die Pod-ID:

      POD_NAME=$(kubectl get pods -o custom-columns=":metadata.name" --no-headers)
      

      Dieser Befehl verwendet die formatierte Ausgabe von kubectl.

   2. Prüfen Sie die Logs des Pods:

      kubectl logs $POD_NAME
      

   3. Suchen Sie nach einem Logeintrag wie dem Folgenden:

      {"severity":"INFO","eventType":"google.cloud.pubsub.topic.v1.messagePublished",
      "message":"Received event of type google.cloud.pubsub.topic.v1.messagePublished.", [...]}
      

Workflows

1. So erstellen Sie ein Ereignis:

   Laden Sie eine Datei in Cloud Storage hoch:

   echo "Hello World" > random.txt
   gsutil cp random.txt gs://trigger-workflows-PROJECT_ID/random.txt
   

   Beim Upload wird ein Ereignis erstellt und der Cloud Run-Dienst loggt die Nachricht des Ereignisses.

2. So prüfen Sie, ob ein Ereignis empfangen wurde:

   1. Prüfen Sie, ob eine Workflowausführung ausgelöst wird. Listen Sie dazu die letzten fünf Ausführungen auf:

      gcloud workflows executions list storage-workflow-tf --limit=5
      

      Die Ausgabe sollte eine Liste von Ausführungen mit NAME, START_TIME, END_TIME und STATUS enthalten.

   2. Rufen Sie die Ergebnisse der letzten Ausführung ab:

      EXECUTION_NAME=$(gcloud workflows executions list storage-workflow-tf --limit=1 --format "value(name)")
      gcloud workflows executions describe $EXECUTION_NAME
      

   3. Die Ausgabe sollte etwa so aussehen:

      ...
      result: '"Received event google.cloud.storage.object.v1.finalized - trigger-workflows-PROJECT_ID, random.txt"'
      state: SUCCEEDED
      ...
      

      Suchen Sie in der Workflow-Ausgabe nach state: SUCCEEDED und result: "Received event".

Bereinigen

Entfernen Sie Ressourcen, die zuvor mit Ihrer Terraform-Konfiguration angewendet wurden, indem Sie den folgenden Befehl ausführen und yes an der Eingabeaufforderung eingeben:

terraform destroy

Sie können auch Ihr Google Cloud-Projekt löschen, um wiederkehrende Gebühren zu vermeiden. Wenn Sie Ihr Google Cloud-Projekt löschen, wird die Abrechnung für alle in diesem Projekt verwendeten Ressourcen beendet.

Achtung: Das Löschen von Projekten hat folgende Auswirkungen:
• Alle Inhalte des Projekts werden gelöscht. Wenn Sie für die Aufgaben in diesem Dokument ein bereits bestehendes Projekt verwendet haben und dieses löschen, werden auch alle anderen im Rahmen des Projekts erstellten Daten gelöscht.
• Benutzerdefinierte Projekt-IDs gehen verloren. Beim Erstellen dieses Projekts haben Sie möglicherweise eine benutzerdefinierte Projekt-ID erstellt, die Sie weiterhin verwenden möchten. Damit die URLs, die die Projekt-ID nutzen, z. B. eine appspot.com-URL, erhalten bleiben, sollten Sie ausgewählte Ressourcen innerhalb des Projekts löschen, statt das gesamte Projekt.
1. Wechseln Sie in der Google Cloud Console zur Seite Ressourcen verwalten.

   Zur Seite „Ressourcen verwalten“

2. Wählen Sie in der Projektliste das Projekt aus, das Sie löschen möchten, und klicken Sie dann auf Löschen.
3. Geben Sie im Dialogfeld die Projekt-ID ein und klicken Sie auf Shut down (Beenden), um das Projekt zu löschen.

Nächste Schritte

• Informationen zum Auslösen eines Workflows mit Ereignissen über die gcloud CLI oder die Console finden Sie unter Workflow mit Ereignissen oder Pub/Sub-Nachrichten auslösen.