Membuat instance Memorystore for Redis Cluster menggunakan Terraform

Panduan memulai ini menunjukkan cara menggunakan Terraform untuk membuat instance Memorystore for Redis Cluster baru. Bagian ini juga menunjukkan cara menghubungkan ke instance menggunakan telnet.

Panduan memulai ini mengasumsikan bahwa Anda memulai file Terraform baru, dan mencakup resource Terraform untuk menyiapkan penyedia Google Cloud . Namun, langkah-langkah untuk mengautentikasi file Terraform dengan penyedia Google Cloud tidak disertakan.

Untuk mengetahui petunjuk tentang cara mengautentikasi Terraform dengan penyedia Google Cloud , lihat Mulai menggunakan penyedia Google Cloud

Sebelum memulai

  1. Sign in to your Google Cloud account. If you're new to Google Cloud, create an account to evaluate how our products perform in real-world scenarios. New customers also get $300 in free credits to run, test, and deploy workloads.

  2. In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

    Go to project selector

  3. Verify that billing is enabled for your Google Cloud project.

  4. In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

    Go to project selector

  5. Verify that billing is enabled for your Google Cloud project.

  6. Jika Anda belum melakukannya, instal Google Cloud SDK.

    Saat diminta, pilih project yang Anda pilih atau buat di atas.

  7. Jika Anda sudah menginstal Google Cloud SDK, update.

    gcloud components update
  8. Aktifkan Memorystore for Redis Cluster API
    Memorystore for Redis Cluster

    9. Mengonfigurasi Terraform untuk Memorystore

    Bagian ini menunjukkan contoh lima resource Terraform yang diperlukan untuk membuat instance Memorystore for Redis Cluster:

    • Konfigurasi Google Cloud penyedia.

    • Konfigurasi instance Memorystore. Dalam panduan ini, clusternya adalah cluster 39 GB dengan tiga node redis-highmem-medium di region us-central1.

    • Kebijakan koneksi layanan Private Service Connect.

    • Subnet untuk instance Anda.

    • Jaringan untuk instance Anda.

    Petunjuk untuk menambahkan resource Terraform ini adalah sebagai berikut:

    1. Tambahkan resource berikut ke file konfigurasi Terraform Anda:

      
provider "google" {
  project = "PROJECT_ID"
}

resource "google_redis_cluster" "cluster-ha" {
  name           = "CLUSTER_ID"
  shard_count    = 3
  psc_configs {
    network = google_compute_network.producer_net.id
  }
  region = "us-central1"
  replica_count = 1
  depends_on = [
    google_network_connectivity_service_connection_policy.default
  ]

}

resource "google_network_connectivity_service_connection_policy" "default" {
  name = "POLICY_NAME"
  location = "us-central1"
  service_class = "gcp-memorystore-redis"
  description   = "my basic service connection policy"
  network = google_compute_network.producer_net.id
  psc_config {
    subnetworks = [google_compute_subnetwork.producer_subnet.id]
  }
}

resource "google_compute_subnetwork" "producer_subnet" {
  name          = "SUBNET_ID"
  ip_cidr_range = "10.0.0.248/29"
  region        = "us-central1"
  network       = google_compute_network.producer_net.id
}

resource "google_compute_network" "producer_net" {
  name                    = "NETWORK_ID"
  auto_create_subnetworks = false
}

      Ganti kode berikut:

      • PROJECT_ID adalah project ID instance Anda.
      • CLUSTER_ID adalah ID pilihan Anda untuk instance Memorystore for Redis Cluster yang Anda buat. ID harus terdiri dari 1 hingga 63 karakter dan hanya menggunakan huruf kecil, angka, atau tanda hubung. ID ini harus dimulai dengan huruf kecil dan diakhiri dengan huruf kecil atau angka.
      • POLICY_NAME adalah nama yang Anda pilih untuk kebijakan koneksi layanan Private Service Connect untuk project Anda. Untuk mengetahui informasi selengkapnya tentang kebijakan koneksi layanan, lihat Jaringan.
      • SUBNET_ID adalah ID subnet yang Anda pilih dan dibuat dalam contoh ini yang digunakan oleh cluster Memorystore.
      • NETWORK_ID adalah ID jaringan yang Anda pilih dan dibuat dalam contoh ini yang digunakan oleh cluster Memorystore.

    Men-deploy file konfigurasi Terraform

    1. Jalankan terraform init.

    2. Jalankan terraform plan.

    3. Jalankan terraform apply.

    Menghubungkan ke instance dari VM Compute Engine

    Selanjutnya, hubungkan ke instance Memorystore for Redis Cluster yang baru dibuat.

    Anda dapat terhubung ke instance dari VM Compute Engine mana pun yang menggunakan jaringan resmi instance.

    1. Jika Anda belum memiliki VM Compute Engine yang menggunakan jaringan resmi yang sama dengan instance Anda, buat VM dan hubungkan ke VM tersebut dengan mengikuti Panduan memulai menggunakan VM Linux.

    2. Instal telnet menggunakan apt-get:

      sudo apt-get install telnet

    3. Dari terminal, telnet ke alamat IP instance, dengan mengganti VARIABLES dengan nilai yang sesuai.

      telnet CLUSTER_DISCOVERY_ENDPOINT_IP_ADDRESS CLUSTER_DISCOVERY_ENDPOINT_PORT_NUMBER

    4. Dalam sesi telnet, masukkan beberapa perintah Redis:

      Enter:

      PING

      Hasil:

      PONG

    Pembersihan

    Agar tidak menimbulkan biaya pada akun Google Cloud Anda untuk resource yang digunakan dalam panduan memulai ini, hapus instance Redis menggunakan langkah-langkah berikut:

    1. Hapus resource google_redis_instance dari file konfigurasi Terraform Anda.
    2. Jalankan Terraform init, plan, dan apply untuk menghancurkan resource Redis.
    3. Hapus semua VM Compute Engine yang Anda buat untuk panduan memulai ini.

    Mengonfigurasi Terraform untuk menyiapkan beberapa jaringan VPC

    Bagian di halaman ini menunjukkan contoh pembuatan instance Memorystore for Redis Cluster dan penyiapan konektivitas di jaringan Virtual Private Cloud (VPC). Untuk menemukan petunjuk dan contoh penggunaan Terraform untuk menyiapkan konektivitas di beberapa jaringan VPC, lihat halaman google_redis_cluster_user_created_connections.

Langkah berikutnya