Version 1.1. Cette version n'est plus compatible, comme indiqué dans la politique de compatibilité avec les versions d'Anthos. Pour obtenir les derniers correctifs et mises à jour pour les failles de sécurité, les expositions et les problèmes affectant Anthos Clusters on VMware (GKE On-Prem), passez à une version compatible. Vous trouverez la version la plus récente ici.

Versions disponibles

Créer un poste de travail administrateur

Cette page explique comment créer la dernière version de la machine virtuelle (VM) de poste de travail administrateur.

Pour mettre à niveau un poste de travail administrateur existant, consultez la page Mettre à jour GKE On-Prem.

Présentation

Le poste de travail administrateur est une VM vSphere qui contient tous les outils dont vous avez besoin pour créer et gérer des clusters GKE On-Prem. Pour créer le poste de travail administrateur, procédez comme suit :

Téléchargez le fichier Open Virtual Appliance (OVA) du poste de travail administrateur, une image compressée de la VM du poste de travail administrateur.
Utilisez govc, l'interface de ligne de commande dans vSphere, pour importer le fichier OVA dans vSphere en tant que modèle de VM.
Copiez et remplissez les fichiers de configuration HashiCorp Terraform.
Utilisez Terraform pour créer la VM.

Avant de commencer

Consultez la présentation du poste de travail administrateur.
Suivez la procédure décrite dans la section Préparer l'installation.
Assurez-vous d'avoir installé govc.
Assurez-vous d'avoir installé la version 0.11 de Terraform.

Télécharger le fichier OVA du poste de travail administrateur

Téléchargez la dernière version du fichier OVA du poste de travail administrateur à partir de la section "Téléchargements". La dernière version du fichier OVA est :

gke-on-prem-admin-appliance-vsphere-1.1.2-gke.0.ova

où 1.1.2-gke.0 est la dernière version de GKE On-Prem. Le fichier OVA inclut tous les composants du cluster, les outils de ligne de commande et toutes les autres entités nécessaires à l'installation et à la gestion des clusters GKE On-Prem. La dernière version du fichier OVA inclut la dernière version de ces entités.

Enregistrez ce fichier sur l'ordinateur que vous utilisez pour créer le poste de travail administrateur.

Utiliser `govc` pour importer le fichier OVA dans vSphere et le marquer comme modèle de VM

Dans les sections suivantes, vous allez :

créer des variables déclarant les éléments de votre environnement vSphere et vCenter Server ;
importer l'OVA du poste de travail d'administrateur dans vSphere et le marquer comme modèle de VM.

Créer des variables pour `govc`

Avant d'importer le fichier OVA du poste de travail administrateur dans vSphere, vous devez fournir à govc certaines variables déclarant les éléments de votre environnement vSphere et vCenter Server.

export GOVC_URL=https://[VCENTER_SERVER_ADDRESS]/sdk
export GOVC_USERNAME=[VCENTER_SERVER_USERNAME]
export GOVC_PASSWORD=[VCENTER_SERVER_PASSWORD]
export GOVC_DATASTORE=[VSPHERE_DATASTORE]
export GOVC_DATACENTER=[VSPHERE_DATACENTER]
export GOVC_INSECURE=true

Vous pouvez choisir d'utiliser le pool de ressources par défaut de vSphere ou créer le vôtre :

# If you want to use a resource pool you've configured yourself, export this variable:
export GOVC_RESOURCE_POOL=[VSPHERE_CLUSTER]/Resources/[VSPHERE_RESOURCE_POOL]

# If you want to use vSphere's default resource pool, export this variable instead:
export GOVC_RESOURCE_POOL=[VSPHERE_CLUSTER]/Resources

où :

[VCENTER_SERVER_ADDRESS] est le nom d'hôte ou l'adresse IP de votre serveur vCenter ;
[VCENTER_SERVER_USERNAME] est le nom d'utilisateur d'un compte détenant le rôle d'administrateur ou des droits équivalents dans le serveur vCenter ;
[VCENTER_SERVER_PASSWORD] est le mot de passe du compte serveur vCenter ;
[VSPHERE_DATASTORE] est le nom du datastore que vous avez configuré dans votre environnement vSphere ;
[VSPHERE_DATACENTER] est le nom du centre de données que vous avez configuré dans votre environnement vSphere ;
[VSPHERE_CLUSTER] est le nom du cluster que vous avez configuré dans votre environnement vSphere.
[VSPHERE_RESOURCE_POOL] est le nom du pool de ressources que vous avez configuré dans votre environnement vSphere.

Importer le fichier OVA dans vSphere : commutateur standard

Si vous utilisez un commutateur standard vSphere, importez le fichier OVA dans vSphere à l'aide de la commande suivante :

govc import.ova -options - ~/gke-on-prem-admin-appliance-vsphere-1.1.2-gke.0.ova <<EOF
{
  "DiskProvisioning": "thin",
  "MarkAsTemplate": true
}
EOF

Importer le fichier OVA dans vSphere : commutateur distribué

Si vous utilisez un commutateur distribué vSphere, importez le fichier OVA dans vSphere à l'aide de cette commande, où [YOUR_DISTRIBUTED_PORT_GROUP_NAME] est le nom de votre groupe de ports distribué :

govc import.ova -options - ~/gke-on-prem-admin-appliance-vsphere-1.1.2-gke.0.ova <<EOF
{
  "DiskProvisioning": "thin",
  "MarkAsTemplate": true,
  "NetworkMapping": [
      {
          "Name": "VM Network",
          "Network": "[YOUR_DISTRIBUTED_PORT_GROUP_NAME]"
      }
  ]
}
EOF

Copier les fichiers de configuration Terraform

Créez un répertoire pour vos fichiers Terraform :
```
mkdir "[TERRAFORM_DIR]"
```
où [TERRAFORM_DIR] est le chemin d'accès au répertoire dans lequel vous souhaitez conserver vos fichiers Terraform.
Copiez l'une des configurations Terraform suivantes, selon que vous souhaitez spécifier une adresse IP statique pour votre poste de travail administrateur ou utiliser un serveur DHCP pour obtenir une adresse IP.

Assurez-vous de copier les deux fichiers TF et TFVARS. Le fichier TF est la configuration HCL de Terraform qui effectue la création de la VM.
Enregistrez les configurations dans [TERRAFORM_DIR]/terraform.tf et [TERRAFORM_DIR]/terraform.tfvars, respectivement.

DHCP

Cliquer sur la flèche d'affichage pour afficher les fichiers Terraform pour DHCP.

terraform.tfvars

# vCenter Server username
vcenter_user = "administrator@vsphere.local"

# vCenter Server password
vcenter_password = ""

# vCenter Server IP or hostname
vcenter_server = ""

# Path in which the admin workstation's VM's public key should be saved
ssh_public_key_path = "~/.ssh/vsphere_workstation.pub"

# Hostname for the VM
vm_name = "admin-workstation"

# vSphere datastore to use for storage
datastore = ""

# vSphere datacenter in which to create the VM
datacenter = ""

# vSphere cluster in which to create the VM
cluster = ""

# vSphere resource pool in which to create VM, if you are using a non-default resource pool
# If you are using the default resource pool, provide a value like "CLUSTER-NAME/Resources"
resource_pool = ""

# vSphere network to use for the VM
network = "VM Network"

# Number of CPUs for this VM. Recommended minimum 4.
num_cpus = 4

# Memory in MB for this VM. Recommended minimum 8192.
memory = 8192

# The VM template (OVA) to clone. Change the version if you imported a different version of the OVA.
vm_template = "gke-on-prem-admin-appliance-vsphere-1.1.2-gke.0"

terraform.tf

#########################
####### VARIABLES #######
#########################

# The following variables are declared in the accompanying TFVARS file

# vCenter Server username
variable "vcenter_user" { }

# vCenter Server password
variable "vcenter_password" { }

# vCenter Server address
variable "vcenter_server" { }

# Path in which the VM's public key should be saved
variable "ssh_public_key_path" { default = "~/.ssh/vsphere_workstation.pub" }

# vSphere network to use for the VM
variable "network" { default = "VM Network"}

# Hostname for the VM
variable "vm_name" { default = "vsphere-workstation" }

# vSphere datacenter in which to create the admin workstation VM
variable "datacenter" { }

# vSphere datastore to use for storage
variable "datastore" { }

# vSphere cluster in which to create the VM
variable "cluster" { }

# vSphere resource pool in which to create the VM
variable "resource_pool" { }

# Number of CPUs for this VM. Recommended minimum 4.
variable "num_cpus" { default = 4 }

# Memory in MB for this VM. Recommended minimum 8192.
variable "memory" { default = 8192 }

# The VM template (OVA) to clone
variable "vm_template" { }

##########################
##########################

provider "vsphere" {
  version        = "~> 1.5"
  user           = "${var.vcenter_user}"
  password       = "${var.vcenter_password}"
  vcenter_server = "${var.vcenter_server}"

  # if you have a self-signed cert
  allow_unverified_ssl = true
}

### vSphere Data ###

data "vsphere_datastore" "datastore" {
  name          = "${var.datastore}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_datacenter" "dc" {
  name = "${var.datacenter}"
}

data "vsphere_compute_cluster" "cluster" {
  name          = "${var.cluster}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_resource_pool" "pool" {
  name          = "${var.resource_pool}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_network" "network" {
  name          = "${var.network}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_virtual_machine" "template_from_ovf" {
  name          = "${var.vm_template}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "template_file" "dhcp_ip_config" {
  template = <<EOF
network:
  version: 2
  ethernets:
    ens192:
      dhcp4: true
EOF
}

data "template_file" "user_data" {
  template = <<EOF
#cloud-config
apt:
  primary:
    - arches: [default]
      uri: http://us-west1.gce.archive.ubuntu.com/ubuntu/
write_files:
  - path: /etc/netplan/99-dhcp.yaml
    permissions: '0644'
    encoding: base64
    content: |
      $${dhcp_ip_config}
runcmd:
  - netplan apply
  - /var/lib/gke/guest-startup.sh
EOF
  vars = {
    dhcp_ip_config = "${base64encode(data.template_file.dhcp_ip_config.rendered)}"

  }
}

### vSphere Resources ###

resource "vsphere_virtual_machine" "vm" {
  name             = "${var.vm_name}"
  resource_pool_id = "${data.vsphere_resource_pool.pool.id}"
  datastore_id     = "${data.vsphere_datastore.datastore.id}"
  num_cpus         = "${var.num_cpus}"
  memory           = "${var.memory}"
  guest_id         = "${data.vsphere_virtual_machine.template_from_ovf.guest_id}"
  enable_disk_uuid = "true"
  scsi_type = "${data.vsphere_virtual_machine.template_from_ovf.scsi_type}"
  network_interface {
    network_id   = "${data.vsphere_network.network.id}"
    adapter_type = "${data.vsphere_virtual_machine.template_from_ovf.network_interface_types[0]}"
  }

  wait_for_guest_net_timeout = 15

  nested_hv_enabled = false
  cpu_performance_counters_enabled = false

  disk {
    label            = "disk0"
    size             = "${max(50, data.vsphere_virtual_machine.template_from_ovf.disks.0.size)}"
    eagerly_scrub    = "${data.vsphere_virtual_machine.template_from_ovf.disks.0.eagerly_scrub}"
    thin_provisioned = "${data.vsphere_virtual_machine.template_from_ovf.disks.0.thin_provisioned}"
  }

  cdrom {
    client_device = true
  }

  vapp {
    properties = {
      hostname    = "${var.vm_name}"
      public-keys = "${file(var.ssh_public_key_path)}"
      user-data   = "${base64encode(data.template_file.user_data.rendered)}"
    }
  }

  clone {
    template_uuid = "${data.vsphere_virtual_machine.template_from_ovf.id}"
  }
}

output "ip_address" {
  value = "${vsphere_virtual_machine.vm.default_ip_address}"
}

Adresse IP statique

Cliquer sur la flèche d'affichage pour afficher les fichiers Terraform des adresses IP statiques

terraform.tfvars

# vCenter Server username
vcenter_user = "administrator@vsphere.local"

# vCenter Server password
vcenter_password = ""

# vCenter Server IP or hostname
vcenter_server = ""

# Path in which the admin workstation's VM's public key should be saved
ssh_public_key_path = "~/.ssh/vsphere_workstation.pub"

# Hostname for the VM
vm_name = "admin-workstation"

# vSphere datastore to use for storage
datastore = ""

# vSphere datacenter in which to create the VM
datacenter = ""

# vSphere cluster in which to create the VM
cluster = ""

# vSphere resource pool in which to create VM, if you are using a non-default resource pool
# If you are using the default resource pool, provide a value like "CLUSTER-NAME/Resources"
resource_pool = ""

# vSphere network to use for the VM
network = "VM Network"

# Number of CPUs for this VM. Recommended minimum 4.
num_cpus = 4

# Memory in MB for this VM. Recommended minimum 8192.
memory = 8192

# The VM template (OVA) to clone. Change the version if you imported a different version of the OVA.
vm_template = "gke-on-prem-admin-appliance-vsphere-1.1.2-gke.0"

################################################
# Static IP settings                           #
################################################

# An IPv4 static IP for the admin workstataion; for example, 100.115.250.100
ipv4_address = "100.115.250.100"

# The netmask prefix length to use; for example, 22
ipv4_netmask_prefix_length = "22"

# The IPv4 gateway the admin workstation should use; for example, 100.115.251.254
ipv4_gateway = "100.115.251.254"

# Comma-delimited DNS servers
dns_nameservers = "8.8.8.8,8.8.4.4"

terraform.tf

#########################
####### VARIABLES #######
#########################

# The following variables are declared in the accompanying TFVARS file

# vCenter Server username
variable "vcenter_user" { }

# vCenter Server password
variable "vcenter_password" { }

# vCenter Server address
variable "vcenter_server" { }

# Path in which the VM's public key should be saved
variable "ssh_public_key_path" { default = "~/.ssh/vsphere_workstation.pub" }

# vSphere network to use for the VM
variable "network" { default = "VM Network"}

# Hostname for the VM
variable "vm_name" { default = "vsphere-workstation" }

# vSphere datacenter in which to create the admin workstation VM
variable "datacenter" { }

# vSphere datastore to use for storage
variable "datastore" { }

# vSphere cluster in which to create the VM
variable "cluster" { }

# vSphere resource pool in which to create the VM
variable "resource_pool" { }

# Number of CPUs for this VM. Recommended minimum 4.
variable "num_cpus" { default = 4 }

# Memory in MB for this VM. Recommended minimum 8192.
variable "memory" { default = 8192 }

# The VM template (OVA) to clone
variable "vm_template" { }

# The IP address to assign to the VM
variable "ipv4_address" { }

# Netmask prefix length
variable "ipv4_netmask_prefix_length" { }

# Default gateway to use
variable "ipv4_gateway" { }

# DNS resolvers to use
variable "dns_nameservers" { }

##########################
##########################

provider "vsphere" {
  version        = "~> 1.5"
  user           = "${var.vcenter_user}"
  password       = "${var.vcenter_password}"
  vcenter_server = "${var.vcenter_server}"

  # if you have a self-signed cert
  allow_unverified_ssl = true
}

### vSphere Data ###

data "vsphere_datastore" "datastore" {
  name          = "${var.datastore}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_datacenter" "dc" {
  name = "${var.datacenter}"
}

data "vsphere_compute_cluster" "cluster" {
  name          = "${var.cluster}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_resource_pool" "pool" {
  name          = "${var.resource_pool}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_network" "network" {
  name          = "${var.network}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

data "vsphere_virtual_machine" "template_from_ovf" {
  name          = "${var.vm_template}"
  datacenter_id = "${data.vsphere_datacenter.dc.id}"
}

##########################
### IF USING STATIC IP ###
##########################
data "template_file" "static_ip_config" {
  template = <<EOF
network:
  version: 2
  ethernets:
    ens192:
      dhcp4: no
      dhcp6: no
      addresses: ["${var.ipv4_address}/${var.ipv4_netmask_prefix_length}"]
      gateway4: ${var.ipv4_gateway}
      nameservers:
        addresses: [${var.dns_nameservers}]
EOF
}

data "template_file" "user_data" {
  template = <<EOF
#cloud-config
apt:
  primary:
    - arches: [default]
      uri: http://us-west1.gce.archive.ubuntu.com/ubuntu/
write_files:
  - path: /tmp/static-ip.yaml
    permissions: '0644'
    encoding: base64
    content: |
      $${static_ip_config}
runcmd:
  - /var/lib/gke/guest-startup.sh
EOF
  vars = {
    static_ip_config = "${base64encode(data.template_file.static_ip_config.rendered)}"

  }
}
##########################
### IF USING STATIC IP ###
##########################

### vSphere Resources ###

resource "vsphere_virtual_machine" "vm" {
  name             = "${var.vm_name}"
  resource_pool_id = "${data.vsphere_resource_pool.pool.id}"
  datastore_id     = "${data.vsphere_datastore.datastore.id}"
  num_cpus         = "${var.num_cpus}"
  memory           = "${var.memory}"
  guest_id         = "${data.vsphere_virtual_machine.template_from_ovf.guest_id}"
  enable_disk_uuid = "true"
  scsi_type = "${data.vsphere_virtual_machine.template_from_ovf.scsi_type}"
  network_interface {
    network_id   = "${data.vsphere_network.network.id}"
    adapter_type = "${data.vsphere_virtual_machine.template_from_ovf.network_interface_types[0]}"
  }

  wait_for_guest_net_timeout = 15

  nested_hv_enabled = false
  cpu_performance_counters_enabled = false

  disk {
    label            = "disk0"
    size             = "${max(50, data.vsphere_virtual_machine.template_from_ovf.disks.0.size)}"
    eagerly_scrub    = "${data.vsphere_virtual_machine.template_from_ovf.disks.0.eagerly_scrub}"
    thin_provisioned = "${data.vsphere_virtual_machine.template_from_ovf.disks.0.thin_provisioned}"
  }

  cdrom {
    client_device = true
  }

  vapp {
    properties = {
      hostname    = "${var.vm_name}"
      public-keys = "${file(var.ssh_public_key_path)}"
      user-data   = "${base64encode(data.template_file.user_data.rendered)}"
    }
  }

  clone {
    template_uuid = "${data.vsphere_virtual_machine.template_from_ovf.id}"
  }
}

output "ip_address" {
  value = "${vsphere_virtual_machine.vm.default_ip_address}"
}

Créer une clé publique SSH

Créez une clé publique SSH pour pouvoir vous connecter en SSH au poste de travail administrateur à partir de votre ordinateur portable ou de votre poste de travail local. Sur les systèmes d'exploitation Linux, vous pouvez utiliser ssh-keygen :

ssh-keygen -t rsa -f ~/.ssh/vsphere_workstation -N ""

Modifier le fichier TFVARS

Ouvrez terraform.tfvars dans un éditeur de texte et fournissez des valeurs pour les variables suivantes. Vous pouvez trouver un grand nombre de ces valeurs en vous connectant au client vCenter :

`vcenter_user`

Fournissez un compte utilisateur de serveur vCenter sous forme de chaîne. Le compte utilisateur doit disposer du rôle d'administrateur ou de droits équivalents (consultez la section Configuration système requise). Exemple :

vcenter_user = "administrator@vsphere.local"

`vcenter_password`

Indiquez le mot de passe du compte utilisateur de serveur vCenter sous forme de chaîne. Exemple :

vcenter_password = "#STyZ2T#Ko2o"

`vcenter_server`

Indiquez l'adresse (IP ou nom d'hôte) de votre serveur vCenter sous forme de chaîne. Exemple :

vcenter_server = "198.51.100.0"

`ssh_public_key_path`

Indiquez le chemin d'accès à la clé publique SSH Vous avez créé ceci à une étape précédente :

ssh_public_key_path = "~/.ssh/vsphere_workstation.pub"

`vm_name`

Indiquez le nom de votre choix pour le poste de travail administrateur :

vm_name = "admin-workstation"

`datastore`

Indiquez le nom de votre datastore vSphere en tant que chaîne :

datastore = "MY-DATASTORE"

`datacenter`

Indiquez le nom de votre centre de données vSphere sous forme de chaîne :

datacenter = "MY-DATACENTER"

`cluster`

Indiquez le nom de votre cluster vSphere sous forme de chaîne :

cluster = "MY-CLUSTER"

`resource_pool`

Si vous utilisez un pool de ressources autre que celui par défaut, indiquez le nom de votre pool de ressources vSphere en tant que chaîne :

resource_pool = "MY-POOL"

Si vous utilisez le pool de ressources par défaut, indiquez la valeur suivante :

resource_pool = "MY-CLUSTER/Resources"

Consultez la section Spécifier le pool de ressources racine pour un hôte autonome.

`network`

Indiquez sous forme de chaîne le réseau vSphere sur lequel vous souhaitez créer votre poste de travail d'administrateur. Exemple :

network = "VM Network"

`vm_template`

Indiquez le nom du modèle de VM sous forme de chaîne. Vous avez créé/importé le fichier OVA et l'avez marqué comme modèle lors d'une étape précédente :

vm_template = "gke-on-prem-admin-appliance-vsphere-[VERSION]"

Utiliser une adresse IP statique pour votre poste de travail administrateur

Si vous souhaitez utiliser une adresse IP statique pour votre poste de travail administrateur, copiez le fichier TF de l'adresse IP statique et le fichier TFVARS. Dans le fichier TFVARS, saisissez les valeurs des variables suivantes :

`ipv4_address`

Indiquez une adresse IP statique IPv4 pour le poste de travail administrateur. Exemple :

ipv4_address = "203.0.113.0"

`ipv4_netmask_prefix_length`

Indiquez le nombre de bits dans le masque de sous-réseau du réseau sur lequel vous souhaitez créer votre poste de travail administrateur. Exemple :

ipv4_netmask_prefix_length = "22"

`ipv4_gateway`

Indiquez la passerelle du sous-réseau dans lequel le poste de travail administrateur doit être créé. Consultez la documentation vsphere_virtual_machine de VMware.

Exemple :

ipv4_gateway = "198.51.100.0

`dns_nameservers`

Fournissez des serveurs de noms DNS à utiliser par le poste de travail administrateur, séparés par des virgules. Exemple :

dns_nameservers = "8.8.8.8,8.8.4.4"

Créer le poste de travail administrateur

Une fois les étapes précédentes effectuées, vous êtes prêt à créer la VM du poste de travail administrateur :

Accédez au répertoire contenant vos fichiers de configuration Terraform (TF et TFVARS) :
```
cd [TERRAFORM_DIR]
```
Initialisez Terraform dans le répertoire et appliquez la configuration. Cela peut prendre quelques minutes.
```
terraform init && terraform apply -auto-approve -input=false
```
Remarque : Le nom du fichier TFVARS doit être terraform.tfvars. Sinon, vous devez transmettre le paramètre --var-file et spécifier le fichier TFVARS.

Se connecter en SSH au poste de travail administrateur

Accédez au répertoire contenant vos fichiers de configuration Terraform.
Récupérez l'adresse IP du poste de travail administrateur :
```
terraform output ip_address
```
Prenez note de l'adresse IP du poste de travail administrateur ou exportez-la sous forme de variable dans votre interface système.
Connectez-vous en SSH au poste de travail administrateur à l'aide de la clé et de l'adresse IP générées :
```
ssh -i ~/.ssh/vsphere_workstation ubuntu@$(terraform output ip_address)
```
Ou, si vous souhaitez simplement utiliser son adresse :
```
ssh -i ~/.ssh/vsphere_workstation ubuntu@[IP_ADDRESS]
```

Vérifier la bonne configuration du poste de travail administrateur

Vérifiez que gkectl et docker sont installés :

gkectl version
docker version

Configurer le proxy pour votre poste de travail administrateur

Si votre environnement est protégé par un proxy, suivez les sections ci-dessous pour configurer Google Cloud CLI et Docker pour utiliser votre proxy.

Configurer Google Cloud CLI pour utiliser votre proxy

Procédez comme suit à partir de la VM du poste de travail administrateur.

Si vous utilisez un proxy pour vous connecter à Internet depuis votre ordinateur portable ou votre poste de travail, vous devez configurer les paramètres du proxy dans Google Cloud CLI, afin de pouvoir exécuter les commandes gcloud et gsutil. Pour obtenir des instructions, consultez la page Configurer gcloud CLI pour une utilisation derrière un proxy/pare-feu.

Configurer un registre Docker pour extraire votre proxy

Procédez comme suit à partir de la VM du poste de travail administrateur.

Si vous souhaitez utiliser un registre Docker et que votre réseau s'exécute derrière un proxy, vous devez configurer le daemon Docker qui s'exécute sur votre poste de travail administrateur pour extraire des images via votre proxy :

Rassemblez les adresses de vos proxys HTTP et HTTPS.
Rassemblez les adresses IP et les noms d'hôte de chaque hôte que vous devez contacter sans proxy, y compris :
- Adresse IP du serveur vCenter.
- Adresses IP de tous les hôtes ESXi.
- Adresses IP que vous souhaitez configurer sur votre équilibreur de charge.
- La plage 192.168.0.0/16.
Dans votre poste de travail administrateur, ajoutez les adresses suivantes à la variable no_proxy :
```
printf -v no_proxy '%s,' [ADDRESSES];
```
Vous pouvez éventuellement exporter la plage vers une variable d'environnement pour référence ultérieure. Gardez à l'esprit que les applications et les processus peuvent utiliser cette variable :
```
export no_proxy="${no_proxy%,}";
```
Ouvrez le fichier de configuration de Docker, stocké dans /root/.docker/config.json, /home/[USER]/.docker/config.json ou ailleurs, en fonction de votre configuration.
Dans le fichier config.json, ajoutez les lignes suivantes :
```
"proxies": {

"default": {
       "httpProxy": "[HTTP_PROXY]",
       "httpsProxy": "[HTTPS_PROXY]",
       "noProxy": "[ADDRESSES]"
           }
}
```
où :
- [HTTP_PROXY] est votre proxy HTTP, si vous en avez un.
- [HTTPS_PROXY] est votre proxy HTTPS, si vous en avez un.
- [ADDRESSES] est une liste d'adresses et de noms d'hôtes séparés par des virgules que vous devez contacter sans proxy.
Redémarrez Docker pour que les modifications prennent effet :
```
sudo systemctl restart docker
```

Dépannage

Pour en savoir plus, consultez Dépannage.

Limite de session du fournisseur vSphere Terraform

GKE On-Prem utilise le fournisseur vSphere de Terraform pour afficher les VM dans votre environnement vSphere. La limite de session du fournisseur est de 1 000 sessions. La mise en œuvre actuelle ne ferme pas les sessions actives après utilisation. Vous pouvez rencontrer des erreurs 503 si trop de sessions sont en cours d'exécution.

Les sessions sont automatiquement fermées après 300 secondes.

Symptômes

Si trop de sessions sont en cours d'exécution, vous pouvez rencontrer l'erreur suivante :

Error connecting to CIS REST endpoint: Login failed: body:
  {"type":"com.vmware.vapi.std.errors.service_unavailable","value":
  {"messages":[{"args":["1000","1000"],"default_message":"Sessions count is
  limited to 1000. Existing sessions are 1000.",
  "id":"com.vmware.vapi.endpoint.failedToLoginMaxSessionCountReached"}]}},
  status: 503 Service Unavailable

Causes probables

Trop de sessions de fournisseur Terraform s'exécutent dans votre environnement.

Solution

Actuellement, cela fonctionne comme prévu. Les sessions sont automatiquement fermées après 300 secondes. Pour en savoir plus, reportez-vous au problème GitHub #618.

Utiliser un proxy pour Docker : `oauth2: cannot fetch token`

Symptômes

Lorsque vous utilisez un proxy, vous rencontrez l'erreur suivante :

oauth2: cannot fetch token: Post https://oauth2.googleapis.com/token: proxyconnect tcp: tls: oversized record received with length 20527

Causes probables

Vous avez peut-être fourni un proxy HTTPS au lieu d'un proxy HTTP.

Solution

Dans votre configuration Docker, définissez l'adresse du proxy sur http:// au lieu de https://.

Vérifier la validité des licences

N'oubliez pas de vérifier que vos licences sont valides, en particulier si vous utilisez des licences d'essai. Des échecs inattendus peuvent se produire si vos licences F5, vos licences vCenter ou vos licences d'hôte ESXi sont arrivées à expiration.

`openssl` ne peut pas valider le fichier OVA du poste de travail administrateur.

Symptômes: L'exécution de openssl dgst sur le fichier OVA du poste de travail administrateur ne renvoie pas Verified OK.
Causes probables: Le fichier OVA comporte un problème qui empêche la validation.
Solution: Essayez à nouveau de télécharger et de déployer le fichier OVA du poste de travail administrateur, comme indiqué dans la section Télécharger le fichier OVA du poste de travail administrateur. Si le problème persiste, contactez Google pour obtenir de l'aide.

Créer un poste de travail administrateur

Présentation

Avant de commencer

Télécharger le fichier OVA du poste de travail administrateur

Utiliser govc pour importer le fichier OVA dans vSphere et le marquer comme modèle de VM

Créer des variables pour govc

Importer le fichier OVA dans vSphere : commutateur standard

Importer le fichier OVA dans vSphere : commutateur distribué

Copier les fichiers de configuration Terraform

DHCP

Cliquer sur la flèche d'affichage pour afficher les fichiers Terraform pour DHCP.

terraform.tfvars

terraform.tf

Adresse IP statique

Cliquer sur la flèche d'affichage pour afficher les fichiers Terraform des adresses IP statiques

terraform.tfvars

terraform.tf

Créer une clé publique SSH

Modifier le fichier TFVARS

vcenter_user

vcenter_password

vcenter_server

ssh_public_key_path

vm_name

datastore

datacenter

cluster

resource_pool

network

vm_template

Utiliser une adresse IP statique pour votre poste de travail administrateur

ipv4_address

ipv4_netmask_prefix_length

ipv4_gateway

dns_nameservers

Créer le poste de travail administrateur

Se connecter en SSH au poste de travail administrateur

Vérifier la bonne configuration du poste de travail administrateur

Configurer le proxy pour votre poste de travail administrateur

Configurer Google Cloud CLI pour utiliser votre proxy

Configurer un registre Docker pour extraire votre proxy

Dépannage

Limite de session du fournisseur vSphere Terraform

Utiliser un proxy pour Docker : oauth2: cannot fetch token

Vérifier la validité des licences

openssl ne peut pas valider le fichier OVA du poste de travail administrateur.

Étapes suivantes

Utiliser `govc` pour importer le fichier OVA dans vSphere et le marquer comme modèle de VM

Créer des variables pour `govc`

`vcenter_user`

`vcenter_password`

`vcenter_server`

`ssh_public_key_path`

`vm_name`

`datastore`

`datacenter`

`cluster`

`resource_pool`

`network`

`vm_template`

`ipv4_address`

`ipv4_netmask_prefix_length`

`ipv4_gateway`

`dns_nameservers`

Utiliser un proxy pour Docker : `oauth2: cannot fetch token`

`openssl` ne peut pas valider le fichier OVA du poste de travail administrateur.