Configurazione di un bilanciatore del carico delle applicazioni classico con bucket Cloud Storage

Questo documento mostra come creare un bilanciatore del carico delle applicazioni esterno per instradare le richieste di contenuti statici ai bucket di Cloud Storage. Dopo aver configurato un bilanciatore del carico con i bucket di backend, le richieste ai percorsi URL che iniziano con /love-to-fetch vengono inviate al bucket Cloud Storage us-east1 e tutte le altre richieste vengono inviate al bucket Cloud Storage europe-north1, indipendentemente dalla regione dell'utente.

Se i tuoi backend pubblicano contenuti dinamici su HTTP(S), valuta la possibilità di utilizzare i servizi di backend anziché i bucket di backend.

---

Per seguire le indicazioni dettagliate per questa attività direttamente nella console Google Cloud, fai clic su Aiuto:

Guidami

---

Bucket Cloud Storage come backend del bilanciatore del carico

Un bilanciatore del carico delle applicazioni esterno utilizza una mappa URL per indirizzare il traffico dai percorsi URL specificati ai tuoi backend.

Nel diagramma seguente, il bilanciatore del carico invia il traffico con un percorso /love-to-fetch/ a un bucket Cloud Storage nella regione us-east1. Tutte le altre richieste vengono inviate a un bucket Cloud Storage nella regione europe-north1.

Distribuzione del traffico in Cloud Storage

Per impostazione predefinita, Cloud Storage utilizza la stessa cache utilizzata da Cloud CDN. Se abiliti Cloud CDN nel bucket di backend, puoi utilizzare i controlli Cloud CDN sui tuoi contenuti. I controlli di Cloud CDN includono, ad esempio, modalità cache, URL firmati e invalidazione. Cloud CDN ti consente inoltre di memorizzare nella cache contenuti di grandi dimensioni (> 10 MB). Se non abiliti Cloud CDN nel tuo bucket di backend, puoi utilizzare solo le intestazioni dell'origine Cache-Control per controllare la memorizzazione nella cache per contenuti più piccoli, come impostato dai metadati di Cloud Storage.

Prima di iniziare

Assicurati che la tua configurazione soddisfi i prerequisiti riportati di seguito. Se utilizzi l'utilità gcloud storage, puoi installarla seguendo le istruzioni riportate in Scoprire l'archiviazione degli oggetti con lo strumento gcloud.

Imposta un progetto predefinito

Console

1. Accedi al tuo account Google Cloud. Se non conosci Google Cloud, crea un account per valutare le prestazioni dei nostri prodotti in scenari reali. I nuovi clienti ricevono anche 300 $di crediti gratuiti per l'esecuzione, il test e il deployment dei carichi di lavoro.

2. Nella pagina del selettore di progetti della console Google Cloud, seleziona o crea un progetto Google Cloud.

   Nota: se non prevedi di conservare le risorse create in questa procedura, crea un progetto anziché selezionarne uno esistente. Dopo aver completato questi passaggi, puoi eliminare il progetto, rimuovendo tutte le risorse associate.

   Vai al selettore progetti

3. Assicurati che la fatturazione sia attivata per il tuo progetto Google Cloud.

4. Nella pagina del selettore di progetti della console Google Cloud, seleziona o crea un progetto Google Cloud.

   Nota: se non prevedi di conservare le risorse create in questa procedura, crea un progetto anziché selezionarne uno esistente. Dopo aver completato questi passaggi, puoi eliminare il progetto, rimuovendo tutte le risorse associate.

   Vai al selettore progetti

5. Assicurati che la fatturazione sia attivata per il tuo progetto Google Cloud.

gcloud

gcloud config set project PROJECT_ID

Sostituisci PROJECT_ID con il progetto che stai utilizzando per questa guida.

Terraform

export GOOGLE_CLOUD_PROJECT=PROJECT_ID

Autorizzazioni

Per seguire questa guida, è necessario creare bucket Cloud Storage e un bilanciatore del carico in un progetto. Devi essere un proprietario o un editor del progetto oppure dovresti avere i seguenti ruoli IAM di Compute Engine:

Attività	Ruolo richiesto
Crea componenti del bilanciatore del carico	Amministratore rete
Creazione di bucket di Cloud Storage	Amministratore oggetti Storage

Per ulteriori informazioni, consulta le seguenti guide:

• Controllo dell'accesso
• Condizioni IAM

Configura una risorsa del certificato SSL

Per un bilanciatore del carico HTTPS, crea una risorsa del certificato SSL come descritto nella seguente documentazione:

• Utilizzo dei certificati SSL autogestiti
• Utilizzo dei certificati SSL gestiti da Google

Ti consigliamo di utilizzare un certificato gestito da Google.

Questo esempio presuppone che tu abbia già una risorsa del certificato SSL denominata www-ssl-cert.

Avviso: non utilizzare un certificato autofirmato per la produzione.

Prepara i bucket e i contenuti di Cloud Storage

Il processo di preparazione dei bucket Cloud Storage è il seguente:

• Crea i bucket.

• Copia i contenuti nei bucket.

• Fornisci l'accesso pubblico ai bucket.

Creazione di bucket di Cloud Storage

In questo esempio, creerai due bucket Cloud Storage a cui il bilanciatore del carico può accedere. Per i deployment di produzione, consigliamo di scegliere un bucket multiregionale, che replica automaticamente gli oggetti in più regioni Google Cloud. Ciò può migliorare la disponibilità dei tuoi contenuti e la tolleranza agli errori nella tua applicazione.

Prendi nota dei nomi dei bucket Cloud Storage che crei, perché verranno utilizzati in seguito. In questa guida, sono indicati come BUCKET_1_NAME e BUCKET_2_NAME.

Console

1. Nella console Google Cloud, vai alla pagina Bucket Cloud Storage.

   Vai ai bucket Cloud Storage

2. Fai clic su Crea bucket.

3. Nella casella Assegna un nome al bucket, inserisci un nome globalmente univoco che segua le linee guida per l'assegnazione.

4. Fai clic su Scegli dove archiviare i tuoi dati.

5. Imposta Tipo di località su Area geografica.

6. Imposta Località su europe-north1. BUCKET_1_NAME in questa guida.

7. Fai clic su Crea.

8. Fai clic su Bucket per tornare alla pagina Bucket Cloud Storage. Segui queste istruzioni per creare un secondo bucket, ma imposta Località su us-east1. BUCKET_2_NAME in questa guida.

gcloud

gcloud storage buckets create gs://BUCKET_1_NAME --project=PROJECT_ID --default-storage-class=standard --location=europe-north1 --uniform-bucket-level-access

gcloud storage buckets create gs://BUCKET_2_NAME --project=PROJECT_ID --default-storage-class=standard --location=us-east1 --uniform-bucket-level-access

Sostituisci BUCKET_1_NAME e BUCKET_2_NAME con i nomi dei bucket che vuoi creare.

Terraform

Per creare i bucket, utilizza la risorsa google_storage_bucket.

# Create Cloud Storage buckets
resource "random_id" "bucket_prefix" {
  byte_length = 8
}

resource "google_storage_bucket" "bucket_1" {
  name                        = "${random_id.bucket_prefix.hex}-bucket-1"
  location                    = "us-east1"
  uniform_bucket_level_access = true
  storage_class               = "STANDARD"
  // delete bucket and contents on destroy.
  force_destroy = true
}

resource "google_storage_bucket" "bucket_2" {
  name                        = "${random_id.bucket_prefix.hex}-bucket-2"
  location                    = "us-east1"
  uniform_bucket_level_access = true
  storage_class               = "STANDARD"
  // delete bucket and contents on destroy.
  force_destroy = true
}

Per scoprire come applicare o rimuovere una configurazione Terraform, consulta Comandi Terraform di base.

Trasferisci i contenuti nei bucket Cloud Storage

Per testare la configurazione in un secondo momento, copia le immagini seguenti da un bucket Cloud Storage pubblico ai tuoi bucket Cloud Storage.

gcloud

1. Fai clic su Attiva Cloud Shell.

2. Esegui i comandi seguenti in Cloud Shell, sostituendo le variabili dei nomi dei bucket con i nomi dei bucket Cloud Storage:

gcloud storage cp gs://gcp-external-http-lb-with-bucket/three-cats.jpg gs://BUCKET_1_NAME/never-fetch/

gcloud storage cp gs://gcp-external-http-lb-with-bucket/three-cats.jpg gs://BUCKET_2_NAME/love-to-fetch/

Terraform

Per copiare elementi nel bucket, puoi utilizzare la risorsa google_storage_bucket_object.

resource "google_storage_bucket_object" "cat_image" {
  name         = "never-fetch/three-cats.jpg"
  source       = "images/three-cats.jpg"
  content_type = "image/jpeg"

  bucket = google_storage_bucket.bucket_1.name
}

resource "google_storage_bucket_object" "dog_image" {
  name         = "love-to-fetch/two-dogs.jpg"
  source       = "images/two-dogs.jpg"
  content_type = "image/jpeg"

  bucket = google_storage_bucket.bucket_2.name
}

In alternativa, utilizza la risorsa null_resource.

resource "null_resource" "upload_cat_image" {
provisioner "local-exec" {
  command = "gcloud storage cp gs://gcp-external-http-lb-with-bucket/three-cats.jpg gs://${google_storage_bucket.bucket_1.name}/never-fetch/"
}
}

resource "null_resource" "upload_dog_image" {
provisioner "local-exec" {
  command = "gcloud storage cp gs://gcp-external-http-lb-with-bucket/two-dogs.jpg gs://${google_storage_bucket.bucket_2.name}/love-to-fetch/"
}
}

Nella console Google Cloud, fai clic su Aggiorna nella pagina dei dettagli di ciascun bucket per verificare che il file sia stato copiato correttamente.

Rendi pubblicamente leggibili i bucket Cloud Storage

Quando rendi i bucket Cloud Storage pubblicamente leggibili, chiunque su internet può elencare e visualizzare gli oggetti e i relativi metadati (esclusi gli ACL). Non includere informazioni sensibili nei bucket pubblici.

Per ridurre la probabilità di esposizione accidentale di informazioni sensibili, non archiviare oggetti pubblici e dati sensibili nello stesso bucket.

Console

Per concedere a tutti gli utenti l'accesso in visualizzazione agli oggetti nei bucket, ripeti la procedura seguente per ogni bucket:

1. Nella console Google Cloud, vai alla pagina Bucket Cloud Storage.

   Vai ai bucket Cloud Storage

2. Fai clic sul nome del bucket, quindi sulla scheda Autorizzazioni.

3. Fai clic su Aggiungi.

4. Nella casella Nuove entità, inserisci allUsers.

5. Nella casella Seleziona un ruolo, seleziona Cloud Storage > Visualizzatore oggetti Storage.

6. Fai clic su Salva.

7. Fai clic su Consenti accesso pubblico.

gcloud

Per concedere a tutti gli utenti l'accesso per visualizzare gli oggetti nei bucket, esegui questi comandi:

gcloud storage buckets add-iam-policy-binding gs://BUCKET_1_NAME --member=allUsers --role=roles/storage.objectViewer

gcloud storage buckets add-iam-policy-binding gs://BUCKET_2_NAME --member=allUsers --role=roles/storage.objectViewer

Terraform

Per concedere a tutti gli utenti l'accesso per visualizzare gli oggetti nei bucket, utilizza la risorsa google_storage_bucket_iam_member e specifica il membro allUsers.

# Make buckets public
resource "google_storage_bucket_iam_member" "bucket_1" {
  bucket = google_storage_bucket.bucket_1.name
  role   = "roles/storage.objectViewer"
  member = "allUsers"
}

resource "google_storage_bucket_iam_member" "bucket_2" {
  bucket = google_storage_bucket.bucket_2.name
  role   = "roles/storage.objectViewer"
  member = "allUsers"
}

Prenotare un indirizzo IP esterno

Dopo aver configurato i bucket Cloud Storage, puoi prenotare un indirizzo IP esterno statico e globale, che il tuo pubblico utilizza per raggiungere il bilanciatore del carico.

Questo passaggio è facoltativo, ma consigliato, poiché un indirizzo IP esterno statico fornisce un indirizzo singolo a cui puntare il dominio.

Nota: puoi saltare questo passaggio e chiedere a Google Cloud di associare un indirizzo IP temporaneo alla regola di forwarding del bilanciatore del carico. Un indirizzo IP temporaneo rimane costante finché esiste la regola di forwarding. Se devi eliminare la regola di forwarding e aggiungerla nuovamente, la regola di forwarding potrebbe ricevere un nuovo indirizzo IP. Se necessario, puoi rendere statico un indirizzo IP temporaneo.

Console

1. Nella console Google Cloud, vai alla pagina Indirizzi IP esterni.

   Vai a Indirizzi IP esterni

2. Fai clic su Prenota indirizzo statico.

3. Nella casella Nome, inserisci example-ip.

4. Imposta Network Service Tier su Premium.

5. Imposta la versione IP su IPv4.

6. Imposta il Tipo su Globale.

7. Fai clic su Prenota.

gcloud

gcloud compute addresses create example-ip \
    --network-tier=PREMIUM \
    --ip-version=IPV4 \
    --global

Prendi nota dell'indirizzo IPv4 riservato:

gcloud compute addresses describe example-ip \
    --format="get(address)" \
    --global

Terraform

Per prenotare un indirizzo IP esterno, utilizza la risorsa google_compute_global_address.

# Reserve IP address
resource "google_compute_global_address" "default" {
  name = "example-ip"
}

Crea un bilanciatore del carico delle applicazioni esterno con bucket di backend

Queste istruzioni riguardano la creazione di un bilanciatore del carico HTTP o HTTPS. Per creare un bilanciatore del carico HTTPS, devi aggiungere una risorsa del certificato SSL al frontend del bilanciatore del carico. Per ulteriori informazioni, consulta la panoramica dei certificati SSL.

Console

Avvia la configurazione

1. Nella console Google Cloud, vai alla pagina Bilanciamento del carico.

   Vai a Bilanciamento del carico

2. Fai clic su Crea bilanciatore del carico.
3. In Tipo di bilanciatore del carico, seleziona Bilanciatore del carico delle applicazioni (HTTP/HTTPS) e fai clic su Avanti.
4. In Pubblico o interno, seleziona Per il pubblico (esterno) e fai clic su Avanti.
5. In Deployment a regione singola o globale, seleziona Ideale per carichi di lavoro globali e fai clic su Avanti.
6. In Generazione del bilanciatore del carico, seleziona Bilanciatore del carico delle applicazioni classico e fai clic su Avanti.
7. Fai clic su Configura.

Configurazione di base

1. Nella casella Nome, inserisci http-lb.

Configura il backend

1. Fai clic su Configurazione backend.

2. Fai clic sulla casella Servizi di backend e bucket di backend, quindi su Crea un bucket di backend.

3. Nella casella Nome bucket di backend, inserisci cats.

4. Nella casella Bucket Cloud Storage, fai clic su Sfoglia.

5. Seleziona BUCKET_1_NAME, quindi fai clic su Seleziona. Quando si crea il bucket di backend cats, viene impostato come predefinito e vi vengono indirizzate tutte le richieste di traffico senza corrispondenza. Non puoi modificare le regole di reindirizzamento di un bucket di backend predefinito nel bilanciatore del carico.

6. Fai clic su Crea.

7. Usa la stessa procedura per creare un bucket di backend denominato dogs, quindi seleziona BUCKET_2_NAME.

8. Fai clic su Ok.

Configura le regole di routing

Le regole di routing determinano come viene indirizzato il traffico. Per configurare il routing, devi impostare regole host e matcher percorso, che sono componenti di configurazione della mappa URL di un bilanciatore del carico delle applicazioni esterno. Per impostare le regole per questo esempio:

1. Fai clic su Regole host e percorso.
2. Per dogs, inserisci * nel campo Host e /love-to-fetch/* nel campo Percorsi.

Configura il frontend

1. Fai clic su Configurazione frontend.

2. Verifica che le seguenti opzioni siano configurate con questi valori:

   Proprietà	Valore (digita un valore o seleziona un'opzione come specificato)
   Protocollo	HTTP
   Livello di servizio di rete	Premium
   Versione IP	IPv4
   Indirizzo IP	example-ip
   Porta	80

   Se vuoi creare un bilanciatore del carico HTTPS anziché un bilanciatore del carico HTTP, devi avere un certificato SSL (gcloud compute ssl-certificates list) e compilare i campi come segue:

   Proprietà	Valore (digita un valore o seleziona un'opzione come specificato)
   Protocollo	HTTP(S)
   Livello di servizio di rete	Premium
   Versione IP	IPv4
   Indirizzo IP	example-ip
   Porta	443
   Seleziona un certificato o creane uno nuovo
   (Facoltativo) Abilita il reindirizzamento da HTTP a HTTPS	Utilizza questa casella di controllo per attivare i reindirizzamenti. L'attivazione di questa casella di controllo crea un bilanciatore del carico HTTP parziale aggiuntivo che utilizza lo stesso indirizzo IP del bilanciatore del carico HTTPS e reindirizza le richieste HTTP al frontend HTTPS del bilanciatore del carico. Questa casella di controllo può essere selezionata solo quando è selezionato il protocollo HTTPS e viene utilizzato un indirizzo IP riservato.

3. Fai clic su Fine.

Rivedi la configurazione

1. Fai clic su Esamina e finalizza.

2. Esamina le regole di frontend, host e percorso e i bucket di backend.

3. Fai clic su Crea e attendi che la creazione del bilanciatore del carico sia completa.

4. Fai clic sul nome del bilanciatore del carico (http-lb).

5. Prendi nota dell'indirizzo IP del bilanciatore del carico, che utilizzerai nella prossima attività. In questa guida, viene definito IP_ADDRESS.

gcloud

Configura il backend

gcloud compute backend-buckets create cats \
  --gcs-bucket-name=BUCKET_1_NAME

gcloud compute backend-buckets create dogs \
  --gcs-bucket-name=BUCKET_2_NAME

Configura la mappa URL

gcloud compute url-maps create http-lb \
  --default-backend-bucket=cats

gcloud compute url-maps add-path-matcher http-lb \
  --path-matcher-name=path-matcher-2 \
  --new-hosts=* \
  --backend-bucket-path-rules="/love-to-fetch/*=dogs" \
  --default-backend-bucket=cats

Configura il proxy di destinazione

gcloud compute target-http-proxies create http-lb-proxy \
  --url-map=http-lb

Configura la regola di forwarding

gcloud compute forwarding-rules create http-lb-forwarding-rule \
  --load-balancing-scheme=EXTERNAL \
  --network-tier=PREMIUM \
  --address=example-ip \
  --global \
  --target-http-proxy=http-lb-proxy \
  --ports=80

Terraform

Per creare il bilanciatore del carico, utilizza le seguenti risorse Terraform.

Configura il backend

Per creare il backend, utilizza la risorsa google_compute_backend_bucket.

# Create LB backend buckets
resource "google_compute_backend_bucket" "bucket_1" {
  name        = "cats"
  description = "Contains cat image"
  bucket_name = google_storage_bucket.bucket_1.name
}

resource "google_compute_backend_bucket" "bucket_2" {
  name        = "dogs"
  description = "Contains dog image"
  bucket_name = google_storage_bucket.bucket_2.name
}

Configura la mappa URL

Per creare la mappa URL, utilizza la risorsa google_compute_url_map.

# Create url map
resource "google_compute_url_map" "default" {
  name = "http-lb"

  default_service = google_compute_backend_bucket.bucket_1.id

  host_rule {
    hosts        = ["*"]
    path_matcher = "path-matcher-2"
  }
  path_matcher {
    name            = "path-matcher-2"
    default_service = google_compute_backend_bucket.bucket_1.id

    path_rule {
      paths   = ["/love-to-fetch/*"]
      service = google_compute_backend_bucket.bucket_2.id
    }
  }
}

Configura il proxy di destinazione

Per creare il proxy HTTP di destinazione, utilizza la risorsa google_compute_target_http_proxy.

# Create HTTP target proxy
resource "google_compute_target_http_proxy" "default" {
  name    = "http-lb-proxy"
  url_map = google_compute_url_map.default.id
}

Configura la regola di forwarding

Per creare la regola di forwarding, utilizza la risorsa google_compute_global_forwarding_rule.

# Create forwarding rule
resource "google_compute_global_forwarding_rule" "default" {
  name                  = "http-lb-forwarding-rule"
  ip_protocol           = "TCP"
  load_balancing_scheme = "EXTERNAL_MANAGED"
  port_range            = "80"
  target                = google_compute_target_http_proxy.default.id
  ip_address            = google_compute_global_address.default.id
}

NOTA: per passare dalla modalità al bilanciatore del carico delle applicazioni classico, imposta l'attributo load_balancing_scheme su "EXTERNAL" anziché su "EXTERNAL_MANAGED".

Per scoprire come applicare o rimuovere una configurazione Terraform, consulta Comandi Terraform di base.

Invia traffico al bilanciatore del carico

Alcuni minuti dopo aver configurato il bilanciatore del carico, puoi iniziare a inviare traffico all'indirizzo IP del bilanciatore del carico.

Console

In un browser web, vai agli indirizzi seguenti per testare il bilanciatore del carico, sostituendo IP_ADDRESS con l'indirizzo IP del bilanciatore del carico:

• http://IP_ADDRESS/love-to-fetch/two-dogs.jpg

• http://IP_ADDRESS/never-fetch/three-cats.jpg

Se hai configurato un bilanciatore del carico HTTP, assicurati che il browser non reindirizzi automaticamente a HTTPS.

gcloud

Utilizza il comando curl per testare la risposta dai seguenti URL. Sostituisci IP_ADDRESS con l'indirizzo IPv4 del bilanciatore del carico:

curl http://IP_ADDRESS/love-to-fetch/two-dogs.jpg

curl http://IP_ADDRESS/never-fetch/three-cats.jpg

Limitazioni

• I bucket di backend sono supportati solo con Application Load Balancer esterni globali e con un Application Load Balancer classico. Non sono supportate dall'Application Load Balancer esterno regionale o da qualsiasi altro tipo di bilanciatore del carico.
• I bucket di backend non sono supportati con Identity-Aware Proxy.

• L'Application Load Balancer classico non supporta completamente i caricamenti nei bucket Cloud Storage. In particolare, tutti parametri di ricerca nella richiesta vengono eliminati durante il caricamento su Cloud Storage.

  Passaggi successivi

• Configurazione del bilanciamento del carico tra più regioni

• Configurazione di Cloud CDN con un bucket di backend

• Utilizzo di esempi di moduli Terraform per bilanciatori del carico delle applicazioni esterni