Creare un trigger utilizzando Terraform

Questo documento descrive come utilizzare le risorse Google Cloud in Terraform per creare trigger Eventarc utilizzando le risorse google_eventarc_trigger per le destinazioni seguenti:

Gli esempi in questo tutorial utilizzano eventi diretti da Cloud Storage, ma possono essere adattati per qualsiasi fornitore di eventi. Ai fini di questo tutorial, vengono create nuove risorse come origine degli eventi.

Per risorse e indicazioni sull'utilizzo di Terraform, consulta la documentazione di Terraform su Google Cloud.

Prima di iniziare

  1. Sign in to your Google Cloud account. If you're new to Google Cloud, create an account to evaluate how our products perform in real-world scenarios. New customers also get $300 in free credits to run, test, and deploy workloads.

  2. In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

    Go to project selector

  3. Make sure that billing is enabled for your Google Cloud project.

  4. In the Google Cloud console, on the project selector page, select or create a Google Cloud project.

    Go to project selector

  5. Make sure that billing is enabled for your Google Cloud project.

  6. Enable the Resource Manager and Identity and Access Management (IAM) APIs.

    Enable the APIs

  7. In the Google Cloud console, activate Cloud Shell.

    Activate Cloud Shell

    At the bottom of the Google Cloud console, a Cloud Shell session starts and displays a command-line prompt. Cloud Shell is a shell environment with the Google Cloud CLI already installed and with values already set for your current project. It can take a few seconds for the session to initialize.

    8. Cloud Shell è un ambiente shell con Terraform già integrato.

Crea trigger Eventarc

Puoi creare trigger Eventarc utilizzando Terraform per destinazioni diverse.

Questo esempio utilizza l'interpolazione per sostituzioni come variabili di riferimento, attributi delle risorse e funzioni di chiamata.

Cloud Run

Utilizzando Cloud Shell, esegui il deployment delle tue risorse con Terraform per creare trigger Eventarc.

1. Abilita le API

Utilizza il codice seguente per abilitare le API richieste:

eventarc/basic/main.tf 
# Enable Cloud Run API
resource "google_project_service" "run" {
  service            = "run.googleapis.com"
  disable_on_destroy = false
}

# Enable Eventarc API
resource "google_project_service" "eventarc" {
  service            = "eventarc.googleapis.com"
  disable_on_destroy = false
}

# Enable Pub/Sub API
resource "google_project_service" "pubsub" {
  service            = "pubsub.googleapis.com"
  disable_on_destroy = false
}

2. Crea un account di servizio e configura IAM

Utilizza il codice seguente per creare un account di servizio e ruoli IAM dedicati:

eventarc/basic/main.tf 
# Used to retrieve project information later
data "google_project" "project" {}

# Create a dedicated service account
resource "google_service_account" "eventarc" {
  account_id   = "eventarc-trigger-sa"
  display_name = "Eventarc Trigger Service Account"
}

# Grant permission to receive Eventarc events
resource "google_project_iam_member" "eventreceiver" {
  project = data.google_project.project.id
  role    = "roles/eventarc.eventReceiver"
  member  = "serviceAccount:${google_service_account.eventarc.email}"
}

# Grant permission to invoke Cloud Run services
resource "google_project_iam_member" "runinvoker" {
  project = data.google_project.project.id
  role    = "roles/run.invoker"
  member  = "serviceAccount:${google_service_account.eventarc.email}"
}

Se hai abilitato l'agente di servizio Pub/Sub entro l'8 aprile 2021, concedi il ruolo iam.serviceAccountTokenCreator all'account di servizio gestito da Google:

resource "google_project_iam_member" "tokencreator" {
   project  = data.google_project.project.id
   role     = "roles/iam.serviceAccountTokenCreator"
   member   = "serviceAccount:service-${data.google_project.project.number}@gcp-sa-pubsub.iam.gserviceaccount.com"
}

3. Crea un bucket Cloud Storage come provider di eventi

Utilizza il codice seguente per creare un bucket Cloud Storage, con autorizzazioni relative a Eventarc:

eventarc/basic/main.tf 
# Cloud Storage bucket names must be globally unique
resource "random_id" "bucket_name_suffix" {
  byte_length = 4
}

# Create a Cloud Storage bucket
resource "google_storage_bucket" "default" {
  name          = "trigger-cloudrun-${data.google_project.project.name}-${random_id.bucket_name_suffix.hex}"
  location      = google_cloud_run_v2_service.default.location
  force_destroy = true

  uniform_bucket_level_access = true
}

# Grant the Cloud Storage service account permission to publish pub/sub topics
data "google_storage_project_service_account" "gcs_account" {}
resource "google_project_iam_member" "pubsubpublisher" {
  project = data.google_project.project.id
  role    = "roles/pubsub.publisher"
  member  = "serviceAccount:${data.google_storage_project_service_account.gcs_account.email_address}"
}

4. Definire un servizio Cloud Run come target di evento

Creare un servizio Cloud Run come destinazione evento per il trigger. Utilizza la risorsa google_cloud_run_v2_service per definire un servizio Cloud Run:

eventarc/basic/main.tf 
# Deploy Cloud Run service
resource "google_cloud_run_v2_service" "default" {
  name     = "hello-events"
  location = "us-central1"

  template {
    containers {
      # This container will log received events
      image = "us-docker.pkg.dev/cloudrun/container/hello"
    }
    service_account = google_service_account.eventarc.email
  }

  depends_on = [google_project_service.run]
}

5. Definisci un trigger Eventarc

Un trigger Eventarc connette il provider di eventi a una destinazione dell'evento. Utilizza la risorsa google_eventarc_trigger per definire il provider di eventi diretti Cloud Storage, inviandolo a una destinazione Cloud Run.

Puoi definire più matching_criteria con gli attributi CloudEvents supportati da Eventarc che funzionano come il valore event-filters specificato quando crei un trigger. Per ulteriori informazioni, segui le istruzioni quando crei un trigger per un provider, un tipo di evento e una destinazione Cloud Run specifici. Gli eventi che corrispondono a tutti i filtri vengono inviati alla destinazione.

eventarc/basic/main.tf 
# Create an Eventarc trigger, routing Cloud Storage events to Cloud Run
resource "google_eventarc_trigger" "default" {
  name     = "trigger-storage-cloudrun-tf"
  location = google_cloud_run_v2_service.default.location

  # Capture objects changed in the bucket
  matching_criteria {
    attribute = "type"
    value     = "google.cloud.storage.object.v1.finalized"
  }
  matching_criteria {
    attribute = "bucket"
    value     = google_storage_bucket.default.name
  }

  # Send events to Cloud Run
  destination {
    cloud_run_service {
      service = google_cloud_run_v2_service.default.name
      region  = google_cloud_run_v2_service.default.location
    }
  }

  service_account = google_service_account.eventarc.email
  depends_on = [
    google_project_service.eventarc,
    google_project_iam_member.pubsubpublisher
  ]
}

6. Applica le modifiche

Per informazioni su come applicare o rimuovere una configurazione Terraform, consulta Comandi di base per Terraform.

Per applicare la configurazione Terraform in un progetto Google Cloud, completa i passaggi nelle sezioni seguenti.

Preparazione di Cloud Shell

  1. Avvia Cloud Shell.

  2. Imposta il progetto Google Cloud predefinito a cui vuoi applicare le configurazioni Terraform.

    Devi eseguire questo comando solo una volta per progetto e puoi eseguirlo in qualsiasi directory.

    export GOOGLE_CLOUD_PROJECT=PROJECT_ID

    Le variabili di ambiente vengono sostituite se imposti valori espliciti nel file di configurazione Terraform.

Prepara la directory

Ogni file di configurazione Terraform deve avere la propria directory (detta anche modulo principale).

  1. In Cloud Shell, crea una directory e un nuovo file al suo interno. Il nome del file deve avere l'estensione .tf, ad esempio main.tf. In questo tutorial, il file viene denominato main.tf. 
    mkdir DIRECTORY && cd DIRECTORY && touch main.tf

  2. Se stai seguendo un tutorial, puoi copiare il codice campione in ogni sezione o passaggio.

    Copia il codice campione nel file main.tf appena creato.

    Facoltativamente, copia il codice da GitHub. Questa opzione è consigliata quando lo snippet Terraform fa parte di una soluzione end-to-end.

  3. Esamina e modifica i parametri di esempio da applicare al tuo ambiente.
  4. Salva le modifiche.
  5. Inizializza Terraform. Devi eseguire questa operazione una sola volta per directory. 
    terraform init

    Facoltativamente, per utilizzare la versione più recente del provider Google, includi l'opzione -upgrade: 

    terraform init -upgrade

Applica le modifiche

  1. Esamina la configurazione e verifica che le risorse che Terraform creerà o aggiornerà corrispondano alle tue aspettative: 
    terraform plan

    Se necessario, apporta le correzioni alla configurazione.

  2. Applica la configurazione Terraform eseguendo il comando seguente e inserendo yes alla richiesta: 
    terraform apply

    Attendi che in Terraform venga visualizzato il messaggio "Apply complete!" (Applicazione completata).

  3. Apri il progetto Google Cloud per visualizzare i risultati. Nella console Google Cloud, vai alle risorse nell'interfaccia utente per assicurarti che Terraform le abbia create o aggiornate.

7. Verifica la creazione di risorse

Per verificare che il servizio sia stato creato:

gcloud run services list --region us-central1

Per verificare che l'attivatore sia stato creato:

gcloud eventarc triggers list --location us-central1

L'output dovrebbe essere simile al seguente:

NAME: trigger-storage-cloudrun-tf
TYPE: google.cloud.storage.object.v1.finalized
DESTINATION: Cloud Run service: hello-events
ACTIVE: Yes
LOCATION: us-central1

GKE

Utilizzando Cloud Shell, esegui il deployment delle tue risorse con Terraform per creare trigger Eventarc.

Il trigger Eventarc richiede un servizio Google Kubernetes Engine. Per semplificare questo tutorial, configurerai questo servizio al di fuori di Terraform, durante l'applicazione di configurazioni Terraform.

1. crea un cluster GKE

Utilizza il codice seguente per abilitare le API richieste:

terraform/eventarc-gke/trigger-gke-eventarc-events/terraform/gke/main.tf 
# Enable GKE API
resource "google_project_service" "container" {
  service            = "container.googleapis.com"
  disable_on_destroy = false
}

# Enable Eventarc API
resource "google_project_service" "eventarc" {
  service            = "eventarc.googleapis.com"
  disable_on_destroy = false
}

# Enable Pub/Sub API
resource "google_project_service" "pubsub" {
  service            = "pubsub.googleapis.com"
  disable_on_destroy = false
}

Utilizza il codice seguente per creare un cluster GKE:

terraform/eventarc-gke/trigger-gke-eventarc-events/terraform/gke/main.tf 
# Create an auto-pilot GKE cluster
resource "google_container_cluster" "gke_cluster" {
  name     = "eventarc-cluster"
  location = "us-central1"

  enable_autopilot = true

  depends_on = [
    google_project_service.container
  ]
}

2. Applica le modifiche

Per informazioni su come applicare o rimuovere una configurazione Terraform, consulta Comandi di base per Terraform.

Per applicare la configurazione Terraform in un progetto Google Cloud, completa i passaggi nelle sezioni seguenti.

Preparazione di Cloud Shell

  1. Avvia Cloud Shell.

  2. Imposta il progetto Google Cloud predefinito a cui vuoi applicare le configurazioni Terraform.

    Devi eseguire questo comando solo una volta per progetto e puoi eseguirlo in qualsiasi directory.

    export GOOGLE_CLOUD_PROJECT=PROJECT_ID

    Le variabili di ambiente vengono sostituite se imposti valori espliciti nel file di configurazione Terraform.

Prepara la directory

Ogni file di configurazione Terraform deve avere la propria directory (detta anche modulo principale).

  1. In Cloud Shell, crea una directory e un nuovo file al suo interno. Il nome del file deve avere l'estensione .tf, ad esempio main.tf. In questo tutorial, il file viene denominato main.tf. 
    mkdir DIRECTORY && cd DIRECTORY && touch main.tf

  2. Se stai seguendo un tutorial, puoi copiare il codice campione in ogni sezione o passaggio.

    Copia il codice campione nel file main.tf appena creato.

    Facoltativamente, copia il codice da GitHub. Questa opzione è consigliata quando lo snippet Terraform fa parte di una soluzione end-to-end.

  3. Esamina e modifica i parametri di esempio da applicare al tuo ambiente.
  4. Salva le modifiche.
  5. Inizializza Terraform. Devi eseguire questa operazione una sola volta per directory. 
    terraform init

    Facoltativamente, per utilizzare la versione più recente del provider Google, includi l'opzione -upgrade: 

    terraform init -upgrade

Applica le modifiche

  1. Esamina la configurazione e verifica che le risorse che Terraform creerà o aggiornerà corrispondano alle tue aspettative: 
    terraform plan

    Se necessario, apporta le correzioni alla configurazione.

  2. Applica la configurazione Terraform eseguendo il comando seguente e inserendo yes alla richiesta: 
    terraform apply

    Attendi che in Terraform venga visualizzato il messaggio "Apply complete!" (Applicazione completata).

  3. Apri il progetto Google Cloud per visualizzare i risultati. Nella console Google Cloud, vai alle risorse nell'interfaccia utente per assicurarti che Terraform le abbia create o aggiornate.

3. Configurare GKE

Eseguire il deployment del container hello di Cloud Run come servizio Kubernetes su GKE. Questo servizio registra richieste ed eventi HTTP ricevuti:

  1. Recupera le credenziali di autenticazione per interagire con il cluster:

    gcloud container clusters get-credentials eventarc-cluster \
   --region=us-central1

  2. Crea un deployment denominato hello-gke:

    kubectl create deployment hello-gke \
   --image=gcr.io/cloudrun/hello

  3. Esponi il deployment come servizio Kubernetes:x

    kubectl expose deployment hello-gke \
   --type ClusterIP --port 80 --target-port 8080

  4. Assicurati che il pod sia in esecuzione:

    kubectl get pods

    L'output dovrebbe essere simile al seguente:

    NAME                        READY   STATUS
hello-gke-df6469d4b-5vv22   1/1     Running

    Se STATUS è Pending, è in corso il deployment del pod. Attendi un minuto per il completamento del deployment e controlla di nuovo lo stato.

  5. Assicurati che il servizio sia in esecuzione:

    kubectl get svc

    L'output dovrebbe essere simile al seguente:

    NAME         TYPE        CLUSTER-IP       EXTERNAL-IP   PORT(S)   AGE
hello-gke    ClusterIP   34.118.226.144   <none>        80/TCP
kubernetes   ClusterIP   34.118.224.1     <none>        443/TCP

4. Crea e configura Eventarc

Utilizza la configurazione seguente per impostare un account di servizio e concedere ruoli specifici a Eventarc per la gestione degli eventi per GKE.

terraform/eventarc-gke/trigger-gke-eventarc-events/terraform/eventarc/main.tf 
# Create a service account to be used by GKE trigger
resource "google_service_account" "eventarc_gke_trigger_sa" {
  account_id   = "eventarc-gke-trigger-sa"
  display_name = "Evenarc GKE Trigger Service Account"
}

# Grant permission to receive Eventarc events
resource "google_project_iam_member" "eventreceiver" {
  project = data.google_project.project.id
  role    = "roles/eventarc.eventReceiver"
  member  = "serviceAccount:${google_service_account.eventarc_gke_trigger_sa.email}"
}

# Grant permission to subscribe to Pub/Sub topics
resource "google_project_iam_member" "pubsubscriber" {
  project = data.google_project.project.id
  role    = "roles/pubsub.subscriber"
  member  = "serviceAccount:${google_service_account.eventarc_gke_trigger_sa.email}"
}

Utilizza il codice seguente per creare un bucket Cloud Storage, con autorizzazioni relative a Eventarc:

terraform/eventarc-gke/trigger-gke-eventarc-events/terraform/eventarc/main.tf 
# Cloud Storage bucket names must be globally unique
resource "random_id" "bucket_name_suffix" {
  byte_length = 4
}

# Create a Cloud Storage bucket
resource "google_storage_bucket" "default" {
  name          = "trigger-gke-${data.google_project.project.name}-${random_id.bucket_name_suffix.hex}"
  location      = "us-central1"
  force_destroy = true

  uniform_bucket_level_access = true
}

# Grant the Cloud Storage service account permission to publish pub/sub topics
data "google_storage_project_service_account" "gcs_account" {}
resource "google_project_iam_member" "pubsubpublisher" {
  project = data.google_project.project.id
  role    = "roles/pubsub.publisher"
  member  = "serviceAccount:${data.google_storage_project_service_account.gcs_account.email_address}"
}

Utilizza la configurazione seguente per abilitare le API richieste e inizializzare i servizi di destinazione GKE Eventarc:

terraform/eventarc-gke/trigger-gke-eventarc-events/terraform/eventarc/main.tf 
# Used to retrieve project_number later
data "google_project" "project" {}

# Enable Eventarc to manage GKE clusters
# This is usually done with: gcloud eventarc gke-destinations init
#
# Eventarc creates a separate Event Forwarder pod for each trigger targeting a
# GKE service, and  requires explicit permissions to make changes to the
# cluster. This is done by granting permissions to a special service account
# (the Eventarc P4SA) to manage resources in the cluster. This needs to be done
# once per Google Cloud project.

# This identity is created with: gcloud beta services identity create --service eventarc.googleapis.com
# This local variable is used for convenience
locals {
  eventarc_sa = "serviceAccount:service-${data.google_project.project.number}@gcp-sa-eventarc.iam.gserviceaccount.com"
}

resource "google_project_iam_member" "computeViewer" {
  project = data.google_project.project.id
  role    = "roles/compute.viewer"
  member  = local.eventarc_sa
}

resource "google_project_iam_member" "containerDeveloper" {
  project = data.google_project.project.id
  role    = "roles/container.developer"
  member  = local.eventarc_sa
}

resource "google_project_iam_member" "serviceAccountAdmin" {
  project = data.google_project.project.id
  role    = "roles/iam.serviceAccountAdmin"
  member  = local.eventarc_sa
}

Creare un trigger Eventarc che instrada gli eventi Pub/Sub al servizio GKE hello-gke.

Puoi definire più matching_criteria con gli attributi CloudEvents supportati da Eventarc che funzionano come il valore event-filters specificato quando crei un trigger. Per ulteriori informazioni, segui le istruzioni quando crei un trigger per provider, tipo di evento e destinazione GKE specifici. Gli eventi che corrispondono a tutti i filtri vengono inviati alla destinazione.

terraform/eventarc-gke/trigger-gke-eventarc-events/terraform/eventarc/main.tf 
# Create an Eventarc trigger, routing Storage events to GKE
resource "google_eventarc_trigger" "default" {
  name     = "trigger-storage-gke-tf"
  location = "us-central1"

  # Capture objects changed in the bucket
  matching_criteria {
    attribute = "type"
    value     = "google.cloud.storage.object.v1.finalized"
  }
  matching_criteria {
    attribute = "bucket"
    value     = google_storage_bucket.default.name
  }

  # Send events to GKE service
  destination {
    gke {
      cluster   = "eventarc-cluster"
      location  = "us-central1"
      namespace = "default"
      path      = "/"
      service   = "hello-gke"
    }
  }

  service_account = google_service_account.eventarc_gke_trigger_sa.email
}

5. Applica le modifiche aggiuntive

Per applicare la configurazione Terraform aggiuntiva in un progetto Google Cloud, completa questi passaggi:

  1. Crea l'account di identità Eventarc:

    gcloud beta services identity create --service eventarc.googleapis.com

  2. Aggiungi al file main.tf esistente il nuovo codice Terraform del passaggio precedente.

  3. Applica le configurazioni di Terraform aggiornate:

    terraform plan
terraform apply

    Attendi che in Terraform venga visualizzato il messaggio "Apply complete!" (Applicazione completata).

  4. Apri il tuo progetto Google Cloud per visualizzare i risultati. Nella console Google Cloud, vai alle risorse nell'interfaccia utente per assicurarti che Terraform le abbia create o aggiornate.

Workflows

Utilizzando Cloud Shell, esegui il deployment delle tue risorse con Terraform per creare un flusso di lavoro e un trigger Eventarc.

1. Abilita le API

Utilizza il codice seguente per abilitare le API richieste:

eventarc/workflows/main.tf 
# Enable Eventarc API
resource "google_project_service" "eventarc" {
  service            = "eventarc.googleapis.com"
  disable_on_destroy = false
}

# Enable Workflows API
resource "google_project_service" "workflows" {
  service            = "workflows.googleapis.com"
  disable_on_destroy = false
}

# Enable Pub/Sub API
resource "google_project_service" "pubsub" {
  service            = "pubsub.googleapis.com"
  disable_on_destroy = false
}

2. Crea un account di servizio e configura IAM

Utilizza il codice seguente per creare un account di servizio dedicato e aggiungere ruoli IAM:

eventarc/workflows/main.tf 
# Used to retrieve project information later
data "google_project" "project" {}

# Create a service account for Eventarc trigger and Workflows
resource "google_service_account" "eventarc" {
  account_id   = "eventarc-workflows-sa"
  display_name = "Eventarc Workflows Service Account"
}

# Grant permission to invoke workflows
resource "google_project_iam_member" "workflowsinvoker" {
  project = data.google_project.project.id
  role    = "roles/workflows.invoker"
  member  = "serviceAccount:${google_service_account.eventarc.email}"
}

# Grant permission to receive events
resource "google_project_iam_member" "eventreceiver" {
  project = data.google_project.project.id
  role    = "roles/eventarc.eventReceiver"
  member  = "serviceAccount:${google_service_account.eventarc.email}"
}

Se hai abilitato l'agente di servizio Pub/Sub entro l'8 aprile 2021, concedi il ruolo iam.serviceAccountTokenCreator all'account di servizio gestito da Google:

resource "google_project_iam_member" "tokencreator" {
   project  = data.google_project.project.id
   role     = "roles/iam.serviceAccountTokenCreator"
   member   = "serviceAccount:service-${data.google_project.project.number}@gcp-sa-pubsub.iam.gserviceaccount.com"
}

3. Crea un bucket Cloud Storage come provider di eventi

Utilizza il codice seguente per creare un bucket Cloud Storage, con autorizzazioni relative a Eventarc:

eventarc/workflows/main.tf 
# Cloud Storage bucket names must be globally unique
resource "random_id" "bucket_name_suffix" {
  byte_length = 4
}

# Create a Cloud Storage bucket
resource "google_storage_bucket" "default" {
  name          = "trigger-workflows-${data.google_project.project.name}-${random_id.bucket_name_suffix.hex}"
  location      = google_workflows_workflow.default.region
  force_destroy = true

  uniform_bucket_level_access = true
}

# Grant the Cloud Storage service account permission to publish Pub/Sub topics
data "google_storage_project_service_account" "gcs_account" {}
resource "google_project_iam_member" "pubsubpublisher" {
  project = data.google_project.project.id
  role    = "roles/pubsub.publisher"
  member  = "serviceAccount:${data.google_storage_project_service_account.gcs_account.email_address}"
}

4. Crea ed esegui il deployment di un flusso di lavoro

Definisci ed esegui il deployment di un flusso di lavoro che viene eseguito quando un oggetto viene aggiornato nel bucket creato:

eventarc/workflows/main.tf 
# Create a workflow
resource "google_workflows_workflow" "default" {
  name        = "storage-workflow-tf"
  region      = "us-central1"
  description = "Workflow that returns information about storage events"

  # Note that $$ is needed for Terraform
  source_contents = <<EOF
  main:
    params: [event]
    steps:
      - log_event:
          call: sys.log
          args:
            text: $${event}
            severity: INFO
      - gather_data:
          assign:
            - bucket: $${event.data.bucket}
            - name: $${event.data.name}
            - message: $${"Received event " + event.type + " - " + bucket + ", " + name}
      - return_data:
          return: $${message}
  EOF

  depends_on = [
    google_project_service.workflows
  ]
}

5. Crea un trigger Eventarc

Creare un trigger Eventarc che instrada gli eventi diretti sul bucket creato a Workflows. Utilizza la risorsa google_eventarc_trigger per definire la risorsa trigger Eventarc.

Puoi definire più matching_criteria con gli attributi CloudEvents supportati da Eventarc che funzionano come il valore event-filters specificato quando crei un trigger. Per ulteriori informazioni, segui le istruzioni quando crei un trigger per provider, tipo di evento e destinazione Workflows specifici.

Gli eventi che corrispondono a tutti i filtri vengono inviati alla destinazione.

eventarc/workflows/main.tf 
# Create an Eventarc trigger, routing Cloud Storage events to Workflows
resource "google_eventarc_trigger" "default" {
  name     = "trigger-storage-workflows-tf"
  location = google_workflows_workflow.default.region

  # Capture objects changed in the bucket
  matching_criteria {
    attribute = "type"
    value     = "google.cloud.storage.object.v1.finalized"
  }
  matching_criteria {
    attribute = "bucket"
    value     = google_storage_bucket.default.name
  }

  # Send events to Workflows
  destination {
    workflow = google_workflows_workflow.default.id
  }

  service_account = google_service_account.eventarc.email

  depends_on = [
    google_project_service.eventarc,
    google_project_service.workflows,
  ]
}

6. Applica le modifiche

Per informazioni su come applicare o rimuovere una configurazione Terraform, consulta Comandi di base per Terraform.

Per applicare la configurazione Terraform in un progetto Google Cloud, completa i passaggi nelle sezioni seguenti.

Preparazione di Cloud Shell

  1. Avvia Cloud Shell.

  2. Imposta il progetto Google Cloud predefinito a cui vuoi applicare le configurazioni Terraform.

    Devi eseguire questo comando solo una volta per progetto e puoi eseguirlo in qualsiasi directory.

    export GOOGLE_CLOUD_PROJECT=PROJECT_ID

    Le variabili di ambiente vengono sostituite se imposti valori espliciti nel file di configurazione Terraform.

Prepara la directory

Ogni file di configurazione Terraform deve avere la propria directory (detta anche modulo principale).

  1. In Cloud Shell, crea una directory e un nuovo file al suo interno. Il nome del file deve avere l'estensione .tf, ad esempio main.tf. In questo tutorial, il file viene denominato main.tf. 
    mkdir DIRECTORY && cd DIRECTORY && touch main.tf

  2. Se stai seguendo un tutorial, puoi copiare il codice campione in ogni sezione o passaggio.

    Copia il codice campione nel file main.tf appena creato.

    Facoltativamente, copia il codice da GitHub. Questa opzione è consigliata quando lo snippet Terraform fa parte di una soluzione end-to-end.

  3. Esamina e modifica i parametri di esempio da applicare al tuo ambiente.
  4. Salva le modifiche.
  5. Inizializza Terraform. Devi eseguire questa operazione una sola volta per directory. 
    terraform init

    Facoltativamente, per utilizzare la versione più recente del provider Google, includi l'opzione -upgrade: 

    terraform init -upgrade

Applica le modifiche

  1. Esamina la configurazione e verifica che le risorse che Terraform creerà o aggiornerà corrispondano alle tue aspettative: 
    terraform plan

    Se necessario, apporta le correzioni alla configurazione.

  2. Applica la configurazione Terraform eseguendo il comando seguente e inserendo yes alla richiesta: 
    terraform apply

    Attendi che in Terraform venga visualizzato il messaggio "Apply complete!" (Applicazione completata).

  3. Apri il progetto Google Cloud per visualizzare i risultati. Nella console Google Cloud, vai alle risorse nell'interfaccia utente per assicurarti che Terraform le abbia create o aggiornate.

7. Verificare la creazione del flusso di lavoro

Per verificare che il flusso di lavoro sia stato creato, esegui:

gcloud workflows list --location us-central1

8. Verifica la creazione del trigger Eventarc

Per verificare che il trigger Eventarc sia creato, esegui:

gcloud eventarc triggers list --location us-central1

L'output dovrebbe essere simile al seguente:

NAME: trigger-storage-workflows-tf
TYPE: google.cloud.storage.object.v1.finalized
DESTINATION: Workflows: storage-workflow-tf
ACTIVE: Yes
LOCATION: us-central1

Generare e visualizzare un evento

Puoi generare un evento e confermare che il trigger Eventarc funzioni come previsto.

Cloud Run

  1. Per generare un evento:

    Carica un file di testo in Cloud Storage:

    echo "Hello World" > random.txt
gsutil cp random.txt gs://trigger-cloudrun-PROJECT_ID/random.txt

    Il caricamento genera un evento e il servizio Cloud Run registra il messaggio dell'evento.

  2. Per verificare la ricezione di un evento:

    1. Visualizza le voci di log relative agli eventi create dal tuo servizio:
    gcloud logging read "resource.type=cloud_run_revision \
    AND resource.labels.service_name=hello-events"

    In alternativa, apri la console Google Cloud, accedi alla risorsa Cloud Run e visualizza i log.

    1. Cerca una voce di log simile alla seguente:
    Received event of type google.cloud.storage.object.v1.finalized.
Event data: { "kind": "storage#object", "id": "trigger-cloudrun-PROJECT_ID/random.txt", ...}

GKE

  1. Per generare un evento:

    Carica un file di testo in Cloud Storage:

    echo "Hello World" > random.txt
gsutil cp random.txt gs://trigger-gke-PROJECT_ID/random.txt

    Il caricamento genera un evento e il servizio Cloud Run registra il messaggio dell'evento.

  2. Per verificare la ricezione di un evento:

    1. Trova l'ID pod:

      POD_NAME=$(kubectl get pods -o custom-columns=":metadata.name" --no-headers)

      Questo comando utilizza l'output formattato di kubectl.

    2. Controlla i log del pod:

      kubectl logs $POD_NAME

    3. Cerca una voce di log simile alla seguente:

      {"severity":"INFO","eventType":"google.cloud.pubsub.topic.v1.messagePublished",
"message":"Received event of type google.cloud.pubsub.topic.v1.messagePublished.", [...]}

Workflows

  1. Per generare un evento:

    Carica un file di testo in Cloud Storage:

    echo "Hello World" > random.txt
gsutil cp random.txt gs://trigger-workflows-PROJECT_ID/random.txt

    Il caricamento genera un evento e il servizio Cloud Run registra il messaggio dell'evento.

  2. Per verificare la ricezione di un evento:

    1. Verifica che l'esecuzione di un flusso di lavoro venga attivata elencando le ultime cinque esecuzioni:

      gcloud workflows executions list storage-workflow-tf --limit=5

      L'output deve includere un elenco di esecuzioni con NAME, START_TIME, END_TIME e STATUS.

    2. Visualizza i risultati dell'esecuzione più recente:

      EXECUTION_NAME=$(gcloud workflows executions list storage-workflow-tf --limit=1 --format "value(name)")
gcloud workflows executions describe $EXECUTION_NAME

    3. Verifica che l'output sia simile al seguente:

      ...
result: '"Received event google.cloud.storage.object.v1.finalized - trigger-workflows-PROJECT_ID, random.txt"'
state: SUCCEEDED
...

      Cerca state: SUCCEEDED e result: "Received event" nell'output dei flussi di lavoro.

Esegui la pulizia

Rimuovi le risorse applicate in precedenza alla configurazione Terraform eseguendo il comando seguente e inserendo yes alla richiesta:

terraform destroy

Puoi anche eliminare il tuo progetto Google Cloud per evitare addebiti. L'eliminazione del progetto Google Cloud interrompe la fatturazione per tutte le risorse utilizzate all'interno del progetto.

  1. In the Google Cloud console, go to the Manage resources page.

    Go to Manage resources

  2. In the project list, select the project that you want to delete, and then click Delete.
  3. In the dialog, type the project ID, and then click Shut down to delete the project.

Passaggi successivi