Terraform을 사용하여 트리거 만들기

이 문서에서는 다음 대상의 google_eventarc_trigger 리소스를 사용하여 Terraform에서 Google Cloud 리소스를 사용하여 Eventarc 트리거를 만드는 방법을 설명합니다.

• Cloud Run: google_cloud_run_v2_service Terraform 리소스를 사용합니다.
• Google Kubernetes Engine: google_container_cluster Terraform 리소스를 사용합니다.
• Workflows: google_workflows_workflow Terraform 리소스를 사용합니다.

이 튜토리얼의 예시에서는 Cloud Storage의 직접 이벤트를 사용하지만 모든 이벤트 제공자에 맞게 조정할 수 있습니다. 이 튜토리얼에서는 이벤트 소스로 새 리소스가 생성됩니다.

Terraform 사용 방법에 대한 리소스와 안내는 Google Cloud 기반 Terraform 문서를 참조하세요.

시작하기 전에

1. Google Cloud 계정에 로그인합니다. Google Cloud를 처음 사용하는 경우 계정을 만들고 Google 제품의 실제 성능을 평가해 보세요. 신규 고객에게는 워크로드를 실행, 테스트, 배포하는 데 사용할 수 있는 $300의 무료 크레딧이 제공됩니다.

2. In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

   Note: If you don't plan to keep the resources that you create in this procedure, create a project instead of selecting an existing project. After you finish these steps, you can delete the project, removing all resources associated with the project.

   Go to project selector

3. Google Cloud 프로젝트에 결제가 사용 설정되어 있는지 확인합니다.

4. In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

   Note: If you don't plan to keep the resources that you create in this procedure, create a project instead of selecting an existing project. After you finish these steps, you can delete the project, removing all resources associated with the project.

   Go to project selector

5. Google Cloud 프로젝트에 결제가 사용 설정되어 있는지 확인합니다.

6. Enable the Resource Manager and Identity and Access Management (IAM) APIs.

   Enable the APIs

7. In the Google Cloud console, activate Cloud Shell.

   Activate Cloud Shell

   At the bottom of the Google Cloud console, a Cloud Shell session starts and displays a command-line prompt. Cloud Shell is a shell environment with the Google Cloud CLI already installed and with values already set for your current project. It can take a few seconds for the session to initialize.

Cloud Shell은 Terraform이 이미 통합된 셸 환경입니다.

Eventarc 트리거 만들기

Terraform을 사용하여 여러 대상에 Eventarc 트리거를 만들 수 있습니다.

이 예시에서는 참조 변수, 리소스 속성, 호출 함수와 같은 대체 항목의 보간 유형을 사용합니다.

Cloud Run

Cloud Shell을 사용하여 Terraform으로 리소스를 배포하여 Eventarc 트리거를 만듭니다.

1. API 사용 설정

다음 코드를 사용하여 필수 API를 사용 설정합니다.

# Enable Cloud Run API
resource "google_project_service" "run" {
  service            = "run.googleapis.com"
  disable_on_destroy = false
}

# Enable Eventarc API
resource "google_project_service" "eventarc" {
  service            = "eventarc.googleapis.com"
  disable_on_destroy = false
}

# Enable Pub/Sub API
resource "google_project_service" "pubsub" {
  service            = "pubsub.googleapis.com"
  disable_on_destroy = false
}

2. 서비스 계정 만들기 및 IAM 구성

다음 코드를 사용하여 전용 서비스 계정과 IAM 역할을 만듭니다.

# Used to retrieve project information later
data "google_project" "project" {}

# Create a dedicated service account
resource "google_service_account" "eventarc" {
  account_id   = "eventarc-trigger-sa"
  display_name = "Eventarc Trigger Service Account"
}

# Grant permission to receive Eventarc events
resource "google_project_iam_member" "eventreceiver" {
  project = data.google_project.project.id
  role    = "roles/eventarc.eventReceiver"
  member  = "serviceAccount:${google_service_account.eventarc.email}"
}

# Grant permission to invoke Cloud Run services
resource "google_project_iam_member" "runinvoker" {
  project = data.google_project.project.id
  role    = "roles/run.invoker"
  member  = "serviceAccount:${google_service_account.eventarc.email}"
}

2021년 4월 8일이나 이전에 Pub/Sub을 사용 설정한 경우 iam.serviceAccountTokenCreator 역할을 서비스 에이전트에 부여합니다.

resource "google_project_iam_member" "tokencreator" {
   project  = data.google_project.project.id
   role     = "roles/iam.serviceAccountTokenCreator"
   member   = "serviceAccount:service-${data.google_project.project.number}@gcp-sa-pubsub.iam.gserviceaccount.com"
}

3. Cloud Storage 버킷을 이벤트 제공자로 만들기

다음 코드를 사용하여 Eventarc 관련 권한으로 Cloud Storage 버킷을 만듭니다.

# Cloud Storage bucket names must be globally unique
resource "random_id" "bucket_name_suffix" {
  byte_length = 4
}

# Create a Cloud Storage bucket
resource "google_storage_bucket" "default" {
  name          = "trigger-cloudrun-${data.google_project.project.name}-${random_id.bucket_name_suffix.hex}"
  location      = google_cloud_run_v2_service.default.location
  force_destroy = true

  uniform_bucket_level_access = true
}

# Grant the Cloud Storage service account permission to publish pub/sub topics
data "google_storage_project_service_account" "gcs_account" {}
resource "google_project_iam_member" "pubsubpublisher" {
  project = data.google_project.project.id
  role    = "roles/pubsub.publisher"
  member  = "serviceAccount:${data.google_storage_project_service_account.gcs_account.email_address}"
}

4. Cloud Run 서비스를 이벤트 대상으로 정의

Cloud Run 서비스를 트리거의 이벤트 대상으로 만듭니다. google_cloud_run_v2_service 리소스를 사용하여 Cloud Run 서비스를 정의합니다.

# Deploy Cloud Run service
resource "google_cloud_run_v2_service" "default" {
  name     = "hello-events"
  location = "us-central1"

  template {
    containers {
      # This container will log received events
      image = "us-docker.pkg.dev/cloudrun/container/hello"
    }
    service_account = google_service_account.eventarc.email
  }

  depends_on = [google_project_service.run]
}

5. Eventarc 트리거 정의

Eventarc 트리거는 이벤트 제공자를 이벤트 대상에 연결합니다. google_eventarc_trigger 리소스를 사용하여 Cloud Run 대상으로 전송하는 Cloud Storage 직접 이벤트 제공자를 정의합니다.

트리거를 만들 때 지정한 event-filters와 같이 작동하는 Eventarc에서 지원하는 CloudEvents 속성을 사용하여 matching_criteria를 여러 개 정의할 수 있습니다. 자세한 내용은 특정 제공자, 이벤트 유형, Cloud Run 대상에 대한 트리거를 만들 때 다음 안내를 따르세요. 모든 필터와 일치하는 이벤트를 대상으로 전송됩니다.

# Create an Eventarc trigger, routing Cloud Storage events to Cloud Run
resource "google_eventarc_trigger" "default" {
  name     = "trigger-storage-cloudrun-tf"
  location = google_cloud_run_v2_service.default.location

  # Capture objects changed in the bucket
  matching_criteria {
    attribute = "type"
    value     = "google.cloud.storage.object.v1.finalized"
  }
  matching_criteria {
    attribute = "bucket"
    value     = google_storage_bucket.default.name
  }

  # Send events to Cloud Run
  destination {
    cloud_run_service {
      service = google_cloud_run_v2_service.default.name
      region  = google_cloud_run_v2_service.default.location
    }
  }

  service_account = google_service_account.eventarc.email
  depends_on = [
    google_project_service.eventarc,
    google_project_iam_member.pubsubpublisher
  ]
}

6. 변경사항 적용

Terraform 구성을 적용하거나 삭제하는 방법은 기본 Terraform 명령어를 참조하세요.

Google Cloud 프로젝트에 Terraform 구성을 적용하려면 다음 섹션의 단계를 완료하세요.

Cloud Shell 준비

1. Cloud Shell을 실행합니다.

2. Terraform 구성을 적용할 기본 Google Cloud 프로젝트를 설정합니다.

   이 명령어는 프로젝트당 한 번만 실행하면 되며 어떤 디렉터리에서도 실행할 수 있습니다.

   export GOOGLE_CLOUD_PROJECT=PROJECT_ID

   Terraform 구성 파일에서 명시적 값을 설정하면 환경 변수가 재정의됩니다.

디렉터리 준비

각 Terraform 구성 파일에는 자체 디렉터리(루트 모듈이라고도 함)가 있어야 합니다.

1. Cloud Shell에서 디렉터리를 만들고 해당 디렉터리 내에 새 파일을 만드세요. 파일 이름에는 .tf 확장자가 있어야 합니다(예: main.tf). 이 튜토리얼에서는 파일을 main.tf라고 합니다.

   mkdir DIRECTORY && cd DIRECTORY && touch main.tf

2. 튜토리얼을 따라 하는 경우 각 섹션이나 단계에서 샘플 코드를 복사할 수 있습니다.

   샘플 코드를 새로 만든 main.tf에 복사합니다.

   필요한 경우 GitHub에서 코드를 복사합니다. 이는 Terraform 스니펫이 엔드 투 엔드 솔루션의 일부인 경우에 권장됩니다.

3. 환경에 적용할 샘플 매개변수를 검토하고 수정합니다.
4. 변경사항을 저장합니다.
5. Terraform을 초기화합니다. 이 작업은 디렉터리당 한 번만 수행하면 됩니다.

   terraform init

   원하는 경우 최신 Google 공급업체 버전을 사용하려면 -upgrade 옵션을 포함합니다.

   terraform init -upgrade

변경사항 적용

1. 구성을 검토하고 Terraform에서 만들거나 업데이트할 리소스가 예상과 일치하는지 확인합니다.

   terraform plan

   필요에 따라 구성을 수정합니다.

2. 다음 명령어를 실행하고 프롬프트에 yes를 입력하여 Terraform 구성을 적용합니다.

   terraform apply

   Terraform에 '적용 완료' 메시지가 표시될 때까지 기다립니다.

3. 결과를 보려면 Google Cloud 프로젝트를 엽니다. Google Cloud 콘솔에서 UI의 리소스로 이동하여 Terraform이 리소스를 만들었거나 업데이트했는지 확인합니다.

참고: Terraform 샘플은 일반적으로 필요한 API가 Google Cloud 프로젝트에서 사용 설정되었다고 가정합니다.

참고: 필요한 모든 권한이 Eventarc 서비스 에이전트에 전파되는 데 몇 분 정도 걸릴 수 있습니다. 이 문제가 발생하면 몇 분 정도 기다린 후 terraform apply를 다시 실행하세요.

7. 리소스 생성 확인

서비스가 만들어졌는지 확인하려면 다음을 수행하세요.

gcloud run services list --region us-central1

트리거가 생성되었는지 확인하려면 다음 명령어를 실행합니다.

gcloud eventarc triggers list --location us-central1

출력은 다음과 비슷하게 표시됩니다.

NAME: trigger-storage-cloudrun-tf
TYPE: google.cloud.storage.object.v1.finalized
DESTINATION: Cloud Run service: hello-events
ACTIVE: Yes
LOCATION: us-central1

참고: 트리거는 즉시 생성되지만 트리거에서 이벤트를 전파하고 필터링하는 데 최대 2분이 걸릴 수 있습니다.

GKE

Cloud Shell을 사용하여 Terraform으로 리소스를 배포하여 Eventarc 트리거를 만듭니다.

Eventarc 트리거를 사용하려면 Google Kubernetes Engine 서비스가 필요합니다. 이 튜토리얼을 단순화하기 위해, Terraform 구성을 적용하는 사이에 Terraform 외부에서 이 서비스를 구성합니다.

1. GKE 클러스터 만들기

다음 코드를 사용하여 필수 API를 사용 설정합니다.

# Enable GKE API
resource "google_project_service" "container" {
  service            = "container.googleapis.com"
  disable_on_destroy = false
}

# Enable Eventarc API
resource "google_project_service" "eventarc" {
  service            = "eventarc.googleapis.com"
  disable_on_destroy = false
}

# Enable Pub/Sub API
resource "google_project_service" "pubsub" {
  service            = "pubsub.googleapis.com"
  disable_on_destroy = false
}

다음 코드를 사용하여 GKE 클러스터를 만듭니다.

# Create an auto-pilot GKE cluster
resource "google_container_cluster" "gke_cluster" {
  name     = "eventarc-cluster"
  location = "us-central1"

  enable_autopilot = true

  depends_on = [
    google_project_service.container
  ]
}

2. 변경사항 적용

Terraform 구성을 적용하거나 삭제하는 방법은 기본 Terraform 명령어를 참조하세요.

Google Cloud 프로젝트에 Terraform 구성을 적용하려면 다음 섹션의 단계를 완료하세요.

Cloud Shell 준비

1. Cloud Shell을 실행합니다.

2. Terraform 구성을 적용할 기본 Google Cloud 프로젝트를 설정합니다.

   이 명령어는 프로젝트당 한 번만 실행하면 되며 어떤 디렉터리에서도 실행할 수 있습니다.

   export GOOGLE_CLOUD_PROJECT=PROJECT_ID

   Terraform 구성 파일에서 명시적 값을 설정하면 환경 변수가 재정의됩니다.

디렉터리 준비

각 Terraform 구성 파일에는 자체 디렉터리(루트 모듈이라고도 함)가 있어야 합니다.

1. Cloud Shell에서 디렉터리를 만들고 해당 디렉터리 내에 새 파일을 만드세요. 파일 이름에는 .tf 확장자가 있어야 합니다(예: main.tf). 이 튜토리얼에서는 파일을 main.tf라고 합니다.

   mkdir DIRECTORY && cd DIRECTORY && touch main.tf

2. 튜토리얼을 따라 하는 경우 각 섹션이나 단계에서 샘플 코드를 복사할 수 있습니다.

   샘플 코드를 새로 만든 main.tf에 복사합니다.

   필요한 경우 GitHub에서 코드를 복사합니다. 이는 Terraform 스니펫이 엔드 투 엔드 솔루션의 일부인 경우에 권장됩니다.

3. 환경에 적용할 샘플 매개변수를 검토하고 수정합니다.
4. 변경사항을 저장합니다.
5. Terraform을 초기화합니다. 이 작업은 디렉터리당 한 번만 수행하면 됩니다.

   terraform init

   원하는 경우 최신 Google 공급업체 버전을 사용하려면 -upgrade 옵션을 포함합니다.

   terraform init -upgrade

변경사항 적용

1. 구성을 검토하고 Terraform에서 만들거나 업데이트할 리소스가 예상과 일치하는지 확인합니다.

   terraform plan

   필요에 따라 구성을 수정합니다.

2. 다음 명령어를 실행하고 프롬프트에 yes를 입력하여 Terraform 구성을 적용합니다.

   terraform apply

   Terraform에 '적용 완료' 메시지가 표시될 때까지 기다립니다.

3. 결과를 보려면 Google Cloud 프로젝트를 엽니다. Google Cloud 콘솔에서 UI의 리소스로 이동하여 Terraform이 리소스를 만들었거나 업데이트했는지 확인합니다.

참고: Terraform 샘플은 일반적으로 필요한 API가 Google Cloud 프로젝트에서 사용 설정되었다고 가정합니다.

3. GKE 구성

사전 빌드된 Cloud Run 이미지 us-docker.pkg.dev/cloudrun/container/hello를 사용하여 HTTP 요청과 로그 이벤트를 수신하는 GKE에 Kubernetes 서비스를 배포합니다.

1. 클러스터와 상호작용하기 위해 사용자 인증 정보를 가져옵니다.

   gcloud container clusters get-credentials eventarc-cluster \
      --region=us-central1
   

2. hello-gke 배포를 만듭니다.

   kubectl create deployment hello-gke \
      --image=us-docker.pkg.dev/cloudrun/container/hello
   

3. 배포를 Kubernetes 서비스로 노출합니다.

   kubectl expose deployment hello-gke \
      --type ClusterIP --port 80 --target-port 8080
   

4. 포드가 실행 중인지 확인합니다.

   kubectl get pods
   

   출력은 다음과 비슷하게 표시됩니다.

   NAME                        READY   STATUS
   hello-gke-df6469d4b-5vv22   1/1     Running
   

   STATUS가 Pending이면 포드가 배포되고 있는 것입니다. 배포가 완료될 때까지 기다린 후 상태를 다시 확인합니다.

5. 서비스가 실행 중인지 확인합니다.

   kubectl get svc
   

   출력은 다음과 비슷하게 표시됩니다.

   NAME         TYPE        CLUSTER-IP       EXTERNAL-IP   PORT(S)   AGE
   hello-gke    ClusterIP   34.118.226.144   <none>        80/TCP
   kubernetes   ClusterIP   34.118.224.1     <none>        443/TCP
   

4. Eventarc 만들기 및 구성

다음 구성을 사용하여 서비스 계정을 설정하고 Eventarc에 GKE의 이벤트를 관리할 수 있는 특정 역할을 부여합니다.

# Create a service account to be used by GKE trigger
resource "google_service_account" "eventarc_gke_trigger_sa" {
  account_id   = "eventarc-gke-trigger-sa"
  display_name = "Evenarc GKE Trigger Service Account"
}

# Grant permission to receive Eventarc events
resource "google_project_iam_member" "eventreceiver" {
  project = data.google_project.project.id
  role    = "roles/eventarc.eventReceiver"
  member  = "serviceAccount:${google_service_account.eventarc_gke_trigger_sa.email}"
}

# Grant permission to subscribe to Pub/Sub topics
resource "google_project_iam_member" "pubsubscriber" {
  project = data.google_project.project.id
  role    = "roles/pubsub.subscriber"
  member  = "serviceAccount:${google_service_account.eventarc_gke_trigger_sa.email}"
}

다음 코드를 사용하여 Eventarc 관련 권한으로 Cloud Storage 버킷을 만듭니다.

# Cloud Storage bucket names must be globally unique
resource "random_id" "bucket_name_suffix" {
  byte_length = 4
}

# Create a Cloud Storage bucket
resource "google_storage_bucket" "default" {
  name          = "trigger-gke-${data.google_project.project.name}-${random_id.bucket_name_suffix.hex}"
  location      = "us-central1"
  force_destroy = true

  uniform_bucket_level_access = true
}

# Grant the Cloud Storage service account permission to publish pub/sub topics
data "google_storage_project_service_account" "gcs_account" {}
resource "google_project_iam_member" "pubsubpublisher" {
  project = data.google_project.project.id
  role    = "roles/pubsub.publisher"
  member  = "serviceAccount:${data.google_storage_project_service_account.gcs_account.email_address}"
}

다음 구성을 사용하여 필수 API를 사용 설정하고 Eventarc GKE 대상 서비스를 초기화합니다.

# Used to retrieve project_number later
data "google_project" "project" {}

# Enable Eventarc to manage GKE clusters
# This is usually done with: gcloud eventarc gke-destinations init
#
# Eventarc creates a separate Event Forwarder pod for each trigger targeting a
# GKE service, and  requires explicit permissions to make changes to the
# cluster. This is done by granting permissions to a special service account
# (the Eventarc P4SA) to manage resources in the cluster. This needs to be done
# once per Google Cloud project.

# This identity is created with: gcloud beta services identity create --service eventarc.googleapis.com
# This local variable is used for convenience
locals {
  eventarc_sa = "serviceAccount:service-${data.google_project.project.number}@gcp-sa-eventarc.iam.gserviceaccount.com"
}

resource "google_project_iam_member" "computeViewer" {
  project = data.google_project.project.id
  role    = "roles/compute.viewer"
  member  = local.eventarc_sa
}

resource "google_project_iam_member" "containerDeveloper" {
  project = data.google_project.project.id
  role    = "roles/container.developer"
  member  = local.eventarc_sa
}

resource "google_project_iam_member" "serviceAccountAdmin" {
  project = data.google_project.project.id
  role    = "roles/iam.serviceAccountAdmin"
  member  = local.eventarc_sa
}

Pub/Sub 이벤트를 hello-gke GKE 서비스로 라우팅하는 Eventarc 트리거를 만듭니다.

트리거를 만들 때 지정한 event-filters와 같이 작동하는 Eventarc에서 지원하는 CloudEvents 속성을 사용하여 matching_criteria를 여러 개 정의할 수 있습니다. 자세한 내용은 특정 제공업체, 이벤트 유형, GKE 대상에 대한 트리거를 만들 때 다음 안내를 따르세요. 모든 필터와 일치하는 이벤트를 대상으로 전송됩니다.

# Create an Eventarc trigger, routing Storage events to GKE
resource "google_eventarc_trigger" "default" {
  name     = "trigger-storage-gke-tf"
  location = "us-central1"

  # Capture objects changed in the bucket
  matching_criteria {
    attribute = "type"
    value     = "google.cloud.storage.object.v1.finalized"
  }
  matching_criteria {
    attribute = "bucket"
    value     = google_storage_bucket.default.name
  }

  # Send events to GKE service
  destination {
    gke {
      cluster   = "eventarc-cluster"
      location  = "us-central1"
      namespace = "default"
      path      = "/"
      service   = "hello-gke"
    }
  }

  service_account = google_service_account.eventarc_gke_trigger_sa.email
}

5. 추가 변경사항 적용

추가 Terraform 구성을 Google Cloud 프로젝트에 적용하려면 다음 단계를 완료합니다.

1. Eventarc ID 계정을 만듭니다.

   gcloud beta services identity create --service eventarc.googleapis.com
   

2. 이전 단계의 새 Terraform 코드를 기존 main.tf 파일에 추가합니다.

3. 업데이트된 Terraform 구성을 적용합니다.

   terraform plan
   terraform apply
   

   Terraform에 '적용 완료' 메시지가 표시될 때까지 기다립니다.

   참고: 필요한 모든 권한이 Eventarc 서비스 에이전트에 전파되는 데 몇 분 정도 걸릴 수 있습니다. 이 문제가 발생하면 몇 분 정도 기다린 후 terraform apply를 다시 실행하세요.

4. 결과를 보려면 Google Cloud 프로젝트를 엽니다. Google Cloud 콘솔에서 UI의 리소스로 이동하여 Terraform이 리소스를 만들었거나 업데이트했는지 확인합니다.

워크플로

Cloud Shell을 사용하여 Terraform으로 리소스를 배포해 워크플로와 Eventarc 트리거를 만듭니다.

1. API 사용 설정

다음 코드를 사용하여 필수 API를 사용 설정합니다.

# Enable Eventarc API
resource "google_project_service" "eventarc" {
  service            = "eventarc.googleapis.com"
  disable_on_destroy = false
}

# Enable Workflows API
resource "google_project_service" "workflows" {
  service            = "workflows.googleapis.com"
  disable_on_destroy = false
}

# Enable Pub/Sub API
resource "google_project_service" "pubsub" {
  service            = "pubsub.googleapis.com"
  disable_on_destroy = false
}

2. 서비스 계정 만들기 및 IAM 구성

다음 코드를 사용하여 전용 서비스 계정을 만들고 IAM 역할을 추가합니다.

# Used to retrieve project information later
data "google_project" "project" {}

# Create a service account for Eventarc trigger and Workflows
resource "google_service_account" "eventarc" {
  account_id   = "eventarc-workflows-sa"
  display_name = "Eventarc Workflows Service Account"
}

# Grant permission to invoke workflows
resource "google_project_iam_member" "workflowsinvoker" {
  project = data.google_project.project.id
  role    = "roles/workflows.invoker"
  member  = "serviceAccount:${google_service_account.eventarc.email}"
}

# Grant permission to receive events
resource "google_project_iam_member" "eventreceiver" {
  project = data.google_project.project.id
  role    = "roles/eventarc.eventReceiver"
  member  = "serviceAccount:${google_service_account.eventarc.email}"
}

2021년 4월 8일이나 이전에 Pub/Sub을 사용 설정한 경우 iam.serviceAccountTokenCreator 역할을 서비스 에이전트에 부여합니다.

resource "google_project_iam_member" "tokencreator" {
   project  = data.google_project.project.id
   role     = "roles/iam.serviceAccountTokenCreator"
   member   = "serviceAccount:service-${data.google_project.project.number}@gcp-sa-pubsub.iam.gserviceaccount.com"
}

3. Cloud Storage 버킷을 이벤트 제공자로 만들기

다음 코드를 사용하여 Eventarc 관련 권한으로 Cloud Storage 버킷을 만듭니다.

# Cloud Storage bucket names must be globally unique
resource "random_id" "bucket_name_suffix" {
  byte_length = 4
}

# Create a Cloud Storage bucket
resource "google_storage_bucket" "default" {
  name          = "trigger-workflows-${data.google_project.project.name}-${random_id.bucket_name_suffix.hex}"
  location      = google_workflows_workflow.default.region
  force_destroy = true

  uniform_bucket_level_access = true
}

# Grant the Cloud Storage service account permission to publish Pub/Sub topics
data "google_storage_project_service_account" "gcs_account" {}
resource "google_project_iam_member" "pubsubpublisher" {
  project = data.google_project.project.id
  role    = "roles/pubsub.publisher"
  member  = "serviceAccount:${data.google_storage_project_service_account.gcs_account.email_address}"
}

4. 워크플로 생성 및 배포

생성된 버킷에서 객체가 업데이트될 때 실행되는 워크플로를 정의하고 배포합니다.

# Create a workflow
resource "google_workflows_workflow" "default" {
  name        = "storage-workflow-tf"
  region      = "us-central1"
  description = "Workflow that returns information about storage events"

  # Note that $$ is needed for Terraform
  source_contents = <<EOF
  main:
    params: [event]
    steps:
      - log_event:
          call: sys.log
          args:
            text: $${event}
            severity: INFO
      - gather_data:
          assign:
            - bucket: $${event.data.bucket}
            - name: $${event.data.name}
            - message: $${"Received event " + event.type + " - " + bucket + ", " + name}
      - return_data:
          return: $${message}
  EOF

  depends_on = [
    google_project_service.workflows
  ]
}

5. Eventarc 트리거 만들기

생성된 버킷의 직접 이벤트를 Workflows로 라우팅하는 Eventarc 트리거를 만듭니다. google_eventarc_trigger 리소스를 사용하여 Eventarc 트리거 리소스를 정의합니다.

트리거를 만들 때 지정한 event-filters와 같이 작동하는 Eventarc에서 지원하는 CloudEvents 속성을 사용하여 matching_criteria를 여러 개 정의할 수 있습니다. 자세한 내용은 특정 제공업체, 이벤트 유형, Workflows 대상에 대한 트리거를 만들 때 다음 안내를 따르세요.

모든 필터와 일치하는 이벤트를 대상으로 전송됩니다.

# Create an Eventarc trigger, routing Cloud Storage events to Workflows
resource "google_eventarc_trigger" "default" {
  name     = "trigger-storage-workflows-tf"
  location = google_workflows_workflow.default.region

  # Capture objects changed in the bucket
  matching_criteria {
    attribute = "type"
    value     = "google.cloud.storage.object.v1.finalized"
  }
  matching_criteria {
    attribute = "bucket"
    value     = google_storage_bucket.default.name
  }

  # Send events to Workflows
  destination {
    workflow = google_workflows_workflow.default.id
  }

  service_account = google_service_account.eventarc.email

  depends_on = [
    google_project_service.eventarc,
    google_project_service.workflows,
  ]
}

6. 변경사항 적용

Terraform 구성을 적용하거나 삭제하는 방법은 기본 Terraform 명령어를 참조하세요.

Google Cloud 프로젝트에 Terraform 구성을 적용하려면 다음 섹션의 단계를 완료하세요.

Cloud Shell 준비

1. Cloud Shell을 실행합니다.

2. Terraform 구성을 적용할 기본 Google Cloud 프로젝트를 설정합니다.

   이 명령어는 프로젝트당 한 번만 실행하면 되며 어떤 디렉터리에서도 실행할 수 있습니다.

   export GOOGLE_CLOUD_PROJECT=PROJECT_ID

   Terraform 구성 파일에서 명시적 값을 설정하면 환경 변수가 재정의됩니다.

디렉터리 준비

각 Terraform 구성 파일에는 자체 디렉터리(루트 모듈이라고도 함)가 있어야 합니다.

1. Cloud Shell에서 디렉터리를 만들고 해당 디렉터리 내에 새 파일을 만드세요. 파일 이름에는 .tf 확장자가 있어야 합니다(예: main.tf). 이 튜토리얼에서는 파일을 main.tf라고 합니다.

   mkdir DIRECTORY && cd DIRECTORY && touch main.tf

2. 튜토리얼을 따라 하는 경우 각 섹션이나 단계에서 샘플 코드를 복사할 수 있습니다.

   샘플 코드를 새로 만든 main.tf에 복사합니다.

   필요한 경우 GitHub에서 코드를 복사합니다. 이는 Terraform 스니펫이 엔드 투 엔드 솔루션의 일부인 경우에 권장됩니다.

3. 환경에 적용할 샘플 매개변수를 검토하고 수정합니다.
4. 변경사항을 저장합니다.
5. Terraform을 초기화합니다. 이 작업은 디렉터리당 한 번만 수행하면 됩니다.

   terraform init

   원하는 경우 최신 Google 공급업체 버전을 사용하려면 -upgrade 옵션을 포함합니다.

   terraform init -upgrade

변경사항 적용

1. 구성을 검토하고 Terraform에서 만들거나 업데이트할 리소스가 예상과 일치하는지 확인합니다.

   terraform plan

   필요에 따라 구성을 수정합니다.

2. 다음 명령어를 실행하고 프롬프트에 yes를 입력하여 Terraform 구성을 적용합니다.

   terraform apply

   Terraform에 '적용 완료' 메시지가 표시될 때까지 기다립니다.

3. 결과를 보려면 Google Cloud 프로젝트를 엽니다. Google Cloud 콘솔에서 UI의 리소스로 이동하여 Terraform이 리소스를 만들었거나 업데이트했는지 확인합니다.

참고: Terraform 샘플은 일반적으로 필요한 API가 Google Cloud 프로젝트에서 사용 설정되었다고 가정합니다.

참고: Eventarc에서 필요한 모든 권한을 서비스 에이전트에 전파하는 데 몇 분 정도 걸릴 수 있습니다. 이 문제가 발생하면 몇 분 정도 기다린 후 terraform apply를 다시 실행하세요.

7. 워크플로 생성 확인

워크플로가 생성되었는지 확인하려면 다음 명령어를 실행합니다.

gcloud workflows list --location us-central1

8. Eventarc 트리거 생성 확인

Eventarc 트리거가 생성되었는지 확인하려면 다음 명령어를 실행합니다.

gcloud eventarc triggers list --location us-central1

출력은 다음과 비슷하게 표시됩니다.

NAME: trigger-storage-workflows-tf
TYPE: google.cloud.storage.object.v1.finalized
DESTINATION: Workflows: storage-workflow-tf
ACTIVE: Yes
LOCATION: us-central1

이벤트 생성 및 확인

이벤트를 생성하고 Eventarc 트리거가 예상대로 작동하는지 확인할 수 있습니다.

Cloud Run

1. 이벤트를 생성하려면 다음 안내를 따르세요.

   텍스트 파일을 Cloud Storage에 업로드합니다.

   echo "Hello World" > random.txt
   gcloud storage cp random.txt gs://trigger-cloudrun-PROJECT_ID/random.txt
   

   업로드 시 이벤트가 생성되고 Cloud Run 서비스에서 이벤트의 메시지를 로깅합니다.

2. 이벤트가 수신되었는지 확인하려면 다음 안내를 따르세요.

   1. 서비스에서 만든 이벤트 관련 로그 항목을 확인합니다.

   gcloud logging read "resource.type=cloud_run_revision \
       AND resource.labels.service_name=hello-events"
   

   또는 Google Cloud 콘솔을 열고 Cloud Run 리소스로 이동하여 로그를 봅니다.

   1. 다음과 같은 로그 항목을 찾습니다.

   Received event of type google.cloud.storage.object.v1.finalized.
   Event data: { "kind": "storage#object", "id": "trigger-cloudrun-PROJECT_ID/random.txt", ...}
   

   참고: 로그 항목이 표시되지 않으면 몇 분 정도 기다린 후 gcloud logging read 명령어를 다시 시도하세요. 트리거가 생성된 후 필터링 이벤트가 시작되는 데 최대 2분이 걸릴 수 있습니다.

GKE

1. 이벤트를 생성하려면 다음 안내를 따르세요.

   텍스트 파일을 Cloud Storage에 업로드합니다.

   echo "Hello World" > random.txt
   gcloud storage cp random.txt gs://trigger-gke-PROJECT_ID/random.txt
   

   업로드 시 이벤트가 생성되고 Cloud Run 서비스에서 이벤트의 메시지를 로깅합니다.

2. 이벤트가 수신되었는지 확인하려면 다음 안내를 따르세요.

   1. 포드 ID를 찾습니다.

      POD_NAME=$(kubectl get pods -o custom-columns=":metadata.name" --no-headers)
      

      이 명령어에서 kubectl의 형식이 지정된 출력을 사용합니다.

   2. 포드의 로그를 확인합니다.

      kubectl logs $POD_NAME
      

   3. 다음과 같은 로그 항목을 찾습니다.

      {"severity":"INFO","eventType":"google.cloud.pubsub.topic.v1.messagePublished",
      "message":"Received event of type google.cloud.pubsub.topic.v1.messagePublished.", [...]}
      

워크플로

1. 이벤트를 생성하려면 다음 안내를 따르세요.

   텍스트 파일을 Cloud Storage에 업로드합니다.

   echo "Hello World" > random.txt
   gcloud storage cp random.txt gs://trigger-workflows-PROJECT_ID/random.txt
   

   업로드 시 이벤트가 생성되고 Cloud Run 서비스에서 이벤트의 메시지를 로깅합니다.

2. 이벤트가 수신되었는지 확인하려면 다음 안내를 따르세요.

   1. 마지막 실행 5개를 나열하여 워크플로 실행이 트리거되는지 확인합니다.

      gcloud workflows executions list storage-workflow-tf --limit=5
      

      출력에는 NAME, START_TIME, END_TIME, STATUS가 있는 실행 목록이 포함됩니다.

   2. 가장 최근 실행 결과를 가져옵니다.

      EXECUTION_NAME=$(gcloud workflows executions list storage-workflow-tf --limit=1 --format "value(name)")
      gcloud workflows executions describe $EXECUTION_NAME
      

   3. 출력이 다음과 비슷한지 확인합니다.

      ...
      result: '"Received event google.cloud.storage.object.v1.finalized - trigger-workflows-PROJECT_ID, random.txt"'
      state: SUCCEEDED
      ...
      

      워크플로 출력에서 state: SUCCEEDED 및 result: "Received event"를 찾습니다.

삭제

다음 명령어를 실행하고 프롬프트에 yes를 입력하여 이전에 Terraform 구성에 적용된 리소스를 삭제합니다.

terraform destroy

비용이 청구되지 않도록 Google Cloud 프로젝트를 삭제할 수도 있습니다. Google Cloud 프로젝트를 삭제하면 프로젝트 내에서 사용되는 모든 리소스에 대한 비용 청구가 중지됩니다.

주의: 프로젝트를 삭제하면 다음과 같은 효과가 발생합니다.
• 프로젝트의 모든 항목이 삭제됩니다. 이 문서의 태스크에 기존 프로젝트를 사용한 경우 프로젝트를 삭제하면 프로젝트에서 수행한 다른 작업도 삭제됩니다.
• 커스텀 프로젝트 ID가 손실됩니다. 이 프로젝트를 만들 때 앞으로 사용할 커스텀 프로젝트 ID를 만들었을 수 있습니다. appspot.com URL과 같이 프로젝트 ID를 사용하는 URL을 보존하려면 전체 프로젝트를 삭제하는 대신 프로젝트 내에서 선택한 리소스만 삭제합니다.
1. In the Google Cloud console, go to the Manage resources page.

   Go to Manage resources

2. In the project list, select the project that you want to delete, and then click Delete.
3. In the dialog, type the project ID, and then click Shut down to delete the project.

다음 단계

• gcloud CLI 또는 콘솔을 사용하여 이벤트로 워크플로를 트리거하려면 이벤트 또는 Pub/Sub 메시지로 워크플로 트리거를 참조하세요.