Servidor cliente NoSQL

O servidor do cliente NoSQL configura e cria duas instâncias do Compute Engine:

Servidor: executa o MongoDB.
Cliente: executa um aplicativo Go personalizado que se comunica com o MongoDB e expõe uma API onde você consome dados do MongoDB.

Comece já

Clique no link a seguir para copiar o código-fonte no Cloud Shell. Depois, um único comando ativará uma cópia de trabalho do aplicativo no seu projeto.

Ver código-fonte no GitHub (em inglês)

Componentes do servidor cliente NoSQL

A arquitetura de servidor de cliente NoSQL utiliza um produto principal. Confira a seguir esse produto com mais informações, incluindo links para vídeos relacionados, documentação do produto e tutoriais interativos.

			Video	Documentos	Tutoriais
	Compute Engine	O Compute Engine é a tecnologia virtual do Google Cloud. Com ele, é possível ativar várias configurações diferentes de VM para atender às suas necessidades de computação.

Scripts

O script de instalação usa um executável escrito em go e ferramentas da CLI do Terraform para pegar um projeto vazio e instalar o aplicativo nele. A saída será um aplicativo em funcionamento e um URL para o endereço IP de balanceamento de carga.

`./main.tf`

Ativar serviços

Os serviços do Google Cloud são desativados em um projeto por padrão. Para usar qualquer uma das soluções apresentadas aqui, temos que ativar o seguinte:

Compute Engine: máquinas virtuais e rede

variable "gcp_service_list" {
    description = "The list of apis necessary for the project"
    type        = list(string)
    default = [
        "compute.googleapis.com",
    ]
}

resource "google_project_service" "all" {
  for_each                   = toset(var.gcp_service_list)
  project                    = var.project_number
  service                    = each.key
  disable_dependent_services = false
  disable_on_destroy         = false
}

Criar regra de firewall

Cria uma regra que abre a porta 80 no firewall e a aplica a qualquer máquina rotulada como http-server

resource "google_compute_firewall" "default-allow-http" {
  name    = "deploystack-allow-http"
  project = var.project_number
  network = "projects/${var.project_id}/global/networks/default"

  allow {
    protocol = "tcp"
    ports    = ["80"]
  }

  source_ranges = ["0.0.0.0/0"]

  target_tags = ["http-server"]
}

Criar instância do servidor

Ativa uma VM que vai atuar como servidor e disponibilizar o MongoDB

# Create Instances
resource "google_compute_instance" "server" {
  name         = "server"
  zone         = var.zone
  project      = var.project_id
  machine_type = "e2-standard-2"
  tags         = ["http-server"]

  boot_disk {
    auto_delete = true
    device_name = "server"
    initialize_params {
      image = "family/ubuntu-1804-lts"
      size  = 10
      type  = "pd-standard"
    }
  }

  network_interface {
    network = "default"
    access_config {
      // Ephemeral public IP
    }
  }

  metadata_startup_script = <<SCRIPT
    apt-get update
    apt-get install -y mongodb
    service mongodb stop
    sed -i 's/bind_ip = 127.0.0.1/bind_ip = 0.0.0.0/' /etc/mongodb.conf
    iptables -t nat -A PREROUTING -p tcp --dport 80 -j REDIRECT --to-port 27017
    service mongodb start
  SCRIPT
  depends_on              = [google_project_service.all]
}

Criar instância do cliente

Ativa uma VM que vai atuar como cliente e consumir dados do MongoDB

resource "google_compute_instance" "client" {
  name         = "client"
  zone         = var.zone
  project      = var.project_id
  machine_type = "e2-standard-2"
  tags         = ["http-server", "https-server"]

  boot_disk {
    auto_delete = true
    device_name = "client"
    initialize_params {
      image = "family/ubuntu-1804-lts"
      size  = 10
      type  = "pd-standard"
    }
  }

  network_interface {
    network = "default"

    access_config {
      // Ephemeral public IP
    }
  }

  metadata_startup_script = <<SCRIPT
    add-apt-repository ppa:longsleep/golang-backports -y && \
    apt update -y && \
    apt install golang-go -y
    mkdir /modcache
    mkdir /go
    mkdir /app && cd /app
    curl https://raw.githubusercontent.com/GoogleCloudPlatform/golang-samples/main/compute/quickstart/compute_quickstart_sample.go --output main.go
    go mod init exec
    GOPATH=/go GOMODCACHE=/modcache GOCACHE=/modcache go mod tidy
    GOPATH=/go GOMODCACHE=/modcache GOCACHE=/modcache go get -u
    sed -i 's/mongoport = "80"/mongoport = "27017"/' /app/main.go
    echo "GOPATH=/go GOMODCACHE=/modcache GOCACHE=/modcache HOST=${google_compute_instance.server.network_interface.0.network_ip} go run main.go"
    GOPATH=/go GOMODCACHE=/modcache GOCACHE=/modcache HOST=${google_compute_instance.server.network_interface.0.network_ip} go run main.go &
  SCRIPT

  depends_on = [google_project_service.all]
}

Conclusão

Depois da execução, você terá uma API de servidor cliente usando o MongoDB em execução em duas instâncias do Compute Engine. Além disso, você precisa ter todo o código para modificar ou estender essa solução de acordo com seu ambiente.