Adicionar operações SQL personalizadas

Este documento mostra como definir operações SQL personalizadas em um arquivo SQLX dedicado.

O Dataform pode executar operações SQL personalizadas que não se encaixam no modelo do Dataform para publicar uma tabela ou gravar uma declaração. É possível definir comandos SQL personalizados para o Dataform a ser executado no BigQuery.

Antes de começar

  1. No console do Google Cloud, acesse a página Dataform.

    Acessar a página do Dataform

  2. Selecione ou crie um repositório.

  3. Selecione ou crie um espaço de trabalho de desenvolvimento.

Funções exigidas

Para ter as permissões necessárias para definir uma operação SQL personalizada, peça ao administrador para conceder a você o papel do IAM de Editor do Dataform (roles/dataform.editor) nos espaços de trabalho. Para mais informações sobre como conceder papéis, consulte Gerenciar acesso.

Talvez você também consiga receber as permissões necessárias por meio de papéis personalizados ou outros papéis predefinidos.

Criar um arquivo para definição personalizada de operação

Armazene arquivos SQLX de definição de operação personalizada no diretório definitions/. Para criar um novo arquivo SQLX no diretório definitions/, siga estas etapas:

  1. Acesse seu espaço de trabalho de desenvolvimento.
  2. No painel Files, ao lado de definitions/, clique no menu More.
  3. Clique em Criar arquivo.

  4. No campo Add a file path, insira o nome do arquivo seguido de .sqlx após definitions/. Por exemplo, definitions/sample-operation.sqlx.

    Os nomes de arquivos só podem incluir números, letras, hifens e sublinhados.

  5. Clique em Criar arquivo.

Definir uma operação SQL personalizada

É possível definir uma operação SQL personalizada em um arquivo SQLX de type: operations. É possível escrever qualquer instrução SQL do BigQuery em um arquivo operations. O Dataform executa suas operações SQL personalizadas no BigQuery sem modificações.

É possível definir várias operações SQL personalizadas em um arquivo SQLX. O BigQuery executa todas as operações em um arquivo no mesmo contexto e cria o SQL executado mesclando todas as operações com um ponto e vírgula ;.

Para definir várias operações SQL personalizadas ao usar o framework de código aberto Dataform com um data warehouse diferente do BigQuery, separe as operações com ---.

Para definir uma operação SQL personalizada em um arquivo SQLX dedicado, siga estas etapas:

  1. No espaço de trabalho de desenvolvimento, selecione o arquivo SQLX para a definição de operação personalizada.

  2. No arquivo, digite o seguinte snippet de código:

    config { type: "operations" }

  3. Fora do bloco config, escreva a operação SQL.

  4. Opcional: clique em Formatar.

O exemplo de código a seguir mostra várias operações SQL personalizadas definidas em um arquivo operations:

config { type: "operations" }

DELETE FROM dataset.table WHERE country = 'GB';

DELETE FROM dataset.table WHERE country = 'FR';

O exemplo de código a seguir mostra uma operação SQL personalizada que cria manualmente uma visualização:

config { type: "operations" }
CREATE OR REPLACE VIEW dataset.table AS (SELECT 1 AS TEST)

Criar uma tabela de saída referenciável

É possível criar manualmente uma tabela em uma operação SQL personalizada que pode ser referenciada em outros scripts. Para criar uma tabela disponível para outros scripts, você precisa declarar que a operação tem uma saída.

Para que o nome da tabela de saída corresponda ao nome do arquivo operations, use a função self na operação CREATE.

Para criar uma tabela em uma operação personalizada e disponibilizá-la para outros scripts, siga estas etapas:

  1. No espaço de trabalho de desenvolvimento, selecione o arquivo SQLX para a definição personalizada de operação.

  2. No arquivo SQLX, insira o seguinte snippet de código:

    config {
 type: "operations",
 hasOutput: true
 }

  3. Opcional: para fazer a correspondência do nome da tabela de saída com o nome do arquivo, escreva uma operação CREATE SQL com a função self no seguinte formato:

    CREATE OR REPLACE TABLE ${self()} AS (CUSTOM_SQL_QUERY)

    Substitua CUSTOM_SQL_QUERY pela instrução SELECT SQL de definição de tabela.

  4. Opcional: clique em Formatar.

Referenciar uma tabela de saída de operação SQL personalizada

  • Para fazer referência a uma tabela de saída de operação SQL personalizada em uma definição do SQLX de uma tabela diferente, insira o nome do arquivo da tabela de saída na função ref.

O exemplo de código a seguir mostra uma operação SQL personalizada em um arquivo custom_SQL_operation_table.sqlx que cria uma tabela referenciável chamada custom_SQL_operation_table:

// filename is custom_SQL_operation_table.sqlx
config {
type: "operations",
hasOutput: true
}
CREATE OR REPLACE VIEW ${self()} AS (SELECT 1 AS TEST)

O exemplo de código a seguir mostra como referenciar custom\_SQL\_operation\_table table em um arquivo SQLX de definição de tabela:

config { type: "table" }
SELECT * FROM ${ref("custom_SQL_operation_table")}

Criar uma tabela vazia

Convém criar uma tabela vazia para que outro serviço possa preenchê-la com dados. É possível criar uma tabela vazia em uma operação SQL personalizada com a função CREATE TABLE. Para poder fazer referência à tabela vazia em outras definições de objetos de fluxo de trabalho SQL, por exemplo, em tabelas e visualizações, adicione a propriedade hasOutput:true ao bloco config da operação de tabela vazia.

  • Para criar uma tabela vazia, use a função CREATE TABLE em um arquivo type: "operations" no seguinte formato:
config {
  type: "operations",
  hasOutput: true  // optional, lets you reference the empty table
}

CREATE TABLE ${self()} (

)

O exemplo de código a seguir mostra uma operação SQL personalizada que cria uma tabela vazia com um número inteiro e uma coluna de string. A tabela vazia criada não pode ser referenciada por outros objetos de fluxo de trabalho SQL:

config {
  type: "operations"
}

CREATE TABLE ${self()} (
  x INT64,
  y STRING
)

A seguir